dh_gencontrol

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_gencontrol - generate and install control file
   6
   7 =cut
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11
  12 =head1 SYNOPSIS
  13
  14 B<dh_gencontrol> [S<I<debhelper options>>] [S<B<--> I<params>>]
  15
  16 =head1 DESCRIPTION
  17
  18 dh_gencontrol is a debhelper program that is responsible for generating
  19 control files, and installing them into the DEBIAN directory with the
  20 proper permissions.
  21
  22 This program is merely a wrapper around L<dpkg-gencontrol(1)>, which calls
  23 it once for each package being acted on, and passes in some additional
  24 useful flags.
  25
  26 =head1 OPTIONS
  27
  28 =over 4
  29
  30 =item B<-u>I<params>, B<--dpkg-gencontrol-params>=I<params>
  31
  32 =item B<--> I<params>
  33
  34 Pass "params" to L<dpkg-gencontrol(1)>.
  35
  36 =back
  37
  38 =cut
  39
  40 init();
  41
  42 foreach my $package (@{$dh{DOPACKAGES}}) {
  43         my $tmp=tmpdir($package);
  44         my $ext=pkgext($package);
  45
  46         my $substvars="debian/${ext}substvars";
  47
  48         my $changelog=pkgfile($package,'changelog');
  49         if (! $changelog) {
  50                 $changelog='debian/changelog';
  51         }
  52
  53         if ( ! -d "$tmp/DEBIAN" ) {
  54                 doit("install","-o",0,"-g",0,"-d","$tmp/DEBIAN");
  55         }
  56
  57         # avoid gratuitous warning
  58         if (! -e $substvars || system("grep -q '^misc:Depends=' $substvars") != 0) {
  59                 complex_doit("echo misc:Depends= >> $substvars");
  60         }
  61
  62         # Generate and install control file.
  63         my @command="dpkg-gencontrol";
  64         if (getpackages() > 1) {
  65                 push @command, "-p$package";
  66         }
  67         if (is_udeb($package)) {
  68                 push @command, "-UHomepage";
  69                 push @command, "-n".udeb_filename($package);
  70         }
  71         doit(@command, "-l$changelog", "-T$substvars",
  72                 "-P$tmp",@{$dh{U_PARAMS}});
  73
  74         # This chmod is only necessary if the user sets the umask to
  75         # something odd.
  76         doit("chmod","644","$tmp/DEBIAN/control");
  77
  78         doit("chown","0:0","$tmp/DEBIAN/control");
  79 }
  80
  81 =head1 SEE ALSO
  82
  83 L<debhelper(7)>
  84
  85 This program is a part of debhelper.
  86
  87 =head1 AUTHOR
  88
  89 Joey Hess <joeyh@debian.org>
  90
  91 =cut