Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2008.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell
  18             &inhibit_log);
  19
  20 my $max_compat=7;
  21
  22 sub init {
  23         my %params=@_;
  24
  25         # Check to see if an option line starts with a dash,
  26         # or DH_OPTIONS is set.
  27         # If so, we need to pass this off to the resource intensive
  28         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  29         if ((defined $ENV{DH_OPTIONS} && length $ENV{DH_OPTIONS}) ||
  30             (defined $ENV{DH_INTERNAL_OPTIONS} && length $ENV{DH_INTERNAL_OPTIONS}) ||
  31             grep /^-/, @ARGV) {
  32                 eval "use Debian::Debhelper::Dh_Getopt";
  33                 error($@) if $@;
  34                 Debian::Debhelper::Dh_Getopt::parseopts($params{options});
  35         }
  36
  37         # Another way to set excludes.
  38         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  39                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  40         }
  41
  42         # Generate EXCLUDE_FIND.
  43         if ($dh{EXCLUDE}) {
  44                 $dh{EXCLUDE_FIND}='';
  45                 foreach (@{$dh{EXCLUDE}}) {
  46                         my $x=$_;
  47                         $x=escape_shell($x);
  48                         $x=~s/\./\\\\./g;
  49                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  50                 }
  51                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  52         }
  53
  54         # Check to see if DH_VERBOSE environment variable was set, if so,
  55         # make sure verbose is on.
  56         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  57                 $dh{VERBOSE}=1;
  58         }
  59
  60         # Check to see if DH_NO_ACT environment variable was set, if so,
  61         # make sure no act mode is on.
  62         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  63                 $dh{NO_ACT}=1;
  64         }
  65
  66         my @allpackages=getpackages();
  67         # Get the name of the main binary package (first one listed in
  68         # debian/control). Only if the main package was not set on the
  69         # command line.
  70         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  71                 $dh{MAINPACKAGE}=$allpackages[0];
  72         }
  73
  74         # Check if packages to build have been specified, if not, fall back to
  75         # the default, doing them all.
  76         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  77                 if ($dh{DOINDEP} || $dh{DOARCH} || $dh{DOSAME}) {
  78                         error("You asked that all arch in(dep) packages be built, but there are none of that type.");
  79                 }
  80                 push @{$dh{DOPACKAGES}},@allpackages;
  81         }
  82
  83         # Check to see if -P was specified. If so, we can only act on a single
  84         # package.
  85         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  86                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  87         }
  88
  89         # Figure out which package is the first one we were instructed to build.
  90         # This package gets special treatement: files and directories specified on
  91         # the command line may affect it.
  92         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
  93
  94         # If no error handling function was specified, just propigate
  95         # errors out.
  96         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
  97                 $dh{ERROR_HANDLER}='exit \$?';
  98         }
  99 }
 100
 101 # Run at exit. Add the command to the log files for the packages it acted
 102 # on, if it's exiting successfully.
 103 my $write_log=1;
 104 sub END {
 105         if ($? == 0 && $write_log) {
 106                 write_log(basename($0), @{$dh{DOPACKAGES}});
 107         }
 108 }
 109
 110 sub write_log {
 111         my $cmd=shift;
 112         my @packages=@_;
 113
 114         foreach my $package (@packages) {
 115                 my $ext=pkgext($package);
 116                 my $log="debian/${ext}debhelper.log";
 117                 open(LOG, ">>", $log) || error("failed to write to ${log}: $!");
 118                 print LOG $cmd."\n";
 119                 close LOG;
 120         }
 121 }
 122
 123 sub inhibit_log {
 124         $write_log=0;
 125 }
 126
 127 # Pass it an array containing the arguments of a shell command like would
 128 # be run by exec(). It turns that into a line like you might enter at the
 129 # shell, escaping metacharacters and quoting arguments that contain spaces.
 130 sub escape_shell {
 131         my @args=@_;
 132         my $line="";
 133         my @ret;
 134         foreach my $word (@args) {
 135                 if ($word=~/\s/) {
 136                         # Escape only a few things since it will be quoted.
 137                         # Note we use double quotes because you cannot
 138                         # escape ' in single quotes, while " can be escaped
 139                         # in double.
 140                         # This does make -V"foo bar" turn into "-Vfoo bar",
 141                         # but that will be parsed identically by the shell
 142                         # anyway..
 143                         $word=~s/([\n`\$"\\])/\\$1/g;
 144                         push @ret, "\"$word\"";
 145                 }
 146                 else {
 147                         # This list is from _Unix in a Nutshell_. (except '#')
 148                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 149                         push @ret,$word;
 150                 }
 151         }
 152         return join(' ', @ret);
 153 }
 154
 155 # Run a command, and display the command to stdout if verbose mode is on.
 156 # All commands that modifiy files in $TMP should be ran via this
 157 # function.
 158 #
 159 # Note that this cannot handle complex commands, especially anything
 160 # involving redirection. Use complex_doit instead.
 161 sub doit {
 162         verbose_print(escape_shell(@_));
 163
 164         if (! $dh{NO_ACT}) {
 165                 system(@_) == 0 || _error_exitcode($_[0]);
 166         }
 167 }
 168
 169 # Run a command and display the command to stdout if verbose mode is on.
 170 # Use doit() if you can, instead of this function, because this function
 171 # forks a shell. However, this function can handle more complicated stuff
 172 # like redirection.
 173 sub complex_doit {
 174         verbose_print(join(" ",@_));
 175
 176         if (! $dh{NO_ACT}) {
 177                 # The join makes system get a scalar so it forks off a shell.
 178                 system(join(" ", @_)) == 0 || _error_exitcode(join(" ", @_))
 179         }
 180 }
 181
 182 sub _error_exitcode {
 183         my $command=shift;
 184         if ($? == -1) {
 185                 error("$command failed to to execute: $!");
 186         }
 187         elsif ($? & 127) {
 188                 error("$command died with signal ".($? & 127));
 189         }
 190         else {
 191                 error("$command returned exit code ".($? >> 8));
 192         }
 193 }
 194
 195 # Run a command that may have a huge number of arguments, like xargs does.
 196 # Pass in a reference to an array containing the arguments, and then other
 197 # parameters that are the command and any parameters that should be passed to
 198 # it each time.
 199 sub xargs {
 200         my $args=shift;
 201
 202         # The kernel can accept command lines up to 20k worth of characters.
 203         my $command_max=20000; # LINUX SPECIFIC!!
 204                         # I could use POSIX::ARG_MAX, but that would be slow.
 205
 206         # Figure out length of static portion of command.
 207         my $static_length=0;
 208         foreach (@_) {
 209                 $static_length+=length($_)+1;
 210         }
 211
 212         my @collect=();
 213         my $length=$static_length;
 214         foreach (@$args) {
 215                 if (length($_) + 1 + $static_length > $command_max) {
 216                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 217                 }
 218                 $length+=length($_) + 1;
 219                 if ($length < $command_max) {
 220                         push @collect, $_;
 221                 }
 222                 else {
 223                         doit(@_,@collect) if $#collect > -1;
 224                         @collect=($_);
 225                         $length=$static_length + length($_) + 1;
 226                 }
 227         }
 228         doit(@_,@collect) if $#collect > -1;
 229 }
 230
 231 # Print something if the verbose flag is on.
 232 sub verbose_print {
 233         my $message=shift;
 234
 235         if ($dh{VERBOSE}) {
 236                 print "\t$message\n";
 237         }
 238 }
 239
 240 # Output an error message and exit.
 241 sub error {
 242         my $message=shift;
 243
 244         warning($message);
 245         exit 1;
 246 }
 247
 248 # Output a warning.
 249 sub warning {
 250         my $message=shift;
 251
 252         print STDERR basename($0).": $message\n";
 253 }
 254
 255 # Returns the basename of the argument passed to it.
 256 sub basename {
 257         my $fn=shift;
 258
 259         $fn=~s/\/$//g; # ignore trailing slashes
 260         $fn=~s:^.*/(.*?)$:$1:;
 261         return $fn;
 262 }
 263
 264 # Returns the directory name of the argument passed to it.
 265 sub dirname {
 266         my $fn=shift;
 267
 268         $fn=~s/\/$//g; # ignore trailing slashes
 269         $fn=~s:^(.*)/.*?$:$1:;
 270         return $fn;
 271 }
 272
 273 # Pass in a number, will return true iff the current compatibility level
 274 # is less than or equal to that number.
 275 {
 276         my $warned_compat=0;
 277         my $c;
 278
 279         sub compat {
 280                 my $num=shift;
 281
 282                 if (! defined $c) {
 283                         $c=1;
 284                         if (defined $ENV{DH_COMPAT}) {
 285                                 $c=$ENV{DH_COMPAT};
 286                         }
 287                         elsif (-e 'debian/compat') {
 288                                 # Try the file..
 289                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 290                                 my $l=<COMPAT_IN>;
 291                                 if (! defined $l || ! length $l) {
 292                                         warning("debian/compat is empty, assuming level $c");
 293                                 }
 294                                 else {
 295                                         chomp $l;
 296                                         $c=$l;
 297                                 }
 298                         }
 299                 }
 300
 301                 if ($c < 4 && ! $warned_compat) {
 302                         warning("Compatibility levels before 4 are deprecated.");
 303                         $warned_compat=1;
 304                 }
 305
 306                 if ($c > $max_compat) {
 307                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 308                 }
 309
 310                 return ($c <= $num);
 311         }
 312 }
 313
 314 # Pass it a name of a binary package, it returns the name of the tmp dir to
 315 # use, for that package.
 316 sub tmpdir {
 317         my $package=shift;
 318
 319         if ($dh{TMPDIR}) {
 320                 return $dh{TMPDIR};
 321         }
 322         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 323                 # This is for back-compatibility with the debian/tmp tradition.
 324                 return "debian/tmp";
 325         }
 326         else {
 327                 return "debian/$package";
 328         }
 329 }
 330
 331 # Pass this the name of a binary package, and the name of the file wanted
 332 # for the package, and it will return the actual existing filename to use.
 333 #
 334 # It tries several filenames:
 335 #   * debian/package.filename.buildarch
 336 #   * debian/package.filename
 337 #   * debian/file (if the package is the main package)
 338 # If --name was specified then tonly the first two are tried, and they must
 339 # have the name after the pacage name:
 340 #   * debian/package.name.filename.buildarch
 341 #   * debian/package.name.filename
 342 sub pkgfile {
 343         my $package=shift;
 344         my $filename=shift;
 345
 346         if (defined $dh{NAME}) {
 347                 $filename="$dh{NAME}.$filename";
 348         }
 349
 350         my @try=("debian/$package.$filename.".buildarch(),
 351                  "debian/$package.$filename");
 352         if ($package eq $dh{MAINPACKAGE}) {
 353                 push @try, "debian/$filename";
 354         }
 355
 356         foreach my $file (@try) {
 357                 if (-f $file &&
 358                     (! $dh{IGNORE} || ! exists $dh{IGNORE}->{$file})) {
 359                         return $file;
 360                 }
 361
 362         }
 363
 364         return "";
 365
 366 }
 367
 368 # Pass it a name of a binary package, it returns the name to prefix to files
 369 # in debian/ for this package.
 370 sub pkgext {
 371         my $package=shift;
 372
 373         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 374                 return "";
 375         }
 376         return "$package.";
 377 }
 378
 379 # Pass it the name of a binary package, it returns the name to install
 380 # files by in eg, etc. Normally this is the same, but --name can override
 381 # it.
 382 sub pkgfilename {
 383         my $package=shift;
 384
 385         if (defined $dh{NAME}) {
 386                 return $dh{NAME};
 387         }
 388         return $package;
 389 }
 390
 391 # Returns 1 if the package is a native debian package, null otherwise.
 392 # As a side effect, sets $dh{VERSION} to the version of this package.
 393 {
 394         # Caches return code so it only needs to run dpkg-parsechangelog once.
 395         my %isnative_cache;
 396
 397         sub isnative {
 398                 my $package=shift;
 399
 400                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 401
 402                 # Make sure we look at the correct changelog.
 403                 my $isnative_changelog=pkgfile($package,"changelog");
 404                 if (! $isnative_changelog) {
 405                         $isnative_changelog="debian/changelog";
 406                 }
 407                 # Get the package version.
 408                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 409                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 410                 # Did the changelog parse fail?
 411                 if (! defined $dh{VERSION}) {
 412                         error("changelog parse failure");
 413                 }
 414
 415                 # Is this a native Debian package?
 416                 if ($dh{VERSION}=~m/.*-/) {
 417                         return $isnative_cache{$package}=0;
 418                 }
 419                 else {
 420                         return $isnative_cache{$package}=1;
 421                 }
 422         }
 423 }
 424
 425 # Automatically add a shell script snippet to a debian script.
 426 # Only works if the script has #DEBHELPER# in it.
 427 #
 428 # Parameters:
 429 # 1: package
 430 # 2: script to add to
 431 # 3: filename of snippet
 432 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 433 sub autoscript {
 434         my $package=shift;
 435         my $script=shift;
 436         my $filename=shift;
 437         my $sed=shift || "";
 438
 439         # This is the file we will modify.
 440         my $outfile="debian/".pkgext($package)."$script.debhelper";
 441
 442         # Figure out what shell script snippet to use.
 443         my $infile;
 444         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 445             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 446                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 447         }
 448         else {
 449                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 450                         $infile="/usr/share/debhelper/autoscripts/$filename";
 451                 }
 452                 else {
 453                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 454                 }
 455         }
 456
 457         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 458            && !compat(5)) {
 459                 # Add fragments to top so they run in reverse order when removing.
 460                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 461                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 462                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 463                 complex_doit("cat $outfile >> $outfile.new");
 464                 complex_doit("mv $outfile.new $outfile");
 465         }
 466         else {
 467                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 468                 complex_doit("sed \"$sed\" $infile >> $outfile");
 469                 complex_doit("echo '# End automatically added section' >> $outfile");
 470         }
 471 }
 472
 473 # Removes a whole substvar line.
 474 sub delsubstvar {
 475         my $package=shift;
 476         my $substvar=shift;
 477
 478         my $ext=pkgext($package);
 479         my $substvarfile="debian/${ext}substvars";
 480
 481         if (-e $substvarfile) {
 482                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 483                 doit("mv", "$substvarfile.new","$substvarfile");
 484         }
 485 }
 486
 487 # Adds a dependency on some package to the specified
 488 # substvar in a package's substvar's file.
 489 sub addsubstvar {
 490         my $package=shift;
 491         my $substvar=shift;
 492         my $deppackage=shift;
 493         my $verinfo=shift;
 494         my $remove=shift;
 495
 496         my $ext=pkgext($package);
 497         my $substvarfile="debian/${ext}substvars";
 498         my $str=$deppackage;
 499         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 500
 501         # Figure out what the line will look like, based on what's there
 502         # now, and what we're to add or remove.
 503         my $line="";
 504         if (-e $substvarfile) {
 505                 my %items;
 506                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 507                 while (<SUBSTVARS_IN>) {
 508                         chomp;
 509                         if (/^\Q$substvar\E=(.*)/) {
 510                                 %items = map { $_ => 1} split(", ", $1);
 511
 512                                 last;
 513                         }
 514                 }
 515                 close SUBSTVARS_IN;
 516                 if (! $remove) {
 517                         $items{$str}=1;
 518                 }
 519                 else {
 520                         delete $items{$str};
 521                 }
 522                 $line=join(", ", sort keys %items);
 523         }
 524         elsif (! $remove) {
 525                 $line=$str;
 526         }
 527
 528         if (length $line) {
 529                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 530                  doit("mv", "$substvarfile.new", $substvarfile);
 531         }
 532         else {
 533                 delsubstvar($package,$substvar);
 534         }
 535 }
 536
 537 # Reads in the specified file, one line at a time. splits on words,
 538 # and returns an array of arrays of the contents.
 539 # If a value is passed in as the second parameter, then glob
 540 # expansion is done in the directory specified by the parameter ("." is
 541 # frequently a good choice).
 542 sub filedoublearray {
 543         my $file=shift;
 544         my $globdir=shift;
 545
 546         my @ret;
 547         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 548         while (<DH_FARRAY_IN>) {
 549                 chomp;
 550                 # Only ignore comments and empty lines in v5 mode.
 551                 if (! compat(4)) {
 552                         next if /^#/ || /^$/;
 553                 }
 554                 my @line;
 555                 # Only do glob expansion in v3 mode.
 556                 #
 557                 # The tricky bit is that the glob expansion is done
 558                 # as if we were in the specified directory, so the
 559                 # filenames that come out are relative to it.
 560                 if (defined $globdir && ! compat(2)) {
 561                         for (map { glob "$globdir/$_" } split) {
 562                                 s#^$globdir/##;
 563                                 push @line, $_;
 564                         }
 565                 }
 566                 else {
 567                         @line = split;
 568                 }
 569                 push @ret, [@line];
 570         }
 571         close DH_FARRAY_IN;
 572
 573         return @ret;
 574 }
 575
 576 # Reads in the specified file, one word at a time, and returns an array of
 577 # the result. Can do globbing as does filedoublearray.
 578 sub filearray {
 579         return map { @$_ } filedoublearray(@_);
 580 }
 581
 582 # Passed a filename, returns true if -X says that file should be excluded.
 583 sub excludefile {
 584         my $filename = shift;
 585         foreach my $f (@{$dh{EXCLUDE}}) {
 586                 return 1 if $filename =~ /\Q$f\E/;
 587         }
 588         return 0;
 589 }
 590
 591 # Returns the build architecture. (Memoized)
 592 {
 593         my $arch;
 594
 595         sub buildarch {
 596                 return $arch if defined $arch;
 597
 598                 $arch=`dpkg-architecture -qDEB_HOST_ARCH 2>/dev/null` || error("dpkg-architecture failed");
 599                 chomp $arch;
 600                 return $arch;
 601         }
 602 }
 603
 604 # Passed an arch and a list of arches to match against, returns true if matched
 605 sub samearch {
 606         my $arch=shift;
 607         my @archlist=split(/\s+/,shift);
 608
 609         foreach my $a (@archlist) {
 610                 system("dpkg-architecture", "-a$arch", "-i$a") == 0 && return 1;
 611         }
 612
 613         return 0;
 614 }
 615
 616 # Returns a list of packages in the control file.
 617 # Must pass "arch" or "indep" or "same" to specify arch-dependant or
 618 # -independant or same arch packages. If nothing is specified, returns all
 619 # packages.
 620 # As a side effect, populates %package_arches and %package_types with the
 621 # types of all packages (not only those returned).
 622 my (%package_types, %package_arches);
 623 sub getpackages {
 624         my $type=shift;
 625
 626         %package_types=();
 627         %package_arches=();
 628
 629         $type="" if ! defined $type;
 630
 631         # Look up the build arch if we need to.
 632         my $buildarch='';
 633         if ($type eq 'same') {
 634                 $buildarch=buildarch();
 635         }
 636
 637         my $package="";
 638         my $arch="";
 639         my $package_type;
 640         my @list=();
 641         my %seen;
 642         open (CONTROL, 'debian/control') ||
 643                 error("cannot read debian/control: $!\n");
 644         while (<CONTROL>) {
 645                 chomp;
 646                 s/\s+$//;
 647                 if (/^Package:\s*(.*)/) {
 648                         $package=$1;
 649                         # Detect duplicate package names in the same control file.
 650                         if (! $seen{$package}) {
 651                                 $seen{$package}=1;
 652                         }
 653                         else {
 654                                 error("debian/control has a duplicate entry for $package");
 655                         }
 656                         $package_type="deb";
 657                 }
 658                 if (/^Architecture:\s*(.*)/) {
 659                         $arch=$1;
 660                 }
 661                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 662                         $package_type=$1;
 663                 }
 664
 665                 if (!$_ or eof) { # end of stanza.
 666                         if ($package) {
 667                                 $package_types{$package}=$package_type;
 668                                 $package_arches{$package}=$arch;
 669                         }
 670                         if ($package &&
 671                             (($type eq 'indep' && $arch eq 'all') ||
 672                              ($type eq 'arch' && $arch ne 'all') ||
 673                              ($type eq 'same' && ($arch eq 'any' || samearch($buildarch, $arch))) ||
 674                              ! $type)) {
 675                                 push @list, $package;
 676                                 $package="";
 677                                 $arch="";
 678                         }
 679                 }
 680         }
 681         close CONTROL;
 682
 683         return @list;
 684 }
 685
 686 # Returns the arch a package will build for.
 687 sub package_arch {
 688         my $package=shift;
 689
 690         if (! exists $package_arches{$package}) {
 691                 warning "package $package is not in control info";
 692                 return buildarch();
 693         }
 694         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 695 }
 696
 697 # Return true if a given package is really a udeb.
 698 sub is_udeb {
 699         my $package=shift;
 700
 701         if (! exists $package_types{$package}) {
 702                 warning "package $package is not in control info";
 703                 return 0;
 704         }
 705         return $package_types{$package} eq 'udeb';
 706 }
 707
 708 # Generates the filename that is used for a udeb package.
 709 sub udeb_filename {
 710         my $package=shift;
 711
 712         my $filearch=package_arch($package);
 713         isnative($package); # side effect
 714         my $version=$dh{VERSION};
 715         $version=~s/^[0-9]+://; # strip any epoch
 716         return "${package}_${version}_$filearch.udeb";
 717 }
 718
 719 # Handles #DEBHELPER# substitution in a script; also can generate a new
 720 # script from scratch if none exists but there is a .debhelper file for it.
 721 sub debhelper_script_subst {
 722         my $package=shift;
 723         my $script=shift;
 724
 725         my $tmp=tmpdir($package);
 726         my $ext=pkgext($package);
 727         my $file=pkgfile($package,$script);
 728
 729         if ($file ne '') {
 730                 if (-f "debian/$ext$script.debhelper") {
 731                         # Add this into the script, where it has #DEBHELPER#
 732                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 733                 }
 734                 else {
 735                         # Just get rid of any #DEBHELPER# in the script.
 736                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 737                 }
 738                 doit("chown","0:0","$tmp/DEBIAN/$script");
 739                 doit("chmod",755,"$tmp/DEBIAN/$script");
 740         }
 741         elsif ( -f "debian/$ext$script.debhelper" ) {
 742                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 743                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 744                 doit("chown","0:0","$tmp/DEBIAN/$script");
 745                 doit("chmod",755,"$tmp/DEBIAN/$script");
 746         }
 747 }
 748
 749 1