dh

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh - debhelper command sequencer
   6
   7 =cut
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11
  12 =head1 SYNOPSIS
  13
  14 B<dh> I<sequence> [B<--with> I<addon>[B<,>I<addon> ...]] [B<--list>] [B<--until> I<cmd>] [B<--before> I<cmd>] [B<--after> I<cmd>] [B<--remaining>] [S<I<debhelper options>>]
  15
  16 =head1 DESCRIPTION
  17
  18 B<dh> runs a sequence of debhelper commands. The supported I<sequence>s
  19 correspond to the targets of a F<debian/rules> file: B<build-arch>,
  20 B<build-indep>, B<build>, B<clean>, B<install-indep>, B<install-arch>,
  21 B<install>, B<binary-arch>, B<binary-indep>, and B<binary>.
  22
  23 Commands in the B<build-indep>, B<install-indep> and B<binary-indep>
  24 sequences are passed the B<-i> option to ensure they only work on
  25 architecture independent packages, and commands in the B<build-arch>,
  26 B<install-arch> and B<binary-arch> sequences are passed the B<-a>
  27 option to ensure they only work on architecture dependent packages.
  28
  29 If F<debian/rules> contains a target with a name like B<override_>I<dh_command>,
  30 then when it would normally run I<dh_command>, B<dh> will instead call that
  31 target. The override target can then run the command with additional options,
  32 or run entirely different commands instead. See examples below. (Note that to
  33 use this feature, you should Build-Depend on debhelper 7.0.50 or above.)
  34
  35 =head1 OPTIONS
  36
  37 =over 4
  38
  39 =item B<--with> I<addon>[B<,>I<addon> ...]
  40
  41 Add the debhelper commands specified by the given addon to appropriate places
  42 in the sequence of commands that is run. This option can be repeated more
  43 than once, or multiple addons can be listed, separated by commas.
  44 This is used when there is a third-party package that provides
  45 debhelper commands. See the F<PROGRAMMING> file for documentation about
  46 the sequence addon interface.
  47
  48 =item B<--without> I<addon>
  49
  50 The inverse of B<--with>, disables using the given addon.
  51
  52 =item B<--list>, B<-l>
  53
  54 List all available addons.
  55
  56 =item B<--until> I<cmd>
  57
  58 Run commands in the sequence until and including I<cmd>, then stop.
  59
  60 =item B<--before> I<cmd>
  61
  62 Run commands in the sequence before I<cmd>, then stop.
  63
  64 =item B<--after> I<cmd>
  65
  66 Run commands in the sequence that come after I<cmd>.
  67
  68 =item B<--remaining>
  69
  70 Run all commands in the sequence that have yet to be run.
  71
  72 =item B<--no-act>
  73
  74 Prints commands that would run for a given sequence, but does not run them.
  75
  76 =back
  77
  78 All other options passed to B<dh> are passed on to each command it runs. This
  79 can be used to set an option like B<-v> or B<-X> or B<-N>, as well as for more
  80 specialised options.
  81
  82 In the above options, I<cmd> can be a full name of a debhelper command, or
  83 a substring. It'll first search for a command in the sequence exactly
  84 matching the name, to avoid any ambiguity. If there are multiple substring
  85 matches, the last one in the sequence will be used.
  86
  87 =cut
  88
  89 sub command_pos {
  90         my $command=shift;
  91         my @sequence=@_;
  92
  93         foreach my $i (0..$#sequence) {
  94                 if ($command eq $sequence[$i]) {
  95                         return $i;
  96                 }
  97         }
  98
  99         my @matches;
 100         foreach my $i (0..$#sequence) {
 101                 if ($sequence[$i] =~ /\Q$command\E/) {
 102                         push @matches, $i;
 103                 }
 104         }
 105         if (! @matches) {
 106                 error "command specification \"$command\" does not match any command in the sequence"
 107         }
 108         else {
 109                 return pop @matches;
 110         }
 111 }
 112
 113 =head1 EXAMPLES
 114
 115 To see what commands are included in a sequence, without actually doing
 116 anything:
 117
 118         dh binary-arch --no-act
 119
 120 This is a very simple rules file, for packages where the default sequences of
 121 commands work with no additional options.
 122
 123         #!/usr/bin/make -f
 124         %:
 125                 dh $@
 126
 127 Often you'll want to pass an option to a specific debhelper command. The
 128 easy way to do with is by adding an override target for that command.
 129
 130         #!/usr/bin/make -f
 131         %:
 132                 dh $@
 133
 134         override_dh_strip:
 135                 dh_strip -Xfoo
 136
 137         override_dh_installdocs:
 138                 dh_installdocs README TODO
 139
 140 Sometimes the automated L<dh_auto_configure(1)> and L<dh_auto_build(1)>
 141 can't guess what to do for a strange package. Here's how to avoid running
 142 either and instead run your own commands.
 143
 144         #!/usr/bin/make -f
 145         %:
 146                 dh $@
 147
 148         override_dh_auto_configure:
 149                 ./mondoconfig
 150
 151         override_dh_auto_build:
 152                 make universe-explode-in-delight
 153
 154 Another common case is wanting to do something manually before or
 155 after a particular debhelper command is run.
 156
 157         #!/usr/bin/make -f
 158         %:
 159                 dh $@
 160
 161         override_dh_fixperms:
 162                 dh_fixperms
 163                 chmod 4755 debian/foo/usr/bin/foo
 164
 165 If your package is a Python package, B<dh> will use B<dh_pysupport> by
 166 default. This is how to use B<dh_pycentral> instead.
 167
 168         #!/usr/bin/make -f
 169         %:
 170                 dh $@ --with python-central
 171
 172 If your package uses autotools and you want to freshen F<config.sub> and
 173 F<config.guess> with newer versions from the B<autotools-dev> package
 174 at build time, you can use some commands provided in B<autotools-dev>
 175 that automate it, like this.
 176
 177         #!/usr/bin/make -f
 178         %:
 179                 dh $@ --with autotools_dev
 180
 181 Here is how to force use of Perl's B<Module::Build> build system,
 182 which can be necessary if debhelper wrongly detects that the package
 183 uses MakeMaker.
 184
 185         #!/usr/bin/make -f
 186         %:
 187                 dh $@ --buildsystem=perl_build
 188
 189 To patch your package using quilt, you can tell B<dh> to use quilt's B<dh>
 190 sequence addons like this:
 191
 192         #!/usr/bin/make -f
 193         %:
 194                 dh $@ --with quilt
 195
 196 Here is an example of overriding where the B<dh_auto_>I<*> commands find
 197 the package's source, for a package where the source is located in a
 198 subdirectory.
 199
 200         #!/usr/bin/make -f
 201         %:
 202                 dh $@ --sourcedirectory=src
 203
 204 And here is an example of how to tell the B<dh_auto_>I<*> commands to build
 205 in a subdirectory, which will be removed on B<clean>.
 206
 207         #!/usr/bin/make -f
 208         %:
 209                 dh $@ --builddirectory=build
 210
 211 If your package can be built in parallel, you can support parallel building
 212 as follows. Then B<dpkg-buildpackage -j> will work.
 213
 214         #!/usr/bin/make -f
 215         %:
 216                 dh $@ --parallel
 217
 218 Here is a way to prevent B<dh> from running several commands that you don't
 219 want it to run, by defining empty override targets for each command.
 220
 221         #!/usr/bin/make -f
 222         %:
 223                 dh $@
 224
 225         # Commands not to run:
 226         override_dh_auto_test override_dh_compress override_dh_fixperms:
 227
 228 Sometimes, you may need to make an override target only run commands when a
 229 particular package is being built. This can be accomplished using
 230 L<dh_listpackages(1)> to test what is being built. For example:
 231
 232         #!/usr/bin/make -f
 233         %:
 234                 dh $@
 235
 236         override_dh_fixperms:
 237                 dh_fixperms
 238         ifneq (,$(filter foo, $(shell dh_listpackages)))
 239                 chmod 4755 debian/foo/usr/bin/foo
 240         endif
 241
 242 Finally, remember that you are not limited to using override targets in the
 243 rules file when using B<dh>. You can also explicitly define any of the regular
 244 rules file targets when it makes sense to do so. A common reason to do this
 245 is if your package needs different B<build-arch> and B<build-indep> targets. For
 246 example, a package with a long document build process can put it in
 247 B<build-indep> to avoid build daemons redundantly building the documentation.
 248
 249         #!/usr/bin/make -f
 250         %:
 251                 dh $@
 252
 253         build: build-arch build-indep ;
 254         build-indep:
 255                 $(MAKE) docs
 256         build-arch:
 257                 $(MAKE) bins
 258
 259 =head1 INTERNALS
 260
 261 If you're curious about B<dh>'s internals, here's how it works under the hood.
 262
 263 Each debhelper command will record when it's successfully run in
 264 F<debian/package.debhelper.log>. (Which B<dh_clean> deletes.) So B<dh> can tell
 265 which commands have already been run, for which packages, and skip running
 266 those commands again.
 267
 268 Each time B<dh> is run, it examines the log, and finds the last logged command
 269 that is in the specified sequence. It then continues with the next command
 270 in the sequence. The B<--until>, B<--before>, B<--after>, and B<--remaining>
 271 options can override this behavior.
 272
 273 A sequence can also have dependencies.  For example, the "binary"
 274 sequence depends upon the "binary-arch" and "binary-indep" sequences,
 275 and the "binary-arch" sequence depends upon the "install-arch"
 276 sequence which in turn depends upon the "build-arch" sequence.  These
 277 will, by default, be run via "debian/rules <sequence>" and so may be
 278 overridden or extended there, or else will run dh again to execute the
 279 depending sequence.  For example, "dh binary-arch" will run
 280 "debian/rules install-arch" which will run "dh install-arch" unless a
 281 custom install-arch target replaces the default target.
 282
 283 B<dh> uses the B<DH_INTERNAL_OPTIONS> environment variable to pass information
 284 through to debhelper commands that are run inside override targets. The
 285 contents (and indeed, existence) of this environment variable, as the name
 286 might suggest, is subject to change at any time.
 287
 288 =cut
 289
 290 # Stash this away before init modifies it.
 291 my @ARGV_orig=@ARGV;
 292
 293 # python-support is enabled by default, at least for now
 294 # (and comes first so python-central loads later and can disable it).
 295 unshift @ARGV, "--with=python-support";
 296
 297 init(options => {
 298                 "until=s" => \$dh{UNTIL},
 299                 "after=s" => \$dh{AFTER},
 300                 "before=s" => \$dh{BEFORE},
 301                 "remaining" => \$dh{REMAINING},
 302                 "with=s" => sub {
 303                         my ($option,$value)=@_;
 304                         push @{$dh{WITH}},split(",", $value);
 305                 },
 306                 "without=s" => sub {
 307                         my ($option,$value)=@_;
 308                         @{$dh{WITH}} = grep { $_ ne $value } @{$dh{WITH}};
 309                 },
 310                 "l" => \&list_addons,
 311                 "list" => \&list_addons,
 312         },
 313         # Disable complaints about unknown options; they are passed on to
 314         # the debhelper commands.
 315         ignore_unknown_options => 1,
 316         # Bundling does not work well since there are unknown options.
 317         bundling => 0,
 318 );
 319 inhibit_log();
 320
 321
 322 # If make is using a jobserver, but it is not available
 323 # to this process, clean out MAKEFLAGS. This avoids
 324 # ugly warnings when calling make.
 325 if (is_make_jobserver_unavailable()) {
 326         clean_jobserver_makeflags();
 327 }
 328
 329 # Definitions of sequences.
 330 my %sequences;
 331 my @bd = qw{
 332         dh_testdir
 333         dh_auto_configure
 334         dh_auto_build
 335         dh_auto_test
 336 };
 337 $sequences{build} = [@bd];
 338 $sequences{'build-indep'} = [@bd];
 339 $sequences{'build-arch'} = [@bd];
 340 $sequences{clean} = [qw{
 341         dh_testdir
 342         dh_auto_clean
 343         dh_clean
 344 }];
 345 my @i = qw{
 346         dh_testroot
 347         dh_prep
 348         dh_installdirs
 349         dh_auto_install
 350
 351         dh_install
 352         dh_installdocs
 353         dh_installchangelogs
 354         dh_installexamples
 355         dh_installman
 356
 357         dh_installcatalogs
 358         dh_installcron
 359         dh_installdebconf
 360         dh_installemacsen
 361         dh_installifupdown
 362         dh_installinfo
 363         dh_installinit
 364         dh_installmenu
 365         dh_installmime
 366         dh_installmodules
 367         dh_installlogcheck
 368         dh_installlogrotate
 369         dh_installpam
 370         dh_installppp
 371         dh_installudev
 372         dh_installwm
 373         dh_installxfonts
 374         dh_bugfiles
 375         dh_lintian
 376         dh_gconf
 377         dh_icons
 378         dh_perl
 379         dh_usrlocal
 380
 381         dh_link
 382         dh_compress
 383         dh_fixperms
 384 };
 385 $sequences{'install'} = [@i];
 386 $sequences{'install-indep'} = [@i];
 387 $sequences{'install-arch'} = [@i];
 388 my @ba=qw{
 389         dh_strip
 390         dh_makeshlibs
 391         dh_shlibdeps
 392 };
 393 my @b=qw{
 394         dh_installdeb
 395         dh_gencontrol
 396         dh_md5sums
 397         dh_builddeb
 398 };
 399 $sequences{binary} = [@ba, @b];
 400 $sequences{'binary-indep'} = [@b];
 401 $sequences{'binary-arch'} = [@ba, @b];
 402
 403 # Sequence dependencies
 404 my %sequence_deps;
 405 $sequence_deps{build} = ['build-arch', 'build-indep'];
 406 $sequence_deps{install} = ['install-arch', 'install-indep'];
 407 $sequence_deps{'install-arch'} = ['build-arch'];
 408 $sequence_deps{'install-indep'} = ['build-indep'];
 409 $sequence_deps{binary} = ['binary-arch', 'binary-indep'];
 410 $sequence_deps{'binary-arch'} = ['install-arch'];
 411 $sequence_deps{'binary-indep'} = ['install-indep'];
 412
 413 # Additional command options
 414 my %command_opts;
 415
 416 # sequence addon interface
 417 sub _insert {
 418         my $offset=shift;
 419         my $existing=shift;
 420         my $new=shift;
 421         foreach my $sequence (keys %sequences) {
 422                 my @list=@{$sequences{$sequence}};
 423                 next unless grep $existing, @list;
 424                 my @new;
 425                 foreach my $command (@list) {
 426                         if ($command eq $existing) {
 427                                 push @new, $new if $offset < 0;
 428                                 push @new, $command;
 429                                 push @new, $new if $offset > 0;
 430                         }
 431                         else {
 432                                 push @new, $command;
 433                         }
 434                 }
 435                 $sequences{$sequence}=\@new;
 436         }
 437 }
 438 sub insert_before {
 439         _insert(-1, @_);
 440 }
 441 sub insert_after {
 442         _insert(1, @_);
 443 }
 444 sub remove_command {
 445         my $command=shift;
 446         foreach my $sequence (keys %sequences) {
 447                 $sequences{$sequence}=[grep { $_ ne $command } @{$sequences{$sequence}}];
 448         }
 449
 450 }
 451 sub add_command {
 452         my $command=shift;
 453         my $sequence=shift;
 454         unshift @{$sequences{$sequence}}, $command;
 455 }
 456 sub add_command_options {
 457         my $command=shift;
 458         push @{$command_opts{$command}}, @_;
 459 }
 460 sub remove_command_options {
 461         my $command=shift;
 462         if (@_) {
 463                 # Remove only specified options
 464                 if (my $opts = $command_opts{$command}) {
 465                         foreach my $opt (@_) {
 466                                 $opts = [ grep { $_ ne $opt } @$opts ];
 467                         }
 468                         $command_opts{$command} = $opts;
 469                 }
 470         }
 471         else {
 472                 # Clear all additional options
 473                 delete $command_opts{$command};
 474         }
 475 }
 476
 477 sub list_addons {
 478         my %addons;
 479
 480         for my $inc (@INC) {
 481                 eval q{use File::Spec};
 482                 my $path = File::Spec->catdir($inc, "Debian/Debhelper/Sequence");
 483                 if (-d $path) {
 484                         for my $module_path (glob "$path/*.pm") {
 485                                 my $name = basename($module_path);
 486                                 $name =~ s/\.pm$//;
 487                                 $name =~ s/_/-/g;
 488                                 $addons{$name} = 1;
 489                         }
 490                 }
 491         }
 492
 493         for my $name (sort keys %addons) {
 494                 print "$name\n";
 495         }
 496
 497         exit 0;
 498 }
 499
 500 foreach my $addon (@{$dh{WITH}}) {
 501         my $mod="Debian::Debhelper::Sequence::$addon";
 502         $mod=~s/-/_/g;
 503         eval "use $mod";
 504         if ($@) {
 505                 error("unable to load addon $addon: $@");
 506         }
 507 }
 508
 509 my $sequence;
 510 if (! compat(7)) {
 511         # From v8, the sequence is the very first parameter.
 512         $sequence=shift @ARGV_orig;
 513         if ($sequence=~/^-/) {
 514                 error "Unknown sequence $sequence (options should not come before the sequence)";
 515         }
 516 }
 517 else {
 518         # Before v8, the sequence could be at any position in the parameters,
 519         # so was what was left after parsing.
 520         $sequence=shift;
 521         if (defined $sequence) {
 522                 @ARGV_orig=grep { $_ ne $sequence } @ARGV_orig;
 523         }
 524 }
 525 if (! defined $sequence) {
 526         error "specify a sequence to run";
 527 }
 528 if ($sequence eq 'debian/rules' ||
 529     $sequence =~ /^override_dh_/) {
 530         # make -B causes the rules file to be run as a target.
 531         # Also support completly empty override targets.
 532         exit 0;
 533 }
 534 elsif (! exists $sequences{$sequence}) {
 535         error "Unknown sequence $sequence (choose from: ".
 536                 join(" ", sort keys %sequences).")";
 537 }
 538 my @sequence=@{$sequences{$sequence}};
 539
 540 # Recursively invoke sequence dependencies before any further processing.
 541 # The dh options are not passed in the environment, to ensure that the
 542 # behaviour is the same if invoked directly.
 543 my $deps = undef;
 544 $deps = $sequence_deps{$sequence}
 545         if (exists($sequence_deps{$sequence}));
 546 if (defined($deps)) {
 547         foreach my $dep (@$deps) {
 548                 my $command = 'debian/rules';
 549                 my @dep_options = ($dep);
 550                 print "   ".escape_shell($command, @dep_options)."\n";
 551                 if (! $dh{NO_ACT}) {
 552                         my $ret=system($command, @dep_options);
 553                         if ($ret >> 8 != 0) {
 554                                 exit $ret >> 8;
 555                         }
 556                         elsif ($ret) {
 557                                 exit 1;
 558                         }
 559                 }
 560         }
 561 }
 562
 563 # The list of all packages that can be acted on.
 564 my @packages=@{$dh{DOPACKAGES}};
 565
 566 # Get the options to pass to commands in the sequence.
 567 # Filter out options intended only for this program.
 568 my @options;
 569 if ($sequence eq 'build-arch' ||
 570     $sequence eq 'install-arch' ||
 571     $sequence eq 'binary-arch') {
 572         push @options, "-a";
 573         # as an optimisation, remove from the list any packages
 574         # that are not arch dependent
 575         my %arch_packages = map { $_ => 1 } getpackages("arch");
 576         @packages = grep { $arch_packages{$_} } @packages;
 577 }
 578 elsif ($sequence eq 'build-indep' ||
 579        $sequence eq 'install-indep' ||
 580        $sequence eq 'binary-indep') {
 581         push @options, "-i";
 582         # ditto optimisation for arch indep
 583         my %indep_packages = map { $_ => 1 } getpackages("indep");
 584         @packages = grep { $indep_packages{$_} } @packages;
 585 }
 586 while (@ARGV_orig) {
 587         my $opt=shift @ARGV_orig;
 588         if ($opt =~ /^--?(after|until|before|with|without)$/) {
 589                 shift @ARGV_orig;
 590                 next;
 591         }
 592         elsif ($opt =~ /^--?(no-act|remaining|(after|until|before|with|without)=)/) {
 593                 next;
 594         }
 595         elsif ($opt=~/^-/) {
 596                 push @options, "-O".$opt;
 597         }
 598         elsif (@options) {
 599                 if ($options[$#options]=~/^-O--/) {
 600                         $options[$#options].="=".$opt;
 601                 }
 602                 else {
 603                         $options[$#options].=$opt;
 604                 }
 605         }
 606 }
 607
 608 # Figure out at what point in the sequence to start for each package.
 609 my %logged;
 610 my %startpoint;
 611 foreach my $package (@packages) {
 612         my @log=load_log($package, \%logged);
 613         if ($dh{AFTER}) {
 614                 # Run commands in the sequence that come after the
 615                 # specified command.
 616                 $startpoint{$package}=command_pos($dh{AFTER}, @sequence) + 1;
 617                 # Write a dummy log entry indicating that the specified
 618                 # command was, in fact, run. This handles the case where
 619                 # no commands remain to run after it, communicating to
 620                 # future dh instances that the specified command should not
 621                 # be run again.
 622                 write_log($sequence[$startpoint{$package}-1], $package);
 623         }
 624         elsif ($dh{REMAINING}) {
 625                 # Start at the beginning so all remaining commands will get
 626                 # run.
 627                 $startpoint{$package}=0;
 628         }
 629         else {
 630                 # Find the last logged command that is in the sequence, and
 631                 # continue with the next command after it. If no logged
 632                 # command is in the sequence, we're starting at the beginning..
 633                 $startpoint{$package}=0;
 634 COMMAND:        foreach my $command (reverse @log) {
 635                         foreach my $i (0..$#sequence) {
 636                                 if ($command eq $sequence[$i]) {
 637                                         $startpoint{$package}=$i+1;
 638                                         last COMMAND;
 639                                 }
 640                         }
 641                 }
 642         }
 643 }
 644
 645 # Figure out what point in the sequence to go to.
 646 my $stoppoint=$#sequence;
 647 if ($dh{UNTIL}) {
 648         $stoppoint=command_pos($dh{UNTIL}, @sequence);
 649 }
 650 elsif ($dh{BEFORE}) {
 651         $stoppoint=command_pos($dh{BEFORE}, @sequence) - 1;
 652 }
 653
 654 # Now run the commands in the sequence.
 655 foreach my $i (0..$stoppoint) {
 656         # Figure out which packages need to run this command.
 657         my @exclude;
 658         foreach my $package (@packages) {
 659                 if ($startpoint{$package} > $i ||
 660                     $logged{$package}{$sequence[$i]}) {
 661                         push @exclude, $package;
 662                 }
 663         }
 664
 665         if (@exclude eq @packages) {
 666                 # Command already done for all packages.
 667                 next;
 668         }
 669
 670         run($sequence[$i], \@packages, \@exclude, @options);
 671 }
 672
 673 sub run {
 674         my $command=shift;
 675         my @packages=@{shift()};
 676         my @exclude=@{shift()};
 677         my @options=@_;
 678
 679         # If some packages are excluded, add flags
 680         # to prevent them from being acted on.
 681         push @options, map { "-N$_" } @exclude;
 682
 683         # Check for override targets in debian/rules and
 684         # run them instead of running the command directly.
 685         my $override_command;
 686         my $has_explicit_target = rules_explicit_target("override_".$command);
 687         if (defined $has_explicit_target) {
 688                 $override_command=$command;
 689                 # Check if target isn't noop
 690                 if ($has_explicit_target) {
 691                         # This passes the options through to commands called
 692                         # inside the target.
 693                         $ENV{DH_INTERNAL_OPTIONS}=join("\x1e", @options);
 694                         # Prevent commands called inside the target from
 695                         # logging.
 696                         $ENV{DH_INHIBIT_LOG}=$command;
 697                         $command="debian/rules";
 698                         @options="override_".$override_command;
 699                 }
 700                 else {
 701                         $command = undef;
 702                 }
 703         }
 704         else {
 705                 # Pass additional command options if any
 706                 unshift @options, @{$command_opts{$command}} if exists $command_opts{$command};
 707         }
 708
 709         if (defined $command) {
 710                 # 3 space indent lines the command being run up under the
 711                 # sequence name after "dh ".
 712                 print "   ".escape_shell($command, @options)."\n";
 713         }
 714         else {
 715                 print "   ", "# Skipping ", $override_command, " - empty override", "\n";
 716         }
 717
 718         if (! $dh{NO_ACT}) {
 719                 if (defined $command) {
 720                         my $ret=system($command, @options);
 721                         if ($ret >> 8 != 0) {
 722                                 exit $ret >> 8;
 723                         }
 724                         elsif ($ret) {
 725                                 exit 1;
 726                         }
 727                 }
 728
 729                 if (defined $override_command) {
 730                         delete $ENV{DH_INTERNAL_OPTIONS};
 731                         delete $ENV{DH_INHIBIT_LOG};
 732                         # Update log for overridden command now that it has
 733                         # finished successfully.
 734                         # (But avoid logging for dh_clean since it removes
 735                         # the log earlier.)
 736                         if ($override_command ne 'dh_clean') {
 737                                 my %packages=map { $_ => 1 } @packages;
 738                                 map { delete $packages{$_} } @exclude;
 739                                 write_log($override_command, keys %packages);
 740                         }
 741                 }
 742         }
 743 }
 744
 745 {
 746 my %targets;
 747 my $rules_parsed;
 748
 749 sub rules_explicit_target {
 750         # Checks if a specified target exists as an explicit target
 751         # in debian/rules.
 752         # undef is returned if target does not exist, 0 if target is noop
 753         # and 1 if target has dependencies or executes commands.
 754         my $target=shift;
 755
 756         if (! $rules_parsed) {
 757                 my $processing_targets = 0;
 758                 my $not_a_target = 0;
 759                 my $current_target;
 760                 open(MAKE, "LC_ALL=C make -Rrnpsf debian/rules debhelper-fail-me 2>/dev/null |");
 761                 while (<MAKE>) {
 762                         if ($processing_targets) {
 763                                 if (/^# Not a target:/) {
 764                                         $not_a_target = 1;
 765                                 }
 766                                 else {
 767                                         if (!$not_a_target && /^([^#:]+)::?\s*(.*)$/) {
 768                                                 # Target is defined. NOTE: if it is a depenency of
 769                                                 # .PHONY it will be defined too but that's ok.
 770                                                 # $2 contains target dependencies if any.
 771                                                 $current_target = $1;
 772                                                 $targets{$current_target} = ($2) ? 1 : 0;
 773                                         }
 774                                         else {
 775                                                 if (defined $current_target) {
 776                                                         if (/^#/) {
 777                                                                 # Check if target has commands to execute
 778                                                                 if (/^#\s*commands to execute/) {
 779                                                                         $targets{$current_target} = 1;
 780                                                                 }
 781                                                         }
 782                                                         else {
 783                                                                 # Target parsed.
 784                                                                 $current_target = undef;
 785                                                         }
 786                                                 }
 787                                         }
 788                                         # "Not a target:" is always followed by
 789                                         # a target name, so resetting this one
 790                                         # here is safe.
 791                                         $not_a_target = 0;
 792                                 }
 793                         }
 794                         elsif (/^# Files$/) {
 795                                 $processing_targets = 1;
 796                         }
 797                 }
 798                 close MAKE;
 799                 $rules_parsed = 1;
 800         }
 801
 802         return $targets{$target};
 803 }
 804
 805 }
 806
 807 =head1 SEE ALSO
 808
 809 L<debhelper(7)>
 810
 811 This program is a part of debhelper.
 812
 813 =head1 AUTHOR
 814
 815 Joey Hess <joeyh@debian.org>
 816
 817 =cut