dh_install

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_install - install files into package build directories
   6
   7 =cut
   8
   9 use strict;
  10 use File::Find;
  11 use Debian::Debhelper::Dh_Lib;
  12
  13 =head1 SYNOPSIS
  14
  15 B<dh_install> [B<-X>I<item>] [B<--autodest>] [B<--sourcedir=>I<dir>] [S<I<debhelper options>>] [S<I<file [...] dest>>]
  16
  17 =head1 DESCRIPTION
  18
  19 dh_install is a debhelper program that handles installing files into package
  20 build directories. There are many dh_install* commands that handle installing
  21 specific types of files such as documentation, examples, man pages, and so on,
  22 and they should be used when possible as they often have extra intelligence for
  23 those particular tasks. dh_install, then, is useful for installing everything
  24 else, for which no particular intelligence is needed. It is a replacement for
  25 the old dh_movefiles command.
  26
  27 This program may be used in one of two ways. If you just have a file or two
  28 that the upstream Makefile does not install for you, you can run dh_install
  29 on them to move them into place. On the other hand, maybe you have a large
  30 package that builds multiple binary packages. You can use the upstream
  31 Makefile to install it all into debian/tmp, and then use dh_install to copy
  32 directories and files from there into the proper package build directories.
  33
  34 From debhelper compatibility level 7 on, dh_install will fall back to
  35 looking in debian/tmp for files, if it doesn't find them in the current
  36 directory (or whereever you've told it to look using --sourcedir).
  37
  38 =head1 FILES
  39
  40 =over 4
  41
  42 =item debian/I<package>.install
  43
  44 List the files to install into each package and the directory they should be
  45 installed to. The format is a set of lines, where each line lists a file or
  46 files to install, and at the end of the line tells the directory it should be
  47 installed in. The name of the files (or directories) to install should be given
  48 relative to the current directory, while the installation directory is given
  49 relative to the package build directory. You may use wildcards in the names of
  50 the files to install (in v3 mode and above).
  51
  52 =back
  53
  54 =head1 OPTIONS
  55
  56 =over 4
  57
  58 =item B<--list-missing>
  59
  60 This option makes dh_install keep track of the files it installs, and then at
  61 the end, compare that list with the files in the source directory. If any of
  62 the files (and symlinks) in the source directory were not installed to
  63 somewhere, it will warn on stderr about that.
  64
  65 This may be useful if you have a large package and want to make sure that
  66 you don't miss installing newly added files in new upstream releases.
  67
  68 Note that files that are excluded from being moved via the -X option are not
  69 warned about.
  70
  71 =item B<--fail-missing>
  72
  73 This option is like --list-missing, except if a file was missed, it will
  74 not only list the missing files, but also fail with a nonzero exit code.
  75
  76 =item B<-Xitem>, B<--exclude=item>
  77
  78 Exclude files that contain "item" anywhere in their filename from
  79 being installed.
  80
  81 =item B<--sourcedir=dir>
  82
  83 Look in the specified directory for files to be installed.
  84
  85 Note that this is not the same as the --sourcedirectory option used
  86 by the dh_auto_* commands. You rarely need to use this option, since
  87 dh_install automatically looks for files in debian/tmp in debhelper
  88 compatibility level 7 and above.
  89
  90 =item B<--autodest>
  91
  92 Guess as the destination directory to install things to. If this is
  93 specified, you should not list destination directories in
  94 debian/package.install files or on the command line. Instead, dh_install
  95 will guess as follows:
  96
  97 Strip off debian/tmp (or the sourcedir if one is given) from the front of
  98 the filename, if it is present, and install into the dirname of the
  99 filename. So if the filename is debian/tmp/usr/bin, then that directory
 100 will be copied to debian/package/usr/. If the filename is
 101 debian/tmp/etc/passwd, it will be copied to debian/package/etc/.
 102
 103 Note that if you list exactly one filename or wildcard-pattern on a line by
 104 itself in a
 105 debian/package.install file, with no explicit destination, then dh_install
 106 will automatically guess the destination even if this flag is not set.
 107
 108 =item I<file [...] dest>
 109
 110 Lists files (or directories) to install and where to install them to.
 111 The files will be installed into the first package dh_install acts on.
 112
 113 =back
 114
 115 =cut
 116
 117 init(options => {
 118         "autodest" => \$dh{AUTODEST},
 119         "list-missing" => \$dh{LIST_MISSING},
 120         "fail-missing" => \$dh{FAIL_MISSING},
 121         "sourcedir=s" => \$dh{SOURCEDIR},
 122 });
 123
 124 my @installed;
 125
 126 my $srcdir = '.';
 127 $srcdir = $dh{SOURCEDIR} if defined $dh{SOURCEDIR};
 128
 129 foreach my $package (@{$dh{DOPACKAGES}}) {
 130         my $tmp=tmpdir($package);
 131         my $file=pkgfile($package,"install");
 132
 133         my @install;
 134         if ($file) {
 135                 @install=filedoublearray($file); # no globbing yet
 136         }
 137
 138         if (($package eq $dh{FIRSTPACKAGE} || $dh{PARAMS_ALL}) && @ARGV) {
 139                 push @install, [@ARGV];
 140         }
 141
 142         # Support for -X flag.
 143         my $exclude = '';
 144         if ($dh{EXCLUDE_FIND}) {
 145                 $exclude = '! \( '.$dh{EXCLUDE_FIND}.' \)';
 146         }
 147
 148         foreach my $set (@install) {
 149                 my $dest;
 150                 my $tmpdest=0;
 151
 152                 if (! defined $dh{AUTODEST} && @$set > 1) {
 153                         $dest=pop @$set;
 154                 }
 155
 156                 my @filelist;
 157                 foreach my $glob (@$set) {
 158                         my @found = glob "$srcdir/$glob";
 159                         if (! compat(6)) {
 160                                 # Fall back to looking in debian/tmp.
 161                                 if (! @found || ! (-e $found[0] || -l $found[0])) {
 162                                         @found = glob "debian/tmp/$glob";
 163                                 }
 164                         }
 165                         push @filelist, @found;
 166                 }
 167
 168                 if (! compat(4)) { # check added in v5
 169                         if (! @filelist) {
 170                                 error("$package missing files (@$set), aborting");
 171                         }
 172                 }
 173                 foreach my $src (@filelist) {
 174                         next if excludefile($src);
 175
 176                         if (! defined $dest) {
 177                                 # Guess at destination directory.
 178                                 $dest=$src;
 179                                 $dest=~s/^(.*\/)?\Q$srcdir\E\///;
 180                                 $dest=~s/^(.*\/)?debian\/tmp\///;
 181                                 $dest=dirname("/".$dest);
 182                                 $tmpdest=1;
 183                         }
 184
 185                         # Make sure the destination directory exists.
 186                         if (! -e "$tmp/$dest") {
 187                                 doit("install","-d","$tmp/$dest");
 188                         }
 189
 190                         # Keep track of what's installed.
 191                         if ($dh{LIST_MISSING} || $dh{FAIL_MISSING}) {
 192                                 # Kill any extra slashes. Makes the
 193                                 # @installed stuff more robust.
 194                                 $src=~y:/:/:s;
 195                                 $src=~s:/+$::;
 196                                 $src=~s:^(\./)*::;
 197                                 push @installed, "\Q$src\E\/.*|\Q$src\E";
 198                         }
 199
 200                         if (-d $src && $exclude) {
 201                                 my $basename = basename($src);
 202                                 my $dir = ($basename eq '.') ? $src : "$src/..";
 203                                 my $pwd=`pwd`;
 204                                 chomp $pwd;
 205                                 complex_doit("cd '$dir' && find '$basename' $exclude \\( -type f -or -type l \\) -exec cp --parents -dp {} $pwd/$tmp/$dest/ \\;");
 206                                 # cp is annoying so I need a separate pass
 207                                 # just for empty directories
 208                                 complex_doit("cd '$dir' && find '$basename' $exclude \\( -type d -and -empty \\) -exec cp --parents -a {} $pwd/$tmp/$dest/ \\;");
 209                         }
 210                         else {
 211                                 doit("cp", "-a", $src, "$tmp/$dest/");
 212                         }
 213
 214                         if ($tmpdest) {
 215                                 $dest=undef;
 216                         }
 217                 }
 218         }
 219 }
 220
 221 if ($dh{LIST_MISSING} || $dh{FAIL_MISSING}) {
 222         # . as srcdir makes no sense, so this is a special case.
 223         if ($srcdir eq '.') {
 224                 $srcdir='debian/tmp';
 225         }
 226
 227         my @missing;
 228         my $installed=join("|", @installed);
 229         $installed=qr{^($installed)$};
 230         find(sub {
 231                 -f || -l || return;
 232                 $_="$File::Find::dir/$_";
 233                 if (! /$installed/ && ! excludefile($_)) {
 234                         my $file=$_;
 235                         $file=~s/^\Q$srcdir\E\///;
 236                         push @missing, $file;
 237                 }
 238         }, $srcdir);
 239         if (@missing) {
 240                 warning "$_ exists in $srcdir but is not installed to anywhere" foreach @missing;
 241                 if ($dh{FAIL_MISSING}) {
 242                         error("missing files, aborting");
 243                 }
 244         }
 245 }
 246
 247 =head1 EXAMPLE
 248
 249 Suppose your package's upstream Makefile installs a binary, a man page, and
 250 a library into appropriate subdirectories of debian/tmp. You want to put
 251 the library into package libfoo, and the rest into package foo. Your rules
 252 file will run "dh_install --sourcedir=debian/tmp". Make debian/foo.install
 253 contain:
 254
 255   usr/bin
 256   usr/share/man/man1
 257
 258 While debian/libfoo.install contains:
 259
 260   usr/lib/libfoo*.so.*
 261
 262 If you want a libfoo-dev package too, debian/libfoo-dev.install might contain:
 263
 264   usr/include
 265   usr/lib/libfoo*.so
 266   usr/share/man/man3
 267
 268 =head1 LIMITATIONS
 269
 270 dh_install cannot rename files or directories, it can only install them
 271 with the names they already have into wherever you want in the package
 272 build tree.
 273
 274 =head1 SEE ALSO
 275
 276 L<debhelper(7)>
 277
 278 This program is a part of debhelper.
 279
 280 =head1 AUTHOR
 281
 282 Joey Hess <joeyh@debian.org>
 283
 284 =cut