dh

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh - debhelper command sequencer
   6
   7 =cut
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11
  12 =head1 SYNOPSIS
  13
  14 B<dh> I<sequence> [B<--with> I<addon>[B<,>I<addon> ...]] [B<--list>] [B<--until> I<cmd>] [B<--before> I<cmd>] [B<--after> I<cmd>] [B<--remaining>] [S<I<debhelper options>>]
  15
  16 =head1 DESCRIPTION
  17
  18 B<dh> runs a sequence of debhelper commands. The supported I<sequence>s
  19 correspond to the targets of a F<debian/rules> file: B<build-arch>,
  20 B<build-indep>, B<build>, B<clean>, B<install-indep>, B<install-arch>,
  21 B<install>, B<binary-arch>, B<binary-indep>, and B<binary>.
  22
  23 Commands in the B<build-indep>, B<install-indep> and B<binary-indep>
  24 sequences are passed the B<-i> option to ensure they only work on
  25 architecture independent packages, and commands in the B<build-arch>,
  26 B<install-arch> and B<binary-arch> sequences are passed the B<-a>
  27 option to ensure they only work on architecture dependent packages.
  28
  29 If F<debian/rules> contains a target with a name like B<override_>I<dh_command>,
  30 then when it would normally run I<dh_command>, B<dh> will instead call that
  31 target. The override target can then run the command with additional options,
  32 or run entirely different commands instead. See examples below. (Note that to
  33 use this feature, you should Build-Depend on debhelper 7.0.50 or above.)
  34
  35 =head1 OPTIONS
  36
  37 =over 4
  38
  39 =item B<--with> I<addon>[B<,>I<addon> ...]
  40
  41 Add the debhelper commands specified by the given addon to appropriate places
  42 in the sequence of commands that is run. This option can be repeated more
  43 than once, or multiple addons can be listed, separated by commas.
  44 This is used when there is a third-party package that provides
  45 debhelper commands. See the F<PROGRAMMING> file for documentation about
  46 the sequence addon interface.
  47
  48 =item B<--without> I<addon>
  49
  50 The inverse of B<--with>, disables using the given addon.
  51
  52 =item B<--list>, B<-l>
  53
  54 List all available addons.
  55
  56 =item B<--until> I<cmd>
  57
  58 Run commands in the sequence until and including I<cmd>, then stop.
  59
  60 =item B<--before> I<cmd>
  61
  62 Run commands in the sequence before I<cmd>, then stop.
  63
  64 =item B<--after> I<cmd>
  65
  66 Run commands in the sequence that come after I<cmd>.
  67
  68 =item B<--remaining>
  69
  70 Run all commands in the sequence that have yet to be run.
  71
  72 =item B<--no-act>
  73
  74 Prints commands that would run for a given sequence, but does not run them.
  75
  76 =back
  77
  78 All other options passed to B<dh> are passed on to each command it runs. This
  79 can be used to set an option like B<-v> or B<-X> or B<-N>, as well as for more
  80 specialised options.
  81
  82 In the above options, I<cmd> can be a full name of a debhelper command, or
  83 a substring. It'll first search for a command in the sequence exactly
  84 matching the name, to avoid any ambiguity. If there are multiple substring
  85 matches, the last one in the sequence will be used.
  86
  87 =cut
  88
  89 sub command_pos {
  90         my $command=shift;
  91         my @sequence=@_;
  92
  93         foreach my $i (0..$#sequence) {
  94                 if ($command eq $sequence[$i]) {
  95                         return $i;
  96                 }
  97         }
  98
  99         my @matches;
 100         foreach my $i (0..$#sequence) {
 101                 if ($sequence[$i] =~ /\Q$command\E/) {
 102                         push @matches, $i;
 103                 }
 104         }
 105         if (! @matches) {
 106                 error "command specification \"$command\" does not match any command in the sequence"
 107         }
 108         else {
 109                 return pop @matches;
 110         }
 111 }
 112
 113 =head1 EXAMPLES
 114
 115 To see what commands are included in a sequence, without actually doing
 116 anything:
 117
 118         dh binary-arch --no-act
 119
 120 This is a very simple rules file, for packages where the default sequences of
 121 commands work with no additional options.
 122
 123         #!/usr/bin/make -f
 124         %:
 125                 dh $@
 126
 127 Often you'll want to pass an option to a specific debhelper command. The
 128 easy way to do with is by adding an override target for that command.
 129
 130         #!/usr/bin/make -f
 131         %:
 132                 dh $@
 133
 134         override_dh_strip:
 135                 dh_strip -Xfoo
 136
 137         override_dh_installdocs:
 138                 dh_installdocs README TODO
 139
 140 Sometimes the automated L<dh_auto_configure(1)> and L<dh_auto_build(1)>
 141 can't guess what to do for a strange package. Here's how to avoid running
 142 either and instead run your own commands.
 143
 144         #!/usr/bin/make -f
 145         %:
 146                 dh $@
 147
 148         override_dh_auto_configure:
 149                 ./mondoconfig
 150
 151         override_dh_auto_build:
 152                 make universe-explode-in-delight
 153
 154 Another common case is wanting to do something manually before or
 155 after a particular debhelper command is run.
 156
 157         #!/usr/bin/make -f
 158         %:
 159                 dh $@
 160
 161         override_dh_fixperms:
 162                 dh_fixperms
 163                 chmod 4755 debian/foo/usr/bin/foo
 164
 165 If your package is a Python package, B<dh> will use B<dh_pysupport> by
 166 default. This is how to use B<dh_pycentral> instead.
 167
 168         #!/usr/bin/make -f
 169         %:
 170                 dh $@ --with python-central
 171
 172 If your package uses autotools and you want to freshen F<config.sub> and
 173 F<config.guess> with newer versions from the B<autotools-dev> package
 174 at build time, you can use some commands provided in B<autotools-dev>
 175 that automate it, like this.
 176
 177         #!/usr/bin/make -f
 178         %:
 179                 dh $@ --with autotools_dev
 180
 181 Here is how to force use of Perl's B<Module::Build> build system,
 182 which can be necessary if debhelper wrongly detects that the package
 183 uses MakeMaker.
 184
 185         #!/usr/bin/make -f
 186         %:
 187                 dh $@ --buildsystem=perl_build
 188
 189 To patch your package using quilt, you can tell B<dh> to use quilt's B<dh>
 190 sequence addons like this:
 191
 192         #!/usr/bin/make -f
 193         %:
 194                 dh $@ --with quilt
 195
 196 Here is an example of overriding where the B<dh_auto_>I<*> commands find
 197 the package's source, for a package where the source is located in a
 198 subdirectory.
 199
 200         #!/usr/bin/make -f
 201         %:
 202                 dh $@ --sourcedirectory=src
 203
 204 And here is an example of how to tell the B<dh_auto_>I<*> commands to build
 205 in a subdirectory, which will be removed on B<clean>.
 206
 207         #!/usr/bin/make -f
 208         %:
 209                 dh $@ --builddirectory=build
 210
 211 If your package can be built in parallel, you can support parallel building
 212 as follows. Then B<dpkg-buildpackage -j> will work.
 213
 214         #!/usr/bin/make -f
 215         %:
 216                 dh $@ --parallel
 217
 218 Here is a way to prevent B<dh> from running several commands that you don't
 219 want it to run, by defining empty override targets for each command.
 220
 221         #!/usr/bin/make -f
 222         %:
 223                 dh $@
 224
 225         # Commands not to run:
 226         override_dh_auto_test override_dh_compress override_dh_fixperms:
 227
 228 Sometimes, you may need to make an override target only run commands when a
 229 particular package is being built. This can be accomplished using
 230 L<dh_listpackages(1)> to test what is being built. For example:
 231
 232         #!/usr/bin/make -f
 233         %:
 234                 dh $@
 235
 236         override_dh_fixperms:
 237                 dh_fixperms
 238         ifneq (,$(filter foo, $(shell dh_listpackages)))
 239                 chmod 4755 debian/foo/usr/bin/foo
 240         endif
 241
 242 Finally, remember that you are not limited to using override targets in the
 243 rules file when using B<dh>. You can also explicitly define any of the regular
 244 rules file targets when it makes sense to do so. A common reason to do this
 245 is when your package needs different B<build-arch> and B<build-indep> targets.
 246 For example, a package with a long document build process can put it in
 247 B<build-indep>.
 248
 249         #!/usr/bin/make -f
 250         %:
 251                 dh $@
 252
 253         build-indep:
 254                 $(MAKE) docs
 255         build-arch:
 256                 $(MAKE) bins
 257
 258 Note that in the example above, dh will arrange for "debian/rules build"
 259 to call your build-indep and build-arch targets. You do not need to
 260 explicitly define the dependencies in the rules file when using dh with
 261 compatability level v9. This example would be more complicated with
 262 earlier compatability levels.
 263
 264 =head1 INTERNALS
 265
 266 If you're curious about B<dh>'s internals, here's how it works under the hood.
 267
 268 Each debhelper command will record when it's successfully run in
 269 F<debian/package.debhelper.log>. (Which B<dh_clean> deletes.) So B<dh> can tell
 270 which commands have already been run, for which packages, and skip running
 271 those commands again.
 272
 273 Each time B<dh> is run, it examines the log, and finds the last logged command
 274 that is in the specified sequence. It then continues with the next command
 275 in the sequence. The B<--until>, B<--before>, B<--after>, and B<--remaining>
 276 options can override this behavior.
 277
 278 A sequence can also run dependent targets in debian/rules.  For
 279 example, the "binary" sequence runs the "install" target.
 280
 281 B<dh> uses the B<DH_INTERNAL_OPTIONS> environment variable to pass information
 282 through to debhelper commands that are run inside override targets. The
 283 contents (and indeed, existence) of this environment variable, as the name
 284 might suggest, is subject to change at any time.
 285
 286 =cut
 287
 288 # Stash this away before init modifies it.
 289 my @ARGV_orig=@ARGV;
 290
 291 # python-support is enabled by default, at least for now
 292 # (and comes first so python-central loads later and can disable it).
 293 unshift @ARGV, "--with=python-support";
 294
 295 init(options => {
 296                 "until=s" => \$dh{UNTIL},
 297                 "after=s" => \$dh{AFTER},
 298                 "before=s" => \$dh{BEFORE},
 299                 "remaining" => \$dh{REMAINING},
 300                 "with=s" => sub {
 301                         my ($option,$value)=@_;
 302                         push @{$dh{WITH}},split(",", $value);
 303                 },
 304                 "without=s" => sub {
 305                         my ($option,$value)=@_;
 306                         @{$dh{WITH}} = grep { $_ ne $value } @{$dh{WITH}};
 307                 },
 308                 "l" => \&list_addons,
 309                 "list" => \&list_addons,
 310         },
 311         # Disable complaints about unknown options; they are passed on to
 312         # the debhelper commands.
 313         ignore_unknown_options => 1,
 314         # Bundling does not work well since there are unknown options.
 315         bundling => 0,
 316 );
 317 inhibit_log();
 318
 319
 320 # If make is using a jobserver, but it is not available
 321 # to this process, clean out MAKEFLAGS. This avoids
 322 # ugly warnings when calling make.
 323 if (is_make_jobserver_unavailable()) {
 324         clean_jobserver_makeflags();
 325 }
 326
 327 # Process the sequence parameter.
 328 my $sequence;
 329 if (! compat(7)) {
 330         # From v8, the sequence is the very first parameter.
 331         $sequence=shift @ARGV_orig;
 332         if ($sequence=~/^-/) {
 333                 error "Unknown sequence $sequence (options should not come before the sequence)";
 334         }
 335 }
 336 else {
 337         # Before v8, the sequence could be at any position in the parameters,
 338         # so was what was left after parsing.
 339         $sequence=shift;
 340         if (defined $sequence) {
 341                 @ARGV_orig=grep { $_ ne $sequence } @ARGV_orig;
 342         }
 343 }
 344 if (! defined $sequence) {
 345         error "specify a sequence to run";
 346 }
 347 # make -B causes the rules file to be run as a target.
 348 # Also support completly empty override targets.
 349 # Note: it's not safe to use rules_explicit_target before this check.
 350 if ($sequence eq 'debian/rules' ||
 351     $sequence =~ /^override_dh_/) {
 352         exit 0;
 353 }
 354
 355
 356 # Definitions of sequences.
 357 my %sequences;
 358 my @bd_minimal = qw{
 359         dh_testdir
 360 };
 361 my @bd = qw{
 362         dh_testdir
 363         dh_auto_configure
 364         dh_auto_build
 365         dh_auto_test
 366 };
 367 my @i_minimal = qw{
 368         dh_testroot
 369 };
 370 my @i = qw{
 371         dh_testroot
 372         dh_prep
 373         dh_installdirs
 374         dh_auto_install
 375
 376         dh_install
 377         dh_installdocs
 378         dh_installchangelogs
 379         dh_installexamples
 380         dh_installman
 381
 382         dh_installcatalogs
 383         dh_installcron
 384         dh_installdebconf
 385         dh_installemacsen
 386         dh_installifupdown
 387         dh_installinfo
 388         dh_installinit
 389         dh_installmenu
 390         dh_installmime
 391         dh_installmodules
 392         dh_installlogcheck
 393         dh_installlogrotate
 394         dh_installpam
 395         dh_installppp
 396         dh_installudev
 397         dh_installwm
 398         dh_installxfonts
 399         dh_installgsettings
 400         dh_bugfiles
 401         dh_ucf
 402         dh_lintian
 403         dh_gconf
 404         dh_icons
 405         dh_perl
 406         dh_usrlocal
 407
 408         dh_link
 409         dh_compress
 410         dh_fixperms
 411 };
 412 my @ba=qw{
 413         dh_strip
 414         dh_makeshlibs
 415         dh_shlibdeps
 416 };
 417 my @b=qw{
 418         dh_installdeb
 419         dh_gencontrol
 420         dh_md5sums
 421         dh_builddeb
 422 };
 423 $sequences{clean} = [qw{
 424         dh_testdir
 425         dh_auto_clean
 426         dh_clean
 427 }];
 428 $sequences{'build-indep'} = [@bd];
 429 $sequences{'build-arch'} = [@bd];
 430 if (! compat(8)) {
 431         # From v9, sequences take standard rules targets into account.
 432         if (rules_explicit_target('build-arch') ||
 433             rules_explicit_target('build-indep')) {
 434                 # run sequences separately
 435                 $sequences{build} = [@bd_minimal, 'rules:build-arch', 'rules:build-indep'];
 436         }
 437         else {
 438                 # run standard sequence (this is faster)
 439                 $sequences{build} = [@bd];
 440         }
 441         $sequences{'install-indep'} = ['rules:build-indep', @i];
 442         $sequences{'install-arch'} = ['rules:build-arch', @i];
 443         if (rules_explicit_target('install-arch') ||
 444             rules_explicit_target('install-indep')) {
 445                 # run sequences separately
 446                 $sequences{'install'} = ['rules:build', @i_minimal, 'rules:install-arch', 'rules:install-indep'];
 447         }
 448         else {
 449                 # run standard sequence (this is faster)
 450                 $sequences{'install'} = ['rules:build', @i, 'rules:install-arch', 'rules:install-indep'];
 451         }
 452         $sequences{'binary-indep'} = ['rules:install-indep', @b];
 453         $sequences{'binary-arch'} = ['rules:install-arch', @ba, @b];
 454         $sequences{binary} = ['rules:install', 'rules:binary-arch', 'rules:binary-indep'];
 455 }
 456 else {
 457         $sequences{build} = [@bd];
 458         $sequences{'install'} = [@{$sequences{build}}, @i];
 459         $sequences{'install-indep'} = [@{$sequences{'build-indep'}}, @i];
 460         $sequences{'install-arch'} = [@{$sequences{'build-arch'}}, @i];
 461         $sequences{binary} = [@{$sequences{install}}, @ba, @b];
 462         $sequences{'binary-indep'} = [@{$sequences{'install-indep'}}, @b];
 463         $sequences{'binary-arch'} = [@{$sequences{'install-arch'}}, @ba, @b];
 464 }
 465
 466 # Additional command options
 467 my %command_opts;
 468
 469 # sequence addon interface
 470 sub _insert {
 471         my $offset=shift;
 472         my $existing=shift;
 473         my $new=shift;
 474         foreach my $sequence (keys %sequences) {
 475                 my @list=@{$sequences{$sequence}};
 476                 next unless grep $existing, @list;
 477                 my @new;
 478                 foreach my $command (@list) {
 479                         if ($command eq $existing) {
 480                                 push @new, $new if $offset < 0;
 481                                 push @new, $command;
 482                                 push @new, $new if $offset > 0;
 483                         }
 484                         else {
 485                                 push @new, $command;
 486                         }
 487                 }
 488                 $sequences{$sequence}=\@new;
 489         }
 490 }
 491 sub insert_before {
 492         _insert(-1, @_);
 493 }
 494 sub insert_after {
 495         _insert(1, @_);
 496 }
 497 sub remove_command {
 498         my $command=shift;
 499         foreach my $sequence (keys %sequences) {
 500                 $sequences{$sequence}=[grep { $_ ne $command } @{$sequences{$sequence}}];
 501         }
 502
 503 }
 504 sub add_command {
 505         my $command=shift;
 506         my $sequence=shift;
 507         unshift @{$sequences{$sequence}}, $command;
 508 }
 509 sub add_command_options {
 510         my $command=shift;
 511         push @{$command_opts{$command}}, @_;
 512 }
 513 sub remove_command_options {
 514         my $command=shift;
 515         if (@_) {
 516                 # Remove only specified options
 517                 if (my $opts = $command_opts{$command}) {
 518                         foreach my $opt (@_) {
 519                                 $opts = [ grep { $_ ne $opt } @$opts ];
 520                         }
 521                         $command_opts{$command} = $opts;
 522                 }
 523         }
 524         else {
 525                 # Clear all additional options
 526                 delete $command_opts{$command};
 527         }
 528 }
 529
 530 sub list_addons {
 531         my %addons;
 532
 533         for my $inc (@INC) {
 534                 eval q{use File::Spec};
 535                 my $path = File::Spec->catdir($inc, "Debian/Debhelper/Sequence");
 536                 if (-d $path) {
 537                         for my $module_path (glob "$path/*.pm") {
 538                                 my $name = basename($module_path);
 539                                 $name =~ s/\.pm$//;
 540                                 $name =~ s/_/-/g;
 541                                 $addons{$name} = 1;
 542                         }
 543                 }
 544         }
 545
 546         for my $name (sort keys %addons) {
 547                 print "$name\n";
 548         }
 549
 550         exit 0;
 551 }
 552
 553 # Load addons, which can modify sequences.
 554 foreach my $addon (@{$dh{WITH}}) {
 555         my $mod="Debian::Debhelper::Sequence::$addon";
 556         $mod=~s/-/_/g;
 557         eval "use $mod";
 558         if ($@) {
 559                 error("unable to load addon $addon: $@");
 560         }
 561 }
 562
 563 if (! exists $sequences{$sequence}) {
 564         error "Unknown sequence $sequence (choose from: ".
 565                 join(" ", sort keys %sequences).")";
 566 }
 567 my @sequence=optimize_sequence(@{$sequences{$sequence}});
 568
 569 # The list of all packages that can be acted on.
 570 my @packages=@{$dh{DOPACKAGES}};
 571
 572 # Get the options to pass to commands in the sequence.
 573 # Filter out options intended only for this program.
 574 my @options;
 575 if ($sequence eq 'build-arch' ||
 576     $sequence eq 'install-arch' ||
 577     $sequence eq 'binary-arch') {
 578         push @options, "-a";
 579         # as an optimisation, remove from the list any packages
 580         # that are not arch dependent
 581         my %arch_packages = map { $_ => 1 } getpackages("arch");
 582         @packages = grep { $arch_packages{$_} } @packages;
 583 }
 584 elsif ($sequence eq 'build-indep' ||
 585        $sequence eq 'install-indep' ||
 586        $sequence eq 'binary-indep') {
 587         push @options, "-i";
 588         # ditto optimisation for arch indep
 589         my %indep_packages = map { $_ => 1 } getpackages("indep");
 590         @packages = grep { $indep_packages{$_} } @packages;
 591 }
 592 while (@ARGV_orig) {
 593         my $opt=shift @ARGV_orig;
 594         if ($opt =~ /^--?(after|until|before|with|without)$/) {
 595                 shift @ARGV_orig;
 596                 next;
 597         }
 598         elsif ($opt =~ /^--?(no-act|remaining|(after|until|before|with|without)=)/) {
 599                 next;
 600         }
 601         elsif ($opt=~/^-/) {
 602                 push @options, "-O".$opt;
 603         }
 604         elsif (@options) {
 605                 if ($options[$#options]=~/^-O--/) {
 606                         $options[$#options].="=".$opt;
 607                 }
 608                 else {
 609                         $options[$#options].=$opt;
 610                 }
 611         }
 612 }
 613
 614 # Figure out at what point in the sequence to start for each package.
 615 my %logged;
 616 my %startpoint;
 617 foreach my $package (@packages) {
 618         my @log=load_log($package, \%logged);
 619         if ($dh{AFTER}) {
 620                 # Run commands in the sequence that come after the
 621                 # specified command.
 622                 $startpoint{$package}=command_pos($dh{AFTER}, @sequence) + 1;
 623                 # Write a dummy log entry indicating that the specified
 624                 # command was, in fact, run. This handles the case where
 625                 # no commands remain to run after it, communicating to
 626                 # future dh instances that the specified command should not
 627                 # be run again.
 628                 write_log($sequence[$startpoint{$package}-1], $package);
 629         }
 630         elsif ($dh{REMAINING}) {
 631                 # Start at the beginning so all remaining commands will get
 632                 # run.
 633                 $startpoint{$package}=0;
 634         }
 635         else {
 636                 # Find the last logged command that is in the sequence, and
 637                 # continue with the next command after it. If no logged
 638                 # command is in the sequence, we're starting at the beginning..
 639                 $startpoint{$package}=0;
 640 COMMAND:        foreach my $command (reverse @log) {
 641                         foreach my $i (0..$#sequence) {
 642                                 if ($command eq $sequence[$i]) {
 643                                         $startpoint{$package}=$i+1;
 644                                         last COMMAND;
 645                                 }
 646                         }
 647                 }
 648         }
 649 }
 650
 651 # Figure out what point in the sequence to go to.
 652 my $stoppoint=$#sequence;
 653 if ($dh{UNTIL}) {
 654         $stoppoint=command_pos($dh{UNTIL}, @sequence);
 655 }
 656 elsif ($dh{BEFORE}) {
 657         $stoppoint=command_pos($dh{BEFORE}, @sequence) - 1;
 658 }
 659
 660 # Now run the commands in the sequence.
 661 foreach my $i (0..$stoppoint) {
 662         # Figure out which packages need to run this command.
 663         my @exclude;
 664         foreach my $package (@packages) {
 665                 if ($startpoint{$package} > $i ||
 666                     $logged{$package}{$sequence[$i]}) {
 667                         push @exclude, $package;
 668                 }
 669         }
 670
 671         if (@exclude eq @packages) {
 672                 # Command already done for all packages.
 673                 next;
 674         }
 675
 676         run($sequence[$i], \@packages, \@exclude, @options);
 677 }
 678
 679 sub run {
 680         my $command=shift;
 681         my @packages=@{shift()};
 682         my @exclude=@{shift()};
 683         my @options=@_;
 684
 685         # If some packages are excluded, add flags
 686         # to prevent them from being acted on.
 687         push @options, map { "-N$_" } @exclude;
 688
 689         # Check for override targets in debian/rules and
 690         # run them instead of running the command directly.
 691         my $override_command;
 692         my $has_explicit_target = rules_explicit_target("override_".$command);
 693
 694         # If the command has a rules: prefix, run debian/rules with
 695         # the remainder as the target.
 696         my $rules_target = rules_target($command);
 697         if (defined $rules_target) {
 698                 # Don't pass DH_ environment variables, since this is
 699                 # a fresh invocation of debian/rules and any sub-dh
 700                 # commands.
 701                 $override_command=$command;
 702                 delete $ENV{DH_INTERNAL_OPTIONS};
 703                 delete $ENV{DH_INTERNAL_OVERRIDE};
 704                 $command="debian/rules";
 705                 @options=$rules_target;
 706         }
 707         elsif (defined $has_explicit_target) {
 708                 $override_command=$command;
 709                 # Check if target isn't noop
 710                 if ($has_explicit_target) {
 711                         # This passes the options through to commands called
 712                         # inside the target.
 713                         $ENV{DH_INTERNAL_OPTIONS}=join("\x1e", @options);
 714                         $ENV{DH_INTERNAL_OVERRIDE}=$command;
 715                         $command="debian/rules";
 716                         @options="override_".$override_command;
 717                 }
 718                 else {
 719                         $command = undef;
 720                 }
 721         }
 722         else {
 723                 # Pass additional command options if any
 724                 unshift @options, @{$command_opts{$command}} if exists $command_opts{$command};
 725         }
 726
 727         if (defined $command) {
 728                 # 3 space indent lines the command being run up under the
 729                 # sequence name after "dh ".
 730                 print "   ".escape_shell($command, @options)."\n";
 731         }
 732         else {
 733                 print "   ", "# Skipping ", $override_command, " - empty override", "\n";
 734         }
 735
 736         if (! $dh{NO_ACT}) {
 737                 if (defined $command) {
 738                         my $ret=system($command, @options);
 739
 740                         if ($ret >> 8 != 0) {
 741                                 exit $ret >> 8;
 742                         }
 743                         elsif ($ret) {
 744                                 exit 1;
 745                         }
 746                 }
 747
 748                 if (defined $override_command) {
 749                         # Update log for overridden command now that it has
 750                         # finished successfully.
 751                         # (But avoid logging for dh_clean since it removes
 752                         # the log earlier.)
 753                         if ($override_command ne 'dh_clean') {
 754                                 my %packages=map { $_ => 1 } @packages;
 755                                 map { delete $packages{$_} } @exclude;
 756                                 write_log($override_command, keys %packages);
 757                                 commit_override_log(keys %packages);
 758                         }
 759
 760                         delete $ENV{DH_INTERNAL_OPTIONS};
 761                         delete $ENV{DH_INTERNAL_OVERRIDE};
 762                 }
 763         }
 764 }
 765
 766 sub optimize_sequence {
 767         my @sequence;
 768         my %seen;
 769         my $add=sub {
 770                 # commands can appear multiple times when sequences are
 771                 # inlined together; only the first should be needed
 772                 my $command=shift;
 773                 if (! $seen{$command}) {
 774                         $seen{$command}=1;
 775                         push @sequence, $command;
 776                 }
 777         };
 778         foreach my $command (@_) {
 779                 my $rules_target=rules_target($command);
 780                 if (defined $rules_target &&
 781                     ! defined rules_explicit_target($rules_target)) {
 782                         # inline the sequence for this implicit target
 783                         $add->($_) foreach optimize_sequence(@{$sequences{$rules_target}});
 784                 }
 785                 else {
 786                         $add->($command);
 787                 }
 788         }
 789         return @sequence;
 790 }
 791
 792 sub rules_target {
 793         my $command=shift;
 794         if ($command =~ /^rules:(.*)/) {
 795                 return $1
 796         }
 797         else {
 798                 return undef;
 799         }
 800 }
 801
 802 {
 803 my %targets;
 804 my $rules_parsed;
 805
 806 sub rules_explicit_target {
 807         # Checks if a specified target exists as an explicit target
 808         # in debian/rules.
 809         # undef is returned if target does not exist, 0 if target is noop
 810         # and 1 if target has dependencies or executes commands.
 811         my $target=shift;
 812
 813         if (! $rules_parsed) {
 814                 my $processing_targets = 0;
 815                 my $not_a_target = 0;
 816                 my $current_target;
 817                 open(MAKE, "LC_ALL=C make -Rrnpsf debian/rules debhelper-fail-me 2>/dev/null |");
 818                 while (<MAKE>) {
 819                         if ($processing_targets) {
 820                                 if (/^# Not a target:/) {
 821                                         $not_a_target = 1;
 822                                 }
 823                                 else {
 824                                         if (!$not_a_target && /^([^#:]+)::?\s*(.*)$/) {
 825                                                 # Target is defined. NOTE: if it is a depenency of
 826                                                 # .PHONY it will be defined too but that's ok.
 827                                                 # $2 contains target dependencies if any.
 828                                                 $current_target = $1;
 829                                                 $targets{$current_target} = ($2) ? 1 : 0;
 830                                         }
 831                                         else {
 832                                                 if (defined $current_target) {
 833                                                         if (/^#/) {
 834                                                                 # Check if target has commands to execute
 835                                                                 if (/^#\s*commands to execute/) {
 836                                                                         $targets{$current_target} = 1;
 837                                                                 }
 838                                                         }
 839                                                         else {
 840                                                                 # Target parsed.
 841                                                                 $current_target = undef;
 842                                                         }
 843                                                 }
 844                                         }
 845                                         # "Not a target:" is always followed by
 846                                         # a target name, so resetting this one
 847                                         # here is safe.
 848                                         $not_a_target = 0;
 849                                 }
 850                         }
 851                         elsif (/^# Files$/) {
 852                                 $processing_targets = 1;
 853                         }
 854                 }
 855                 close MAKE;
 856                 $rules_parsed = 1;
 857         }
 858
 859         return $targets{$target};
 860 }
 861
 862 }
 863
 864 =head1 SEE ALSO
 865
 866 L<debhelper(7)>
 867
 868 This program is a part of debhelper.
 869
 870 =head1 AUTHOR
 871
 872 Joey Hess <joeyh@debian.org>
 873
 874 =cut