Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2008.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell
  18             &inhibit_log &load_log &write_log &dpkg_architecture_value
  19             &sourcepackage &get_make_jobserver_status);
  20
  21 my $max_compat=7;
  22
  23 sub init {
  24         my %params=@_;
  25
  26         # Check to see if an option line starts with a dash,
  27         # or DH_OPTIONS is set.
  28         # If so, we need to pass this off to the resource intensive
  29         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  30         if ((defined $ENV{DH_OPTIONS} && length $ENV{DH_OPTIONS}) ||
  31             (defined $ENV{DH_INTERNAL_OPTIONS} && length $ENV{DH_INTERNAL_OPTIONS}) ||
  32             grep /^-/, @ARGV) {
  33                 eval "use Debian::Debhelper::Dh_Getopt";
  34                 error($@) if $@;
  35                 Debian::Debhelper::Dh_Getopt::parseopts($params{options});
  36         }
  37
  38         # Another way to set excludes.
  39         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  40                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  41         }
  42
  43         # Generate EXCLUDE_FIND.
  44         if ($dh{EXCLUDE}) {
  45                 $dh{EXCLUDE_FIND}='';
  46                 foreach (@{$dh{EXCLUDE}}) {
  47                         my $x=$_;
  48                         $x=escape_shell($x);
  49                         $x=~s/\./\\\\./g;
  50                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  51                 }
  52                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  53         }
  54
  55         # Check to see if DH_VERBOSE environment variable was set, if so,
  56         # make sure verbose is on.
  57         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  58                 $dh{VERBOSE}=1;
  59         }
  60
  61         # Check to see if DH_NO_ACT environment variable was set, if so,
  62         # make sure no act mode is on.
  63         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  64                 $dh{NO_ACT}=1;
  65         }
  66
  67         my @allpackages=getpackages();
  68         # Get the name of the main binary package (first one listed in
  69         # debian/control). Only if the main package was not set on the
  70         # command line.
  71         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  72                 $dh{MAINPACKAGE}=$allpackages[0];
  73         }
  74
  75         # Check if packages to build have been specified, if not, fall back to
  76         # the default, doing them all.
  77         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  78                 push @{$dh{DOPACKAGES}},@allpackages;
  79         }
  80
  81         # Check to see if -P was specified. If so, we can only act on a single
  82         # package.
  83         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  84                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  85         }
  86
  87         # Figure out which package is the first one we were instructed to build.
  88         # This package gets special treatement: files and directories specified on
  89         # the command line may affect it.
  90         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
  91
  92         # If no error handling function was specified, just propigate
  93         # errors out.
  94         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
  95                 $dh{ERROR_HANDLER}='exit \$?';
  96         }
  97 }
  98
  99 # Run at exit. Add the command to the log files for the packages it acted
 100 # on, if it's exiting successfully.
 101 my $write_log=1;
 102 sub END {
 103         if ($? == 0 && $write_log) {
 104                 write_log(basename($0), @{$dh{DOPACKAGES}});
 105         }
 106 }
 107
 108 sub load_log {
 109         my ($package, $db)=@_;
 110         my $ext=pkgext($package);
 111
 112         my @log;
 113         open(LOG, "<", "debian/${ext}debhelper.log") || return;
 114         while (<LOG>) {
 115                 chomp;
 116                 push @log, $_;
 117                 $db->{$package}{$_}=1 if defined $db;
 118         }
 119         close LOG;
 120         return @log;
 121 }
 122
 123 sub write_log {
 124         my $cmd=shift;
 125         my @packages=@_;
 126
 127         foreach my $package (@packages) {
 128                 my $ext=pkgext($package);
 129                 my $log="debian/${ext}debhelper.log";
 130                 open(LOG, ">>", $log) || error("failed to write to ${log}: $!");
 131                 print LOG $cmd."\n";
 132                 close LOG;
 133         }
 134 }
 135
 136 sub inhibit_log {
 137         $write_log=0;
 138 }
 139
 140 # Pass it an array containing the arguments of a shell command like would
 141 # be run by exec(). It turns that into a line like you might enter at the
 142 # shell, escaping metacharacters and quoting arguments that contain spaces.
 143 sub escape_shell {
 144         my @args=@_;
 145         my $line="";
 146         my @ret;
 147         foreach my $word (@args) {
 148                 if ($word=~/\s/) {
 149                         # Escape only a few things since it will be quoted.
 150                         # Note we use double quotes because you cannot
 151                         # escape ' in single quotes, while " can be escaped
 152                         # in double.
 153                         # This does make -V"foo bar" turn into "-Vfoo bar",
 154                         # but that will be parsed identically by the shell
 155                         # anyway..
 156                         $word=~s/([\n`\$"\\])/\\$1/g;
 157                         push @ret, "\"$word\"";
 158                 }
 159                 else {
 160                         # This list is from _Unix in a Nutshell_. (except '#')
 161                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 162                         push @ret,$word;
 163                 }
 164         }
 165         return join(' ', @ret);
 166 }
 167
 168 # Run a command, and display the command to stdout if verbose mode is on.
 169 # All commands that modifiy files in $TMP should be ran via this
 170 # function.
 171 #
 172 # Note that this cannot handle complex commands, especially anything
 173 # involving redirection. Use complex_doit instead.
 174 sub doit {
 175         verbose_print(escape_shell(@_));
 176
 177         if (! $dh{NO_ACT}) {
 178                 system(@_) == 0 || _error_exitcode(join(" ", @_));
 179         }
 180 }
 181
 182 # Run a command and display the command to stdout if verbose mode is on.
 183 # Use doit() if you can, instead of this function, because this function
 184 # forks a shell. However, this function can handle more complicated stuff
 185 # like redirection.
 186 sub complex_doit {
 187         verbose_print(join(" ",@_));
 188
 189         if (! $dh{NO_ACT}) {
 190                 # The join makes system get a scalar so it forks off a shell.
 191                 system(join(" ", @_)) == 0 || _error_exitcode(join(" ", @_))
 192         }
 193 }
 194
 195 sub _error_exitcode {
 196         my $command=shift;
 197         if ($? == -1) {
 198                 error("$command failed to to execute: $!");
 199         }
 200         elsif ($? & 127) {
 201                 error("$command died with signal ".($? & 127));
 202         }
 203         else {
 204                 error("$command returned exit code ".($? >> 8));
 205         }
 206 }
 207
 208 # A helper subroutine for detecting (based on MAKEFLAGS) if make jobserver
 209 # is enabled, if it is available or MAKEFLAGS contains "jobs" option.
 210 # It returns current status (jobserver, jobserver-unavailable or jobs-N where
 211 # N is number of jobs, 0 if infinite) and MAKEFLAGS cleaned up from
 212 # job control options.
 213 sub get_make_jobserver_status {
 214         my $jobsre = qr/(?:^|\s)(?:(?:-j\s*|--jobs(?:=|\s+))(\d+)?|--jobs)\b/;
 215         my $status = "";
 216         my $makeflags;
 217
 218         if (exists $ENV{MAKEFLAGS}) {
 219                 $makeflags = $ENV{MAKEFLAGS};
 220                 if ($makeflags =~ /(?:^|\s)--jobserver-fds=(\d+)/) {
 221                         $status = "jobserver";
 222                         if (!open(my $in, "<&", "$1")) {
 223                                 # Job server is unavailable
 224                                 $status .= "-unavailable";
 225                         }
 226                         else {
 227                                 close $in;
 228                         }
 229                         # Clean makeflags up
 230                         $makeflags =~ s/(?:^|\s)--jobserver-fds=\S+//g;
 231                         $makeflags =~ s/(?:^|\s)-j\b//g;
 232                 }
 233                 elsif (my @m = ($makeflags =~ /$jobsre/g)) {
 234                         # Job count is specified in MAKEFLAGS. Whenever make reads it, a new
 235                         # jobserver will be started. Job count returned is 0 if infinite.
 236                         $status = "jobs-" . (defined $m[$#m] ? $m[$#m] : "0");
 237                         # Clean makeflags up from "jobs" option(s)
 238                         $makeflags =~ s/$jobsre//g;
 239                 }
 240         }
 241         if ($status) {
 242                 # MAKEFLAGS could be unset if it is empty
 243                 $makeflags = undef if $makeflags =~ /^\s*$/;
 244         }
 245         return wantarray ? ($status, $makeflags) : $status;
 246 }
 247
 248 # Run a command that may have a huge number of arguments, like xargs does.
 249 # Pass in a reference to an array containing the arguments, and then other
 250 # parameters that are the command and any parameters that should be passed to
 251 # it each time.
 252 sub xargs {
 253         my $args=shift;
 254
 255         # The kernel can accept command lines up to 20k worth of characters.
 256         my $command_max=20000; # LINUX SPECIFIC!!
 257                         # I could use POSIX::ARG_MAX, but that would be slow.
 258
 259         # Figure out length of static portion of command.
 260         my $static_length=0;
 261         foreach (@_) {
 262                 $static_length+=length($_)+1;
 263         }
 264
 265         my @collect=();
 266         my $length=$static_length;
 267         foreach (@$args) {
 268                 if (length($_) + 1 + $static_length > $command_max) {
 269                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 270                 }
 271                 $length+=length($_) + 1;
 272                 if ($length < $command_max) {
 273                         push @collect, $_;
 274                 }
 275                 else {
 276                         doit(@_,@collect) if $#collect > -1;
 277                         @collect=($_);
 278                         $length=$static_length + length($_) + 1;
 279                 }
 280         }
 281         doit(@_,@collect) if $#collect > -1;
 282 }
 283
 284 # Print something if the verbose flag is on.
 285 sub verbose_print {
 286         my $message=shift;
 287
 288         if ($dh{VERBOSE}) {
 289                 print "\t$message\n";
 290         }
 291 }
 292
 293 # Output an error message and exit.
 294 sub error {
 295         my $message=shift;
 296
 297         warning($message);
 298         exit 1;
 299 }
 300
 301 # Output a warning.
 302 sub warning {
 303         my $message=shift;
 304
 305         print STDERR basename($0).": $message\n";
 306 }
 307
 308 # Returns the basename of the argument passed to it.
 309 sub basename {
 310         my $fn=shift;
 311
 312         $fn=~s/\/$//g; # ignore trailing slashes
 313         $fn=~s:^.*/(.*?)$:$1:;
 314         return $fn;
 315 }
 316
 317 # Returns the directory name of the argument passed to it.
 318 sub dirname {
 319         my $fn=shift;
 320
 321         $fn=~s/\/$//g; # ignore trailing slashes
 322         $fn=~s:^(.*)/.*?$:$1:;
 323         return $fn;
 324 }
 325
 326 # Pass in a number, will return true iff the current compatibility level
 327 # is less than or equal to that number.
 328 {
 329         my $warned_compat=0;
 330         my $c;
 331
 332         sub compat {
 333                 my $num=shift;
 334
 335                 if (! defined $c) {
 336                         $c=1;
 337                         if (defined $ENV{DH_COMPAT}) {
 338                                 $c=$ENV{DH_COMPAT};
 339                         }
 340                         elsif (-e 'debian/compat') {
 341                                 # Try the file..
 342                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 343                                 my $l=<COMPAT_IN>;
 344                                 close COMPAT_IN;
 345                                 if (! defined $l || ! length $l) {
 346                                         warning("debian/compat is empty, assuming level $c");
 347                                 }
 348                                 else {
 349                                         chomp $l;
 350                                         $c=$l;
 351                                 }
 352                         }
 353                 }
 354
 355                 if ($c < 4 && ! $warned_compat) {
 356                         warning("Compatibility levels before 5 are deprecated.");
 357                         $warned_compat=1;
 358                 }
 359
 360                 if ($c > $max_compat) {
 361                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 362                 }
 363
 364                 return ($c <= $num);
 365         }
 366 }
 367
 368 # Pass it a name of a binary package, it returns the name of the tmp dir to
 369 # use, for that package.
 370 sub tmpdir {
 371         my $package=shift;
 372
 373         if ($dh{TMPDIR}) {
 374                 return $dh{TMPDIR};
 375         }
 376         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 377                 # This is for back-compatibility with the debian/tmp tradition.
 378                 return "debian/tmp";
 379         }
 380         else {
 381                 return "debian/$package";
 382         }
 383 }
 384
 385 # Pass this the name of a binary package, and the name of the file wanted
 386 # for the package, and it will return the actual existing filename to use.
 387 #
 388 # It tries several filenames:
 389 #   * debian/package.filename.buildarch
 390 #   * debian/package.filename.buildos
 391 #   * debian/package.filename
 392 #   * debian/filename (if the package is the main package)
 393 # If --name was specified then the files
 394 # must have the name after the package name:
 395 #   * debian/package.name.filename.buildarch
 396 #   * debian/package.name.filename.buildos
 397 #   * debian/package.name.filename
 398 #   * debian/name.filename (if the package is the main package)
 399 sub pkgfile {
 400         my $package=shift;
 401         my $filename=shift;
 402
 403         if (defined $dh{NAME}) {
 404                 $filename="$dh{NAME}.$filename";
 405         }
 406
 407         my @try=("debian/$package.$filename.".buildarch(),
 408                  "debian/$package.$filename.".buildos(),
 409                  "debian/$package.$filename");
 410         if ($package eq $dh{MAINPACKAGE}) {
 411                 push @try, "debian/$filename";
 412         }
 413
 414         foreach my $file (@try) {
 415                 if (-f $file &&
 416                     (! $dh{IGNORE} || ! exists $dh{IGNORE}->{$file})) {
 417                         return $file;
 418                 }
 419
 420         }
 421
 422         return "";
 423
 424 }
 425
 426 # Pass it a name of a binary package, it returns the name to prefix to files
 427 # in debian/ for this package.
 428 sub pkgext {
 429         my $package=shift;
 430
 431         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 432                 return "";
 433         }
 434         return "$package.";
 435 }
 436
 437 # Pass it the name of a binary package, it returns the name to install
 438 # files by in eg, etc. Normally this is the same, but --name can override
 439 # it.
 440 sub pkgfilename {
 441         my $package=shift;
 442
 443         if (defined $dh{NAME}) {
 444                 return $dh{NAME};
 445         }
 446         return $package;
 447 }
 448
 449 # Returns 1 if the package is a native debian package, null otherwise.
 450 # As a side effect, sets $dh{VERSION} to the version of this package.
 451 {
 452         # Caches return code so it only needs to run dpkg-parsechangelog once.
 453         my %isnative_cache;
 454
 455         sub isnative {
 456                 my $package=shift;
 457
 458                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 459
 460                 # Make sure we look at the correct changelog.
 461                 my $isnative_changelog=pkgfile($package,"changelog");
 462                 if (! $isnative_changelog) {
 463                         $isnative_changelog="debian/changelog";
 464                 }
 465                 # Get the package version.
 466                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 467                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 468                 # Did the changelog parse fail?
 469                 if (! defined $dh{VERSION}) {
 470                         error("changelog parse failure");
 471                 }
 472
 473                 # Is this a native Debian package?
 474                 if ($dh{VERSION}=~m/.*-/) {
 475                         return $isnative_cache{$package}=0;
 476                 }
 477                 else {
 478                         return $isnative_cache{$package}=1;
 479                 }
 480         }
 481 }
 482
 483 # Automatically add a shell script snippet to a debian script.
 484 # Only works if the script has #DEBHELPER# in it.
 485 #
 486 # Parameters:
 487 # 1: package
 488 # 2: script to add to
 489 # 3: filename of snippet
 490 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 491 sub autoscript {
 492         my $package=shift;
 493         my $script=shift;
 494         my $filename=shift;
 495         my $sed=shift || "";
 496
 497         # This is the file we will modify.
 498         my $outfile="debian/".pkgext($package)."$script.debhelper";
 499
 500         # Figure out what shell script snippet to use.
 501         my $infile;
 502         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 503             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 504                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 505         }
 506         else {
 507                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 508                         $infile="/usr/share/debhelper/autoscripts/$filename";
 509                 }
 510                 else {
 511                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 512                 }
 513         }
 514
 515         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 516            && !compat(5)) {
 517                 # Add fragments to top so they run in reverse order when removing.
 518                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 519                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 520                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 521                 complex_doit("cat $outfile >> $outfile.new");
 522                 complex_doit("mv $outfile.new $outfile");
 523         }
 524         else {
 525                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 526                 complex_doit("sed \"$sed\" $infile >> $outfile");
 527                 complex_doit("echo '# End automatically added section' >> $outfile");
 528         }
 529 }
 530
 531 # Removes a whole substvar line.
 532 sub delsubstvar {
 533         my $package=shift;
 534         my $substvar=shift;
 535
 536         my $ext=pkgext($package);
 537         my $substvarfile="debian/${ext}substvars";
 538
 539         if (-e $substvarfile) {
 540                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 541                 doit("mv", "$substvarfile.new","$substvarfile");
 542         }
 543 }
 544
 545 # Adds a dependency on some package to the specified
 546 # substvar in a package's substvar's file.
 547 sub addsubstvar {
 548         my $package=shift;
 549         my $substvar=shift;
 550         my $deppackage=shift;
 551         my $verinfo=shift;
 552         my $remove=shift;
 553
 554         my $ext=pkgext($package);
 555         my $substvarfile="debian/${ext}substvars";
 556         my $str=$deppackage;
 557         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 558
 559         # Figure out what the line will look like, based on what's there
 560         # now, and what we're to add or remove.
 561         my $line="";
 562         if (-e $substvarfile) {
 563                 my %items;
 564                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 565                 while (<SUBSTVARS_IN>) {
 566                         chomp;
 567                         if (/^\Q$substvar\E=(.*)/) {
 568                                 %items = map { $_ => 1} split(", ", $1);
 569
 570                                 last;
 571                         }
 572                 }
 573                 close SUBSTVARS_IN;
 574                 if (! $remove) {
 575                         $items{$str}=1;
 576                 }
 577                 else {
 578                         delete $items{$str};
 579                 }
 580                 $line=join(", ", sort keys %items);
 581         }
 582         elsif (! $remove) {
 583                 $line=$str;
 584         }
 585
 586         if (length $line) {
 587                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 588                  doit("mv", "$substvarfile.new", $substvarfile);
 589         }
 590         else {
 591                 delsubstvar($package,$substvar);
 592         }
 593 }
 594
 595 # Reads in the specified file, one line at a time. splits on words,
 596 # and returns an array of arrays of the contents.
 597 # If a value is passed in as the second parameter, then glob
 598 # expansion is done in the directory specified by the parameter ("." is
 599 # frequently a good choice).
 600 sub filedoublearray {
 601         my $file=shift;
 602         my $globdir=shift;
 603
 604         my @ret;
 605         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 606         while (<DH_FARRAY_IN>) {
 607                 chomp;
 608                 # Only ignore comments and empty lines in v5 mode.
 609                 if (! compat(4)) {
 610                         next if /^#/ || /^$/;
 611                 }
 612                 my @line;
 613                 # Only do glob expansion in v3 mode.
 614                 #
 615                 # The tricky bit is that the glob expansion is done
 616                 # as if we were in the specified directory, so the
 617                 # filenames that come out are relative to it.
 618                 if (defined $globdir && ! compat(2)) {
 619                         for (map { glob "$globdir/$_" } split) {
 620                                 s#^$globdir/##;
 621                                 push @line, $_;
 622                         }
 623                 }
 624                 else {
 625                         @line = split;
 626                 }
 627                 push @ret, [@line];
 628         }
 629         close DH_FARRAY_IN;
 630
 631         return @ret;
 632 }
 633
 634 # Reads in the specified file, one word at a time, and returns an array of
 635 # the result. Can do globbing as does filedoublearray.
 636 sub filearray {
 637         return map { @$_ } filedoublearray(@_);
 638 }
 639
 640 # Passed a filename, returns true if -X says that file should be excluded.
 641 sub excludefile {
 642         my $filename = shift;
 643         foreach my $f (@{$dh{EXCLUDE}}) {
 644                 return 1 if $filename =~ /\Q$f\E/;
 645         }
 646         return 0;
 647 }
 648
 649 sub dpkg_architecture_value {
 650         my $var = shift;
 651         my $value=`dpkg-architecture -q$var` || error("dpkg-architecture failed");
 652         chomp $value;
 653         return $value;
 654 }
 655
 656 # Returns the build architecture. (Memoized)
 657 {
 658         my $arch;
 659
 660         sub buildarch {
 661                 if (!defined $arch) {
 662                     $arch=dpkg_architecture_value('DEB_HOST_ARCH');
 663                 }
 664                 return $arch;
 665         }
 666 }
 667
 668 # Returns the build OS. (Memoized)
 669 {
 670         my $os;
 671
 672         sub buildos {
 673                 if (!defined $os) {
 674                         $os=dpkg_architecture_value("DEB_HOST_ARCH_OS");
 675                 }
 676                 return $os;
 677         }
 678 }
 679
 680 # Passed an arch and a list of arches to match against, returns true if matched
 681 sub samearch {
 682         my $arch=shift;
 683         my @archlist=split(/\s+/,shift);
 684
 685         foreach my $a (@archlist) {
 686                 system("dpkg-architecture", "-a$arch", "-i$a") == 0 && return 1;
 687         }
 688
 689         return 0;
 690 }
 691
 692 # Returns source package name
 693 sub sourcepackage {
 694         open (CONTROL, 'debian/control') ||
 695             error("cannot read debian/control: $!\n");
 696         while (<CONTROL>) {
 697                 chomp;
 698                 s/\s+$//;
 699                 if (/^Source:\s*(.*)/) {
 700                         close CONTROL;
 701                         return $1;
 702                 }
 703         }
 704
 705         close CONTROL;
 706         error("could not find Source: line in control file.");
 707 }
 708
 709 # Returns a list of packages in the control file.
 710 # Pass "arch" or "indep" to specify arch-dependant or
 711 # independant. If nothing is specified, returns all packages.
 712 # As a side effect, populates %package_arches and %package_types with the
 713 # types of all packages (not only those returned).
 714 my (%package_types, %package_arches);
 715 sub getpackages {
 716         my $type=shift;
 717
 718         %package_types=();
 719         %package_arches=();
 720
 721         $type="" if ! defined $type;
 722
 723         my $package="";
 724         my $arch="";
 725         my $package_type;
 726         my @list=();
 727         my %seen;
 728         open (CONTROL, 'debian/control') ||
 729                 error("cannot read debian/control: $!\n");
 730         while (<CONTROL>) {
 731                 chomp;
 732                 s/\s+$//;
 733                 if (/^Package:\s*(.*)/) {
 734                         $package=$1;
 735                         # Detect duplicate package names in the same control file.
 736                         if (! $seen{$package}) {
 737                                 $seen{$package}=1;
 738                         }
 739                         else {
 740                                 error("debian/control has a duplicate entry for $package");
 741                         }
 742                         $package_type="deb";
 743                 }
 744                 if (/^Architecture:\s*(.*)/) {
 745                         $arch=$1;
 746                 }
 747                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 748                         $package_type=$1;
 749                 }
 750
 751                 if (!$_ or eof) { # end of stanza.
 752                         if ($package) {
 753                                 $package_types{$package}=$package_type;
 754                                 $package_arches{$package}=$arch;
 755                         }
 756
 757                         if ($package &&
 758                             (($type eq 'indep' && $arch eq 'all') ||
 759                              ($type eq 'arch' && ($arch eq 'any' ||
 760                                              ($arch ne 'all' &&
 761                                               samearch(buildarch(), $arch)))) ||
 762                              ! $type)) {
 763                                 push @list, $package;
 764                                 $package="";
 765                                 $arch="";
 766                         }
 767                 }
 768         }
 769         close CONTROL;
 770
 771         return @list;
 772 }
 773
 774 # Returns the arch a package will build for.
 775 sub package_arch {
 776         my $package=shift;
 777
 778         if (! exists $package_arches{$package}) {
 779                 warning "package $package is not in control info";
 780                 return buildarch();
 781         }
 782         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 783 }
 784
 785 # Return true if a given package is really a udeb.
 786 sub is_udeb {
 787         my $package=shift;
 788
 789         if (! exists $package_types{$package}) {
 790                 warning "package $package is not in control info";
 791                 return 0;
 792         }
 793         return $package_types{$package} eq 'udeb';
 794 }
 795
 796 # Generates the filename that is used for a udeb package.
 797 sub udeb_filename {
 798         my $package=shift;
 799
 800         my $filearch=package_arch($package);
 801         isnative($package); # side effect
 802         my $version=$dh{VERSION};
 803         $version=~s/^[0-9]+://; # strip any epoch
 804         return "${package}_${version}_$filearch.udeb";
 805 }
 806
 807 # Handles #DEBHELPER# substitution in a script; also can generate a new
 808 # script from scratch if none exists but there is a .debhelper file for it.
 809 sub debhelper_script_subst {
 810         my $package=shift;
 811         my $script=shift;
 812
 813         my $tmp=tmpdir($package);
 814         my $ext=pkgext($package);
 815         my $file=pkgfile($package,$script);
 816
 817         if ($file ne '') {
 818                 if (-f "debian/$ext$script.debhelper") {
 819                         # Add this into the script, where it has #DEBHELPER#
 820                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 821                 }
 822                 else {
 823                         # Just get rid of any #DEBHELPER# in the script.
 824                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 825                 }
 826                 doit("chown","0:0","$tmp/DEBIAN/$script");
 827                 doit("chmod",755,"$tmp/DEBIAN/$script");
 828         }
 829         elsif ( -f "debian/$ext$script.debhelper" ) {
 830                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 831                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 832                 doit("chown","0:0","$tmp/DEBIAN/$script");
 833                 doit("chmod",755,"$tmp/DEBIAN/$script");
 834         }
 835 }
 836
 837 1