dh_installdocs

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_installdocs - install documentation into package build directories
   6
   7 =cut
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11
  12 =head1 SYNOPSIS
  13
  14 B<dh_installdocs> [S<I<debhelper options>>] [B<-A>] [B<-n>] [B<-X>I<item>] [S<I<file ...>>]
  15
  16 =head1 DESCRIPTION
  17
  18 dh_installdocs is a debhelper program that is responsible for installing
  19 documentation into usr/share/doc/package in package build directories.
  20
  21 dh_installdocs automatically installs debian/copyright if it exists. If
  22 dh_installdocs is acting on multiple packages, debian/copyright files will be
  23 installed into all packages. However, if you need to have separate copyright
  24 files for different binary packages, you can use files named
  25 debian/package.copyright.
  26
  27 Any filenames specified as parameters will be installed into the first
  28 package dh_installdocs is told to act on. By default, this is the first
  29 binary package in debian/control, but if you use B<-p>, B<-i>, or B<-a> flags, it
  30 will be the first package specified by those flags.
  31
  32 Also, debian/README.Debian (or debian/README.debian) and debian/TODO, if
  33 they exist, will be installed into the first binary package listed in
  34 debian/control, if dh_installdocs is acting on that package. Note that
  35 debian/TODO will be installed named TODO.Debian, if the package is not a
  36 debian native package. Also note that README.debian is installed as
  37 README.Debian, for consistency. Note that debian/package.README.Debian and
  38 debian/package.TODO can be used to specify files for subpackages.
  39
  40 Files named debian/package.docs can list other files to be installed.
  41
  42 Files named debian/package.doc-base, will be installed as doc-base control
  43 files, and will make this program automatically generate the postinst and
  44 prerm commands needed to interface with the doc-base package. Note that the
  45 doc-id will be determined from the "Document:" entry in the
  46 doc-base control file in question.
  47
  48 If your package needs to register more than one document, you need multiple
  49 files. To accomplish this, you can use files named debian/package.doc-base.*
  50
  51 =head1 OPTIONS
  52
  53 =over 4
  54
  55 =item B<-A>, B<--all>
  56
  57 Install all files specified by command line parameters in ALL packages
  58 acted on.
  59
  60 =item B<-n>, B<--noscripts>
  61
  62 Do not modify postinst/prerm scripts.
  63
  64 =item B<-Xitem>, B<--exclude=item>
  65
  66 Exclude files that contain "item" anywhere in their filename from
  67 being installed.
  68
  69 =item I<file ...>
  70
  71 Install these files as documentation into the first package acted on. (Or
  72 in all packages if B<-A> is specified).
  73
  74 =back
  75
  76 =head1 EXAMPLES
  77
  78 This is an example of a debian/package.docs file:
  79
  80   README
  81   TODO
  82   debian/notes-for-maintainers.txt
  83   docs/manual.txt
  84   docs/manual.pdf
  85   docs/manual-html/
  86
  87 =head1 NOTES
  88
  89 Note that dh_installdocs will happily copy entire directory hierarchies if
  90 you ask it to (similar to cp -a). If it is asked to install a
  91 directory, it will install the complete contents of the directory.
  92
  93 Note that this command is not idempotent. "dh_clean B<-k>" should be called
  94 between invocations of this command. Otherwise, it may cause multiple
  95 instances of the same text to be added to maintainer scripts.
  96
  97 =cut
  98
  99 init();
 100
 101 foreach my $package (@{$dh{DOPACKAGES}}) {
 102         next if is_udeb($package);
 103
 104         my $tmp=tmpdir($package);
 105         my $file=pkgfile($package,"docs");
 106
 107         # If this is a symlink, leave it alone.
 108         if ( ! -d "$tmp/usr/share/doc/$package" &&
 109              ! -l "$tmp/usr/share/doc/$package") {
 110                 doit("install","-g",0,"-o",0,"-d","$tmp/usr/share/doc/$package");
 111         }
 112
 113         my @docs;
 114
 115         if ($file) {
 116                 @docs=filearray($file, ".");
 117         }
 118
 119         if (($package eq $dh{FIRSTPACKAGE} || $dh{PARAMS_ALL}) && @ARGV) {
 120                 push @docs, @ARGV;
 121         }
 122
 123         if (@docs) {
 124                 my $exclude = '';
 125                 if ($dh{EXCLUDE_FIND}) {
 126                         $exclude = ' -and ! \( '.$dh{EXCLUDE_FIND}.' \)';
 127                 }
 128                 foreach my $doc (@docs) {
 129                         next if excludefile($doc);
 130                         next if ! -s $doc && ! compat(4); # ignore empty BUGS, etc
 131                         if (-d $doc && $exclude) {
 132                             my ($dir_basename) = basename($doc);
 133                             # Pity there's no cp --exclude ..
 134                             my $pwd=`pwd`;
 135                             chomp $pwd;
 136                             complex_doit("cd $doc/.. && find $dir_basename \\( -type f or -type l \\)$exclude -exec cp --parents -dp {} $pwd/$tmp/usr/share/doc/$package \\;");
 137                         }
 138                         else {
 139                                 doit("cp","-a",$doc,"$tmp/usr/share/doc/$package");
 140                         }
 141                 }
 142                 doit("chown","-R","0:0","$tmp/usr/share/doc");
 143                 doit("chmod","-R","go=rX","$tmp/usr/share/doc");
 144                 doit("chmod","-R","u+rw","$tmp/usr/share/doc");
 145         }
 146
 147         # .Debian is correct, according to policy, but I'm easy.
 148         my $readme_debian=pkgfile($package,'README.Debian');
 149         if (! $readme_debian) {
 150                 $readme_debian=pkgfile($package,'README.debian');
 151         }
 152         if ($readme_debian && ! excludefile($readme_debian)) {
 153                 doit("install","-g",0,"-o",0,"-m","644","-p","$readme_debian",
 154                         "$tmp/usr/share/doc/$package/README.Debian");
 155         }
 156
 157         my $todo=pkgfile($package,'TODO');
 158         if ($todo && ! excludefile($todo)) {
 159                 if (isnative($package)) {
 160                         doit("install","-g",0,"-o",0,"-m","644","-p",$todo,
 161                                 "$tmp/usr/share/doc/$package/TODO");
 162                 }
 163                 else {
 164                         doit("install","-g",0,"-o",0,"-m","644","-p",$todo,
 165                                 "$tmp/usr/share/doc/$package/TODO.Debian");
 166                 }
 167         }
 168
 169         # If the "directory" is a dangling symlink, then don't install
 170         # the copyright file. This is useful for multibinary packages
 171         # that share a doc directory.
 172         if (-d "$tmp/usr/share/doc/$package") {
 173                 # Support debian/package.copyright, but if not present, fall
 174                 # back on debian/copyright for all packages, not just the
 175                 # main binary package.
 176                 my $copyright=pkgfile($package,'copyright');
 177                 if (! $copyright && -e "debian/copyright") {
 178                         $copyright="debian/copyright";
 179                 }
 180                 if ($copyright && ! excludefile($copyright)) {
 181                                 doit("install","-g",0,"-o",0,"-m","644","-p",$copyright,
 182                                         "$tmp/usr/share/doc/$package/copyright");
 183                 }
 184         }
 185
 186         # Handle doc-base files. There are two filename formats, the usual
 187         # plus an extended format (debian/package.*).
 188         my %doc_ids;
 189
 190         opendir(DEB,"debian/") || error("can't read debian directory: $!");
 191         # If this is the main package, we need to handle unprefixed filenames.
 192         # For all packages, we must support both the usual filename format plus
 193         # that format with a period an something appended.
 194         my $regexp="\Q$package\E\.";
 195         if ($package eq $dh{MAINPACKAGE}) {
 196                 $regexp="(|$regexp)";
 197         }
 198         foreach my $fn (grep {/^${regexp}doc-base(\..*)?$/} readdir(DEB)) {
 199                 # .EX are example files, generated by eg, dh-make
 200                 next if $fn=~/\.EX$/;
 201                 # Parse the file to get the doc id.
 202                 open (IN, "debian/$fn") || die "Cannot read debian/$fn.";
 203                 while (<IN>) {
 204                         if (/^Document:\s+(.*)(\s+)?/) {
 205                                 $doc_ids{$fn}=$1;
 206                                 last;
 207                         }
 208                 }
 209                 close IN;
 210         }
 211         closedir(DEB);
 212
 213         if (%doc_ids) {
 214                 if (! -d "$tmp/usr/share/doc-base/") {
 215                         doit("install","-g",0,"-o",0,"-d","$tmp/usr/share/doc-base/");
 216                 }
 217         }
 218         foreach my $fn (keys %doc_ids) {
 219                 doit("install","-g",0,"-o",0,"-m644","-p","debian/$fn",
 220                      "$tmp/usr/share/doc-base/$doc_ids{$fn}");
 221                 if (! $dh{NOSCRIPTS}) {
 222                         autoscript($package,"postinst","postinst-doc-base",
 223                                 "s/#DOC-ID#/$doc_ids{$fn}/",
 224                         );
 225                         autoscript($package,"prerm","prerm-doc-base",
 226                                 "s/#DOC-ID#/$doc_ids{$fn}/",
 227                         );
 228                 }
 229         }
 230 }
 231
 232 =head1 SEE ALSO
 233
 234 L<debhelper(7)>
 235
 236 This program is a part of debhelper.
 237
 238 =head1 AUTHOR
 239
 240 Joey Hess <joeyh@debian.org>
 241
 242 =cut