dh_installdeb

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_installdeb - install files into the DEBIAN directory
   6
   7 =cut
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11
  12 =head1 SYNOPSIS
  13
  14 B<dh_installdeb> [S<I<debhelper options>>]
  15
  16 =head1 DESCRIPTION
  17
  18 dh_installdeb is a debhelper program that is responsible for installing
  19 files into the DEBIAN directories in package build directories with the
  20 correct permissions.
  21
  22 dh_installdeb automatically installs the following files from debian/ into
  23 the DEBIAN directory:
  24   package.postinst
  25   package.preinst
  26   package.postrm
  27   package.prerm
  28   package.shlibs
  29   package.conffiles
  30
  31 The postinst, preinst, postrm, and prerm are handled specially: If a
  32 corresponding file named debian/package.script.debhelper exists, the contents
  33 of that file are merged into the script as follows: If the script exists,
  34 then anywhere in it that "#DEBHELPER#" appears, the text of the .debhelper
  35 file is inserted. If the script does not exist, then a script is generated
  36 from the .debhelper file. The .debhelper files are created by other debhelper
  37 programs, such as L<dh_installmenu(1)>, and are shell script fragments.
  38
  39 In V3 compatibility mode and higher, all files in the etc/ directory in a
  40 package will automatically be flagged as conffiles by this program, so
  41 there is no need to list them manually in package.conffiles.
  42
  43 =cut
  44
  45 init();
  46
  47 foreach my $package (@{$dh{DOPACKAGES}}) {
  48         my $tmp=tmpdir($package);
  49         my $ext=pkgext($package);
  50
  51         if (! -d "$tmp/DEBIAN") {
  52                 doit("install","-o",0,"-g",0,"-d","$tmp/DEBIAN");
  53         }
  54
  55         if (is_udeb($package)) {
  56                 # For udebs, only do the postinst, and no #DEBHELPER#.
  57                 my $f=pkgfile($package,"postinst");
  58                 if ($f) {
  59                         doit("install", "-o", 0, "-g", 0, "-m", 755,
  60                              $f, "$tmp/DEBIAN/postinst");
  61                 }
  62                 next;
  63         }
  64
  65         # Install debian install scripts.
  66         # If any .debhelper files exist, add them into the scripts.
  67         foreach my $file (qw{postinst preinst prerm postrm}) {
  68                 my $f=pkgfile($package,$file);
  69                 if ($f) {
  70                         if (-f "debian/$ext$file.debhelper") {
  71                                 # Add this into the script, where it has
  72                                 # #DEBHELPER#
  73                                 complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$file.debhelper}~eg' < $f > $tmp/DEBIAN/$file");
  74                         }
  75                         else {
  76                                 # Just get rid of any #DEBHELPER# in the
  77                                 # script.
  78                                 complex_doit("sed s/#DEBHELPER#// < $f > $tmp/DEBIAN/$file");
  79                         }
  80                         doit("chown","0:0","$tmp/DEBIAN/$file");
  81                         doit("chmod",755,"$tmp/DEBIAN/$file");
  82                 }
  83                 else {
  84                         # Auto-generate script header and add .debhelper
  85                         # content to it.
  86                         if (-f "debian/$ext$file.debhelper") {
  87                                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$file");
  88                                 complex_doit("cat debian/$ext$file.debhelper >> $tmp/DEBIAN/$file");
  89                                 doit("chown","0:0","$tmp/DEBIAN/$file");
  90                                 doit("chmod",755,"$tmp/DEBIAN/$file");
  91                         }
  92                 }
  93         }
  94
  95         # Install non-executable files
  96         foreach my $file (qw{shlibs conffiles}) {
  97                 my $f=pkgfile($package,$file);
  98                 if ($f) {
  99                         doit("install","-o",0,"-g",0,"-m",644,"-p",$f,"$tmp/DEBIAN/$file");
 100                 }
 101         }
 102
 103         # Automatic conffiles registration: If it is in /etc, it is a
 104         # conffile.
 105         if (! compat(2) && -d "$tmp/etc") {
 106                 complex_doit("find $tmp/etc -type f -printf '/etc/%P\n' >> $tmp/DEBIAN/conffiles");
 107                 # Anything found?
 108                 if (-z "$tmp/DEBIAN/conffiles") {
 109                         doit("rm", "-f", "$tmp/DEBIAN/conffiles");
 110                 }
 111                 else {
 112                         doit("chmod", 644, "$tmp/DEBIAN/conffiles");
 113                 }
 114         }
 115 }
 116
 117 =head1 SEE ALSO
 118
 119 L<debhelper(7)>
 120
 121 This program is a part of debhelper.
 122
 123 =head1 AUTHOR
 124
 125 Joey Hess <joeyh@debian.org>
 126
 127 =cut