dh

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh - debhelper command sequencer
   6
   7 =cut
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11
  12 =head1 SYNOPSIS
  13
  14 B<dh> sequence [B<--with> I<addon>[,I<addon>,...]] [B<--list>] [B<--until> I<cmd>] [B<--before> I<cmd>] [B<--after> I<cmd>] [B<--remaining>] [S<I<debhelper options>>]
  15
  16 =head1 DESCRIPTION
  17
  18 dh runs a sequence of debhelper commands. The supported sequences
  19 correspond to the targets of a debian/rules file: "build", "clean",
  20 "install", "binary-arch", "binary-indep", and "binary".
  21
  22 Commands in the binary-indep sequence are passed the "-i" option to ensure
  23 they only work on binary independent packages, and commands in the
  24 binary-arch sequences are passed the "-a" option to ensure they only work
  25 on architecture dependent packages.
  26
  27 Each debhelper command will record when it's successfully run in
  28 debian/package.debhelper.log. (Which dh_clean deletes.) So dh can tell
  29 which commands have already been run, for which packages, and skip running
  30 those commands again.
  31
  32 Each time dh is run, it examines the log, and finds the last logged command
  33 that is in the specified sequence. It then continues with the next command
  34 in the sequence. The B<--until>, B<--before>, B<--after>, and B<--remaining>
  35 options can override this behavior.
  36
  37 If debian/rules contains a target with a name like "override_I<dh_command>",
  38 then when it gets to that command in the sequence, dh will run that
  39 target from the rules file, rather than running the actual command. The
  40 override target can then run the command with additional options, or run
  41 entirely different commands instead. (Note that to use this feature,
  42 you should Build-Depend on debhelper 7.0.50 or above.)
  43
  44 =head1 OPTIONS
  45
  46 =over 4
  47
  48 =item B<--with> I<addon>[,I<addon>,...]
  49
  50 Add the debhelper commands specified by the given addon to appropriate places
  51 in the sequence of commands that is run. This option can be repeated more
  52 than once, or multiple addons can be listed, separated by commas.
  53 This is used when there is a third-party package that provides
  54 debhelper commands. See the PROGRAMMING file for documentation about
  55 the sequence addon interface.
  56
  57 =item B<--without> I<addon>
  58
  59 The inverse of --with, disables using the given addon.
  60
  61 =item B<--list>, B<-l>
  62
  63 List all available addons.
  64
  65 =item B<--until> I<cmd>
  66
  67 Run commands in the sequence until and including I<cmd>, then stop.
  68
  69 =item B<--before> I<cmd>
  70
  71 Run commands in the sequence before I<cmd>, then stop.
  72
  73 =item B<--after> I<cmd>
  74
  75 Run commands in the sequence that come after I<cmd>.
  76
  77 =item B<--remaining>
  78
  79 Run all commands in the sequence that have yet to be run.
  80
  81 =back
  82
  83 All other options passed to dh are passed on to each command it runs. This
  84 can be used to set an option like "-v" or "-X" or "-N", as well as for more
  85 specialised options.
  86
  87 =head1 COMMAND SPECIFICATION
  88
  89 I<cmd> can be a full name of a debhelper command, or a substring. It'll first
  90 search for a command in the sequence exactly matching the name, to avoid any
  91 ambiguity. If there are multiple substring matches, the last one in the
  92 sequence will be used.
  93
  94 =cut
  95
  96 sub command_pos {
  97         my $command=shift;
  98         my @sequence=@_;
  99
 100         foreach my $i (0..$#sequence) {
 101                 if ($command eq $sequence[$i]) {
 102                         return $i;
 103                 }
 104         }
 105
 106         my @matches;
 107         foreach my $i (0..$#sequence) {
 108                 if ($sequence[$i] =~ /\Q$command\E/) {
 109                         push @matches, $i;
 110                 }
 111         }
 112         if (! @matches) {
 113                 error "command specification \"$command\" does not match any command in the sequence"
 114         }
 115         else {
 116                 return pop @matches;
 117         }
 118 }
 119
 120 =head1 EXAMPLES
 121
 122 To see what commands are included in a sequence, without actually doing
 123 anything:
 124
 125         dh binary-arch --no-act
 126
 127 This is a very simple rules file, for packages where the default sequences of
 128 commands work with no additional options.
 129
 130         #!/usr/bin/make -f
 131         %:
 132                 dh $@
 133
 134 Often you'll want to pass an option to a specific debhelper command. The
 135 easy way to do with is by adding an override target for that command.
 136
 137         #!/usr/bin/make -f
 138         %:
 139                 dh $@
 140
 141         override_dh_strip:
 142                 dh_strip -Xfoo
 143
 144         override_dh_installdocs:
 145                 dh_installdocs README TODO
 146
 147 Sometimes the automated dh_auto_configure and dh_auto_build can't guess
 148 what to do for a strange package. Here's how to avoid running either
 149 and instead run your own commands.
 150
 151         #!/usr/bin/make -f
 152         %:
 153                 dh $@
 154
 155         override_dh_auto_configure:
 156                 ./mondoconfig
 157
 158         override_dh_auto_build:
 159                 make universe-explode-in-delight
 160
 161 Another common case is wanting to do something manually before or
 162 after a particular debhelper command is run.
 163
 164         #!/usr/bin/make -f
 165         %:
 166                 dh $@
 167
 168         override_dh_fixperms:
 169                 dh_fixperms
 170                 chmod 4755 debian/foo/usr/bin/foo
 171
 172 If your package is a python package, dh will use dh_pysupport by
 173 default. This is how to use dh_pycentral instead.
 174
 175         #!/usr/bin/make -f
 176         %:
 177                 dh --with python-central $@
 178
 179 To patch your package using quilt, you can tell dh to use quilt's dh
 180 sequence addons like this:
 181
 182         #!/usr/bin/make -f
 183         %:
 184                 dh --with quilt $@
 185
 186 Here is an example of overriding where the dh_auto_* commands find
 187 the package's source, for a package where the source is located in a
 188 subdirectory. It also forces use of perl's Module::Build build system,
 189 which can be necessary if debhelper wrongly detects that the package
 190 uses MakeMaker.
 191
 192         #!/usr/bin/make -f
 193         %:
 194                 dh --sourcedirectory=src --buildsystem=perl_build $@
 195
 196 =cut
 197
 198 # Stash this away before init modifies it.
 199 my @ARGV_orig=@ARGV;
 200
 201 # python-support is enabled by default, at least for now
 202 # (and comes first so python-central loads later and can disable it).
 203 unshift @ARGV, "--with=python-support";
 204
 205 # Disable complaints about unknown options for both dh and the commands
 206 # it runs. This is done because dh accepts and passes on options that may
 207 # be specific to only some debhelper commands.
 208 $ENV{DH_IGNORE_UNKNOWN_OPTIONS}=1;
 209
 210 init(options => {
 211         "until=s" => \$dh{UNTIL},
 212         "after=s" => \$dh{AFTER},
 213         "before=s" => \$dh{BEFORE},
 214         "remaining" => \$dh{REMAINING},
 215         "with=s" => sub {
 216                 my ($option,$value)=@_;
 217                 push @{$dh{WITH}},split(",", $value);
 218         },
 219         "without=s" => sub {
 220                 my ($option,$value)=@_;
 221                 @{$dh{WITH}} = grep { $_ ne $value } @{$dh{WITH}};
 222         },
 223         "l" => \$dh{LIST},
 224         "list" => \$dh{LIST},
 225 });
 226 inhibit_log();
 227
 228 # Definitions of sequences.
 229 my %sequences;
 230 $sequences{build} = [qw{
 231         dh_testdir
 232         dh_auto_configure
 233         dh_auto_build
 234         dh_auto_test
 235 }],
 236 $sequences{clean} = [qw{
 237         dh_testdir
 238         dh_auto_clean
 239         dh_clean
 240 }];
 241 $sequences{install} = [@{$sequences{build}}, qw{
 242         dh_testroot
 243         dh_prep
 244         dh_installdirs
 245         dh_auto_install
 246
 247         dh_install
 248         dh_installdocs
 249         dh_installchangelogs
 250         dh_installexamples
 251         dh_installman
 252
 253         dh_installcatalogs
 254         dh_installcron
 255         dh_installdebconf
 256         dh_installemacsen
 257         dh_installifupdown
 258         dh_installinfo
 259         dh_installinit
 260         dh_installmenu
 261         dh_installmime
 262         dh_installmodules
 263         dh_installlogcheck
 264         dh_installlogrotate
 265         dh_installpam
 266         dh_installppp
 267         dh_installudev
 268         dh_installwm
 269         dh_installxfonts
 270         dh_bugfiles
 271         dh_lintian
 272         dh_gconf
 273         dh_icons
 274         dh_perl
 275         dh_usrlocal
 276
 277         dh_link
 278         dh_compress
 279         dh_fixperms
 280 }];
 281 my @b=qw{
 282         dh_installdeb
 283         dh_gencontrol
 284         dh_md5sums
 285         dh_builddeb
 286 };
 287 $sequences{'binary-indep'} = [@{$sequences{install}}, @b];
 288 $sequences{binary} = [@{$sequences{install}}, qw{
 289         dh_strip
 290         dh_makeshlibs
 291         dh_shlibdeps
 292 }, @b];
 293 $sequences{'binary-arch'} = [@{$sequences{binary}}];
 294
 295 # Additional command options
 296 my %command_opts;
 297
 298 # sequence addon interface
 299 sub _insert {
 300         my $offset=shift;
 301         my $existing=shift;
 302         my $new=shift;
 303         foreach my $sequence (keys %sequences) {
 304                 my @list=@{$sequences{$sequence}};
 305                 next unless grep $existing, @list;
 306                 my @new;
 307                 foreach my $command (@list) {
 308                         if ($command eq $existing) {
 309                                 push @new, $new if $offset < 0;
 310                                 push @new, $command;
 311                                 push @new, $new if $offset > 0;
 312                         }
 313                         else {
 314                                 push @new, $command;
 315                         }
 316                 }
 317                 $sequences{$sequence}=\@new;
 318         }
 319 }
 320 sub insert_before {
 321         _insert(-1, @_);
 322 }
 323 sub insert_after {
 324         _insert(1, @_);
 325 }
 326 sub remove_command {
 327         my $command=shift;
 328         foreach my $sequence (keys %sequences) {
 329                 $sequences{$sequence}=[grep { $_ ne $command } @{$sequences{$sequence}}];
 330         }
 331
 332 }
 333 sub add_command {
 334         my $command=shift;
 335         my $sequence=shift;
 336         unshift @{$sequences{$sequence}}, $command;
 337 }
 338 sub add_command_options {
 339         my $command=shift;
 340         push @{$command_opts{$command}}, @_;
 341 }
 342 sub remove_command_options {
 343         my $command=shift;
 344         if (@_) {
 345                 # Remove only specified options
 346                 if (my $opts = $command_opts{$command}) {
 347                         foreach my $opt (@_) {
 348                                 $opts = [ grep { $_ ne $opt } @$opts ];
 349                         }
 350                         $command_opts{$command} = $opts;
 351                 }
 352         }
 353         else {
 354                 # Clear all additional options
 355                 delete $command_opts{$command};
 356         }
 357 }
 358
 359 if ($dh{LIST}) {
 360         my %addons;
 361
 362         for my $inc (@INC) {
 363                 eval q{use File::Spec};
 364                 my $path = File::Spec->catdir($inc, "Debian/Debhelper/Sequence");
 365                 if (-d $path) {
 366                         for my $module_path (glob "$path/*.pm") {
 367                                 my $name = basename($module_path);
 368                                 $name =~ s/\.pm$//;
 369                                 $name =~ s/_/-/g;
 370                                 $addons{$name} = 1;
 371                         }
 372                 }
 373         }
 374
 375         for my $name (sort keys %addons) {
 376                 print "$name\n";
 377         }
 378
 379         exit 0;
 380 }
 381
 382 foreach my $addon (@{$dh{WITH}}) {
 383         my $mod="Debian::Debhelper::Sequence::$addon";
 384         $mod=~s/-/_/g;
 385         eval "use $mod";
 386         if ($@) {
 387                 error("unable to load addon $addon: $@");
 388         }
 389 }
 390
 391 # Get the sequence of commands to run.
 392 if (! @ARGV) {
 393         error "specify a sequence to run";
 394 }
 395 my $sequence=shift;
 396 if ($sequence eq 'debian/rules' ||
 397     $sequence =~ /^override_dh_/) {
 398         # make -B causes the rules file to be run as a target
 399         # and support completly empty override targets
 400         exit 0
 401 }
 402 elsif (! exists $sequences{$sequence}) {
 403         error "Unknown sequence $sequence (choose from: ".
 404                 join(" ", sort keys %sequences).")";
 405 }
 406 my @sequence=@{$sequences{$sequence}};
 407
 408 # The list of all packages that can be acted on.
 409 my @packages=@{$dh{DOPACKAGES}};
 410
 411 # Get the options to pass to commands in the sequence.
 412 # Filter out options intended only for this program.
 413 my @options;
 414 if ($sequence eq 'binary-arch') {
 415         push @options, "-a";
 416         # as an optimisation, remove from the list any packages
 417         # that are not arch dependent
 418         my %arch_packages = map { $_ => 1 } getpackages("arch");
 419         @packages = grep { $arch_packages{$_} } @packages;
 420 }
 421 elsif ($sequence eq 'binary-indep') {
 422         push @options, "-i";
 423         # ditto optimisation for arch indep
 424         my %indep_packages = map { $_ => 1 } getpackages("indep");
 425         @packages = grep { $indep_packages{$_} } @packages;
 426 }
 427 while (@ARGV_orig) {
 428         my $opt=shift @ARGV_orig;
 429         next if $opt eq $sequence;
 430         if ($opt =~ /^--?(after|until|before|with|without)$/) {
 431                 shift @ARGV_orig;
 432                 next;
 433         }
 434         elsif ($opt =~ /^--?(no-act|remaining|(after|until|before|with|without)=)/) {
 435                 next;
 436         }
 437         push @options, $opt;
 438 }
 439
 440 # Figure out at what point in the sequence to start for each package.
 441 my %logged;
 442 my %startpoint;
 443 foreach my $package (@packages) {
 444         my @log=load_log($package, \%logged);
 445         if ($dh{AFTER}) {
 446                 # Run commands in the sequence that come after the
 447                 # specified command.
 448                 $startpoint{$package}=command_pos($dh{AFTER}, @sequence) + 1;
 449                 # Write a dummy log entry indicating that the specified
 450                 # command was, in fact, run. This handles the case where
 451                 # no commands remain to run after it, communicating to
 452                 # future dh instances that the specified command should not
 453                 # be run again.
 454                 write_log($sequence[$startpoint{$package}-1], $package);
 455         }
 456         elsif ($dh{REMAINING}) {
 457                 # Start at the beginning so all remaining commands will get
 458                 # run.
 459                 $startpoint{$package}=0;
 460         }
 461         else {
 462                 # Find the last logged command that is in the sequence, and
 463                 # continue with the next command after it. If no logged
 464                 # command is in the sequence, we're starting at the beginning..
 465                 $startpoint{$package}=0;
 466 COMMAND:        foreach my $command (reverse @log) {
 467                         foreach my $i (0..$#sequence) {
 468                                 if ($command eq $sequence[$i]) {
 469                                         $startpoint{$package}=$i+1;
 470                                         last COMMAND;
 471                                 }
 472                         }
 473                 }
 474         }
 475 }
 476
 477 # Figure out what point in the sequence to go to.
 478 my $stoppoint=$#sequence;
 479 if ($dh{UNTIL}) {
 480         $stoppoint=command_pos($dh{UNTIL}, @sequence);
 481 }
 482 elsif ($dh{BEFORE}) {
 483         $stoppoint=command_pos($dh{BEFORE}, @sequence) - 1;
 484 }
 485
 486 # Now run the commands in the sequence.
 487 foreach my $i (0..$stoppoint) {
 488         # Figure out which packages need to run this command.
 489         my @exclude;
 490         foreach my $package (@packages) {
 491                 if ($startpoint{$package} > $i ||
 492                     $logged{$package}{$sequence[$i]}) {
 493                         push @exclude, $package;
 494                 }
 495         }
 496
 497         if (@exclude eq @packages) {
 498                 # Command already done for all packages.
 499                 next;
 500         }
 501
 502         run($sequence[$i], \@packages, \@exclude, @options);
 503 }
 504
 505 sub run {
 506         my $command=shift;
 507         my @packages=@{shift()};
 508         my @exclude=@{shift()};
 509         my @options=@_;
 510
 511         # If some packages are excluded, add flags
 512         # to prevent them from being acted on.
 513         push @options, map { "-N$_" } @exclude;
 514
 515         # Check for override targets in debian/rules and
 516         # run them instead of running the command directly.
 517         my $override_command;
 518         if (rules_explicit_target("override_".$command)) {
 519                 $override_command=$command;
 520                 # This passes the options through to commands called
 521                 # inside the target.
 522                 $ENV{DH_INTERNAL_OPTIONS}=join("\x1e", @options);
 523                 $command="debian/rules";
 524                 @options="override_".$override_command;
 525         }
 526         else {
 527                 # Pass additional command options if any
 528                 unshift @options, @{$command_opts{$command}} if exists $command_opts{$command};
 529         }
 530
 531         # 3 space indent lines the command being run up under the
 532         # sequence name after "dh ".
 533         print "   ".escape_shell($command, @options)."\n";
 534
 535         if (! $dh{NO_ACT}) {
 536                 my $ret=system($command, @options);
 537                 if ($ret >> 8 != 0) {
 538                         exit $ret >> 8;
 539                 }
 540                 elsif ($ret) {
 541                         exit 1;
 542                 }
 543
 544                 if (defined $override_command) {
 545                         delete $ENV{DH_INTERNAL_OPTIONS};
 546                         # Need to handle logging for overriden commands here,
 547                         # because the actual debhelper command may not have
 548                         # been run by the rules file target.
 549                         # (But avoid logging for dh_clean since it removes
 550                         # the log earlier.)
 551                         if ($override_command ne 'dh_clean') {
 552                                 my %packages=map { $_ => 1 } @packages;
 553                                 map { delete $packages{$_} } @exclude;
 554                                 write_log($override_command, keys %packages);
 555                         }
 556                 }
 557         }
 558 }
 559
 560 {
 561 my %targets;
 562 my $rules_parsed;
 563
 564 sub rules_explicit_target {
 565         # Checks if a specified target exists as an explicit target
 566         # in debian/rules.
 567         my $target=shift;
 568
 569         if (! $rules_parsed) {
 570                 my $processing_targets = 0;
 571                 my $not_a_target = 0;
 572                 open(MAKE, "LC_ALL=C make -Rrnpsf debian/rules debhelper-fail-me 2>/dev/null |");
 573                 while (<MAKE>) {
 574                         if ($processing_targets) {
 575                                 if (/^# Not a target:/) {
 576                                         $not_a_target = 1;
 577                                 }
 578                                 else {
 579                                         if (!$not_a_target && /^([^#:]+)::?/) {
 580                                                 # Target is defined.
 581                                                 # NOTE: if it is a depenency
 582                                                 # of .PHONY it will be
 583                                                 # defined too but that's ok.
 584                                                 $targets{$1} = 1;
 585                                         }
 586                                         # "Not a target:" is always followed by
 587                                         # a target name, so resetting this one
 588                                         # here is safe.
 589                                         $not_a_target = 0;
 590                                 }
 591                         } elsif (/^# Files$/) {
 592                                 $processing_targets = 1;
 593                         }
 594                 }
 595                 close MAKE;
 596                 $rules_parsed = 1;
 597         }
 598
 599         return exists $targets{$target};
 600 }
 601
 602 }
 603
 604 =head1 SEE ALSO
 605
 606 L<debhelper(7)>
 607
 608 This program is a part of debhelper.
 609
 610 =head1 AUTHOR
 611
 612 Joey Hess <joeyh@debian.org>
 613
 614 =cut