Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2008.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell
  18             &inhibit_log &load_log &write_log &commit_override_log
  19             &dpkg_architecture_value &sourcepackage
  20             &is_make_jobserver_unavailable &clean_jobserver_makeflags
  21             &cross_command &set_buildflags &get_buildoption);
  22
  23 my $max_compat=9;
  24
  25 sub init {
  26         my %params=@_;
  27
  28         # Check to see if an option line starts with a dash,
  29         # or DH_OPTIONS is set.
  30         # If so, we need to pass this off to the resource intensive
  31         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  32         if ((defined $ENV{DH_OPTIONS} && length $ENV{DH_OPTIONS}) ||
  33             (defined $ENV{DH_INTERNAL_OPTIONS} && length $ENV{DH_INTERNAL_OPTIONS}) ||
  34             grep /^-/, @ARGV) {
  35                 eval "use Debian::Debhelper::Dh_Getopt";
  36                 error($@) if $@;
  37                 Debian::Debhelper::Dh_Getopt::parseopts(%params);
  38         }
  39
  40         # Another way to set excludes.
  41         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  42                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  43         }
  44
  45         # Generate EXCLUDE_FIND.
  46         if ($dh{EXCLUDE}) {
  47                 $dh{EXCLUDE_FIND}='';
  48                 foreach (@{$dh{EXCLUDE}}) {
  49                         my $x=$_;
  50                         $x=escape_shell($x);
  51                         $x=~s/\./\\\\./g;
  52                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  53                 }
  54                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  55         }
  56
  57         # Check to see if DH_VERBOSE environment variable was set, if so,
  58         # make sure verbose is on.
  59         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  60                 $dh{VERBOSE}=1;
  61         }
  62
  63         # Check to see if DH_NO_ACT environment variable was set, if so,
  64         # make sure no act mode is on.
  65         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  66                 $dh{NO_ACT}=1;
  67         }
  68
  69         # Get the name of the main binary package (first one listed in
  70         # debian/control). Only if the main package was not set on the
  71         # command line.
  72         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  73                 my @allpackages=getpackages();
  74                 $dh{MAINPACKAGE}=$allpackages[0];
  75         }
  76
  77         # Check if packages to build have been specified, if not, fall back to
  78         # the default, building all relevant packages.
  79         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  80                 push @{$dh{DOPACKAGES}}, getpackages('both');
  81         }
  82
  83         # Check to see if -P was specified. If so, we can only act on a single
  84         # package.
  85         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  86                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  87         }
  88
  89         # Figure out which package is the first one we were instructed to build.
  90         # This package gets special treatement: files and directories specified on
  91         # the command line may affect it.
  92         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
  93
  94         # If no error handling function was specified, just propigate
  95         # errors out.
  96         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
  97                 $dh{ERROR_HANDLER}='exit \$?';
  98         }
  99 }
 100
 101 # Run at exit. Add the command to the log files for the packages it acted
 102 # on, if it's exiting successfully.
 103 my $write_log=1;
 104 sub END {
 105         if ($? == 0 && $write_log) {
 106                 write_log(basename($0), @{$dh{DOPACKAGES}});
 107         }
 108 }
 109
 110 sub logfile {
 111         my $package=shift;
 112         my $ext=pkgext($package);
 113         return "debian/${ext}debhelper.log"
 114 }
 115
 116 sub add_override {
 117         my $line=shift;
 118         $line="override_$ENV{DH_INTERNAL_OVERRIDE} $line"
 119                 if defined $ENV{DH_INTERNAL_OVERRIDE};
 120         return $line;
 121 }
 122
 123 sub remove_override {
 124         my $line=shift;
 125         $line=~s/^\Qoverride_$ENV{DH_INTERNAL_OVERRIDE}\E\s+//
 126                 if defined $ENV{DH_INTERNAL_OVERRIDE};
 127         return $line;
 128 }
 129
 130 sub load_log {
 131         my ($package, $db)=@_;
 132
 133         my @log;
 134         open(LOG, "<", logfile($package)) || return;
 135         while (<LOG>) {
 136                 chomp;
 137                 my $command=remove_override($_);
 138                 push @log, $command;
 139                 $db->{$package}{$command}=1 if defined $db;
 140         }
 141         close LOG;
 142         return @log;
 143 }
 144
 145 sub write_log {
 146         my $cmd=shift;
 147         my @packages=@_;
 148
 149         return if $dh{NO_ACT};
 150
 151         foreach my $package (@packages) {
 152                 my $log=logfile($package);
 153                 open(LOG, ">>", $log) || error("failed to write to ${log}: $!");
 154                 print LOG add_override($cmd)."\n";
 155                 close LOG;
 156         }
 157 }
 158
 159 sub commit_override_log {
 160         my @packages=@_;
 161
 162         return if $dh{NO_ACT};
 163
 164         foreach my $package (@packages) {
 165                 my @log=map { remove_override($_) } load_log($package);
 166                 my $log=logfile($package);
 167                 open(LOG, ">", $log) || error("failed to write to ${log}: $!");
 168                 print LOG $_."\n" foreach @log;
 169                 close LOG;
 170         }
 171 }
 172
 173 sub inhibit_log {
 174         $write_log=0;
 175 }
 176
 177 # Pass it an array containing the arguments of a shell command like would
 178 # be run by exec(). It turns that into a line like you might enter at the
 179 # shell, escaping metacharacters and quoting arguments that contain spaces.
 180 sub escape_shell {
 181         my @args=@_;
 182         my $line="";
 183         my @ret;
 184         foreach my $word (@args) {
 185                 if ($word=~/\s/) {
 186                         # Escape only a few things since it will be quoted.
 187                         # Note we use double quotes because you cannot
 188                         # escape ' in single quotes, while " can be escaped
 189                         # in double.
 190                         # This does make -V"foo bar" turn into "-Vfoo bar",
 191                         # but that will be parsed identically by the shell
 192                         # anyway..
 193                         $word=~s/([\n`\$"\\])/\\$1/g;
 194                         push @ret, "\"$word\"";
 195                 }
 196                 else {
 197                         # This list is from _Unix in a Nutshell_. (except '#')
 198                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 199                         push @ret,$word;
 200                 }
 201         }
 202         return join(' ', @ret);
 203 }
 204
 205 # Run a command, and display the command to stdout if verbose mode is on.
 206 # All commands that modifiy files in $TMP should be ran via this
 207 # function.
 208 #
 209 # Note that this cannot handle complex commands, especially anything
 210 # involving redirection. Use complex_doit instead.
 211 sub doit {
 212         verbose_print(escape_shell(@_));
 213
 214         if (! $dh{NO_ACT}) {
 215                 system(@_) == 0 || _error_exitcode(join(" ", @_));
 216         }
 217 }
 218
 219 # Run a command and display the command to stdout if verbose mode is on.
 220 # Use doit() if you can, instead of this function, because this function
 221 # forks a shell. However, this function can handle more complicated stuff
 222 # like redirection.
 223 sub complex_doit {
 224         verbose_print(join(" ",@_));
 225
 226         if (! $dh{NO_ACT}) {
 227                 # The join makes system get a scalar so it forks off a shell.
 228                 system(join(" ", @_)) == 0 || _error_exitcode(join(" ", @_))
 229         }
 230 }
 231
 232 sub _error_exitcode {
 233         my $command=shift;
 234         if ($? == -1) {
 235                 error("$command failed to to execute: $!");
 236         }
 237         elsif ($? & 127) {
 238                 error("$command died with signal ".($? & 127));
 239         }
 240         else {
 241                 error("$command returned exit code ".($? >> 8));
 242         }
 243 }
 244
 245 # Run a command that may have a huge number of arguments, like xargs does.
 246 # Pass in a reference to an array containing the arguments, and then other
 247 # parameters that are the command and any parameters that should be passed to
 248 # it each time.
 249 sub xargs {
 250         my $args=shift;
 251
 252         # The kernel can accept command lines up to 20k worth of characters.
 253         my $command_max=20000; # LINUX SPECIFIC!!
 254                         # (And obsolete; it's bigger now.)
 255                         # I could use POSIX::ARG_MAX, but that would be slow.
 256
 257         # Figure out length of static portion of command.
 258         my $static_length=0;
 259         foreach (@_) {
 260                 $static_length+=length($_)+1;
 261         }
 262
 263         my @collect=();
 264         my $length=$static_length;
 265         foreach (@$args) {
 266                 if (length($_) + 1 + $static_length > $command_max) {
 267                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 268                 }
 269                 $length+=length($_) + 1;
 270                 if ($length < $command_max) {
 271                         push @collect, $_;
 272                 }
 273                 else {
 274                         doit(@_,@collect) if $#collect > -1;
 275                         @collect=($_);
 276                         $length=$static_length + length($_) + 1;
 277                 }
 278         }
 279         doit(@_,@collect) if $#collect > -1;
 280 }
 281
 282 # Print something if the verbose flag is on.
 283 sub verbose_print {
 284         my $message=shift;
 285
 286         if ($dh{VERBOSE}) {
 287                 print "\t$message\n";
 288         }
 289 }
 290
 291 # Output an error message and die (can be caught).
 292 sub error {
 293         my $message=shift;
 294
 295         die basename($0).": $message\n";
 296 }
 297
 298 # Output a warning.
 299 sub warning {
 300         my $message=shift;
 301
 302         print STDERR basename($0).": $message\n";
 303 }
 304
 305 # Returns the basename of the argument passed to it.
 306 sub basename {
 307         my $fn=shift;
 308
 309         $fn=~s/\/$//g; # ignore trailing slashes
 310         $fn=~s:^.*/(.*?)$:$1:;
 311         return $fn;
 312 }
 313
 314 # Returns the directory name of the argument passed to it.
 315 sub dirname {
 316         my $fn=shift;
 317
 318         $fn=~s/\/$//g; # ignore trailing slashes
 319         $fn=~s:^(.*)/.*?$:$1:;
 320         return $fn;
 321 }
 322
 323 # Pass in a number, will return true iff the current compatibility level
 324 # is less than or equal to that number.
 325 {
 326         my $warned_compat=0;
 327         my $c;
 328
 329         sub compat {
 330                 my $num=shift;
 331
 332                 if (! defined $c) {
 333                         $c=1;
 334                         if (defined $ENV{DH_COMPAT}) {
 335                                 $c=$ENV{DH_COMPAT};
 336                         }
 337                         elsif (-e 'debian/compat') {
 338                                 # Try the file..
 339                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 340                                 my $l=<COMPAT_IN>;
 341                                 close COMPAT_IN;
 342                                 if (! defined $l || ! length $l) {
 343                                         warning("debian/compat is empty, assuming level $c");
 344                                 }
 345                                 else {
 346                                         chomp $l;
 347                                         $c=$l;
 348                                 }
 349                         }
 350                 }
 351
 352                 if ($c <= 4 && ! $warned_compat) {
 353                         warning("Compatibility levels before 5 are deprecated.");
 354                         $warned_compat=1;
 355                 }
 356
 357                 if ($c > $max_compat) {
 358                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 359                 }
 360
 361                 return ($c <= $num);
 362         }
 363 }
 364
 365 # Pass it a name of a binary package, it returns the name of the tmp dir to
 366 # use, for that package.
 367 sub tmpdir {
 368         my $package=shift;
 369
 370         if ($dh{TMPDIR}) {
 371                 return $dh{TMPDIR};
 372         }
 373         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 374                 # This is for back-compatibility with the debian/tmp tradition.
 375                 return "debian/tmp";
 376         }
 377         else {
 378                 return "debian/$package";
 379         }
 380 }
 381
 382 # Pass this the name of a binary package, and the name of the file wanted
 383 # for the package, and it will return the actual existing filename to use.
 384 #
 385 # It tries several filenames:
 386 #   * debian/package.filename.buildarch
 387 #   * debian/package.filename.buildos
 388 #   * debian/package.filename
 389 #   * debian/filename (if the package is the main package)
 390 # If --name was specified then the files
 391 # must have the name after the package name:
 392 #   * debian/package.name.filename.buildarch
 393 #   * debian/package.name.filename.buildos
 394 #   * debian/package.name.filename
 395 #   * debian/name.filename (if the package is the main package)
 396 sub pkgfile {
 397         my $package=shift;
 398         my $filename=shift;
 399
 400         if (defined $dh{NAME}) {
 401                 $filename="$dh{NAME}.$filename";
 402         }
 403
 404         # First, check for files ending in buildarch and buildos.
 405         my $match;
 406         foreach my $file (glob("debian/$package.$filename.*")) {
 407                 next if ! -f $file;
 408                 next if $dh{IGNORE} && exists $dh{IGNORE}->{$file};
 409                 if ($file eq "debian/$package.$filename.".buildarch()) {
 410                         $match=$file;
 411                         # buildarch files are used in preference to buildos files.
 412                         last;
 413                 }
 414                 elsif ($file eq "debian/$package.$filename.".buildos()) {
 415                         $match=$file;
 416                 }
 417         }
 418         return $match if defined $match;
 419
 420         my @try=("debian/$package.$filename");
 421         if ($package eq $dh{MAINPACKAGE}) {
 422                 push @try, "debian/$filename";
 423         }
 424
 425         foreach my $file (@try) {
 426                 if (-f $file &&
 427                     (! $dh{IGNORE} || ! exists $dh{IGNORE}->{$file})) {
 428                         return $file;
 429                 }
 430
 431         }
 432
 433         return "";
 434
 435 }
 436
 437 # Pass it a name of a binary package, it returns the name to prefix to files
 438 # in debian/ for this package.
 439 sub pkgext {
 440         my $package=shift;
 441
 442         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 443                 return "";
 444         }
 445         return "$package.";
 446 }
 447
 448 # Pass it the name of a binary package, it returns the name to install
 449 # files by in eg, etc. Normally this is the same, but --name can override
 450 # it.
 451 sub pkgfilename {
 452         my $package=shift;
 453
 454         if (defined $dh{NAME}) {
 455                 return $dh{NAME};
 456         }
 457         return $package;
 458 }
 459
 460 # Returns 1 if the package is a native debian package, null otherwise.
 461 # As a side effect, sets $dh{VERSION} to the version of this package.
 462 {
 463         # Caches return code so it only needs to run dpkg-parsechangelog once.
 464         my %isnative_cache;
 465
 466         sub isnative {
 467                 my $package=shift;
 468
 469                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 470
 471                 # Make sure we look at the correct changelog.
 472                 my $isnative_changelog=pkgfile($package,"changelog");
 473                 if (! $isnative_changelog) {
 474                         $isnative_changelog="debian/changelog";
 475                 }
 476                 # Get the package version.
 477                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 478                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 479                 # Did the changelog parse fail?
 480                 if (! defined $dh{VERSION}) {
 481                         error("changelog parse failure");
 482                 }
 483
 484                 # Is this a native Debian package?
 485                 if ($dh{VERSION}=~m/.*-/) {
 486                         return $isnative_cache{$package}=0;
 487                 }
 488                 else {
 489                         return $isnative_cache{$package}=1;
 490                 }
 491         }
 492 }
 493
 494 # Automatically add a shell script snippet to a debian script.
 495 # Only works if the script has #DEBHELPER# in it.
 496 #
 497 # Parameters:
 498 # 1: package
 499 # 2: script to add to
 500 # 3: filename of snippet
 501 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 502 sub autoscript {
 503         my $package=shift;
 504         my $script=shift;
 505         my $filename=shift;
 506         my $sed=shift || "";
 507
 508         # This is the file we will modify.
 509         my $outfile="debian/".pkgext($package)."$script.debhelper";
 510
 511         # Figure out what shell script snippet to use.
 512         my $infile;
 513         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 514             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 515                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 516         }
 517         else {
 518                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 519                         $infile="/usr/share/debhelper/autoscripts/$filename";
 520                 }
 521                 else {
 522                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 523                 }
 524         }
 525
 526         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 527            && !compat(5)) {
 528                 # Add fragments to top so they run in reverse order when removing.
 529                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 530                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 531                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 532                 complex_doit("cat $outfile >> $outfile.new");
 533                 complex_doit("mv $outfile.new $outfile");
 534         }
 535         else {
 536                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 537                 complex_doit("sed \"$sed\" $infile >> $outfile");
 538                 complex_doit("echo '# End automatically added section' >> $outfile");
 539         }
 540 }
 541
 542 # Removes a whole substvar line.
 543 sub delsubstvar {
 544         my $package=shift;
 545         my $substvar=shift;
 546
 547         my $ext=pkgext($package);
 548         my $substvarfile="debian/${ext}substvars";
 549
 550         if (-e $substvarfile) {
 551                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 552                 doit("mv", "$substvarfile.new","$substvarfile");
 553         }
 554 }
 555
 556 # Adds a dependency on some package to the specified
 557 # substvar in a package's substvar's file.
 558 sub addsubstvar {
 559         my $package=shift;
 560         my $substvar=shift;
 561         my $deppackage=shift;
 562         my $verinfo=shift;
 563         my $remove=shift;
 564
 565         my $ext=pkgext($package);
 566         my $substvarfile="debian/${ext}substvars";
 567         my $str=$deppackage;
 568         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 569
 570         # Figure out what the line will look like, based on what's there
 571         # now, and what we're to add or remove.
 572         my $line="";
 573         if (-e $substvarfile) {
 574                 my %items;
 575                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 576                 while (<SUBSTVARS_IN>) {
 577                         chomp;
 578                         if (/^\Q$substvar\E=(.*)/) {
 579                                 %items = map { $_ => 1} split(", ", $1);
 580
 581                                 last;
 582                         }
 583                 }
 584                 close SUBSTVARS_IN;
 585                 if (! $remove) {
 586                         $items{$str}=1;
 587                 }
 588                 else {
 589                         delete $items{$str};
 590                 }
 591                 $line=join(", ", sort keys %items);
 592         }
 593         elsif (! $remove) {
 594                 $line=$str;
 595         }
 596
 597         if (length $line) {
 598                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 599                  doit("mv", "$substvarfile.new", $substvarfile);
 600         }
 601         else {
 602                 delsubstvar($package,$substvar);
 603         }
 604 }
 605
 606 # Reads in the specified file, one line at a time. splits on words,
 607 # and returns an array of arrays of the contents.
 608 # If a value is passed in as the second parameter, then glob
 609 # expansion is done in the directory specified by the parameter ("." is
 610 # frequently a good choice).
 611 sub filedoublearray {
 612         my $file=shift;
 613         my $globdir=shift;
 614
 615         my @ret;
 616         open (DH_FARRAY_IN, $file) || error("cannot read $file: $!");
 617         while (<DH_FARRAY_IN>) {
 618                 chomp;
 619                 # Only ignore comments and empty lines in v5 mode.
 620                 if (! compat(4)) {
 621                         next if /^#/ || /^$/;
 622                 }
 623                 my @line;
 624                 # Only do glob expansion in v3 mode.
 625                 #
 626                 # The tricky bit is that the glob expansion is done
 627                 # as if we were in the specified directory, so the
 628                 # filenames that come out are relative to it.
 629                 if (defined $globdir && ! compat(2)) {
 630                         foreach (map { glob "$globdir/$_" } split) {
 631                                 s#^$globdir/##;
 632                                 push @line, $_;
 633                         }
 634                 }
 635                 else {
 636                         @line = split;
 637                 }
 638                 push @ret, [@line];
 639         }
 640         close DH_FARRAY_IN;
 641
 642         return @ret;
 643 }
 644
 645 # Reads in the specified file, one word at a time, and returns an array of
 646 # the result. Can do globbing as does filedoublearray.
 647 sub filearray {
 648         return map { @$_ } filedoublearray(@_);
 649 }
 650
 651 # Passed a filename, returns true if -X says that file should be excluded.
 652 sub excludefile {
 653         my $filename = shift;
 654         foreach my $f (@{$dh{EXCLUDE}}) {
 655                 return 1 if $filename =~ /\Q$f\E/;
 656         }
 657         return 0;
 658 }
 659
 660 {
 661         my %dpkg_arch_output;
 662         sub dpkg_architecture_value {
 663                 my $var = shift;
 664                 if (! exists($dpkg_arch_output{$var})) {
 665                         local $_;
 666                         open(PIPE, '-|', 'dpkg-architecture')
 667                                 or error("dpkg-architecture failed");
 668                         while (<PIPE>) {
 669                                 chomp;
 670                                 my ($k, $v) = split(/=/, $_, 2);
 671                                 $dpkg_arch_output{$k} = $v;
 672                         }
 673                         close(PIPE);
 674                 }
 675                 return $dpkg_arch_output{$var};
 676         }
 677 }
 678
 679 # Returns the build architecture.
 680 sub buildarch {
 681         dpkg_architecture_value('DEB_HOST_ARCH');
 682 }
 683
 684 # Returns the build OS.
 685 sub buildos {
 686         dpkg_architecture_value("DEB_HOST_ARCH_OS");
 687 }
 688
 689 # Passed an arch and a list of arches to match against, returns true if matched
 690 {
 691         my %knownsame;
 692
 693         sub samearch {
 694                 my $arch=shift;
 695                 my @archlist=split(/\s+/,shift);
 696
 697                 foreach my $a (@archlist) {
 698                         # Avoid expensive dpkg-architecture call to compare
 699                         # with a simple architecture name. "linux-any" and
 700                         # other architecture wildcards are (currently)
 701                         # always hypenated.
 702                         if ($a !~ /-/) {
 703                                 return 1 if $arch eq $a;
 704                         }
 705                         elsif (exists $knownsame{$arch}{$a}) {
 706                                 return 1 if $knownsame{$arch}{$a};
 707                         }
 708                         elsif (system("dpkg-architecture", "-a$arch", "-i$a") == 0) {
 709                                 return $knownsame{$arch}{$a}=1;
 710                         }
 711                         else {
 712                                 $knownsame{$arch}{$a}=0;
 713                         }
 714                 }
 715
 716                 return 0;
 717         }
 718 }
 719
 720 # Returns source package name
 721 sub sourcepackage {
 722         open (CONTROL, 'debian/control') ||
 723             error("cannot read debian/control: $!\n");
 724         while (<CONTROL>) {
 725                 chomp;
 726                 s/\s+$//;
 727                 if (/^Source:\s*(.*)/) {
 728                         close CONTROL;
 729                         return $1;
 730                 }
 731         }
 732
 733         close CONTROL;
 734         error("could not find Source: line in control file.");
 735 }
 736
 737 # Returns a list of packages in the control file.
 738 # Pass "arch" or "indep" to specify arch-dependant (that will be built
 739 # for the system's arch) or independant. If nothing is specified,
 740 # returns all packages. Also, "both" returns the union of "arch" and "indep"
 741 # packages.
 742 # As a side effect, populates %package_arches and %package_types with the
 743 # types of all packages (not only those returned).
 744 my (%package_types, %package_arches);
 745 sub getpackages {
 746         my $type=shift;
 747
 748         %package_types=();
 749         %package_arches=();
 750
 751         $type="" if ! defined $type;
 752
 753         my $package="";
 754         my $arch="";
 755         my $package_type;
 756         my @list=();
 757         my %seen;
 758         open (CONTROL, 'debian/control') ||
 759                 error("cannot read debian/control: $!\n");
 760         while (<CONTROL>) {
 761                 chomp;
 762                 s/\s+$//;
 763                 if (/^Package:\s*(.*)/) {
 764                         $package=$1;
 765                         # Detect duplicate package names in the same control file.
 766                         if (! $seen{$package}) {
 767                                 $seen{$package}=1;
 768                         }
 769                         else {
 770                                 error("debian/control has a duplicate entry for $package");
 771                         }
 772                         $package_type="deb";
 773                 }
 774                 if (/^Architecture:\s*(.*)/) {
 775                         $arch=$1;
 776                 }
 777                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 778                         $package_type=$1;
 779                 }
 780
 781                 if (!$_ or eof) { # end of stanza.
 782                         if ($package) {
 783                                 $package_types{$package}=$package_type;
 784                                 $package_arches{$package}=$arch;
 785                         }
 786
 787                         if ($package &&
 788                             ((($type eq 'indep' || $type eq 'both') && $arch eq 'all') ||
 789                              (($type eq 'arch'  || $type eq 'both') && ($arch eq 'any' ||
 790                                              ($arch ne 'all' &&
 791                                               samearch(buildarch(), $arch)))) ||
 792                              ! $type)) {
 793                                 push @list, $package;
 794                                 $package="";
 795                                 $arch="";
 796                         }
 797                 }
 798         }
 799         close CONTROL;
 800
 801         return @list;
 802 }
 803
 804 # Returns the arch a package will build for.
 805 sub package_arch {
 806         my $package=shift;
 807
 808         if (! exists $package_arches{$package}) {
 809                 warning "package $package is not in control info";
 810                 return buildarch();
 811         }
 812         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 813 }
 814
 815 # Return true if a given package is really a udeb.
 816 sub is_udeb {
 817         my $package=shift;
 818
 819         if (! exists $package_types{$package}) {
 820                 warning "package $package is not in control info";
 821                 return 0;
 822         }
 823         return $package_types{$package} eq 'udeb';
 824 }
 825
 826 # Generates the filename that is used for a udeb package.
 827 sub udeb_filename {
 828         my $package=shift;
 829
 830         my $filearch=package_arch($package);
 831         isnative($package); # side effect
 832         my $version=$dh{VERSION};
 833         $version=~s/^[0-9]+://; # strip any epoch
 834         return "${package}_${version}_$filearch.udeb";
 835 }
 836
 837 # Handles #DEBHELPER# substitution in a script; also can generate a new
 838 # script from scratch if none exists but there is a .debhelper file for it.
 839 sub debhelper_script_subst {
 840         my $package=shift;
 841         my $script=shift;
 842
 843         my $tmp=tmpdir($package);
 844         my $ext=pkgext($package);
 845         my $file=pkgfile($package,$script);
 846
 847         if ($file ne '') {
 848                 if (-f "debian/$ext$script.debhelper") {
 849                         # Add this into the script, where it has #DEBHELPER#
 850                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 851                 }
 852                 else {
 853                         # Just get rid of any #DEBHELPER# in the script.
 854                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 855                 }
 856                 doit("chown","0:0","$tmp/DEBIAN/$script");
 857                 doit("chmod",755,"$tmp/DEBIAN/$script");
 858         }
 859         elsif ( -f "debian/$ext$script.debhelper" ) {
 860                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 861                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 862                 doit("chown","0:0","$tmp/DEBIAN/$script");
 863                 doit("chmod",755,"$tmp/DEBIAN/$script");
 864         }
 865 }
 866
 867 # Checks if make's jobserver is enabled via MAKEFLAGS, but
 868 # the FD used to communicate with it is actually not available.
 869 sub is_make_jobserver_unavailable {
 870         if (exists $ENV{MAKEFLAGS} &&
 871             $ENV{MAKEFLAGS} =~ /(?:^|\s)--jobserver-fds=(\d+)/) {
 872                 if (!open(my $in, "<&$1")) {
 873                         return 1; # unavailable
 874                 }
 875                 else {
 876                         close $in;
 877                         return 0; # available
 878                 }
 879         }
 880
 881         return; # no jobserver specified
 882 }
 883
 884 # Cleans out jobserver options from MAKEFLAGS.
 885 sub clean_jobserver_makeflags {
 886         if (exists $ENV{MAKEFLAGS}) {
 887                 if ($ENV{MAKEFLAGS} =~ /(?:^|\s)--jobserver-fds=(\d+)/) {
 888                         $ENV{MAKEFLAGS} =~ s/(?:^|\s)--jobserver-fds=\S+//g;
 889                         $ENV{MAKEFLAGS} =~ s/(?:^|\s)-j\b//g;
 890                 }
 891                 delete $ENV{MAKEFLAGS} if $ENV{MAKEFLAGS} =~ /^\s*$/;
 892         }
 893 }
 894
 895 # If cross-compiling, returns appropriate cross version of command.
 896 sub cross_command {
 897         my $command=shift;
 898         if (dpkg_architecture_value("DEB_BUILD_GNU_TYPE")
 899             ne dpkg_architecture_value("DEB_HOST_GNU_TYPE")) {
 900                 return dpkg_architecture_value("DEB_HOST_GNU_TYPE")."-$command";
 901         }
 902         else {
 903                 return $command;
 904         }
 905 }
 906
 907 # Sets environment variables from dpkg-buildflags. Avoids changing
 908 # any existing environment variables.
 909 sub set_buildflags {
 910         return if $ENV{DH_INTERNAL_BUILDFLAGS} || compat(8);
 911         $ENV{DH_INTERNAL_BUILDFLAGS}=1;
 912
 913         eval "use Dpkg::BuildFlags";
 914         if ($@) {
 915                 warning "unable to load build flags: $@";
 916                 return;
 917         }
 918
 919         my $buildflags = Dpkg::BuildFlags->new();
 920         $buildflags->load_config();
 921         foreach my $flag ($buildflags->list()) {
 922                 next unless $flag =~ /^[A-Z]/; # Skip flags starting with lowercase
 923                 if (! exists $ENV{$flag}) {
 924                         $ENV{$flag} = $buildflags->get($flag);
 925                 }
 926         }
 927 }
 928
 929 # Gets a DEB_BUILD_OPTIONS option, if set.
 930 sub get_buildoption {
 931         my $wanted=shift;
 932
 933         return undef unless exists $ENV{DEB_BUILD_OPTIONS};
 934
 935         foreach my $opt (split(/\s+/, $ENV{DEB_BUILD_OPTIONS})) {
 936                 # currently parallel= is the only one with a parameter
 937                 if ($opt =~ /^parallel=(-?\d+)$/ && $wanted eq 'parallel') {
 938                         return $1;
 939                 }
 940                 elsif ($opt eq $wanted) {
 941                         return 1;
 942                 }
 943         }
 944 }
 945
 946 1