dh_installchangelogs

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_installchangelogs - install changelogs into package build directories
   6
   7 =cut
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11
  12 =head1 SYNOPSIS
  13
  14 B<dh_installchangelogs> [S<I<debhelper options>>] [B<-k>] [I<upstream>]
  15
  16 =head1 DESCRIPTION
  17
  18 dh_installchangelogs is a debhelper program that is responsible for
  19 installing changelogs into package build directories.
  20
  21 dh_installchangelogs determines if the package is a debian native package,
  22 and if so, it installs debian/changelog into usr/share/doc/package/changelog
  23 in the package build directory. Otherwise, it installs debian/changelog
  24 into usr/share/doc/package/changelog.Debian in the package build directory. (If
  25 files named debian/package.changelog exist, they will be used in preference
  26 to debian/changelog.)
  27
  28 Parallelling the debian changelog handling, this program also takes care of
  29 NEWS.Debian files. If there is a debian/NEWS file, it is installed as
  30 usr/share/doc/package/NEWS.Debian. debian/package.NEWS files can also be
  31 used.
  32
  33 An upstream changelog file may be specified as an option. If none is
  34 specified, a few common filenames are tried. (In compatability level 7 and
  35 above.)
  36
  37 If there is an upstream changelog file, it will be be installed as
  38 usr/share/doc/package/changelog in the package build directory. If the
  39 changelog is a html file (determined by file extension), it will be
  40 installed as usr/share/doc/package/changelog.html instead, and will be
  41 converted to plain text with html2text to generate
  42 usr/share/doc/package/changelog.
  43
  44 =head1 OPTIONS
  45
  46 =over 4
  47
  48 =item B<-k>, B<--keep>
  49
  50 Keep the original name of the upstream changelog. This will be accomplished
  51 by installing the upstream changelog as "changelog", and making a symlink from
  52 that to the original name of the changelog file. This can be useful if the
  53 upstream changelog has an unusual name, or if other documentation in the
  54 package refers to the changelog file.
  55
  56 =item I<upstream>
  57
  58 Install this file as the upstream changelog.
  59
  60 =back
  61
  62 =cut
  63
  64 init();
  65
  66 my $upstream=shift;
  67 my $changelog_name="changelog.Debian";
  68 if (! defined $upstream) {
  69         if (! isnative($dh{MAINPACKAGE}) && !compat(6)) {
  70                 foreach my $name (qw{ChangeLog Changelog Changes CHANGES changelog}) {
  71                         if (-e $name) {
  72                                 $upstream=$name;
  73                                 last;
  74                         }
  75                 }
  76         }
  77         if (isnative($dh{MAINPACKAGE})) {
  78                 $changelog_name='changelog';
  79         }
  80 }
  81 my $news_name="NEWS.Debian";
  82
  83 foreach my $package (@{$dh{DOPACKAGES}}) {
  84         next if is_udeb($package);
  85
  86         my $tmp=tmpdir($package);
  87         my $changelog=pkgfile($package,"changelog");
  88         my $news=pkgfile($package,"NEWS");
  89
  90         if (!$changelog) {
  91                 $changelog="debian/changelog";
  92         }
  93         if (!$news) {
  94                 $news="debian/NEWS";
  95         }
  96
  97         if (! -e $changelog) {
  98                 error("could not find changelog $changelog");
  99         }
 100
 101         if (! -d "$tmp/usr/share/doc/$package") {
 102                 # If it is a dangling symlink, then don't do anything.
 103                 # Think multi-binary packages that depend on each other and
 104                 # want to link doc dirs.
 105                 next if -l "$tmp/usr/share/doc/$package";
 106
 107                 doit("install","-d","$tmp/usr/share/doc/$package");
 108         }
 109         doit("install","-o",0,"-g",0,"-p","-m644",$changelog,
 110                 "$tmp/usr/share/doc/$package/$changelog_name");
 111         if (-e $news) {
 112                 doit("install","-o",0,"-g",0,"-p","-m644",$news,
 113                         "$tmp/usr/share/doc/$package/$news_name");
 114         }
 115
 116         if (defined $upstream) {
 117                 my $link_to;
 118                 if ($upstream=~m/\.html?$/i) {
 119                         # HTML changelog
 120                         doit("install","-o",0,"-g",0,"-p","-m644",
 121                                 $upstream,"$tmp/usr/share/doc/$package/changelog.html");
 122                         doit("html2text","-nobs","-o","$tmp/usr/share/doc/$package/changelog",$upstream);
 123                         $link_to='changelog.html';
 124                 }
 125                 else {
 126                         doit("install","-o",0,"-g",0,"-p","-m644",
 127                                 $upstream,"$tmp/usr/share/doc/$package/changelog");
 128                         $link_to='changelog';
 129                 }
 130                 if ($dh{K_FLAG}) {
 131                         # Install symlink to original name of the upstream changelog file.
 132                         # Use basename in case original file was in a subdirectory or something.
 133                         doit("ln","-sf",$link_to,"$tmp/usr/share/doc/$package/".basename($upstream));
 134                 }
 135         }
 136 }
 137
 138 =head1 SEE ALSO
 139
 140 L<debhelper(7)>
 141
 142 This program is a part of debhelper.
 143
 144 =head1 AUTHOR
 145
 146 Joey Hess <joeyh@debian.org>
 147
 148 =cut