dh

   1 #!/usr/bin/perl -w
   2
   3 =head1 NAME
   4
   5 dh - debhelper command sequencer
   6
   7 =cut
   8
   9 use strict;
  10 use Debian::Debhelper::Dh_Lib;
  11
  12 =head1 SYNOPSIS
  13
  14 B<dh> sequence [B<--with> I<addon>[,I<addon>,...]] [B<--until> I<cmd>] [B<--before> I<cmd>] [B<--after> I<cmd>] [B<--remaining>] [S<I<debhelper options>>]
  15
  16 =head1 DESCRIPTION
  17
  18 dh runs a sequence of debhelper commands. The supported sequences
  19 correspond to the targets of a debian/rules file: "build", "clean",
  20 "install", "binary-arch", "binary-indep", and "binary".
  21
  22 Commands in the binary-indep sequence are passed the "-i" option to ensure
  23 they only work on binary independent packages, and commands in the
  24 binary-arch sequences are passed the "-a" option to ensure they only work
  25 on architecture dependent packages.
  26
  27 Each debhelper command will record when it's successfully run in
  28 debian/package.debhelper.log. (Which dh_clean deletes.) So dh can tell
  29 which commands have already been run, for which packages, and skip running
  30 those commands again.
  31
  32 Each time dh is run, it examines the log, and finds the last logged command
  33 that is in the specified sequence. It then continues with the next command
  34 in the sequence. The B<--until>, B<--before>, B<--after>, and B<--remaining>
  35 options can override this behavior.
  36
  37 If debian/rules contains a target with a name like "override_I<dh_command>",
  38 then when it gets to that command in the sequence, dh will run that
  39 target from the rules file, rather than running the actual command. The
  40 override target can then run the command with additional options, or run
  41 entirely different commands instead. (Note that to use this feature,
  42 you should Build-Depend on debhelper 7.0.50 or above.)
  43
  44 =head1 OPTIONS
  45
  46 =over 4
  47
  48 =item B<--with> I<addon>[,I<addon>,...]
  49
  50 Add the debhelper commands specified by the given addon to appropriate places
  51 in the sequence of commands that is run. This option can be repeated more
  52 than once, or multiple addons can be listed, separated by commas.
  53 This is used when there is a third-party package that provides
  54 debhelper commands. See the PROGRAMMING file for documentation about
  55 the sequence addon interface.
  56
  57 =item B<--without> I<addon>
  58
  59 The inverse of --with, disables using the given addon.
  60
  61 =item B<--until> I<cmd>
  62
  63 Run commands in the sequence until and including I<cmd>, then stop.
  64
  65 =item B<--before> I<cmd>
  66
  67 Run commands in the sequence before I<cmd>, then stop.
  68
  69 =item B<--after> I<cmd>
  70
  71 Run commands in the sequence that come after I<cmd>.
  72
  73 =item B<--remaining>
  74
  75 Run all commands in the sequence that have yet to be run.
  76
  77 =back
  78
  79 All other options passed to dh are passed on to each command it runs. This
  80 can be used to set an option like "-v" or "-X" or "-N", as well as for more
  81 specialised options.
  82
  83 =head1 COMMAND SPECIFICATION
  84
  85 I<cmd> can be a full name of a debhelper command, or a substring. It'll first
  86 search for a command in the sequence exactly matching the name, to avoid any
  87 ambiguity. If there are multiple substring matches, the last one in the
  88 sequence will be used.
  89
  90 =cut
  91
  92 sub command_pos {
  93         my $command=shift;
  94         my @sequence=@_;
  95
  96         foreach my $i (0..$#sequence) {
  97                 if ($command eq $sequence[$i]) {
  98                         return $i;
  99                 }
 100         }
 101
 102         my @matches;
 103         foreach my $i (0..$#sequence) {
 104                 if ($sequence[$i] =~ /\Q$command\E/) {
 105                         push @matches, $i;
 106                 }
 107         }
 108         if (! @matches) {
 109                 error "command specification \"$command\" does not match any command in the sequence"
 110         }
 111         else {
 112                 return pop @matches;
 113         }
 114 }
 115
 116 =head1 EXAMPLES
 117
 118 To see what commands are included in a sequence, without actually doing
 119 anything:
 120
 121         dh binary-arch --no-act
 122
 123 This is a very simple rules file, for packages where the default sequences of
 124 commands work with no additional options.
 125
 126         #!/usr/bin/make -f
 127         %:
 128                 dh $@
 129
 130 Often you'll want to pass an option to a specific debhelper command. The
 131 easy way to do with is by adding an override target for that command.
 132
 133         #!/usr/bin/make -f
 134         %:
 135                 dh $@
 136
 137         override_dh_strip:
 138                 dh_strip -Xfoo
 139
 140         override_dh_installdocs:
 141                 dh_installdocs README TODO
 142
 143 Sometimes the automated dh_auto_configure and dh_auto_build can't guess
 144 what to do for a strange package. Here's how to avoid running either
 145 and instead run your own commands.
 146
 147         #!/usr/bin/make -f
 148         %:
 149                 dh $@
 150
 151         override_dh_auto_configure:
 152                 ./mondoconfig
 153
 154         override_dh_auto_build:
 155                 make universe-explode-in-delight
 156
 157 Another common case is wanting to do something manually before or
 158 after a particular debhelper command is run.
 159
 160         #!/usr/bin/make -f
 161         %:
 162                 dh $@
 163
 164         override_dh_fixperms:
 165                 dh_fixperms
 166                 chmod 4755 debian/foo/usr/bin/foo
 167
 168 If your package is a python package, dh will use dh_pysupport by
 169 default. This is how to use dh_pycentral instead.
 170
 171         #!/usr/bin/make -f
 172         %:
 173                 dh --with python-central $@
 174
 175 To patch your package using quilt, you can tell dh to use quilt's dh
 176 sequence addons like this:
 177
 178         #!/usr/bin/make -f
 179         %:
 180                 dh --with quilt $@
 181
 182 =cut
 183
 184 # Stash this away before init modifies it.
 185 my @ARGV_orig=@ARGV;
 186
 187 # python-support is enabled by default, at least for now
 188 # (and comes first so python-central loads later and can disable it).
 189 unshift @ARGV, "--with=python-support";
 190
 191 init(options => {
 192         "until=s" => \$dh{UNTIL},
 193         "after=s" => \$dh{AFTER},
 194         "before=s" => \$dh{BEFORE},
 195         "remaining" => \$dh{REMAINING},
 196         "with=s" => sub {
 197                 my ($option,$value)=@_;
 198                 push @{$dh{WITH}},split(",", $value);
 199         },
 200         "without=s" => sub {
 201                 my ($option,$value)=@_;
 202                 @{$dh{WITH}} = grep { $_ ne $value } @{$dh{WITH}};
 203         },
 204 });
 205 inhibit_log();
 206
 207 # Definitions of sequences.
 208 my %sequences;
 209 $sequences{build} = [qw{
 210         dh_testdir
 211         dh_auto_configure
 212         dh_auto_build
 213         dh_auto_test
 214 }],
 215 $sequences{clean} = [qw{
 216         dh_testdir
 217         dh_auto_clean
 218         dh_clean
 219 }];
 220 $sequences{install} = [@{$sequences{build}}, qw{
 221         dh_testroot
 222         dh_prep
 223         dh_installdirs
 224         dh_auto_install
 225
 226         dh_install
 227         dh_installdocs
 228         dh_installchangelogs
 229         dh_installexamples
 230         dh_installman
 231
 232         dh_installcatalogs
 233         dh_installcron
 234         dh_installdebconf
 235         dh_installcatalogs
 236         dh_installemacsen
 237         dh_installifupdown
 238         dh_installinfo
 239         dh_installinit
 240         dh_installmenu
 241         dh_installmime
 242         dh_installmodules
 243         dh_installlogcheck
 244         dh_installlogrotate
 245         dh_installpam
 246         dh_installppp
 247         dh_installudev
 248         dh_installwm
 249         dh_installxfonts
 250         dh_bugfiles
 251         dh_lintian
 252         dh_gconf
 253         dh_icons
 254         dh_perl
 255         dh_usrlocal
 256
 257         dh_link
 258         dh_compress
 259         dh_fixperms
 260 }];
 261 my @b=qw{
 262         dh_installdeb
 263         dh_gencontrol
 264         dh_md5sums
 265         dh_builddeb
 266 };
 267 $sequences{'binary-indep'} = [@{$sequences{install}}, @b];
 268 $sequences{binary} = [@{$sequences{install}}, qw{
 269         dh_strip
 270         dh_makeshlibs
 271         dh_shlibdeps
 272 }, @b];
 273 $sequences{'binary-arch'} = [@{$sequences{binary}}];
 274
 275 # sequence addon interface
 276 sub _insert {
 277         my $offset=shift;
 278         my $existing=shift;
 279         my $new=shift;
 280         foreach my $sequence (keys %sequences) {
 281                 my @list=@{$sequences{$sequence}};
 282                 next unless grep $existing, @list;
 283                 my @new;
 284                 foreach my $command (@list) {
 285                         if ($command eq $existing) {
 286                                 push @new, $new if $offset < 0;
 287                                 push @new, $command;
 288                                 push @new, $new if $offset > 0;
 289                         }
 290                         else {
 291                                 push @new, $command;
 292                         }
 293                 }
 294                 $sequences{$sequence}=\@new;
 295         }
 296 }
 297 sub insert_before {
 298         _insert(-1, @_);
 299 }
 300 sub insert_after {
 301         _insert(1, @_);
 302 }
 303 sub remove_command {
 304         my $command=shift;
 305         foreach my $sequence (keys %sequences) {
 306                 $sequences{$sequence}=[grep { $_ ne $command } @{$sequences{$sequence}}];
 307         }
 308
 309 }
 310 foreach my $addon (@{$dh{WITH}}) {
 311         my $mod="Debian::Debhelper::Sequence::$addon";
 312         $mod=~s/-/_/g;
 313         eval "use $mod";
 314         if ($@) {
 315                 error("--with $addon not supported or failed to load module $mod");
 316         }
 317 }
 318
 319 # Get the sequence of commands to run.
 320 if (! @ARGV) {
 321         error "specify a sequence to run";
 322 }
 323 my $sequence=shift;
 324 if ($sequence eq 'debian/rules' ||
 325     $sequence =~ /^override_dh_/) {
 326         # make -B causes the rules file to be run as a target
 327         # and support completly empty override targets
 328         exit 0
 329 }
 330 elsif (! exists $sequences{$sequence}) {
 331         error "Unknown sequence $sequence (choose from: ".
 332                 join(" ", sort keys %sequences).")";
 333 }
 334 my @sequence=@{$sequences{$sequence}};
 335
 336 # The list of all packages that can be acted on.
 337 my @packages=@{$dh{DOPACKAGES}};
 338
 339 # Get the options to pass to commands in the sequence.
 340 # Filter out options intended only for this program.
 341 my @options;
 342 if ($sequence eq 'binary-arch') {
 343         push @options, "-a";
 344         # as an optimisation, remove from the list any packages
 345         # that are not arch dependent
 346         my %arch_packages = map { $_ => 1 } getpackages("arch");
 347         @packages = grep { $arch_packages{$_} } @packages;
 348 }
 349 elsif ($sequence eq 'binary-indep') {
 350         push @options, "-i";
 351         # ditto optimisation for arch indep
 352         my %indep_packages = map { $_ => 1 } getpackages("indep");
 353         @packages = grep { $indep_packages{$_} } @packages;
 354 }
 355 while (@ARGV_orig) {
 356         my $opt=shift @ARGV_orig;
 357         next if $opt eq $sequence;
 358         if ($opt =~ /^--?(after|until|before|with|without)$/) {
 359                 shift @ARGV_orig;
 360                 next;
 361         }
 362         elsif ($opt =~ /^--?(no-act|remaining|(after|until|before|with|without)=)/) {
 363                 next;
 364         }
 365         push @options, $opt;
 366 }
 367
 368 # Figure out at what point in the sequence to start for each package.
 369 my %logged;
 370 my %startpoint;
 371 foreach my $package (@packages) {
 372         my @log=load_log($package, \%logged);
 373         if ($dh{AFTER}) {
 374                 # Run commands in the sequence that come after the
 375                 # specified command.
 376                 $startpoint{$package}=command_pos($dh{AFTER}, @sequence) + 1;
 377                 # Write a dummy log entry indicating that the specified
 378                 # command was, in fact, run. This handles the case where
 379                 # no commands remain to run after it, communicating to
 380                 # future dh instances that the specified command should not
 381                 # be run again.
 382                 write_log($sequence[$startpoint{$package}-1], $package);
 383         }
 384         elsif ($dh{REMAINING}) {
 385                 # Start at the beginning so all remaining commands will get
 386                 # run.
 387                 $startpoint{$package}=0;
 388         }
 389         else {
 390                 # Find the last logged command that is in the sequence, and
 391                 # continue with the next command after it. If no logged
 392                 # command is in the sequence, we're starting at the beginning..
 393                 $startpoint{$package}=0;
 394 COMMAND:        foreach my $command (reverse @log) {
 395                         foreach my $i (0..$#sequence) {
 396                                 if ($command eq $sequence[$i]) {
 397                                         $startpoint{$package}=$i+1;
 398                                         last COMMAND;
 399                                 }
 400                         }
 401                 }
 402         }
 403 }
 404
 405 # Figure out what point in the sequence to go to.
 406 my $stoppoint=$#sequence;
 407 if ($dh{UNTIL}) {
 408         $stoppoint=command_pos($dh{UNTIL}, @sequence);
 409 }
 410 elsif ($dh{BEFORE}) {
 411         $stoppoint=command_pos($dh{BEFORE}, @sequence) - 1;
 412 }
 413
 414 # Now run the commands in the sequence.
 415 foreach my $i (0..$stoppoint) {
 416         # Figure out which packages need to run this command.
 417         my @exclude;
 418         foreach my $package (@packages) {
 419                 if ($startpoint{$package} > $i ||
 420                     $logged{$package}{$sequence[$i]}) {
 421                         push @exclude, $package;
 422                 }
 423         }
 424
 425         if (@exclude eq @packages) {
 426                 # Command already done for all packages.
 427                 next;
 428         }
 429
 430         run($sequence[$i], \@packages, \@exclude, @options);
 431 }
 432
 433 sub run {
 434         my $command=shift;
 435         my @packages=@{shift()};
 436         my @exclude=@{shift()};
 437         my @options=@_;
 438
 439         # If some packages are excluded, add flags
 440         # to prevent them from being acted on.
 441         push @options, map { "-N$_" } @exclude;
 442
 443         # Check for override targets in debian/rules and
 444         # run them instead of running the command directly.
 445         my $override_command;
 446         if (rules_explicit_target("override_".$command)) {
 447                 $override_command=$command;
 448                 # This passes the options through to commands called
 449                 # inside the target.
 450                 $ENV{DH_INTERNAL_OPTIONS}=join(" ", @options);
 451                 $command="debian/rules";
 452                 @options="override_".$override_command;
 453         }
 454
 455         # 3 space indent lines the command being run up under the
 456         # sequence name after "dh ".
 457         print "   ".escape_shell($command, @options)."\n";
 458
 459         if (! $dh{NO_ACT}) {
 460                 my $ret=system($command, @options);
 461                 if ($ret >> 8 != 0) {
 462                         exit $ret >> 8;
 463                 }
 464                 elsif ($ret) {
 465                         exit 1;
 466                 }
 467
 468                 if (defined $override_command) {
 469                         delete $ENV{DH_INTERNAL_OPTIONS};
 470                         # Need to handle logging for overriden commands here,
 471                         # because the actual debhelper command may not have
 472                         # been run by the rules file target.
 473                         # (But avoid logging for dh_clean since it removes
 474                         # the log earlier.)
 475                         if ($override_command ne 'dh_clean') {
 476                                 my %packages=map { $_ => 1 } @packages;
 477                                 map { delete $packages{$_} } @exclude;
 478                                 write_log($override_command, keys %packages);
 479                         }
 480                 }
 481         }
 482 }
 483
 484 {
 485 my %targets;
 486 my $rules_parsed;
 487
 488 sub rules_explicit_target {
 489         # Checks if a specified target exists as an explicit target
 490         # in debian/rules.
 491         my $target=shift;
 492
 493         if (! $rules_parsed) {
 494                 my $processing_targets = 0;
 495                 my $not_a_target = 0;
 496                 open(MAKE, "LC_ALL=C make -Rrnpsf debian/rules debhelper-fail-me 2>/dev/null |");
 497                 while (<MAKE>) {
 498                         if ($processing_targets) {
 499                                 if (/^# Not a target:/) {
 500                                         $not_a_target = 1;
 501                                 }
 502                                 else {
 503                                         if (!$not_a_target && /^([^#:]+)::?/) {
 504                                                 # Target is defined.
 505                                                 # NOTE: if it is a depenency
 506                                                 # of .PHONY it will be
 507                                                 # defined too but that's ok.
 508                                                 $targets{$1} = 1;
 509                                         }
 510                                         # "Not a target:" is always followed by
 511                                         # a target name, so resetting this one
 512                                         # here is safe.
 513                                         $not_a_target = 0;
 514                                 }
 515                         } elsif (/^# Files$/) {
 516                                 $processing_targets = 1;
 517                         }
 518                 }
 519                 close MAKE;
 520                 $rules_parsed = 1;
 521         }
 522
 523         return exists $targets{$target};
 524 }
 525
 526 }
 527
 528 =head1 SEE ALSO
 529
 530 L<debhelper(7)>
 531
 532 This program is a part of debhelper.
 533
 534 =head1 AUTHOR
 535
 536 Joey Hess <joeyh@debian.org>
 537
 538 =cut