dh_clean

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh_clean - clean up package build directories
   6
   7 =cut
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11
  12 =head1 SYNOPSIS
  13
  14 B<dh_clean> [S<I<debhelper options>>] [B<-k>] [B<-d>] [B<-X>I<item>] [S<I<file ...>>]
  15
  16 =head1 DESCRIPTION
  17
  18 dh_clean is a debhelper program that is responsible for cleaning up after a
  19 package is built. It removes the package build directories, and removes some
  20 other files, such as debian/substvars, debian/files, and any detritus left
  21 behind by other debhelper commands (debian/*.debhelper). It also removes
  22 common files that should not appear in a debian diff:
  23   #*# *~ DEADJOE *.orig *.rej *.SUMS TAGS core .deps/* *.P
  24
  25 =head1 OPTIONS
  26
  27 =over 4
  28
  29 =item B<-k>, B<--keep>
  30
  31 Do not delete debian/files. When do you want to use this? Anytime you have a
  32 debian/rules that has 2 binary targets that build different .deb packages;
  33 for example, one target is binary-arch, and the other is binary-indep, or
  34 one target builds the shared library, and the other the -dev package. If you
  35 didn't use -k in these cases, then debian/files would be deleted in the
  36 middle, and your changes file will only contain the last binary package that
  37 was built.
  38
  39 =item B<-d>, B<--dirs-only>
  40
  41 Only clean the package build directories, do not clean up any other files
  42 at all.
  43
  44 =item B<-X>I<item> B<--exclude=>I<item>
  45
  46 Exclude files that contain "item" anywhere in their filename from being
  47 deleted, even if they would normally be deleted. You may use this option
  48 multiple times to build up a list of things to exclude.
  49
  50 =item I<file ...>
  51
  52 Delete these files too.
  53
  54 =back
  55
  56 =cut
  57
  58 init();
  59
  60 foreach my $package (@{$dh{DOPACKAGES}}) {
  61         my $tmp=tmpdir($package);
  62         my $ext=pkgext($package);
  63
  64         if (! $dh{D_FLAG}) {
  65                 doit("rm","-f","debian/${ext}substvars")
  66                         unless excludefile("debian/${ext}substvars");
  67         }
  68
  69         doit ("rm","-rf",$tmp)
  70                 unless excludefile($tmp);
  71 }
  72
  73 if (! $dh{D_FLAG}) {
  74         if (@ARGV) {
  75                 doit("rm","-f","--",@ARGV);
  76         }
  77
  78         if (! $dh{K_FLAG}) {
  79                 doit("rm","-f","debian/files")
  80                         unless excludefile("debian/files");
  81         }
  82
  83         # These are all debhelper temp files, and so it is safe to
  84         # wildcard them.
  85         complex_doit("rm -f debian/*.debhelper");
  86
  87         # Remove some files that were left around by older versions of
  88         # debhelper.
  89         doit("rm","-f","debian/substvars");
  90
  91         # See if some files that would normally be deleted are excluded.
  92         my $find_options='';
  93         if (defined($dh{EXCLUDE_FIND}) && $dh{EXCLUDE_FIND} ne '') {
  94                 $find_options="-a ! ( $dh{EXCLUDE_FIND} )";
  95         }
  96
  97         # Remove other temp files.
  98         # (The \s+ is important, \s won't work because find would get null
  99         # parameters). Note that you _don't_ quote wildcards used by find
 100         # in here.
 101         doit(split(/\s+/,"find . -type f -a
 102                 ( -name #*# -o -name .*~ -o -name *~ -o -name DEADJOE
 103                  -o -name *.orig -o -name *.rej -o -name *.bak
 104                  -o -name .*.orig -o -name .*.rej -o -name .SUMS
 105                  -o -name TAGS -o -name core -o ( -path */.deps/* -a -name *.P )
 106                 ) $find_options -exec rm -f {} ;"));
 107 }
 108
 109 doit('rm', '-rf', 'debian/tmp') if -x 'debian/tmp' && ! compat(1);
 110
 111 =head1 SEE ALSO
 112
 113 L<debhelper(1)>
 114
 115 This program is a part of debhelper.
 116
 117 =head1 AUTHOR
 118
 119 Joey Hess <joeyh@debian.org>
 120
 121 =cut