Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2008.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell
  18             &inhibit_log &load_log &write_log &dpkg_architecture_value
  19             &sourcepackage
  20             &is_make_jobserver_unavailable &clean_jobserver_makeflags);
  21
  22 my $max_compat=7;
  23
  24 sub init {
  25         my %params=@_;
  26
  27         # Check to see if an option line starts with a dash,
  28         # or DH_OPTIONS is set.
  29         # If so, we need to pass this off to the resource intensive
  30         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  31         if ((defined $ENV{DH_OPTIONS} && length $ENV{DH_OPTIONS}) ||
  32             (defined $ENV{DH_INTERNAL_OPTIONS} && length $ENV{DH_INTERNAL_OPTIONS}) ||
  33             grep /^-/, @ARGV) {
  34                 eval "use Debian::Debhelper::Dh_Getopt";
  35                 error($@) if $@;
  36                 Debian::Debhelper::Dh_Getopt::parseopts($params{options});
  37         }
  38
  39         # Another way to set excludes.
  40         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  41                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  42         }
  43
  44         # Generate EXCLUDE_FIND.
  45         if ($dh{EXCLUDE}) {
  46                 $dh{EXCLUDE_FIND}='';
  47                 foreach (@{$dh{EXCLUDE}}) {
  48                         my $x=$_;
  49                         $x=escape_shell($x);
  50                         $x=~s/\./\\\\./g;
  51                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  52                 }
  53                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  54         }
  55
  56         # Check to see if DH_VERBOSE environment variable was set, if so,
  57         # make sure verbose is on.
  58         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  59                 $dh{VERBOSE}=1;
  60         }
  61
  62         # Check to see if DH_NO_ACT environment variable was set, if so,
  63         # make sure no act mode is on.
  64         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  65                 $dh{NO_ACT}=1;
  66         }
  67
  68         my @allpackages=getpackages();
  69         # Get the name of the main binary package (first one listed in
  70         # debian/control). Only if the main package was not set on the
  71         # command line.
  72         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  73                 $dh{MAINPACKAGE}=$allpackages[0];
  74         }
  75
  76         # Check if packages to build have been specified, if not, fall back to
  77         # the default, doing them all.
  78         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  79                 push @{$dh{DOPACKAGES}},@allpackages;
  80         }
  81
  82         # Check to see if -P was specified. If so, we can only act on a single
  83         # package.
  84         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  85                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  86         }
  87
  88         # Figure out which package is the first one we were instructed to build.
  89         # This package gets special treatement: files and directories specified on
  90         # the command line may affect it.
  91         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
  92
  93         # If no error handling function was specified, just propigate
  94         # errors out.
  95         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
  96                 $dh{ERROR_HANDLER}='exit \$?';
  97         }
  98 }
  99
 100 # Run at exit. Add the command to the log files for the packages it acted
 101 # on, if it's exiting successfully.
 102 my $write_log=1;
 103 sub END {
 104         if ($? == 0 && $write_log) {
 105                 write_log(basename($0), @{$dh{DOPACKAGES}});
 106         }
 107 }
 108
 109 sub load_log {
 110         my ($package, $db)=@_;
 111         my $ext=pkgext($package);
 112
 113         my @log;
 114         open(LOG, "<", "debian/${ext}debhelper.log") || return;
 115         while (<LOG>) {
 116                 chomp;
 117                 push @log, $_;
 118                 $db->{$package}{$_}=1 if defined $db;
 119         }
 120         close LOG;
 121         return @log;
 122 }
 123
 124 sub write_log {
 125         my $cmd=shift;
 126         my @packages=@_;
 127
 128         foreach my $package (@packages) {
 129                 my $ext=pkgext($package);
 130                 my $log="debian/${ext}debhelper.log";
 131                 open(LOG, ">>", $log) || error("failed to write to ${log}: $!");
 132                 print LOG $cmd."\n";
 133                 close LOG;
 134         }
 135 }
 136
 137 sub inhibit_log {
 138         $write_log=0;
 139 }
 140
 141 # Pass it an array containing the arguments of a shell command like would
 142 # be run by exec(). It turns that into a line like you might enter at the
 143 # shell, escaping metacharacters and quoting arguments that contain spaces.
 144 sub escape_shell {
 145         my @args=@_;
 146         my $line="";
 147         my @ret;
 148         foreach my $word (@args) {
 149                 if ($word=~/\s/) {
 150                         # Escape only a few things since it will be quoted.
 151                         # Note we use double quotes because you cannot
 152                         # escape ' in single quotes, while " can be escaped
 153                         # in double.
 154                         # This does make -V"foo bar" turn into "-Vfoo bar",
 155                         # but that will be parsed identically by the shell
 156                         # anyway..
 157                         $word=~s/([\n`\$"\\])/\\$1/g;
 158                         push @ret, "\"$word\"";
 159                 }
 160                 else {
 161                         # This list is from _Unix in a Nutshell_. (except '#')
 162                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 163                         push @ret,$word;
 164                 }
 165         }
 166         return join(' ', @ret);
 167 }
 168
 169 # Run a command, and display the command to stdout if verbose mode is on.
 170 # All commands that modifiy files in $TMP should be ran via this
 171 # function.
 172 #
 173 # Note that this cannot handle complex commands, especially anything
 174 # involving redirection. Use complex_doit instead.
 175 sub doit {
 176         verbose_print(escape_shell(@_));
 177
 178         if (! $dh{NO_ACT}) {
 179                 system(@_) == 0 || _error_exitcode(join(" ", @_));
 180         }
 181 }
 182
 183 # Run a command and display the command to stdout if verbose mode is on.
 184 # Use doit() if you can, instead of this function, because this function
 185 # forks a shell. However, this function can handle more complicated stuff
 186 # like redirection.
 187 sub complex_doit {
 188         verbose_print(join(" ",@_));
 189
 190         if (! $dh{NO_ACT}) {
 191                 # The join makes system get a scalar so it forks off a shell.
 192                 system(join(" ", @_)) == 0 || _error_exitcode(join(" ", @_))
 193         }
 194 }
 195
 196 sub _error_exitcode {
 197         my $command=shift;
 198         if ($? == -1) {
 199                 error("$command failed to to execute: $!");
 200         }
 201         elsif ($? & 127) {
 202                 error("$command died with signal ".($? & 127));
 203         }
 204         else {
 205                 error("$command returned exit code ".($? >> 8));
 206         }
 207 }
 208
 209 # Run a command that may have a huge number of arguments, like xargs does.
 210 # Pass in a reference to an array containing the arguments, and then other
 211 # parameters that are the command and any parameters that should be passed to
 212 # it each time.
 213 sub xargs {
 214         my $args=shift;
 215
 216         # The kernel can accept command lines up to 20k worth of characters.
 217         my $command_max=20000; # LINUX SPECIFIC!!
 218                         # I could use POSIX::ARG_MAX, but that would be slow.
 219
 220         # Figure out length of static portion of command.
 221         my $static_length=0;
 222         foreach (@_) {
 223                 $static_length+=length($_)+1;
 224         }
 225
 226         my @collect=();
 227         my $length=$static_length;
 228         foreach (@$args) {
 229                 if (length($_) + 1 + $static_length > $command_max) {
 230                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 231                 }
 232                 $length+=length($_) + 1;
 233                 if ($length < $command_max) {
 234                         push @collect, $_;
 235                 }
 236                 else {
 237                         doit(@_,@collect) if $#collect > -1;
 238                         @collect=($_);
 239                         $length=$static_length + length($_) + 1;
 240                 }
 241         }
 242         doit(@_,@collect) if $#collect > -1;
 243 }
 244
 245 # Print something if the verbose flag is on.
 246 sub verbose_print {
 247         my $message=shift;
 248
 249         if ($dh{VERBOSE}) {
 250                 print "\t$message\n";
 251         }
 252 }
 253
 254 # Output an error message and exit.
 255 sub error {
 256         my $message=shift;
 257
 258         warning($message);
 259         exit 1;
 260 }
 261
 262 # Output a warning.
 263 sub warning {
 264         my $message=shift;
 265
 266         print STDERR basename($0).": $message\n";
 267 }
 268
 269 # Returns the basename of the argument passed to it.
 270 sub basename {
 271         my $fn=shift;
 272
 273         $fn=~s/\/$//g; # ignore trailing slashes
 274         $fn=~s:^.*/(.*?)$:$1:;
 275         return $fn;
 276 }
 277
 278 # Returns the directory name of the argument passed to it.
 279 sub dirname {
 280         my $fn=shift;
 281
 282         $fn=~s/\/$//g; # ignore trailing slashes
 283         $fn=~s:^(.*)/.*?$:$1:;
 284         return $fn;
 285 }
 286
 287 # Pass in a number, will return true iff the current compatibility level
 288 # is less than or equal to that number.
 289 {
 290         my $warned_compat=0;
 291         my $c;
 292
 293         sub compat {
 294                 my $num=shift;
 295
 296                 if (! defined $c) {
 297                         $c=1;
 298                         if (defined $ENV{DH_COMPAT}) {
 299                                 $c=$ENV{DH_COMPAT};
 300                         }
 301                         elsif (-e 'debian/compat') {
 302                                 # Try the file..
 303                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 304                                 my $l=<COMPAT_IN>;
 305                                 close COMPAT_IN;
 306                                 if (! defined $l || ! length $l) {
 307                                         warning("debian/compat is empty, assuming level $c");
 308                                 }
 309                                 else {
 310                                         chomp $l;
 311                                         $c=$l;
 312                                 }
 313                         }
 314                 }
 315
 316                 if ($c <= 4 && ! $warned_compat) {
 317                         warning("Compatibility levels before 5 are deprecated.");
 318                         $warned_compat=1;
 319                 }
 320
 321                 if ($c > $max_compat) {
 322                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 323                 }
 324
 325                 return ($c <= $num);
 326         }
 327 }
 328
 329 # Pass it a name of a binary package, it returns the name of the tmp dir to
 330 # use, for that package.
 331 sub tmpdir {
 332         my $package=shift;
 333
 334         if ($dh{TMPDIR}) {
 335                 return $dh{TMPDIR};
 336         }
 337         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 338                 # This is for back-compatibility with the debian/tmp tradition.
 339                 return "debian/tmp";
 340         }
 341         else {
 342                 return "debian/$package";
 343         }
 344 }
 345
 346 # Pass this the name of a binary package, and the name of the file wanted
 347 # for the package, and it will return the actual existing filename to use.
 348 #
 349 # It tries several filenames:
 350 #   * debian/package.filename.buildarch
 351 #   * debian/package.filename.buildos
 352 #   * debian/package.filename
 353 #   * debian/filename (if the package is the main package)
 354 # If --name was specified then the files
 355 # must have the name after the package name:
 356 #   * debian/package.name.filename.buildarch
 357 #   * debian/package.name.filename.buildos
 358 #   * debian/package.name.filename
 359 #   * debian/name.filename (if the package is the main package)
 360 sub pkgfile {
 361         my $package=shift;
 362         my $filename=shift;
 363
 364         if (defined $dh{NAME}) {
 365                 $filename="$dh{NAME}.$filename";
 366         }
 367
 368         my @try=("debian/$package.$filename.".buildarch(),
 369                  "debian/$package.$filename.".buildos(),
 370                  "debian/$package.$filename");
 371         if ($package eq $dh{MAINPACKAGE}) {
 372                 push @try, "debian/$filename";
 373         }
 374
 375         foreach my $file (@try) {
 376                 if (-f $file &&
 377                     (! $dh{IGNORE} || ! exists $dh{IGNORE}->{$file})) {
 378                         return $file;
 379                 }
 380
 381         }
 382
 383         return "";
 384
 385 }
 386
 387 # Pass it a name of a binary package, it returns the name to prefix to files
 388 # in debian/ for this package.
 389 sub pkgext {
 390         my $package=shift;
 391
 392         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 393                 return "";
 394         }
 395         return "$package.";
 396 }
 397
 398 # Pass it the name of a binary package, it returns the name to install
 399 # files by in eg, etc. Normally this is the same, but --name can override
 400 # it.
 401 sub pkgfilename {
 402         my $package=shift;
 403
 404         if (defined $dh{NAME}) {
 405                 return $dh{NAME};
 406         }
 407         return $package;
 408 }
 409
 410 # Returns 1 if the package is a native debian package, null otherwise.
 411 # As a side effect, sets $dh{VERSION} to the version of this package.
 412 {
 413         # Caches return code so it only needs to run dpkg-parsechangelog once.
 414         my %isnative_cache;
 415
 416         sub isnative {
 417                 my $package=shift;
 418
 419                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 420
 421                 # Make sure we look at the correct changelog.
 422                 my $isnative_changelog=pkgfile($package,"changelog");
 423                 if (! $isnative_changelog) {
 424                         $isnative_changelog="debian/changelog";
 425                 }
 426                 # Get the package version.
 427                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 428                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 429                 # Did the changelog parse fail?
 430                 if (! defined $dh{VERSION}) {
 431                         error("changelog parse failure");
 432                 }
 433
 434                 # Is this a native Debian package?
 435                 if ($dh{VERSION}=~m/.*-/) {
 436                         return $isnative_cache{$package}=0;
 437                 }
 438                 else {
 439                         return $isnative_cache{$package}=1;
 440                 }
 441         }
 442 }
 443
 444 # Automatically add a shell script snippet to a debian script.
 445 # Only works if the script has #DEBHELPER# in it.
 446 #
 447 # Parameters:
 448 # 1: package
 449 # 2: script to add to
 450 # 3: filename of snippet
 451 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 452 sub autoscript {
 453         my $package=shift;
 454         my $script=shift;
 455         my $filename=shift;
 456         my $sed=shift || "";
 457
 458         # This is the file we will modify.
 459         my $outfile="debian/".pkgext($package)."$script.debhelper";
 460
 461         # Figure out what shell script snippet to use.
 462         my $infile;
 463         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 464             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 465                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 466         }
 467         else {
 468                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 469                         $infile="/usr/share/debhelper/autoscripts/$filename";
 470                 }
 471                 else {
 472                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 473                 }
 474         }
 475
 476         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 477            && !compat(5)) {
 478                 # Add fragments to top so they run in reverse order when removing.
 479                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 480                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 481                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 482                 complex_doit("cat $outfile >> $outfile.new");
 483                 complex_doit("mv $outfile.new $outfile");
 484         }
 485         else {
 486                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 487                 complex_doit("sed \"$sed\" $infile >> $outfile");
 488                 complex_doit("echo '# End automatically added section' >> $outfile");
 489         }
 490 }
 491
 492 # Removes a whole substvar line.
 493 sub delsubstvar {
 494         my $package=shift;
 495         my $substvar=shift;
 496
 497         my $ext=pkgext($package);
 498         my $substvarfile="debian/${ext}substvars";
 499
 500         if (-e $substvarfile) {
 501                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 502                 doit("mv", "$substvarfile.new","$substvarfile");
 503         }
 504 }
 505
 506 # Adds a dependency on some package to the specified
 507 # substvar in a package's substvar's file.
 508 sub addsubstvar {
 509         my $package=shift;
 510         my $substvar=shift;
 511         my $deppackage=shift;
 512         my $verinfo=shift;
 513         my $remove=shift;
 514
 515         my $ext=pkgext($package);
 516         my $substvarfile="debian/${ext}substvars";
 517         my $str=$deppackage;
 518         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 519
 520         # Figure out what the line will look like, based on what's there
 521         # now, and what we're to add or remove.
 522         my $line="";
 523         if (-e $substvarfile) {
 524                 my %items;
 525                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 526                 while (<SUBSTVARS_IN>) {
 527                         chomp;
 528                         if (/^\Q$substvar\E=(.*)/) {
 529                                 %items = map { $_ => 1} split(", ", $1);
 530
 531                                 last;
 532                         }
 533                 }
 534                 close SUBSTVARS_IN;
 535                 if (! $remove) {
 536                         $items{$str}=1;
 537                 }
 538                 else {
 539                         delete $items{$str};
 540                 }
 541                 $line=join(", ", sort keys %items);
 542         }
 543         elsif (! $remove) {
 544                 $line=$str;
 545         }
 546
 547         if (length $line) {
 548                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 549                  doit("mv", "$substvarfile.new", $substvarfile);
 550         }
 551         else {
 552                 delsubstvar($package,$substvar);
 553         }
 554 }
 555
 556 # Reads in the specified file, one line at a time. splits on words,
 557 # and returns an array of arrays of the contents.
 558 # If a value is passed in as the second parameter, then glob
 559 # expansion is done in the directory specified by the parameter ("." is
 560 # frequently a good choice).
 561 sub filedoublearray {
 562         my $file=shift;
 563         my $globdir=shift;
 564
 565         my @ret;
 566         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 567         while (<DH_FARRAY_IN>) {
 568                 chomp;
 569                 # Only ignore comments and empty lines in v5 mode.
 570                 if (! compat(4)) {
 571                         next if /^#/ || /^$/;
 572                 }
 573                 my @line;
 574                 # Only do glob expansion in v3 mode.
 575                 #
 576                 # The tricky bit is that the glob expansion is done
 577                 # as if we were in the specified directory, so the
 578                 # filenames that come out are relative to it.
 579                 if (defined $globdir && ! compat(2)) {
 580                         for (map { glob "$globdir/$_" } split) {
 581                                 s#^$globdir/##;
 582                                 push @line, $_;
 583                         }
 584                 }
 585                 else {
 586                         @line = split;
 587                 }
 588                 push @ret, [@line];
 589         }
 590         close DH_FARRAY_IN;
 591
 592         return @ret;
 593 }
 594
 595 # Reads in the specified file, one word at a time, and returns an array of
 596 # the result. Can do globbing as does filedoublearray.
 597 sub filearray {
 598         return map { @$_ } filedoublearray(@_);
 599 }
 600
 601 # Passed a filename, returns true if -X says that file should be excluded.
 602 sub excludefile {
 603         my $filename = shift;
 604         foreach my $f (@{$dh{EXCLUDE}}) {
 605                 return 1 if $filename =~ /\Q$f\E/;
 606         }
 607         return 0;
 608 }
 609
 610 sub dpkg_architecture_value {
 611         my $var = shift;
 612         my $value=`dpkg-architecture -q$var` || error("dpkg-architecture failed");
 613         chomp $value;
 614         return $value;
 615 }
 616
 617 # Returns the build architecture. (Memoized)
 618 {
 619         my $arch;
 620
 621         sub buildarch {
 622                 if (!defined $arch) {
 623                     $arch=dpkg_architecture_value('DEB_HOST_ARCH');
 624                 }
 625                 return $arch;
 626         }
 627 }
 628
 629 # Returns the build OS. (Memoized)
 630 {
 631         my $os;
 632
 633         sub buildos {
 634                 if (!defined $os) {
 635                         $os=dpkg_architecture_value("DEB_HOST_ARCH_OS");
 636                 }
 637                 return $os;
 638         }
 639 }
 640
 641 # Passed an arch and a list of arches to match against, returns true if matched
 642 sub samearch {
 643         my $arch=shift;
 644         my @archlist=split(/\s+/,shift);
 645
 646         foreach my $a (@archlist) {
 647                 system("dpkg-architecture", "-a$arch", "-i$a") == 0 && return 1;
 648         }
 649
 650         return 0;
 651 }
 652
 653 # Returns source package name
 654 sub sourcepackage {
 655         open (CONTROL, 'debian/control') ||
 656             error("cannot read debian/control: $!\n");
 657         while (<CONTROL>) {
 658                 chomp;
 659                 s/\s+$//;
 660                 if (/^Source:\s*(.*)/) {
 661                         close CONTROL;
 662                         return $1;
 663                 }
 664         }
 665
 666         close CONTROL;
 667         error("could not find Source: line in control file.");
 668 }
 669
 670 # Returns a list of packages in the control file.
 671 # Pass "arch" or "indep" to specify arch-dependant or
 672 # independant. If nothing is specified, returns all packages.
 673 # As a side effect, populates %package_arches and %package_types with the
 674 # types of all packages (not only those returned).
 675 my (%package_types, %package_arches);
 676 sub getpackages {
 677         my $type=shift;
 678
 679         %package_types=();
 680         %package_arches=();
 681
 682         $type="" if ! defined $type;
 683
 684         my $package="";
 685         my $arch="";
 686         my $package_type;
 687         my @list=();
 688         my %seen;
 689         open (CONTROL, 'debian/control') ||
 690                 error("cannot read debian/control: $!\n");
 691         while (<CONTROL>) {
 692                 chomp;
 693                 s/\s+$//;
 694                 if (/^Package:\s*(.*)/) {
 695                         $package=$1;
 696                         # Detect duplicate package names in the same control file.
 697                         if (! $seen{$package}) {
 698                                 $seen{$package}=1;
 699                         }
 700                         else {
 701                                 error("debian/control has a duplicate entry for $package");
 702                         }
 703                         $package_type="deb";
 704                 }
 705                 if (/^Architecture:\s*(.*)/) {
 706                         $arch=$1;
 707                 }
 708                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 709                         $package_type=$1;
 710                 }
 711
 712                 if (!$_ or eof) { # end of stanza.
 713                         if ($package) {
 714                                 $package_types{$package}=$package_type;
 715                                 $package_arches{$package}=$arch;
 716                         }
 717
 718                         if ($package &&
 719                             (($type eq 'indep' && $arch eq 'all') ||
 720                              ($type eq 'arch' && ($arch eq 'any' ||
 721                                              ($arch ne 'all' &&
 722                                               samearch(buildarch(), $arch)))) ||
 723                              ! $type)) {
 724                                 push @list, $package;
 725                                 $package="";
 726                                 $arch="";
 727                         }
 728                 }
 729         }
 730         close CONTROL;
 731
 732         return @list;
 733 }
 734
 735 # Returns the arch a package will build for.
 736 sub package_arch {
 737         my $package=shift;
 738
 739         if (! exists $package_arches{$package}) {
 740                 warning "package $package is not in control info";
 741                 return buildarch();
 742         }
 743         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 744 }
 745
 746 # Return true if a given package is really a udeb.
 747 sub is_udeb {
 748         my $package=shift;
 749
 750         if (! exists $package_types{$package}) {
 751                 warning "package $package is not in control info";
 752                 return 0;
 753         }
 754         return $package_types{$package} eq 'udeb';
 755 }
 756
 757 # Generates the filename that is used for a udeb package.
 758 sub udeb_filename {
 759         my $package=shift;
 760
 761         my $filearch=package_arch($package);
 762         isnative($package); # side effect
 763         my $version=$dh{VERSION};
 764         $version=~s/^[0-9]+://; # strip any epoch
 765         return "${package}_${version}_$filearch.udeb";
 766 }
 767
 768 # Handles #DEBHELPER# substitution in a script; also can generate a new
 769 # script from scratch if none exists but there is a .debhelper file for it.
 770 sub debhelper_script_subst {
 771         my $package=shift;
 772         my $script=shift;
 773
 774         my $tmp=tmpdir($package);
 775         my $ext=pkgext($package);
 776         my $file=pkgfile($package,$script);
 777
 778         if ($file ne '') {
 779                 if (-f "debian/$ext$script.debhelper") {
 780                         # Add this into the script, where it has #DEBHELPER#
 781                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 782                 }
 783                 else {
 784                         # Just get rid of any #DEBHELPER# in the script.
 785                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 786                 }
 787                 doit("chown","0:0","$tmp/DEBIAN/$script");
 788                 doit("chmod",755,"$tmp/DEBIAN/$script");
 789         }
 790         elsif ( -f "debian/$ext$script.debhelper" ) {
 791                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 792                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 793                 doit("chown","0:0","$tmp/DEBIAN/$script");
 794                 doit("chmod",755,"$tmp/DEBIAN/$script");
 795         }
 796 }
 797
 798 # Checks if make's jobserver is enabled via MAKEFLAGS, but
 799 # the FD used to communicate with it is actually not available.
 800 sub is_make_jobserver_unavailable {
 801         if (exists $ENV{MAKEFLAGS} &&
 802             $ENV{MAKEFLAGS} =~ /(?:^|\s)--jobserver-fds=(\d+)/) {
 803                 if (!open(my $in, "<&$1")) {
 804                         return 1; # unavailable
 805                 }
 806                 else {
 807                         close $in;
 808                         return 0; # available
 809                 }
 810         }
 811
 812         return; # no jobserver specified
 813 }
 814
 815 # Cleans out jobserver options from MAKEFLAGS.
 816 sub clean_jobserver_makeflags {
 817         if (exists $ENV{MAKEFLAGS}) {
 818                 if ($ENV{MAKEFLAGS} =~ /(?:^|\s)--jobserver-fds=(\d+)/) {
 819                         $ENV{MAKEFLAGS} =~ s/(?:^|\s)--jobserver-fds=\S+//g;
 820                         $ENV{MAKEFLAGS} =~ s/(?:^|\s)-j\b//g;
 821                 }
 822                 delete $ENV{MAKEFLAGS} if $ENV{MAKEFLAGS} =~ /^\s*$/;
 823         }
 824 }
 825
 826 1