dh

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh - debhelper command sequencer
   6
   7 =cut
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11
  12 =head1 SYNOPSIS
  13
  14 B<dh> I<sequence> [B<--with> I<addon>[B<,>I<addon> ...]] [B<--list>] [B<--until> I<cmd>] [B<--before> I<cmd>] [B<--after> I<cmd>] [B<--remaining>] [S<I<debhelper options>>]
  15
  16 =head1 DESCRIPTION
  17
  18 B<dh> runs a sequence of debhelper commands. The supported I<sequence>s
  19 correspond to the targets of a F<debian/rules> file: B<build-arch>,
  20 B<build-indep>, B<build>, B<clean>, B<install-indep>, B<install-arch>,
  21 B<install>, B<binary-arch>, B<binary-indep>, and B<binary>.
  22
  23 Commands in the B<build-indep>, B<install-indep> and B<binary-indep>
  24 sequences are passed the B<-i> option to ensure they only work on
  25 architecture independent packages, and commands in the B<build-arch>,
  26 B<install-arch> and B<binary-arch> sequences are passed the B<-a>
  27 option to ensure they only work on architecture dependent packages.
  28
  29 If F<debian/rules> contains a target with a name like B<override_>I<dh_command>,
  30 then when it would normally run I<dh_command>, B<dh> will instead call that
  31 target. The override target can then run the command with additional options,
  32 or run entirely different commands instead. See examples below. (Note that to
  33 use this feature, you should Build-Depend on debhelper 7.0.50 or above.)
  34
  35 =head1 OPTIONS
  36
  37 =over 4
  38
  39 =item B<--with> I<addon>[B<,>I<addon> ...]
  40
  41 Add the debhelper commands specified by the given addon to appropriate places
  42 in the sequence of commands that is run. This option can be repeated more
  43 than once, or multiple addons can be listed, separated by commas.
  44 This is used when there is a third-party package that provides
  45 debhelper commands. See the F<PROGRAMMING> file for documentation about
  46 the sequence addon interface.
  47
  48 =item B<--without> I<addon>
  49
  50 The inverse of B<--with>, disables using the given addon.
  51
  52 =item B<--list>, B<-l>
  53
  54 List all available addons.
  55
  56 =item B<--until> I<cmd>
  57
  58 Run commands in the sequence until and including I<cmd>, then stop.
  59
  60 =item B<--before> I<cmd>
  61
  62 Run commands in the sequence before I<cmd>, then stop.
  63
  64 =item B<--after> I<cmd>
  65
  66 Run commands in the sequence that come after I<cmd>.
  67
  68 =item B<--remaining>
  69
  70 Run all commands in the sequence that have yet to be run.
  71
  72 =item B<--no-act>
  73
  74 Prints commands that would run for a given sequence, but does not run them.
  75
  76 =back
  77
  78 All other options passed to B<dh> are passed on to each command it runs. This
  79 can be used to set an option like B<-v> or B<-X> or B<-N>, as well as for more
  80 specialised options.
  81
  82 In the above options, I<cmd> can be a full name of a debhelper command, or
  83 a substring. It'll first search for a command in the sequence exactly
  84 matching the name, to avoid any ambiguity. If there are multiple substring
  85 matches, the last one in the sequence will be used.
  86
  87 =cut
  88
  89 sub command_pos {
  90         my $command=shift;
  91         my @sequence=@_;
  92
  93         foreach my $i (0..$#sequence) {
  94                 if ($command eq $sequence[$i]) {
  95                         return $i;
  96                 }
  97         }
  98
  99         my @matches;
 100         foreach my $i (0..$#sequence) {
 101                 if ($sequence[$i] =~ /\Q$command\E/) {
 102                         push @matches, $i;
 103                 }
 104         }
 105         if (! @matches) {
 106                 error "command specification \"$command\" does not match any command in the sequence"
 107         }
 108         else {
 109                 return pop @matches;
 110         }
 111 }
 112
 113 =head1 EXAMPLES
 114
 115 To see what commands are included in a sequence, without actually doing
 116 anything:
 117
 118         dh binary-arch --no-act
 119
 120 This is a very simple rules file, for packages where the default sequences of
 121 commands work with no additional options.
 122
 123         #!/usr/bin/make -f
 124         %:
 125                 dh $@
 126
 127 Often you'll want to pass an option to a specific debhelper command. The
 128 easy way to do with is by adding an override target for that command.
 129
 130         #!/usr/bin/make -f
 131         %:
 132                 dh $@
 133
 134         override_dh_strip:
 135                 dh_strip -Xfoo
 136
 137         override_dh_installdocs:
 138                 dh_installdocs README TODO
 139
 140 Sometimes the automated L<dh_auto_configure(1)> and L<dh_auto_build(1)>
 141 can't guess what to do for a strange package. Here's how to avoid running
 142 either and instead run your own commands.
 143
 144         #!/usr/bin/make -f
 145         %:
 146                 dh $@
 147
 148         override_dh_auto_configure:
 149                 ./mondoconfig
 150
 151         override_dh_auto_build:
 152                 make universe-explode-in-delight
 153
 154 Another common case is wanting to do something manually before or
 155 after a particular debhelper command is run.
 156
 157         #!/usr/bin/make -f
 158         %:
 159                 dh $@
 160
 161         override_dh_fixperms:
 162                 dh_fixperms
 163                 chmod 4755 debian/foo/usr/bin/foo
 164
 165 If your package is a Python package, B<dh> will use B<dh_pysupport> by
 166 default. This is how to use B<dh_pycentral> instead.
 167
 168         #!/usr/bin/make -f
 169         %:
 170                 dh $@ --with python-central
 171
 172 If your package uses autotools and you want to freshen F<config.sub> and
 173 F<config.guess> with newer versions from the B<autotools-dev> package
 174 at build time, you can use some commands provided in B<autotools-dev>
 175 that automate it, like this.
 176
 177         #!/usr/bin/make -f
 178         %:
 179                 dh $@ --with autotools_dev
 180
 181 Here is how to force use of Perl's B<Module::Build> build system,
 182 which can be necessary if debhelper wrongly detects that the package
 183 uses MakeMaker.
 184
 185         #!/usr/bin/make -f
 186         %:
 187                 dh $@ --buildsystem=perl_build
 188
 189 To patch your package using quilt, you can tell B<dh> to use quilt's B<dh>
 190 sequence addons like this:
 191
 192         #!/usr/bin/make -f
 193         %:
 194                 dh $@ --with quilt
 195
 196 Here is an example of overriding where the B<dh_auto_>I<*> commands find
 197 the package's source, for a package where the source is located in a
 198 subdirectory.
 199
 200         #!/usr/bin/make -f
 201         %:
 202                 dh $@ --sourcedirectory=src
 203
 204 And here is an example of how to tell the B<dh_auto_>I<*> commands to build
 205 in a subdirectory, which will be removed on B<clean>.
 206
 207         #!/usr/bin/make -f
 208         %:
 209                 dh $@ --builddirectory=build
 210
 211 If your package can be built in parallel, you can support parallel building
 212 as follows. Then B<dpkg-buildpackage -j> will work.
 213
 214         #!/usr/bin/make -f
 215         %:
 216                 dh $@ --parallel
 217
 218 Here is a way to prevent B<dh> from running several commands that you don't
 219 want it to run, by defining empty override targets for each command.
 220
 221         #!/usr/bin/make -f
 222         %:
 223                 dh $@
 224
 225         # Commands not to run:
 226         override_dh_auto_test override_dh_compress override_dh_fixperms:
 227
 228 Sometimes, you may need to make an override target only run commands when a
 229 particular package is being built. This can be accomplished using
 230 L<dh_listpackages(1)> to test what is being built. For example:
 231
 232         #!/usr/bin/make -f
 233         %:
 234                 dh $@
 235
 236         override_dh_fixperms:
 237                 dh_fixperms
 238         ifneq (,$(filter foo, $(shell dh_listpackages)))
 239                 chmod 4755 debian/foo/usr/bin/foo
 240         endif
 241
 242 Finally, remember that you are not limited to using override targets in the
 243 rules file when using B<dh>. You can also explicitly define any of the regular
 244 rules file targets when it makes sense to do so. A common reason to do this
 245 is when your package needs different B<build-arch> and B<build-indep> targets.
 246 For example, a package with a long document build process can put it in
 247 B<build-indep>.
 248
 249         #!/usr/bin/make -f
 250         %:
 251                 dh $@
 252
 253         build-indep:
 254                 $(MAKE) docs
 255         build-arch:
 256                 $(MAKE) bins
 257
 258 Note that in the example above, dh will arrange for "debian/rules build"
 259 to call your build-indep and build-arch targets. You do not need to
 260 explicitly define the dependencies in the rules file when using dh.
 261
 262 =head1 INTERNALS
 263
 264 If you're curious about B<dh>'s internals, here's how it works under the hood.
 265
 266 Each debhelper command will record when it's successfully run in
 267 F<debian/package.debhelper.log>. (Which B<dh_clean> deletes.) So B<dh> can tell
 268 which commands have already been run, for which packages, and skip running
 269 those commands again.
 270
 271 Each time B<dh> is run, it examines the log, and finds the last logged command
 272 that is in the specified sequence. It then continues with the next command
 273 in the sequence. The B<--until>, B<--before>, B<--after>, and B<--remaining>
 274 options can override this behavior.
 275
 276 A sequence can also run dependent targets in debian/rules.  For
 277 example, the "binary" sequence runs the "install" target.
 278
 279 B<dh> uses the B<DH_INTERNAL_OPTIONS> environment variable to pass information
 280 through to debhelper commands that are run inside override targets. The
 281 contents (and indeed, existence) of this environment variable, as the name
 282 might suggest, is subject to change at any time.
 283
 284 =cut
 285
 286 # Stash this away before init modifies it.
 287 my @ARGV_orig=@ARGV;
 288
 289 # python-support is enabled by default, at least for now
 290 # (and comes first so python-central loads later and can disable it).
 291 unshift @ARGV, "--with=python-support";
 292
 293 init(options => {
 294                 "until=s" => \$dh{UNTIL},
 295                 "after=s" => \$dh{AFTER},
 296                 "before=s" => \$dh{BEFORE},
 297                 "remaining" => \$dh{REMAINING},
 298                 "with=s" => sub {
 299                         my ($option,$value)=@_;
 300                         push @{$dh{WITH}},split(",", $value);
 301                 },
 302                 "without=s" => sub {
 303                         my ($option,$value)=@_;
 304                         @{$dh{WITH}} = grep { $_ ne $value } @{$dh{WITH}};
 305                 },
 306                 "l" => \&list_addons,
 307                 "list" => \&list_addons,
 308         },
 309         # Disable complaints about unknown options; they are passed on to
 310         # the debhelper commands.
 311         ignore_unknown_options => 1,
 312         # Bundling does not work well since there are unknown options.
 313         bundling => 0,
 314 );
 315 inhibit_log();
 316
 317
 318 # If make is using a jobserver, but it is not available
 319 # to this process, clean out MAKEFLAGS. This avoids
 320 # ugly warnings when calling make.
 321 if (is_make_jobserver_unavailable()) {
 322         clean_jobserver_makeflags();
 323 }
 324
 325 # Definitions of sequences.
 326 my %sequences;
 327 my @bd_minimal = qw{
 328         dh_testdir
 329 };
 330 my @bd = qw{
 331         dh_testdir
 332         dh_auto_configure
 333         dh_auto_build
 334         dh_auto_test
 335         };
 336 # rules:build-arch and rules:build-indep are not called by build,
 337 # as an optimisation (code below will adjust this if explicit targets exist).
 338 $sequences{build} = [@bd];
 339 $sequences{'build-indep'} = [@bd];
 340 $sequences{'build-arch'} = [@bd];
 341 $sequences{clean} = [qw{
 342         dh_testdir
 343         dh_auto_clean
 344         dh_clean
 345 }];
 346 my @i_minimal = qw{
 347         dh_testroot
 348 };
 349 my @i = qw{
 350         dh_testroot
 351         dh_prep
 352         dh_installdirs
 353         dh_auto_install
 354
 355         dh_install
 356         dh_installdocs
 357         dh_installchangelogs
 358         dh_installexamples
 359         dh_installman
 360
 361         dh_installcatalogs
 362         dh_installcron
 363         dh_installdebconf
 364         dh_installemacsen
 365         dh_installifupdown
 366         dh_installinfo
 367         dh_installinit
 368         dh_installmenu
 369         dh_installmime
 370         dh_installmodules
 371         dh_installlogcheck
 372         dh_installlogrotate
 373         dh_installpam
 374         dh_installppp
 375         dh_installudev
 376         dh_installwm
 377         dh_installxfonts
 378         dh_installgsettings
 379         dh_bugfiles
 380         dh_ucf
 381         dh_lintian
 382         dh_gconf
 383         dh_icons
 384         dh_perl
 385         dh_usrlocal
 386
 387         dh_link
 388         dh_compress
 389         dh_fixperms
 390 };
 391 # The install sequences will call rules:build before running
 392 # the standard sequence. rules:install-arch and rules:install-indep
 393 # are not called by install, as an optimisation (code below will adjust
 394 # this if explicit targets exist).
 395 $sequences{'install'} = ['rules:build', @i, 'rules:install-arch', 'rules:install-indep'];
 396 $sequences{'install-indep'} = ['rules:build-indep', @i];
 397 $sequences{'install-arch'} = ['rules:build-arch', @i];
 398 my @ba=qw{
 399         dh_strip
 400         dh_makeshlibs
 401         dh_shlibdeps
 402 };
 403 my @b=qw{
 404         dh_installdeb
 405         dh_gencontrol
 406         dh_md5sums
 407         dh_builddeb
 408 };
 409 # The binary sequences will call 'debian/rules install' before running
 410 # the standard sequence.
 411 $sequences{binary} = ['rules:install', 'rules:binary-arch', 'rules:binary-indep'];
 412 $sequences{'binary-indep'} = ['rules:install-indep', @b];
 413 $sequences{'binary-arch'} = ['rules:install-arch', @ba, @b];
 414
 415 # Additional command options
 416 my %command_opts;
 417
 418 # sequence addon interface
 419 sub _insert {
 420         my $offset=shift;
 421         my $existing=shift;
 422         my $new=shift;
 423         foreach my $sequence (keys %sequences) {
 424                 my @list=@{$sequences{$sequence}};
 425                 next unless grep $existing, @list;
 426                 my @new;
 427                 foreach my $command (@list) {
 428                         if ($command eq $existing) {
 429                                 push @new, $new if $offset < 0;
 430                                 push @new, $command;
 431                                 push @new, $new if $offset > 0;
 432                         }
 433                         else {
 434                                 push @new, $command;
 435                         }
 436                 }
 437                 $sequences{$sequence}=\@new;
 438         }
 439 }
 440 sub insert_before {
 441         _insert(-1, @_);
 442 }
 443 sub insert_after {
 444         _insert(1, @_);
 445 }
 446 sub remove_command {
 447         my $command=shift;
 448         foreach my $sequence (keys %sequences) {
 449                 $sequences{$sequence}=[grep { $_ ne $command } @{$sequences{$sequence}}];
 450         }
 451
 452 }
 453 sub add_command {
 454         my $command=shift;
 455         my $sequence=shift;
 456         unshift @{$sequences{$sequence}}, $command;
 457 }
 458 sub add_command_options {
 459         my $command=shift;
 460         push @{$command_opts{$command}}, @_;
 461 }
 462 sub remove_command_options {
 463         my $command=shift;
 464         if (@_) {
 465                 # Remove only specified options
 466                 if (my $opts = $command_opts{$command}) {
 467                         foreach my $opt (@_) {
 468                                 $opts = [ grep { $_ ne $opt } @$opts ];
 469                         }
 470                         $command_opts{$command} = $opts;
 471                 }
 472         }
 473         else {
 474                 # Clear all additional options
 475                 delete $command_opts{$command};
 476         }
 477 }
 478
 479 sub list_addons {
 480         my %addons;
 481
 482         for my $inc (@INC) {
 483                 eval q{use File::Spec};
 484                 my $path = File::Spec->catdir($inc, "Debian/Debhelper/Sequence");
 485                 if (-d $path) {
 486                         for my $module_path (glob "$path/*.pm") {
 487                                 my $name = basename($module_path);
 488                                 $name =~ s/\.pm$//;
 489                                 $name =~ s/_/-/g;
 490                                 $addons{$name} = 1;
 491                         }
 492                 }
 493         }
 494
 495         for my $name (sort keys %addons) {
 496                 print "$name\n";
 497         }
 498
 499         exit 0;
 500 }
 501
 502 foreach my $addon (@{$dh{WITH}}) {
 503         my $mod="Debian::Debhelper::Sequence::$addon";
 504         $mod=~s/-/_/g;
 505         eval "use $mod";
 506         if ($@) {
 507                 error("unable to load addon $addon: $@");
 508         }
 509 }
 510
 511 my $sequence;
 512 if (! compat(7)) {
 513         # From v8, the sequence is the very first parameter.
 514         $sequence=shift @ARGV_orig;
 515         if ($sequence=~/^-/) {
 516                 error "Unknown sequence $sequence (options should not come before the sequence)";
 517         }
 518 }
 519 else {
 520         # Before v8, the sequence could be at any position in the parameters,
 521         # so was what was left after parsing.
 522         $sequence=shift;
 523         if (defined $sequence) {
 524                 @ARGV_orig=grep { $_ ne $sequence } @ARGV_orig;
 525         }
 526 }
 527 if (! defined $sequence) {
 528         error "specify a sequence to run";
 529 }
 530 # make -B causes the rules file to be run as a target.
 531 # Also support completly empty override targets.
 532 # Note: it's not safe to use rules_explicit_target before this check.
 533 if ($sequence eq 'debian/rules' ||
 534     $sequence =~ /^override_dh_/) {
 535         exit 0;
 536 }
 537 elsif (! exists $sequences{$sequence}) {
 538         error "Unknown sequence $sequence (choose from: ".
 539                 join(" ", sort keys %sequences).")";
 540 }
 541
 542 # If debian/rules defines build-arch or build-indep, run sequences separately.
 543 if (rules_explicit_target('build-arch') ||
 544     rules_explicit_target('build-indep')) {
 545         $sequences{build} = [@bd_minimal, 'rules:build-arch', 'rules:build-indep'];
 546 }
 547 # If debian/rules defines install-arch or install-indep, run sequences
 548 # separately.
 549 if (rules_explicit_target('install-arch') ||
 550     rules_explicit_target('install-indep')) {
 551         $sequences{'install'} = ['rules:build', @i_minimal, 'rules:install-arch', 'rules:install-indep'];
 552 }
 553
 554 my @sequence=@{$sequences{$sequence}};
 555
 556 # The list of all packages that can be acted on.
 557 my @packages=@{$dh{DOPACKAGES}};
 558
 559 # Get the options to pass to commands in the sequence.
 560 # Filter out options intended only for this program.
 561 my @options;
 562 if ($sequence eq 'build-arch' ||
 563     $sequence eq 'install-arch' ||
 564     $sequence eq 'binary-arch') {
 565         push @options, "-a";
 566         # as an optimisation, remove from the list any packages
 567         # that are not arch dependent
 568         my %arch_packages = map { $_ => 1 } getpackages("arch");
 569         @packages = grep { $arch_packages{$_} } @packages;
 570 }
 571 elsif ($sequence eq 'build-indep' ||
 572        $sequence eq 'install-indep' ||
 573        $sequence eq 'binary-indep') {
 574         push @options, "-i";
 575         # ditto optimisation for arch indep
 576         my %indep_packages = map { $_ => 1 } getpackages("indep");
 577         @packages = grep { $indep_packages{$_} } @packages;
 578 }
 579 while (@ARGV_orig) {
 580         my $opt=shift @ARGV_orig;
 581         if ($opt =~ /^--?(after|until|before|with|without)$/) {
 582                 shift @ARGV_orig;
 583                 next;
 584         }
 585         elsif ($opt =~ /^--?(no-act|remaining|(after|until|before|with|without)=)/) {
 586                 next;
 587         }
 588         elsif ($opt=~/^-/) {
 589                 push @options, "-O".$opt;
 590         }
 591         elsif (@options) {
 592                 if ($options[$#options]=~/^-O--/) {
 593                         $options[$#options].="=".$opt;
 594                 }
 595                 else {
 596                         $options[$#options].=$opt;
 597                 }
 598         }
 599 }
 600
 601 # Figure out at what point in the sequence to start for each package.
 602 my %logged;
 603 my %startpoint;
 604 foreach my $package (@packages) {
 605         my @log=load_log($package, \%logged);
 606         if ($dh{AFTER}) {
 607                 # Run commands in the sequence that come after the
 608                 # specified command.
 609                 $startpoint{$package}=command_pos($dh{AFTER}, @sequence) + 1;
 610                 # Write a dummy log entry indicating that the specified
 611                 # command was, in fact, run. This handles the case where
 612                 # no commands remain to run after it, communicating to
 613                 # future dh instances that the specified command should not
 614                 # be run again.
 615                 write_log($sequence[$startpoint{$package}-1], $package);
 616         }
 617         elsif ($dh{REMAINING}) {
 618                 # Start at the beginning so all remaining commands will get
 619                 # run.
 620                 $startpoint{$package}=0;
 621         }
 622         else {
 623                 # Find the last logged command that is in the sequence, and
 624                 # continue with the next command after it. If no logged
 625                 # command is in the sequence, we're starting at the beginning..
 626                 $startpoint{$package}=0;
 627 COMMAND:        foreach my $command (reverse @log) {
 628                         foreach my $i (0..$#sequence) {
 629                                 if ($command eq $sequence[$i]) {
 630                                         $startpoint{$package}=$i+1;
 631                                         last COMMAND;
 632                                 }
 633                         }
 634                 }
 635         }
 636 }
 637
 638 # Figure out what point in the sequence to go to.
 639 my $stoppoint=$#sequence;
 640 if ($dh{UNTIL}) {
 641         $stoppoint=command_pos($dh{UNTIL}, @sequence);
 642 }
 643 elsif ($dh{BEFORE}) {
 644         $stoppoint=command_pos($dh{BEFORE}, @sequence) - 1;
 645 }
 646
 647 # Now run the commands in the sequence.
 648 foreach my $i (0..$stoppoint) {
 649         # Figure out which packages need to run this command.
 650         my @exclude;
 651         foreach my $package (@packages) {
 652                 if ($startpoint{$package} > $i ||
 653                     $logged{$package}{$sequence[$i]}) {
 654                         push @exclude, $package;
 655                 }
 656         }
 657
 658         if (@exclude eq @packages) {
 659                 # Command already done for all packages.
 660                 next;
 661         }
 662
 663         run($sequence[$i], \@packages, \@exclude, @options);
 664 }
 665
 666 sub run {
 667         my $command=shift;
 668         my @packages=@{shift()};
 669         my @exclude=@{shift()};
 670         my @options=@_;
 671
 672         # If some packages are excluded, add flags
 673         # to prevent them from being acted on.
 674         push @options, map { "-N$_" } @exclude;
 675
 676         # If the command has a rules: prefix, run debian/rules with
 677         # the remainder as the target.
 678         my $rules_target = undef;
 679         if ($command =~ /^rules:(.*)/) {
 680                 $rules_target = $1;
 681         }
 682
 683         # Check for override targets in debian/rules and
 684         # run them instead of running the command directly.
 685         my $override_command;
 686         my $has_explicit_target = rules_explicit_target("override_".$command);
 687
 688         if (defined $rules_target) {
 689                 # Don't pass DH_ environment variables, since this is
 690                 # a fresh invocation of debian/rules and any sub-dh
 691                 # commands.
 692                 $override_command=$command;
 693                 delete $ENV{DH_INTERNAL_OPTIONS};
 694                 delete $ENV{DH_INTERNAL_OVERRIDE};
 695                 $command="debian/rules";
 696                 @options=$rules_target;
 697         }
 698         elsif (defined $has_explicit_target) {
 699                 $override_command=$command;
 700                 # Check if target isn't noop
 701                 if ($has_explicit_target) {
 702                         # This passes the options through to commands called
 703                         # inside the target.
 704                         $ENV{DH_INTERNAL_OPTIONS}=join("\x1e", @options);
 705                         $ENV{DH_INTERNAL_OVERRIDE}=$command;
 706                         $command="debian/rules";
 707                         @options="override_".$override_command;
 708                 }
 709                 else {
 710                         $command = undef;
 711                 }
 712         }
 713         else {
 714                 # Pass additional command options if any
 715                 unshift @options, @{$command_opts{$command}} if exists $command_opts{$command};
 716         }
 717
 718         if (defined $command) {
 719                 # 3 space indent lines the command being run up under the
 720                 # sequence name after "dh ".
 721                 print "   ".escape_shell($command, @options)."\n";
 722         }
 723         else {
 724                 print "   ", "# Skipping ", $override_command, " - empty override", "\n";
 725         }
 726
 727         if (! $dh{NO_ACT}) {
 728                 if (defined $command) {
 729                         my $ret=system($command, @options);
 730
 731                         if ($ret >> 8 != 0) {
 732                                 exit $ret >> 8;
 733                         }
 734                         elsif ($ret) {
 735                                 exit 1;
 736                         }
 737                 }
 738
 739                 if (defined $override_command) {
 740                         # Update log for overridden command now that it has
 741                         # finished successfully.
 742                         # (But avoid logging for dh_clean since it removes
 743                         # the log earlier.)
 744                         if ($override_command ne 'dh_clean') {
 745                                 my %packages=map { $_ => 1 } @packages;
 746                                 map { delete $packages{$_} } @exclude;
 747                                 write_log($override_command, keys %packages);
 748                                 commit_override_log(keys %packages);
 749                         }
 750
 751                         delete $ENV{DH_INTERNAL_OPTIONS};
 752                         delete $ENV{DH_INTERNAL_OVERRIDE};
 753                 }
 754         }
 755 }
 756
 757 {
 758 my %targets;
 759 my $rules_parsed;
 760
 761 sub rules_explicit_target {
 762         # Checks if a specified target exists as an explicit target
 763         # in debian/rules.
 764         # undef is returned if target does not exist, 0 if target is noop
 765         # and 1 if target has dependencies or executes commands.
 766         my $target=shift;
 767
 768         if (! $rules_parsed) {
 769                 my $processing_targets = 0;
 770                 my $not_a_target = 0;
 771                 my $current_target;
 772                 open(MAKE, "LC_ALL=C make -Rrnpsf debian/rules debhelper-fail-me 2>/dev/null |");
 773                 while (<MAKE>) {
 774                         if ($processing_targets) {
 775                                 if (/^# Not a target:/) {
 776                                         $not_a_target = 1;
 777                                 }
 778                                 else {
 779                                         if (!$not_a_target && /^([^#:]+)::?\s*(.*)$/) {
 780                                                 # Target is defined. NOTE: if it is a depenency of
 781                                                 # .PHONY it will be defined too but that's ok.
 782                                                 # $2 contains target dependencies if any.
 783                                                 $current_target = $1;
 784                                                 $targets{$current_target} = ($2) ? 1 : 0;
 785                                         }
 786                                         else {
 787                                                 if (defined $current_target) {
 788                                                         if (/^#/) {
 789                                                                 # Check if target has commands to execute
 790                                                                 if (/^#\s*commands to execute/) {
 791                                                                         $targets{$current_target} = 1;
 792                                                                 }
 793                                                         }
 794                                                         else {
 795                                                                 # Target parsed.
 796                                                                 $current_target = undef;
 797                                                         }
 798                                                 }
 799                                         }
 800                                         # "Not a target:" is always followed by
 801                                         # a target name, so resetting this one
 802                                         # here is safe.
 803                                         $not_a_target = 0;
 804                                 }
 805                         }
 806                         elsif (/^# Files$/) {
 807                                 $processing_targets = 1;
 808                         }
 809                 }
 810                 close MAKE;
 811                 $rules_parsed = 1;
 812         }
 813
 814         return $targets{$target};
 815 }
 816
 817 }
 818
 819 =head1 SEE ALSO
 820
 821 L<debhelper(7)>
 822
 823 This program is a part of debhelper.
 824
 825 =head1 AUTHOR
 826
 827 Joey Hess <joeyh@debian.org>
 828
 829 =cut