dh_install

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_install - install files into package build directories
   6
   7 =cut
   8
   9 use strict;
  10 use File::Find;
  11 use Debian::Debhelper::Dh_Lib;
  12
  13 =head1 SYNOPSIS
  14
  15 B<dh_install> [B<-X>I<item>] [B<--autodest>] [B<--sourcedir=>I<dir>] [S<I<debhelper options>>] [S<I<file [...] dest>>]
  16
  17 =head1 DESCRIPTION
  18
  19 dh_install is a debhelper program that handles installing files into package
  20 build directories. There are many dh_install* commands that handle installing
  21 specific types of files such as documentation, examples, man pages, and so on,
  22 and they should be used when possible as they often have extra intelligence for
  23 those particular tasks. dh_install, then, is useful for installing everything
  24 else, for which no particular intelligence is needed. It is a replacement for
  25 the old dh_movefiles command.
  26
  27 Files named debian/package.install list the files to install into each
  28 package and the directory they should be installed to. The format is a set
  29 of lines, where each line lists a file or files to install, and at the end
  30 of the line tells the directory it should be installed in. The name of the
  31 files (or directories) to install should be given relative to the current
  32 directory, while the installation directory is given relative to the
  33 package build directory. You may use wildcards in the names of the files to
  34 install (in v3 mode and above).
  35
  36 This program may be used in one of two ways. If you just have a file or two
  37 that the upstream Makefile does not install for you, you can run dh_install
  38 on them to move them into place. On the other hand, maybe you have a large
  39 package that builds multiple binary packages. You can use the upstream
  40 Makefile to install it all into debian/tmp, and then use dh_install to copy
  41 directories and files from there into the proper package build directories.
  42
  43 From debhelper compatibility level 7 on, dh_install will fall back to
  44 looking in debian/tmp for files, if it doesn't find them in the current
  45 directory (or whereever you've told it to look using --srcdir).
  46
  47 =head1 OPTIONS
  48
  49 =over 4
  50
  51 =item B<--autodest>
  52
  53 Guess as the destination directory to install things to. If this is
  54 specified, you should not list destination directories in
  55 debian/package.install files or on the command line. Instead, dh_install
  56 will guess as follows:
  57
  58 Strip off debian/tmp (or the sourcedir if one is given) from the front of
  59 the filename, if it is present, and install into the dirname of the
  60 filename. So if the filename is debian/tmp/usr/bin, then that directory
  61 will be copied to debian/package/usr/. If the filename is
  62 debian/tmp/etc/passwd, it will be copied to debian/package/etc/.
  63
  64 Note that if you list exactly one filename or wildcard-pattern on a line by
  65 itself in a
  66 debian/package.install file, with no explicit destination, then dh_install
  67 will automatically guess the destination even if this flag is not set.
  68
  69 =item B<--fail-missing>
  70
  71 This option is like --list-missing, except if a file was missed, it will
  72 not only list the missing files, but also fail with a nonzero exit code.
  73
  74 =item B<--list-missing>
  75
  76 This option makes dh_install keep track of the files it installs, and then at
  77 the end, compare that list with the files in the source directory. If any of
  78 the files (and symlinks) in the source directory were not installed to
  79 somewhere, it will warn on stderr about that.
  80
  81 This may be useful if you have a large package and want to make sure that
  82 you don't miss installing newly added files in new upstream releases.
  83
  84 Note that files that are excluded from being moved via the -X option are not
  85 warned about.
  86
  87 =item B<--sourcedir=dir>
  88
  89 Makes all source files be found under dir. If this is specified, it is
  90 akin to all the source filenames having "dir/" prepended to them.
  91
  92 To make dh_install behave like the old dh_movefiles, move your
  93 package.files file to package.install and call dh_install with
  94 "--sourcedir=debian/tmp" appended to the command. This will
  95 approximate dh_movefiles behaviour, except it will copy files instead
  96 of moving them.
  97
  98 =item B<-Xitem>, B<--exclude=item>
  99
 100 Exclude files that contain "item" anywhere in their filename from
 101 being installed.
 102
 103 =item I<file [...] dest>
 104
 105 Lists files (or directories) to install and where to install them to.
 106 The files will be installed into the first package dh_install acts on.
 107
 108 =back
 109
 110 =cut
 111
 112 init(options => {
 113         "autodest" => \$dh{AUTODEST},
 114         "list-missing" => \$dh{LIST_MISSING},
 115         "fail-missing" => \$dh{FAIL_MISSING},
 116 });
 117
 118 my @installed;
 119
 120 my $srcdir = '.';
 121 $srcdir = $dh{SOURCEDIR}."/" if defined $dh{SOURCEDIR};
 122
 123 foreach my $package (@{$dh{DOPACKAGES}}) {
 124         my $tmp=tmpdir($package);
 125         my $file=pkgfile($package,"install");
 126
 127         my @install;
 128         if ($file) {
 129                 @install=filedoublearray($file); # no globbing yet
 130         }
 131
 132         if (($package eq $dh{FIRSTPACKAGE} || $dh{PARAMS_ALL}) && @ARGV) {
 133                 push @install, [@ARGV];
 134         }
 135
 136         # Support for -X flag.
 137         my $exclude = '';
 138         if ($dh{EXCLUDE_FIND}) {
 139                 $exclude = '! \( '.$dh{EXCLUDE_FIND}.' \)';
 140         }
 141
 142         foreach my $set (@install) {
 143                 my $dest;
 144                 my $tmpdest=0;
 145
 146                 if (! defined $dh{AUTODEST} && @$set > 1) {
 147                         $dest=pop @$set;
 148                 }
 149
 150                 my @filelist;
 151                 foreach my $glob (@$set) {
 152                         my @found = glob "$srcdir/$glob";
 153                         if (! compat(6)) {
 154                                 # Fall back to looking in debian/tmp.
 155                                 if (! @found || ! -e $found[0]) {
 156                                         @found = glob "debian/tmp/$glob";
 157                                 }
 158                         }
 159                         push @filelist, @found;
 160                 }
 161
 162                 if (! compat(4)) { # check added in v5
 163                         # glob now, relative to srcdir
 164                         if (! @filelist) {
 165                                 error("$package missing files (@$set), aborting");
 166                         }
 167                 }
 168                 foreach my $src (@filelist) {
 169                         next if excludefile($src);
 170
 171                         if (! defined $dest) {
 172                                 # Guess at destination directory.
 173                                 $dest=$src;
 174                                 my $strip=$srcdir;
 175                                 if ($strip eq '.') {
 176                                         $strip = "debian/tmp";
 177                                 }
 178                                 $dest=~s/^(.*\/)?\Q$strip\E//;
 179                                 $dest=dirname($dest);
 180                                 $tmpdest=1;
 181                         }
 182
 183                         # Make sure the destination directory exists.
 184                         if (! -e "$tmp/$dest") {
 185                                 doit("install","-d","$tmp/$dest");
 186                         }
 187
 188                         # Keep track of what's installed.
 189                         if ($dh{LIST_MISSING} || $dh{FAIL_MISSING}) {
 190                                 # Kill any extra slashes. Makes the
 191                                 # @installed stuff more robust.
 192                                 $src=~y:/:/:s;
 193                                 $src=~s:/+$::;
 194                                 $src=~s:^(\./)*::;
 195                                 push @installed, "\Q$src\E\/.*|\Q$src\E";
 196                         }
 197
 198                         if (-d $src && $exclude) {
 199                                 my $basename = basename($src);
 200                                 my $dir = ($basename eq '.') ? $src : "$src/..";
 201                                 my $pwd=`pwd`;
 202                                 chomp $pwd;
 203                                 complex_doit("cd '$dir' && find '$basename' $exclude \\( -type f -or -type l \\) -exec cp --parents -dp {} $pwd/$tmp/$dest/ \\;");
 204                                 # cp is annoying so I need a separate pass
 205                                 # just for empty directories
 206                                 complex_doit("cd '$dir' && find '$basename' $exclude \\( -type d -and -empty \\) -exec cp --parents -a {} $pwd/$tmp/$dest/ \\;");
 207                         }
 208                         else {
 209                                 doit("cp", "-a", $src, "$tmp/$dest/");
 210                         }
 211
 212                         if ($tmpdest) {
 213                                 $dest=undef;
 214                         }
 215                 }
 216         }
 217 }
 218
 219 if ($dh{LIST_MISSING} || $dh{FAIL_MISSING}) {
 220         # . as srcdir makes no sense, so this is a special case.
 221         if ($srcdir eq '.') {
 222                 $srcdir='debian/tmp';
 223         }
 224
 225         my @missing;
 226         my $installed=join("|", @installed);
 227         $installed=qr{^($installed)$};
 228         find(sub {
 229                 -f || -l || return;
 230                 $_="$File::Find::dir/$_";
 231                 if (! /$installed/ && ! excludefile($_)) {
 232                         my $file=$_;
 233                         $file=~s/^\Q$srcdir\E\///;
 234                         push @missing, $file;
 235                 }
 236         }, $srcdir);
 237         if (@missing) {
 238                 warning "$_ exists in $srcdir but is not installed to anywhere" foreach @missing;
 239                 if ($dh{FAIL_MISSING}) {
 240                         error("missing files, aborting");
 241                 }
 242         }
 243 }
 244
 245 =head1 EXAMPLE
 246
 247 Suppose your package's upstream Makefile installs a binary, a man page, and
 248 a library into appropriate subdirectories of debian/tmp. You want to put
 249 the library into package libfoo, and the rest into package foo. Your rules
 250 file will run "dh_install --sourcedir=debian/tmp". Make debian/foo.install
 251 contain:
 252
 253   usr/bin
 254   usr/share/man/man1
 255
 256 While debian/libfoo.install contains:
 257
 258   usr/lib/libfoo*.so.*
 259
 260 If you want a libfoo-dev package too, debian/libfoo-dev.install might contain:
 261
 262   usr/include
 263   usr/lib/libfoo*.so
 264   usr/share/man/man3
 265
 266 =head1 LIMITATIONS
 267
 268 dh_install cannot rename files or directories, it can only install them
 269 with the names they already have into wherever you want in the package
 270 build tree.
 271
 272 =head1 SEE ALSO
 273
 274 L<debhelper(7)>
 275
 276 This program is a part of debhelper.
 277
 278 =head1 AUTHOR
 279
 280 Joey Hess <joeyh@debian.org>
 281
 282 =cut