dh_install

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_install - install files into package build directories
   6
   7 =cut
   8
   9 use strict;
  10 use File::Find;
  11 use Debian::Debhelper::Dh_Lib;
  12
  13 =head1 SYNOPSIS
  14
  15 B<dh_install> [B<-X>I<item>] [B<--autodest>] [B<--sourcedir=>I<dir>] [S<I<debhelper options>>] [S<I<file [...] dest>>]
  16
  17 =head1 DESCRIPTION
  18
  19 dh_install is a debhelper program that handles installing files into package
  20 build directories. There are many dh_install* commands that handle installing
  21 specific types of files such as documentation, examples, man pages, and so on,
  22 and they should be used when possible as they often have extra intelligence for
  23 those particular tasks. dh_install, then, is useful for installing everything
  24 else, for which no particular intelligence is needed. It is a replacement for
  25 the old dh_movefiles command.
  26
  27 Files named debian/package.install list the files to install into each
  28 package and the directory they should be installed to. The format is a set
  29 of lines, where each line lists a file or files to install, and at the end
  30 of the line tells the directory it should be installed in. The name of the
  31 files (or directories) to install should be given relative to the current
  32 directory, while the installation directory is given relative to the
  33 package build directory. You may use wildcards in the names of the files to
  34 install (in v3 mode and above).
  35
  36 This program may be used in one of two ways. If you just have a file or two
  37 that the upstream Makefile does not install for you, you can run dh_install
  38 on them to move them into place. On the other hand, maybe you have a large
  39 package that builds multiple binary packages. You can use the upstream
  40 Makefile to install it all into debian/tmp, and then use dh_install to copy
  41 directories and files from there into the proper package build directories.
  42
  43 From debhelper compatibility level 7 on, dh_install will fall back to
  44 looking in debian/tmp for files, if it doesn't find them in the current
  45 directory (or whereever you've told it to look using --sourcedir).
  46
  47 =head1 OPTIONS
  48
  49 =over 4
  50
  51 =item B<--autodest>
  52
  53 Guess as the destination directory to install things to. If this is
  54 specified, you should not list destination directories in
  55 debian/package.install files or on the command line. Instead, dh_install
  56 will guess as follows:
  57
  58 Strip off debian/tmp (or the sourcedir if one is given) from the front of
  59 the filename, if it is present, and install into the dirname of the
  60 filename. So if the filename is debian/tmp/usr/bin, then that directory
  61 will be copied to debian/package/usr/. If the filename is
  62 debian/tmp/etc/passwd, it will be copied to debian/package/etc/.
  63
  64 Note that if you list exactly one filename or wildcard-pattern on a line by
  65 itself in a
  66 debian/package.install file, with no explicit destination, then dh_install
  67 will automatically guess the destination even if this flag is not set.
  68
  69 =item B<--fail-missing>
  70
  71 This option is like --list-missing, except if a file was missed, it will
  72 not only list the missing files, but also fail with a nonzero exit code.
  73
  74 =item B<--list-missing>
  75
  76 This option makes dh_install keep track of the files it installs, and then at
  77 the end, compare that list with the files in the source directory. If any of
  78 the files (and symlinks) in the source directory were not installed to
  79 somewhere, it will warn on stderr about that.
  80
  81 This may be useful if you have a large package and want to make sure that
  82 you don't miss installing newly added files in new upstream releases.
  83
  84 Note that files that are excluded from being moved via the -X option are not
  85 warned about.
  86
  87 =item B<--sourcedir=dir>
  88
  89 Makes all files to be installed be found under dir. If this is
  90 specified, it is akin to all the filenames having "dir/" prepended
  91 to them.
  92
  93 =item B<-Xitem>, B<--exclude=item>
  94
  95 Exclude files that contain "item" anywhere in their filename from
  96 being installed.
  97
  98 =item I<file [...] dest>
  99
 100 Lists files (or directories) to install and where to install them to.
 101 The files will be installed into the first package dh_install acts on.
 102
 103 =back
 104
 105 =cut
 106
 107 init(options => {
 108         "autodest" => \$dh{AUTODEST},
 109         "list-missing" => \$dh{LIST_MISSING},
 110         "fail-missing" => \$dh{FAIL_MISSING},
 111 });
 112
 113 my @installed;
 114
 115 my $srcdir = '.';
 116 $srcdir = $dh{SOURCEDIR} if defined $dh{SOURCEDIR};
 117
 118 foreach my $package (@{$dh{DOPACKAGES}}) {
 119         my $tmp=tmpdir($package);
 120         my $file=pkgfile($package,"install");
 121
 122         my @install;
 123         if ($file) {
 124                 @install=filedoublearray($file); # no globbing yet
 125         }
 126
 127         if (($package eq $dh{FIRSTPACKAGE} || $dh{PARAMS_ALL}) && @ARGV) {
 128                 push @install, [@ARGV];
 129         }
 130
 131         # Support for -X flag.
 132         my $exclude = '';
 133         if ($dh{EXCLUDE_FIND}) {
 134                 $exclude = '! \( '.$dh{EXCLUDE_FIND}.' \)';
 135         }
 136
 137         foreach my $set (@install) {
 138                 my $dest;
 139                 my $tmpdest=0;
 140
 141                 if (! defined $dh{AUTODEST} && @$set > 1) {
 142                         $dest=pop @$set;
 143                 }
 144
 145                 my @filelist;
 146                 foreach my $glob (@$set) {
 147                         my @found = glob "$srcdir/$glob";
 148                         if (! compat(6)) {
 149                                 # Fall back to looking in debian/tmp.
 150                                 if (! @found || ! (-e $found[0] || -l $found[0])) {
 151                                         @found = glob "debian/tmp/$glob";
 152                                 }
 153                         }
 154                         push @filelist, @found;
 155                 }
 156
 157                 if (! compat(4)) { # check added in v5
 158                         # glob now, relative to srcdir
 159                         if (! @filelist) {
 160                                 error("$package missing files (@$set), aborting");
 161                         }
 162                 }
 163                 foreach my $src (@filelist) {
 164                         next if excludefile($src);
 165
 166                         if (! defined $dest) {
 167                                 # Guess at destination directory.
 168                                 $dest=$src;
 169                                 $dest=~s/^(.*\/)?\Q$srcdir\E\/// ||
 170                                         $dest=~s/^(.*\/)?debian\/tmp\///;
 171                                 $dest=dirname("/".$dest);
 172                                 $tmpdest=1;
 173                         }
 174
 175                         # Make sure the destination directory exists.
 176                         if (! -e "$tmp/$dest") {
 177                                 doit("install","-d","$tmp/$dest");
 178                         }
 179
 180                         # Keep track of what's installed.
 181                         if ($dh{LIST_MISSING} || $dh{FAIL_MISSING}) {
 182                                 # Kill any extra slashes. Makes the
 183                                 # @installed stuff more robust.
 184                                 $src=~y:/:/:s;
 185                                 $src=~s:/+$::;
 186                                 $src=~s:^(\./)*::;
 187                                 push @installed, "\Q$src\E\/.*|\Q$src\E";
 188                         }
 189
 190                         if (-d $src && $exclude) {
 191                                 my $basename = basename($src);
 192                                 my $dir = ($basename eq '.') ? $src : "$src/..";
 193                                 my $pwd=`pwd`;
 194                                 chomp $pwd;
 195                                 complex_doit("cd '$dir' && find '$basename' $exclude \\( -type f -or -type l \\) -exec cp --parents -dp {} $pwd/$tmp/$dest/ \\;");
 196                                 # cp is annoying so I need a separate pass
 197                                 # just for empty directories
 198                                 complex_doit("cd '$dir' && find '$basename' $exclude \\( -type d -and -empty \\) -exec cp --parents -a {} $pwd/$tmp/$dest/ \\;");
 199                         }
 200                         else {
 201                                 doit("cp", "-a", $src, "$tmp/$dest/");
 202                         }
 203
 204                         if ($tmpdest) {
 205                                 $dest=undef;
 206                         }
 207                 }
 208         }
 209 }
 210
 211 if ($dh{LIST_MISSING} || $dh{FAIL_MISSING}) {
 212         # . as srcdir makes no sense, so this is a special case.
 213         if ($srcdir eq '.') {
 214                 $srcdir='debian/tmp';
 215         }
 216
 217         my @missing;
 218         my $installed=join("|", @installed);
 219         $installed=qr{^($installed)$};
 220         find(sub {
 221                 -f || -l || return;
 222                 $_="$File::Find::dir/$_";
 223                 if (! /$installed/ && ! excludefile($_)) {
 224                         my $file=$_;
 225                         $file=~s/^\Q$srcdir\E\///;
 226                         push @missing, $file;
 227                 }
 228         }, $srcdir);
 229         if (@missing) {
 230                 warning "$_ exists in $srcdir but is not installed to anywhere" foreach @missing;
 231                 if ($dh{FAIL_MISSING}) {
 232                         error("missing files, aborting");
 233                 }
 234         }
 235 }
 236
 237 =head1 EXAMPLE
 238
 239 Suppose your package's upstream Makefile installs a binary, a man page, and
 240 a library into appropriate subdirectories of debian/tmp. You want to put
 241 the library into package libfoo, and the rest into package foo. Your rules
 242 file will run "dh_install --sourcedir=debian/tmp". Make debian/foo.install
 243 contain:
 244
 245   usr/bin
 246   usr/share/man/man1
 247
 248 While debian/libfoo.install contains:
 249
 250   usr/lib/libfoo*.so.*
 251
 252 If you want a libfoo-dev package too, debian/libfoo-dev.install might contain:
 253
 254   usr/include
 255   usr/lib/libfoo*.so
 256   usr/share/man/man3
 257
 258 =head1 LIMITATIONS
 259
 260 dh_install cannot rename files or directories, it can only install them
 261 with the names they already have into wherever you want in the package
 262 build tree.
 263
 264 =head1 SEE ALSO
 265
 266 L<debhelper(7)>
 267
 268 This program is a part of debhelper.
 269
 270 =head1 AUTHOR
 271
 272 Joey Hess <joeyh@debian.org>
 273
 274 =cut