Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2008.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell
  18             &inhibit_log &load_log &write_log);
  19
  20 my $max_compat=7;
  21
  22 sub init {
  23         my %params=@_;
  24
  25         # Check to see if an option line starts with a dash,
  26         # or DH_OPTIONS is set.
  27         # If so, we need to pass this off to the resource intensive
  28         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  29         if ((defined $ENV{DH_OPTIONS} && length $ENV{DH_OPTIONS}) ||
  30             (defined $ENV{DH_INTERNAL_OPTIONS} && length $ENV{DH_INTERNAL_OPTIONS}) ||
  31             grep /^-/, @ARGV) {
  32                 eval "use Debian::Debhelper::Dh_Getopt";
  33                 error($@) if $@;
  34                 Debian::Debhelper::Dh_Getopt::parseopts($params{options});
  35         }
  36
  37         # Another way to set excludes.
  38         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  39                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  40         }
  41
  42         # Generate EXCLUDE_FIND.
  43         if ($dh{EXCLUDE}) {
  44                 $dh{EXCLUDE_FIND}='';
  45                 foreach (@{$dh{EXCLUDE}}) {
  46                         my $x=$_;
  47                         $x=escape_shell($x);
  48                         $x=~s/\./\\\\./g;
  49                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  50                 }
  51                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  52         }
  53
  54         # Check to see if DH_VERBOSE environment variable was set, if so,
  55         # make sure verbose is on.
  56         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  57                 $dh{VERBOSE}=1;
  58         }
  59
  60         # Check to see if DH_NO_ACT environment variable was set, if so,
  61         # make sure no act mode is on.
  62         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  63                 $dh{NO_ACT}=1;
  64         }
  65
  66         my @allpackages=getpackages();
  67         # Get the name of the main binary package (first one listed in
  68         # debian/control). Only if the main package was not set on the
  69         # command line.
  70         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  71                 $dh{MAINPACKAGE}=$allpackages[0];
  72         }
  73
  74         # Check if packages to build have been specified, if not, fall back to
  75         # the default, doing them all.
  76         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  77                 push @{$dh{DOPACKAGES}},@allpackages;
  78         }
  79
  80         # Check to see if -P was specified. If so, we can only act on a single
  81         # package.
  82         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  83                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  84         }
  85
  86         # Figure out which package is the first one we were instructed to build.
  87         # This package gets special treatement: files and directories specified on
  88         # the command line may affect it.
  89         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
  90
  91         # If no error handling function was specified, just propigate
  92         # errors out.
  93         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
  94                 $dh{ERROR_HANDLER}='exit \$?';
  95         }
  96 }
  97
  98 # Run at exit. Add the command to the log files for the packages it acted
  99 # on, if it's exiting successfully.
 100 my $write_log=1;
 101 sub END {
 102         if ($? == 0 && $write_log) {
 103                 write_log(basename($0), @{$dh{DOPACKAGES}});
 104         }
 105 }
 106
 107 sub load_log {
 108         my ($package, $db)=@_;
 109         my $ext=pkgext($package);
 110
 111         my @log;
 112         open(LOG, "<", "debian/${ext}debhelper.log") || return;
 113         while (<LOG>) {
 114                 chomp;
 115                 push @log, $_;
 116                 $db->{$package}{$_}=1 if defined $db;
 117         }
 118         close LOG;
 119         return @log;
 120 }
 121
 122 sub write_log {
 123         my $cmd=shift;
 124         my @packages=@_;
 125
 126         foreach my $package (@packages) {
 127                 my $ext=pkgext($package);
 128                 my $log="debian/${ext}debhelper.log";
 129                 open(LOG, ">>", $log) || error("failed to write to ${log}: $!");
 130                 print LOG $cmd."\n";
 131                 close LOG;
 132         }
 133 }
 134
 135 sub inhibit_log {
 136         $write_log=0;
 137 }
 138
 139 # Pass it an array containing the arguments of a shell command like would
 140 # be run by exec(). It turns that into a line like you might enter at the
 141 # shell, escaping metacharacters and quoting arguments that contain spaces.
 142 sub escape_shell {
 143         my @args=@_;
 144         my $line="";
 145         my @ret;
 146         foreach my $word (@args) {
 147                 if ($word=~/\s/) {
 148                         # Escape only a few things since it will be quoted.
 149                         # Note we use double quotes because you cannot
 150                         # escape ' in single quotes, while " can be escaped
 151                         # in double.
 152                         # This does make -V"foo bar" turn into "-Vfoo bar",
 153                         # but that will be parsed identically by the shell
 154                         # anyway..
 155                         $word=~s/([\n`\$"\\])/\\$1/g;
 156                         push @ret, "\"$word\"";
 157                 }
 158                 else {
 159                         # This list is from _Unix in a Nutshell_. (except '#')
 160                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 161                         push @ret,$word;
 162                 }
 163         }
 164         return join(' ', @ret);
 165 }
 166
 167 # Run a command, and display the command to stdout if verbose mode is on.
 168 # All commands that modifiy files in $TMP should be ran via this
 169 # function.
 170 #
 171 # Note that this cannot handle complex commands, especially anything
 172 # involving redirection. Use complex_doit instead.
 173 sub doit {
 174         verbose_print(escape_shell(@_));
 175
 176         if (! $dh{NO_ACT}) {
 177                 system(@_) == 0 || _error_exitcode($_[0]);
 178         }
 179 }
 180
 181 # Run a command and display the command to stdout if verbose mode is on.
 182 # Use doit() if you can, instead of this function, because this function
 183 # forks a shell. However, this function can handle more complicated stuff
 184 # like redirection.
 185 sub complex_doit {
 186         verbose_print(join(" ",@_));
 187
 188         if (! $dh{NO_ACT}) {
 189                 # The join makes system get a scalar so it forks off a shell.
 190                 system(join(" ", @_)) == 0 || _error_exitcode(join(" ", @_))
 191         }
 192 }
 193
 194 sub _error_exitcode {
 195         my $command=shift;
 196         if ($? == -1) {
 197                 error("$command failed to to execute: $!");
 198         }
 199         elsif ($? & 127) {
 200                 error("$command died with signal ".($? & 127));
 201         }
 202         else {
 203                 error("$command returned exit code ".($? >> 8));
 204         }
 205 }
 206
 207 # Run a command that may have a huge number of arguments, like xargs does.
 208 # Pass in a reference to an array containing the arguments, and then other
 209 # parameters that are the command and any parameters that should be passed to
 210 # it each time.
 211 sub xargs {
 212         my $args=shift;
 213
 214         # The kernel can accept command lines up to 20k worth of characters.
 215         my $command_max=20000; # LINUX SPECIFIC!!
 216                         # I could use POSIX::ARG_MAX, but that would be slow.
 217
 218         # Figure out length of static portion of command.
 219         my $static_length=0;
 220         foreach (@_) {
 221                 $static_length+=length($_)+1;
 222         }
 223
 224         my @collect=();
 225         my $length=$static_length;
 226         foreach (@$args) {
 227                 if (length($_) + 1 + $static_length > $command_max) {
 228                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 229                 }
 230                 $length+=length($_) + 1;
 231                 if ($length < $command_max) {
 232                         push @collect, $_;
 233                 }
 234                 else {
 235                         doit(@_,@collect) if $#collect > -1;
 236                         @collect=($_);
 237                         $length=$static_length + length($_) + 1;
 238                 }
 239         }
 240         doit(@_,@collect) if $#collect > -1;
 241 }
 242
 243 # Print something if the verbose flag is on.
 244 sub verbose_print {
 245         my $message=shift;
 246
 247         if ($dh{VERBOSE}) {
 248                 print "\t$message\n";
 249         }
 250 }
 251
 252 # Output an error message and exit.
 253 sub error {
 254         my $message=shift;
 255
 256         warning($message);
 257         exit 1;
 258 }
 259
 260 # Output a warning.
 261 sub warning {
 262         my $message=shift;
 263
 264         print STDERR basename($0).": $message\n";
 265 }
 266
 267 # Returns the basename of the argument passed to it.
 268 sub basename {
 269         my $fn=shift;
 270
 271         $fn=~s/\/$//g; # ignore trailing slashes
 272         $fn=~s:^.*/(.*?)$:$1:;
 273         return $fn;
 274 }
 275
 276 # Returns the directory name of the argument passed to it.
 277 sub dirname {
 278         my $fn=shift;
 279
 280         $fn=~s/\/$//g; # ignore trailing slashes
 281         $fn=~s:^(.*)/.*?$:$1:;
 282         return $fn;
 283 }
 284
 285 # Pass in a number, will return true iff the current compatibility level
 286 # is less than or equal to that number.
 287 {
 288         my $warned_compat=0;
 289         my $c;
 290
 291         sub compat {
 292                 my $num=shift;
 293
 294                 if (! defined $c) {
 295                         $c=1;
 296                         if (defined $ENV{DH_COMPAT}) {
 297                                 $c=$ENV{DH_COMPAT};
 298                         }
 299                         elsif (-e 'debian/compat') {
 300                                 # Try the file..
 301                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 302                                 my $l=<COMPAT_IN>;
 303                                 close COMPAT_IN;
 304                                 if (! defined $l || ! length $l) {
 305                                         warning("debian/compat is empty, assuming level $c");
 306                                 }
 307                                 else {
 308                                         chomp $l;
 309                                         $c=$l;
 310                                 }
 311                         }
 312                 }
 313
 314                 if ($c < 4 && ! $warned_compat) {
 315                         warning("Compatibility levels before 5 are deprecated.");
 316                         $warned_compat=1;
 317                 }
 318
 319                 if ($c > $max_compat) {
 320                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 321                 }
 322
 323                 return ($c <= $num);
 324         }
 325 }
 326
 327 # Pass it a name of a binary package, it returns the name of the tmp dir to
 328 # use, for that package.
 329 sub tmpdir {
 330         my $package=shift;
 331
 332         if ($dh{TMPDIR}) {
 333                 return $dh{TMPDIR};
 334         }
 335         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 336                 # This is for back-compatibility with the debian/tmp tradition.
 337                 return "debian/tmp";
 338         }
 339         else {
 340                 return "debian/$package";
 341         }
 342 }
 343
 344 # Pass this the name of a binary package, and the name of the file wanted
 345 # for the package, and it will return the actual existing filename to use.
 346 #
 347 # It tries several filenames:
 348 #   * debian/package.filename.buildarch
 349 #   * debian/package.filename.buildos
 350 #   * debian/package.filename
 351 #   * debian/filename (if the package is the main package)
 352 # If --name was specified then the files
 353 # must have the name after the package name:
 354 #   * debian/package.name.filename.buildarch
 355 #   * debian/package.name.filename.buildos
 356 #   * debian/package.name.filename
 357 #   * debian/name.filename (if the package is the main package)
 358 sub pkgfile {
 359         my $package=shift;
 360         my $filename=shift;
 361
 362         if (defined $dh{NAME}) {
 363                 $filename="$dh{NAME}.$filename";
 364         }
 365
 366         my @try=("debian/$package.$filename.".buildarch(),
 367                  "debian/$package.$filename.".buildos(),
 368                  "debian/$package.$filename");
 369         if ($package eq $dh{MAINPACKAGE}) {
 370                 push @try, "debian/$filename";
 371         }
 372
 373         foreach my $file (@try) {
 374                 if (-f $file &&
 375                     (! $dh{IGNORE} || ! exists $dh{IGNORE}->{$file})) {
 376                         return $file;
 377                 }
 378
 379         }
 380
 381         return "";
 382
 383 }
 384
 385 # Pass it a name of a binary package, it returns the name to prefix to files
 386 # in debian/ for this package.
 387 sub pkgext {
 388         my $package=shift;
 389
 390         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 391                 return "";
 392         }
 393         return "$package.";
 394 }
 395
 396 # Pass it the name of a binary package, it returns the name to install
 397 # files by in eg, etc. Normally this is the same, but --name can override
 398 # it.
 399 sub pkgfilename {
 400         my $package=shift;
 401
 402         if (defined $dh{NAME}) {
 403                 return $dh{NAME};
 404         }
 405         return $package;
 406 }
 407
 408 # Returns 1 if the package is a native debian package, null otherwise.
 409 # As a side effect, sets $dh{VERSION} to the version of this package.
 410 {
 411         # Caches return code so it only needs to run dpkg-parsechangelog once.
 412         my %isnative_cache;
 413
 414         sub isnative {
 415                 my $package=shift;
 416
 417                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 418
 419                 # Make sure we look at the correct changelog.
 420                 my $isnative_changelog=pkgfile($package,"changelog");
 421                 if (! $isnative_changelog) {
 422                         $isnative_changelog="debian/changelog";
 423                 }
 424                 # Get the package version.
 425                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 426                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 427                 # Did the changelog parse fail?
 428                 if (! defined $dh{VERSION}) {
 429                         error("changelog parse failure");
 430                 }
 431
 432                 # Is this a native Debian package?
 433                 if ($dh{VERSION}=~m/.*-/) {
 434                         return $isnative_cache{$package}=0;
 435                 }
 436                 else {
 437                         return $isnative_cache{$package}=1;
 438                 }
 439         }
 440 }
 441
 442 # Automatically add a shell script snippet to a debian script.
 443 # Only works if the script has #DEBHELPER# in it.
 444 #
 445 # Parameters:
 446 # 1: package
 447 # 2: script to add to
 448 # 3: filename of snippet
 449 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 450 sub autoscript {
 451         my $package=shift;
 452         my $script=shift;
 453         my $filename=shift;
 454         my $sed=shift || "";
 455
 456         # This is the file we will modify.
 457         my $outfile="debian/".pkgext($package)."$script.debhelper";
 458
 459         # Figure out what shell script snippet to use.
 460         my $infile;
 461         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 462             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 463                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 464         }
 465         else {
 466                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 467                         $infile="/usr/share/debhelper/autoscripts/$filename";
 468                 }
 469                 else {
 470                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 471                 }
 472         }
 473
 474         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 475            && !compat(5)) {
 476                 # Add fragments to top so they run in reverse order when removing.
 477                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 478                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 479                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 480                 complex_doit("cat $outfile >> $outfile.new");
 481                 complex_doit("mv $outfile.new $outfile");
 482         }
 483         else {
 484                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 485                 complex_doit("sed \"$sed\" $infile >> $outfile");
 486                 complex_doit("echo '# End automatically added section' >> $outfile");
 487         }
 488 }
 489
 490 # Removes a whole substvar line.
 491 sub delsubstvar {
 492         my $package=shift;
 493         my $substvar=shift;
 494
 495         my $ext=pkgext($package);
 496         my $substvarfile="debian/${ext}substvars";
 497
 498         if (-e $substvarfile) {
 499                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 500                 doit("mv", "$substvarfile.new","$substvarfile");
 501         }
 502 }
 503
 504 # Adds a dependency on some package to the specified
 505 # substvar in a package's substvar's file.
 506 sub addsubstvar {
 507         my $package=shift;
 508         my $substvar=shift;
 509         my $deppackage=shift;
 510         my $verinfo=shift;
 511         my $remove=shift;
 512
 513         my $ext=pkgext($package);
 514         my $substvarfile="debian/${ext}substvars";
 515         my $str=$deppackage;
 516         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 517
 518         # Figure out what the line will look like, based on what's there
 519         # now, and what we're to add or remove.
 520         my $line="";
 521         if (-e $substvarfile) {
 522                 my %items;
 523                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 524                 while (<SUBSTVARS_IN>) {
 525                         chomp;
 526                         if (/^\Q$substvar\E=(.*)/) {
 527                                 %items = map { $_ => 1} split(", ", $1);
 528
 529                                 last;
 530                         }
 531                 }
 532                 close SUBSTVARS_IN;
 533                 if (! $remove) {
 534                         $items{$str}=1;
 535                 }
 536                 else {
 537                         delete $items{$str};
 538                 }
 539                 $line=join(", ", sort keys %items);
 540         }
 541         elsif (! $remove) {
 542                 $line=$str;
 543         }
 544
 545         if (length $line) {
 546                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 547                  doit("mv", "$substvarfile.new", $substvarfile);
 548         }
 549         else {
 550                 delsubstvar($package,$substvar);
 551         }
 552 }
 553
 554 # Reads in the specified file, one line at a time. splits on words,
 555 # and returns an array of arrays of the contents.
 556 # If a value is passed in as the second parameter, then glob
 557 # expansion is done in the directory specified by the parameter ("." is
 558 # frequently a good choice).
 559 sub filedoublearray {
 560         my $file=shift;
 561         my $globdir=shift;
 562
 563         my @ret;
 564         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 565         while (<DH_FARRAY_IN>) {
 566                 chomp;
 567                 # Only ignore comments and empty lines in v5 mode.
 568                 if (! compat(4)) {
 569                         next if /^#/ || /^$/;
 570                 }
 571                 my @line;
 572                 # Only do glob expansion in v3 mode.
 573                 #
 574                 # The tricky bit is that the glob expansion is done
 575                 # as if we were in the specified directory, so the
 576                 # filenames that come out are relative to it.
 577                 if (defined $globdir && ! compat(2)) {
 578                         for (map { glob "$globdir/$_" } split) {
 579                                 s#^$globdir/##;
 580                                 push @line, $_;
 581                         }
 582                 }
 583                 else {
 584                         @line = split;
 585                 }
 586                 push @ret, [@line];
 587         }
 588         close DH_FARRAY_IN;
 589
 590         return @ret;
 591 }
 592
 593 # Reads in the specified file, one word at a time, and returns an array of
 594 # the result. Can do globbing as does filedoublearray.
 595 sub filearray {
 596         return map { @$_ } filedoublearray(@_);
 597 }
 598
 599 # Passed a filename, returns true if -X says that file should be excluded.
 600 sub excludefile {
 601         my $filename = shift;
 602         foreach my $f (@{$dh{EXCLUDE}}) {
 603                 return 1 if $filename =~ /\Q$f\E/;
 604         }
 605         return 0;
 606 }
 607
 608 # Returns the build architecture. (Memoized)
 609 {
 610         my $arch;
 611
 612         sub buildarch {
 613                 return $arch if defined $arch;
 614
 615                 $arch=`dpkg-architecture -qDEB_HOST_ARCH 2>/dev/null` || error("dpkg-architecture failed");
 616                 chomp $arch;
 617                 return $arch;
 618         }
 619 }
 620
 621 # Returns the build OS. (Memoized)
 622 {
 623         my $os;
 624
 625         sub buildos {
 626                 return $os if defined $os;
 627
 628                 $os=`dpkg-architecture -qDEB_HOST_ARCH_OS 2>/dev/null` || error("dpkg-architecture failed");
 629                 chomp $os;
 630                 return $os;
 631         }
 632 }
 633
 634 # Passed an arch and a list of arches to match against, returns true if matched
 635 sub samearch {
 636         my $arch=shift;
 637         my @archlist=split(/\s+/,shift);
 638
 639         foreach my $a (@archlist) {
 640                 system("dpkg-architecture", "-a$arch", "-i$a") == 0 && return 1;
 641         }
 642
 643         return 0;
 644 }
 645
 646 # Returns a list of packages in the control file.
 647 # Must pass "arch" or "indep" or "same" to specify arch-dependant or
 648 # -independant or same arch packages. If nothing is specified, returns all
 649 # packages.
 650 # As a side effect, populates %package_arches and %package_types with the
 651 # types of all packages (not only those returned).
 652 my (%package_types, %package_arches);
 653 sub getpackages {
 654         my $type=shift;
 655
 656         %package_types=();
 657         %package_arches=();
 658
 659         $type="" if ! defined $type;
 660
 661         # Look up the build arch if we need to.
 662         my $buildarch='';
 663         if ($type eq 'same') {
 664                 $buildarch=buildarch();
 665         }
 666
 667         my $package="";
 668         my $arch="";
 669         my $package_type;
 670         my @list=();
 671         my %seen;
 672         open (CONTROL, 'debian/control') ||
 673                 error("cannot read debian/control: $!\n");
 674         while (<CONTROL>) {
 675                 chomp;
 676                 s/\s+$//;
 677                 if (/^Package:\s*(.*)/) {
 678                         $package=$1;
 679                         # Detect duplicate package names in the same control file.
 680                         if (! $seen{$package}) {
 681                                 $seen{$package}=1;
 682                         }
 683                         else {
 684                                 error("debian/control has a duplicate entry for $package");
 685                         }
 686                         $package_type="deb";
 687                 }
 688                 if (/^Architecture:\s*(.*)/) {
 689                         $arch=$1;
 690                 }
 691                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 692                         $package_type=$1;
 693                 }
 694
 695                 if (!$_ or eof) { # end of stanza.
 696                         if ($package) {
 697                                 $package_types{$package}=$package_type;
 698                                 $package_arches{$package}=$arch;
 699                         }
 700                         if ($package &&
 701                             (($type eq 'indep' && $arch eq 'all') ||
 702                              ($type eq 'arch' && $arch ne 'all') ||
 703                              ($type eq 'same' && ($arch eq 'any' || samearch($buildarch, $arch))) ||
 704                              ! $type)) {
 705                                 push @list, $package;
 706                                 $package="";
 707                                 $arch="";
 708                         }
 709                 }
 710         }
 711         close CONTROL;
 712
 713         return @list;
 714 }
 715
 716 # Returns the arch a package will build for.
 717 sub package_arch {
 718         my $package=shift;
 719
 720         if (! exists $package_arches{$package}) {
 721                 warning "package $package is not in control info";
 722                 return buildarch();
 723         }
 724         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 725 }
 726
 727 # Return true if a given package is really a udeb.
 728 sub is_udeb {
 729         my $package=shift;
 730
 731         if (! exists $package_types{$package}) {
 732                 warning "package $package is not in control info";
 733                 return 0;
 734         }
 735         return $package_types{$package} eq 'udeb';
 736 }
 737
 738 # Generates the filename that is used for a udeb package.
 739 sub udeb_filename {
 740         my $package=shift;
 741
 742         my $filearch=package_arch($package);
 743         isnative($package); # side effect
 744         my $version=$dh{VERSION};
 745         $version=~s/^[0-9]+://; # strip any epoch
 746         return "${package}_${version}_$filearch.udeb";
 747 }
 748
 749 # Handles #DEBHELPER# substitution in a script; also can generate a new
 750 # script from scratch if none exists but there is a .debhelper file for it.
 751 sub debhelper_script_subst {
 752         my $package=shift;
 753         my $script=shift;
 754
 755         my $tmp=tmpdir($package);
 756         my $ext=pkgext($package);
 757         my $file=pkgfile($package,$script);
 758
 759         if ($file ne '') {
 760                 if (-f "debian/$ext$script.debhelper") {
 761                         # Add this into the script, where it has #DEBHELPER#
 762                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 763                 }
 764                 else {
 765                         # Just get rid of any #DEBHELPER# in the script.
 766                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 767                 }
 768                 doit("chown","0:0","$tmp/DEBIAN/$script");
 769                 doit("chmod",755,"$tmp/DEBIAN/$script");
 770         }
 771         elsif ( -f "debian/$ext$script.debhelper" ) {
 772                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 773                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 774                 doit("chown","0:0","$tmp/DEBIAN/$script");
 775                 doit("chmod",755,"$tmp/DEBIAN/$script");
 776         }
 777 }
 778
 779 1