dh_install

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_install - install files into package build directories
   6
   7 =cut
   8
   9 use strict;
  10 use File::Find;
  11 use Debian::Debhelper::Dh_Lib;
  12
  13 =head1 SYNOPSIS
  14
  15 B<dh_install> [B<-X>I<item>] [B<--autodest>] [B<--sourcedir=>I<dir>] [S<I<debhelper options>>] [S<I<file [...] dest>>]
  16
  17 =head1 DESCRIPTION
  18
  19 dh_install is a debhelper program that handles installing files into package
  20 build directories. There are many dh_install* commands that handle installing
  21 specific types of files such as documentation, examples, man pages, and so on,
  22 and they should be used when possible as they often have extra intelligence for
  23 those particular tasks. dh_install, then, is useful for installing everything
  24 else, for which no particular intelligence is needed. It is a replacement for
  25 the old dh_movefiles command.
  26
  27 Files named debian/package.install list the files to install into each
  28 package and the directory they should be installed to. The format is a set
  29 of lines, where each line lists a file or files to install, and at the end
  30 of the line tells the directory it should be installed in. The name of the
  31 files (or directories) to install should be given relative to the current
  32 directory, while the installation directory is given relative to the
  33 package build directory. You may use wildcards in the names of the files to
  34 install (in v3 mode and above).
  35
  36 This program may be used in one of two ways. If you just have a file or two
  37 that the upstream Makefile does not install for you, you can run dh_install
  38 on them to move them into place. On the other hand, maybe you have a large
  39 package that builds multiple binary packages. You can use the upstream
  40 Makefile to install it all into debian/tmp, and then use dh_install to copy
  41 directories and files from there into the proper package build directories.
  42
  43 =head1 OPTIONS
  44
  45 =over 4
  46
  47 =item B<-Xitem>, B<--exclude=item>
  48
  49 Exclude files that contain "item" anywhere in their filename from
  50 being installed.
  51
  52 =item B<--autodest>
  53
  54 Guess as the destination directory to install things to. If this is
  55 specified, you should not list destination directories in
  56 debian/package.install files or on the command line. Instead, dh_install
  57 will guess as follows:
  58
  59 Strip off debian/tmp (or the sourcedir if one is given) from the front of
  60 the filename, if it is present, and install into the dirname of the
  61 filename. So if the filename is debian/tmp/usr/bin, then that directory
  62 will be copied to debian/package/usr/. If the filename is
  63 debian/tmp/etc/passwd, it will be copied to debian/package/etc/.
  64
  65 Note that if you list only a filename on a line by itself in a
  66 debian/package.install file, with no explicit destination, then dh_install
  67 will automatically guess the destination even if this flag is not set.
  68
  69 =item B<--list-missing>
  70
  71 This option makes dh_install keep track of the files it installs, and then at
  72 the end, compare that list with the files in the source directory. If any of
  73 the files (and symlinks) in the source directory were not installed to
  74 somewhere, it will warn on stderr about that.
  75
  76 This may be useful if you have a large package and want to make sure that
  77 you don't miss installing newly added files in new upstream releases.
  78
  79 Note that files that are excluded from being moved via the -X option are not
  80 warned about.
  81
  82 =item B<--fail-missing>
  83
  84 This option is like --list-missing, except if a file was missed, it will
  85 not only list the missing files, but also fail with a nonzero exit code.
  86
  87 =item B<--sourcedir=dir>
  88
  89 Makes all source files be found under dir. If this is specified, it is
  90 akin to all the source filenames having "dir/" prepended to them.
  91
  92 To make dh_install behave like the old dh_movefiles, move your
  93 package.files file to package.install and call dh_install with
  94 "--sourcedir=debian/tmp" appended to the command. This will
  95 approximate dh_movefiles behaviour, except it will copy files instead
  96 of moving them.
  97
  98 =item I<file [...] dest>
  99
 100 Lists files (or directories) to install and where to install them to.
 101 The files will be installed into the first package dh_install acts on.
 102
 103 =back
 104
 105 =cut
 106
 107 init();
 108
 109 my @installed;
 110
 111 my $srcdir = '.';
 112 $srcdir = $dh{SOURCEDIR}."/" if defined $dh{SOURCEDIR};
 113
 114 foreach my $package (@{$dh{DOPACKAGES}}) {
 115         my $tmp=tmpdir($package);
 116         my $file=pkgfile($package,"install");
 117
 118         my @install;
 119         if ($file) {
 120                 @install=filedoublearray($file); # no globbing yet
 121         }
 122
 123         if (($package eq $dh{FIRSTPACKAGE} || $dh{PARAMS_ALL}) && @ARGV) {
 124                 push @install, [@ARGV];
 125         }
 126
 127         # Support for -X flag.
 128         my $exclude = '';
 129         if ($dh{EXCLUDE_FIND}) {
 130                 $exclude = '! \( '.$dh{EXCLUDE_FIND}.' \)';
 131         }
 132
 133         foreach my $set (@install) {
 134                 my $dest;
 135                 my $tmpdest=0;
 136
 137                 if (! defined $dh{AUTODEST} && @$set > 1) {
 138                         $dest=pop @$set;
 139                 }
 140                 # glob now, relative to srcdir
 141                 foreach my $src (map { glob "$srcdir/$_" } @$set) {
 142                         next if excludefile($src);
 143
 144                         if (! defined $dest) {
 145                                 # Guess at destination directory.
 146                                 $dest=$src;
 147                                 my $strip=$srcdir;
 148                                 if ($strip eq '.') {
 149                                         $strip = "debian/tmp";
 150                                 }
 151                                 $dest=~s/^(.*\/)?\Q$strip\E//;
 152                                 $dest=dirname($dest);
 153                                 $tmpdest=1;
 154                         }
 155
 156                         # Make sure the destination directory exists.
 157                         if (! -e "$tmp/$dest") {
 158                                 doit("install","-d","$tmp/$dest");
 159                         }
 160
 161                         # Keep track of what's installed.
 162                         if ($dh{LIST_MISSING} || $dh{FAIL_MISSING}) {
 163                                 # Kill any extra slashes. Makes the
 164                                 # @installed stuff more robust.
 165                                 $src=~y:/:/:s;
 166                                 $src=~s:/+$::;
 167                                 $src=~s:^(\./)*::;
 168                                 push @installed, "\Q$src\E\/.*|\Q$src\E";
 169                         }
 170
 171                         if (-d $src && $exclude) {
 172                                 my ($dir_basename) = basename($src);
 173                                 # Pity there's no cp --exclude ..
 174                                 my $pwd=`pwd`;
 175                                 chomp $pwd;
 176                                 complex_doit("cd $src/.. && find $dir_basename $exclude \\( -type f -or -type l \\) -exec cp --parents -dp {} $pwd/$tmp/$dest/ \\;");
 177                                 # cp is annoying so I need a separate pass
 178                                 # just for empty directories
 179                                 complex_doit("cd $src/.. && find $dir_basename $exclude \\( -type d -and -empty \\) -exec cp --parents -a {} $pwd/$tmp/$dest/ \\;");
 180                         }
 181                         else {
 182                                 doit("cp", "-a", $src, "$tmp/$dest/");
 183                         }
 184
 185                         if ($tmpdest) {
 186                                 $dest=undef;
 187                         }
 188                 }
 189         }
 190 }
 191
 192 if ($dh{LIST_MISSING} || $dh{FAIL_MISSING}) {
 193         # . as srcdir makes no sense, so this is a special case.
 194         if ($srcdir eq '.') {
 195                 $srcdir='debian/tmp';
 196         }
 197
 198         my @missing;
 199         my $installed=join("|", @installed);
 200         $installed=qr{^$installed$};
 201         find(sub {
 202                 -f || -l || return;
 203                 $_="$File::Find::dir/$_";
 204                 push @missing, $_ unless /$installed/ || excludefile($_);
 205         }, $srcdir);
 206         if (@missing) {
 207                 warning "$_ exists in debian/tmp but not installed to anywhere" foreach @missing;
 208                 if ($dh{FAIL_MISSING}) {
 209                         error("missing files, aborting");
 210                 }
 211         }
 212 }
 213
 214 =head1 EXAMPLE
 215
 216 Suppose your package's upstream Makefile installs a binary, a man page, and
 217 a library into appropriate subdirectories of debian/tmp. You want to put
 218 the library into package libfoo, and the rest into package foo. Your rules
 219 file will run "dh_install --sourcedir=debian/tmp". Make debian/foo.install
 220 contain:
 221
 222   usr/bin
 223   usr/share/man/man1
 224
 225 While debian/libfoo.install contains:
 226
 227   usr/libfoo*.so.*
 228
 229 If you want a libfoo-dev package too, debian/libfoo-dev.install might contain:
 230
 231   usr/include
 232   usr/lib/libfoo*.so
 233   usr/share/man/man3
 234
 235 =head1 LIMITATIONS
 236
 237 dh_install cannot rename files or directories, it can only install them
 238 with the names they already have into wherever you want in the package
 239 build tree.
 240
 241 =head1 SEE ALSO
 242
 243 L<debhelper(7)>
 244
 245 This program is a part of debhelper.
 246
 247 =head1 AUTHOR
 248
 249 Joey Hess <joeyh@debian.org>
 250
 251 =cut