Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2008.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell
  18             &inhibit_log &load_log &write_log &dpkg_architecture_value
  19             &sourcepackage
  20             &is_make_jobserver_unavailable &clean_jobserver_makeflags);
  21
  22 my $max_compat=7;
  23
  24 sub init {
  25         my %params=@_;
  26
  27         # Check to see if an option line starts with a dash,
  28         # or DH_OPTIONS is set.
  29         # If so, we need to pass this off to the resource intensive
  30         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  31         if ((defined $ENV{DH_OPTIONS} && length $ENV{DH_OPTIONS}) ||
  32             (defined $ENV{DH_INTERNAL_OPTIONS} && length $ENV{DH_INTERNAL_OPTIONS}) ||
  33             grep /^-/, @ARGV) {
  34                 eval "use Debian::Debhelper::Dh_Getopt";
  35                 error($@) if $@;
  36                 Debian::Debhelper::Dh_Getopt::parseopts(%params);
  37         }
  38
  39         # Another way to set excludes.
  40         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  41                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  42         }
  43
  44         # Generate EXCLUDE_FIND.
  45         if ($dh{EXCLUDE}) {
  46                 $dh{EXCLUDE_FIND}='';
  47                 foreach (@{$dh{EXCLUDE}}) {
  48                         my $x=$_;
  49                         $x=escape_shell($x);
  50                         $x=~s/\./\\\\./g;
  51                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  52                 }
  53                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  54         }
  55
  56         # Check to see if DH_VERBOSE environment variable was set, if so,
  57         # make sure verbose is on.
  58         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  59                 $dh{VERBOSE}=1;
  60         }
  61
  62         # Check to see if DH_NO_ACT environment variable was set, if so,
  63         # make sure no act mode is on.
  64         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  65                 $dh{NO_ACT}=1;
  66         }
  67
  68         # Get the name of the main binary package (first one listed in
  69         # debian/control). Only if the main package was not set on the
  70         # command line.
  71         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  72                 my @allpackages=getpackages();
  73                 $dh{MAINPACKAGE}=$allpackages[0];
  74         }
  75
  76         # Check if packages to build have been specified, if not, fall back to
  77         # the default, building all relevant packages.
  78         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  79                 push @{$dh{DOPACKAGES}}, getpackages('both');
  80         }
  81
  82         # Check to see if -P was specified. If so, we can only act on a single
  83         # package.
  84         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  85                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  86         }
  87
  88         # Figure out which package is the first one we were instructed to build.
  89         # This package gets special treatement: files and directories specified on
  90         # the command line may affect it.
  91         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
  92
  93         # If no error handling function was specified, just propigate
  94         # errors out.
  95         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
  96                 $dh{ERROR_HANDLER}='exit \$?';
  97         }
  98 }
  99
 100 # Run at exit. Add the command to the log files for the packages it acted
 101 # on, if it's exiting successfully.
 102 my $write_log=1;
 103 sub END {
 104         if ($? == 0 && $write_log) {
 105                 write_log(basename($0), @{$dh{DOPACKAGES}});
 106         }
 107 }
 108
 109 sub load_log {
 110         my ($package, $db)=@_;
 111         my $ext=pkgext($package);
 112
 113         my @log;
 114         open(LOG, "<", "debian/${ext}debhelper.log") || return;
 115         while (<LOG>) {
 116                 chomp;
 117                 push @log, $_;
 118                 $db->{$package}{$_}=1 if defined $db;
 119         }
 120         close LOG;
 121         return @log;
 122 }
 123
 124 sub write_log {
 125         my $cmd=shift;
 126         my @packages=@_;
 127
 128         foreach my $package (@packages) {
 129                 my $ext=pkgext($package);
 130                 my $log="debian/${ext}debhelper.log";
 131                 open(LOG, ">>", $log) || error("failed to write to ${log}: $!");
 132                 print LOG $cmd."\n";
 133                 close LOG;
 134         }
 135 }
 136
 137 sub inhibit_log {
 138         $write_log=0;
 139 }
 140
 141 # Pass it an array containing the arguments of a shell command like would
 142 # be run by exec(). It turns that into a line like you might enter at the
 143 # shell, escaping metacharacters and quoting arguments that contain spaces.
 144 sub escape_shell {
 145         my @args=@_;
 146         my $line="";
 147         my @ret;
 148         foreach my $word (@args) {
 149                 if ($word=~/\s/) {
 150                         # Escape only a few things since it will be quoted.
 151                         # Note we use double quotes because you cannot
 152                         # escape ' in single quotes, while " can be escaped
 153                         # in double.
 154                         # This does make -V"foo bar" turn into "-Vfoo bar",
 155                         # but that will be parsed identically by the shell
 156                         # anyway..
 157                         $word=~s/([\n`\$"\\])/\\$1/g;
 158                         push @ret, "\"$word\"";
 159                 }
 160                 else {
 161                         # This list is from _Unix in a Nutshell_. (except '#')
 162                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 163                         push @ret,$word;
 164                 }
 165         }
 166         return join(' ', @ret);
 167 }
 168
 169 # Run a command, and display the command to stdout if verbose mode is on.
 170 # All commands that modifiy files in $TMP should be ran via this
 171 # function.
 172 #
 173 # Note that this cannot handle complex commands, especially anything
 174 # involving redirection. Use complex_doit instead.
 175 sub doit {
 176         verbose_print(escape_shell(@_));
 177
 178         if (! $dh{NO_ACT}) {
 179                 system(@_) == 0 || _error_exitcode(join(" ", @_));
 180         }
 181 }
 182
 183 # Run a command and display the command to stdout if verbose mode is on.
 184 # Use doit() if you can, instead of this function, because this function
 185 # forks a shell. However, this function can handle more complicated stuff
 186 # like redirection.
 187 sub complex_doit {
 188         verbose_print(join(" ",@_));
 189
 190         if (! $dh{NO_ACT}) {
 191                 # The join makes system get a scalar so it forks off a shell.
 192                 system(join(" ", @_)) == 0 || _error_exitcode(join(" ", @_))
 193         }
 194 }
 195
 196 sub _error_exitcode {
 197         my $command=shift;
 198         if ($? == -1) {
 199                 error("$command failed to to execute: $!");
 200         }
 201         elsif ($? & 127) {
 202                 error("$command died with signal ".($? & 127));
 203         }
 204         else {
 205                 error("$command returned exit code ".($? >> 8));
 206         }
 207 }
 208
 209 # Run a command that may have a huge number of arguments, like xargs does.
 210 # Pass in a reference to an array containing the arguments, and then other
 211 # parameters that are the command and any parameters that should be passed to
 212 # it each time.
 213 sub xargs {
 214         my $args=shift;
 215
 216         # The kernel can accept command lines up to 20k worth of characters.
 217         my $command_max=20000; # LINUX SPECIFIC!!
 218                         # I could use POSIX::ARG_MAX, but that would be slow.
 219
 220         # Figure out length of static portion of command.
 221         my $static_length=0;
 222         foreach (@_) {
 223                 $static_length+=length($_)+1;
 224         }
 225
 226         my @collect=();
 227         my $length=$static_length;
 228         foreach (@$args) {
 229                 if (length($_) + 1 + $static_length > $command_max) {
 230                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 231                 }
 232                 $length+=length($_) + 1;
 233                 if ($length < $command_max) {
 234                         push @collect, $_;
 235                 }
 236                 else {
 237                         doit(@_,@collect) if $#collect > -1;
 238                         @collect=($_);
 239                         $length=$static_length + length($_) + 1;
 240                 }
 241         }
 242         doit(@_,@collect) if $#collect > -1;
 243 }
 244
 245 # Print something if the verbose flag is on.
 246 sub verbose_print {
 247         my $message=shift;
 248
 249         if ($dh{VERBOSE}) {
 250                 print "\t$message\n";
 251         }
 252 }
 253
 254 # Output an error message and die (can be caught).
 255 sub error {
 256         my $message=shift;
 257
 258         die basename($0).": $message\n";
 259 }
 260
 261 # Output a warning.
 262 sub warning {
 263         my $message=shift;
 264
 265         print STDERR basename($0).": $message\n";
 266 }
 267
 268 # Returns the basename of the argument passed to it.
 269 sub basename {
 270         my $fn=shift;
 271
 272         $fn=~s/\/$//g; # ignore trailing slashes
 273         $fn=~s:^.*/(.*?)$:$1:;
 274         return $fn;
 275 }
 276
 277 # Returns the directory name of the argument passed to it.
 278 sub dirname {
 279         my $fn=shift;
 280
 281         $fn=~s/\/$//g; # ignore trailing slashes
 282         $fn=~s:^(.*)/.*?$:$1:;
 283         return $fn;
 284 }
 285
 286 # Pass in a number, will return true iff the current compatibility level
 287 # is less than or equal to that number.
 288 {
 289         my $warned_compat=0;
 290         my $c;
 291
 292         sub compat {
 293                 my $num=shift;
 294
 295                 if (! defined $c) {
 296                         $c=1;
 297                         if (defined $ENV{DH_COMPAT}) {
 298                                 $c=$ENV{DH_COMPAT};
 299                         }
 300                         elsif (-e 'debian/compat') {
 301                                 # Try the file..
 302                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 303                                 my $l=<COMPAT_IN>;
 304                                 close COMPAT_IN;
 305                                 if (! defined $l || ! length $l) {
 306                                         warning("debian/compat is empty, assuming level $c");
 307                                 }
 308                                 else {
 309                                         chomp $l;
 310                                         $c=$l;
 311                                 }
 312                         }
 313                 }
 314
 315                 if ($c <= 4 && ! $warned_compat) {
 316                         warning("Compatibility levels before 5 are deprecated.");
 317                         $warned_compat=1;
 318                 }
 319
 320                 if ($c > $max_compat) {
 321                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 322                 }
 323
 324                 return ($c <= $num);
 325         }
 326 }
 327
 328 # Pass it a name of a binary package, it returns the name of the tmp dir to
 329 # use, for that package.
 330 sub tmpdir {
 331         my $package=shift;
 332
 333         if ($dh{TMPDIR}) {
 334                 return $dh{TMPDIR};
 335         }
 336         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 337                 # This is for back-compatibility with the debian/tmp tradition.
 338                 return "debian/tmp";
 339         }
 340         else {
 341                 return "debian/$package";
 342         }
 343 }
 344
 345 # Pass this the name of a binary package, and the name of the file wanted
 346 # for the package, and it will return the actual existing filename to use.
 347 #
 348 # It tries several filenames:
 349 #   * debian/package.filename.buildarch
 350 #   * debian/package.filename.buildos
 351 #   * debian/package.filename
 352 #   * debian/filename (if the package is the main package)
 353 # If --name was specified then the files
 354 # must have the name after the package name:
 355 #   * debian/package.name.filename.buildarch
 356 #   * debian/package.name.filename.buildos
 357 #   * debian/package.name.filename
 358 #   * debian/name.filename (if the package is the main package)
 359 sub pkgfile {
 360         my $package=shift;
 361         my $filename=shift;
 362
 363         if (defined $dh{NAME}) {
 364                 $filename="$dh{NAME}.$filename";
 365         }
 366
 367         # First, check for files ending in buildarch and buildos.
 368         my $match;
 369         foreach my $file (glob("debian/$package.$filename.*")) {
 370                 next if ! -f $file;
 371                 next if $dh{IGNORE} && exists $dh{IGNORE}->{$file};
 372                 if ($file eq "debian/$package.$filename.".buildarch()) {
 373                         $match=$file;
 374                         # buildarch files are used in preference to buildos files.
 375                         last;
 376                 }
 377                 elsif ($file eq "debian/$package.$filename.".buildos()) {
 378                         $match=$file;
 379                 }
 380         }
 381         return $match if defined $match;
 382
 383         my @try=("debian/$package.$filename");
 384         if ($package eq $dh{MAINPACKAGE}) {
 385                 push @try, "debian/$filename";
 386         }
 387
 388         foreach my $file (@try) {
 389                 if (-f $file &&
 390                     (! $dh{IGNORE} || ! exists $dh{IGNORE}->{$file})) {
 391                         return $file;
 392                 }
 393
 394         }
 395
 396         return "";
 397
 398 }
 399
 400 # Pass it a name of a binary package, it returns the name to prefix to files
 401 # in debian/ for this package.
 402 sub pkgext {
 403         my $package=shift;
 404
 405         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 406                 return "";
 407         }
 408         return "$package.";
 409 }
 410
 411 # Pass it the name of a binary package, it returns the name to install
 412 # files by in eg, etc. Normally this is the same, but --name can override
 413 # it.
 414 sub pkgfilename {
 415         my $package=shift;
 416
 417         if (defined $dh{NAME}) {
 418                 return $dh{NAME};
 419         }
 420         return $package;
 421 }
 422
 423 # Returns 1 if the package is a native debian package, null otherwise.
 424 # As a side effect, sets $dh{VERSION} to the version of this package.
 425 {
 426         # Caches return code so it only needs to run dpkg-parsechangelog once.
 427         my %isnative_cache;
 428
 429         sub isnative {
 430                 my $package=shift;
 431
 432                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 433
 434                 # Make sure we look at the correct changelog.
 435                 my $isnative_changelog=pkgfile($package,"changelog");
 436                 if (! $isnative_changelog) {
 437                         $isnative_changelog="debian/changelog";
 438                 }
 439                 # Get the package version.
 440                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 441                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 442                 # Did the changelog parse fail?
 443                 if (! defined $dh{VERSION}) {
 444                         error("changelog parse failure");
 445                 }
 446
 447                 # Is this a native Debian package?
 448                 if ($dh{VERSION}=~m/.*-/) {
 449                         return $isnative_cache{$package}=0;
 450                 }
 451                 else {
 452                         return $isnative_cache{$package}=1;
 453                 }
 454         }
 455 }
 456
 457 # Automatically add a shell script snippet to a debian script.
 458 # Only works if the script has #DEBHELPER# in it.
 459 #
 460 # Parameters:
 461 # 1: package
 462 # 2: script to add to
 463 # 3: filename of snippet
 464 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 465 sub autoscript {
 466         my $package=shift;
 467         my $script=shift;
 468         my $filename=shift;
 469         my $sed=shift || "";
 470
 471         # This is the file we will modify.
 472         my $outfile="debian/".pkgext($package)."$script.debhelper";
 473
 474         # Figure out what shell script snippet to use.
 475         my $infile;
 476         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 477             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 478                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 479         }
 480         else {
 481                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 482                         $infile="/usr/share/debhelper/autoscripts/$filename";
 483                 }
 484                 else {
 485                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 486                 }
 487         }
 488
 489         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 490            && !compat(5)) {
 491                 # Add fragments to top so they run in reverse order when removing.
 492                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 493                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 494                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 495                 complex_doit("cat $outfile >> $outfile.new");
 496                 complex_doit("mv $outfile.new $outfile");
 497         }
 498         else {
 499                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 500                 complex_doit("sed \"$sed\" $infile >> $outfile");
 501                 complex_doit("echo '# End automatically added section' >> $outfile");
 502         }
 503 }
 504
 505 # Removes a whole substvar line.
 506 sub delsubstvar {
 507         my $package=shift;
 508         my $substvar=shift;
 509
 510         my $ext=pkgext($package);
 511         my $substvarfile="debian/${ext}substvars";
 512
 513         if (-e $substvarfile) {
 514                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 515                 doit("mv", "$substvarfile.new","$substvarfile");
 516         }
 517 }
 518
 519 # Adds a dependency on some package to the specified
 520 # substvar in a package's substvar's file.
 521 sub addsubstvar {
 522         my $package=shift;
 523         my $substvar=shift;
 524         my $deppackage=shift;
 525         my $verinfo=shift;
 526         my $remove=shift;
 527
 528         my $ext=pkgext($package);
 529         my $substvarfile="debian/${ext}substvars";
 530         my $str=$deppackage;
 531         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 532
 533         # Figure out what the line will look like, based on what's there
 534         # now, and what we're to add or remove.
 535         my $line="";
 536         if (-e $substvarfile) {
 537                 my %items;
 538                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 539                 while (<SUBSTVARS_IN>) {
 540                         chomp;
 541                         if (/^\Q$substvar\E=(.*)/) {
 542                                 %items = map { $_ => 1} split(", ", $1);
 543
 544                                 last;
 545                         }
 546                 }
 547                 close SUBSTVARS_IN;
 548                 if (! $remove) {
 549                         $items{$str}=1;
 550                 }
 551                 else {
 552                         delete $items{$str};
 553                 }
 554                 $line=join(", ", sort keys %items);
 555         }
 556         elsif (! $remove) {
 557                 $line=$str;
 558         }
 559
 560         if (length $line) {
 561                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 562                  doit("mv", "$substvarfile.new", $substvarfile);
 563         }
 564         else {
 565                 delsubstvar($package,$substvar);
 566         }
 567 }
 568
 569 # Reads in the specified file, one line at a time. splits on words,
 570 # and returns an array of arrays of the contents.
 571 # If a value is passed in as the second parameter, then glob
 572 # expansion is done in the directory specified by the parameter ("." is
 573 # frequently a good choice).
 574 sub filedoublearray {
 575         my $file=shift;
 576         my $globdir=shift;
 577
 578         my @ret;
 579         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 580         while (<DH_FARRAY_IN>) {
 581                 chomp;
 582                 # Only ignore comments and empty lines in v5 mode.
 583                 if (! compat(4)) {
 584                         next if /^#/ || /^$/;
 585                 }
 586                 my @line;
 587                 # Only do glob expansion in v3 mode.
 588                 #
 589                 # The tricky bit is that the glob expansion is done
 590                 # as if we were in the specified directory, so the
 591                 # filenames that come out are relative to it.
 592                 if (defined $globdir && ! compat(2)) {
 593                         foreach (map { glob "$globdir/$_" } split) {
 594                                 s#^$globdir/##;
 595                                 push @line, $_;
 596                         }
 597                 }
 598                 else {
 599                         @line = split;
 600                 }
 601                 push @ret, [@line];
 602         }
 603         close DH_FARRAY_IN;
 604
 605         return @ret;
 606 }
 607
 608 # Reads in the specified file, one word at a time, and returns an array of
 609 # the result. Can do globbing as does filedoublearray.
 610 sub filearray {
 611         return map { @$_ } filedoublearray(@_);
 612 }
 613
 614 # Passed a filename, returns true if -X says that file should be excluded.
 615 sub excludefile {
 616         my $filename = shift;
 617         foreach my $f (@{$dh{EXCLUDE}}) {
 618                 return 1 if $filename =~ /\Q$f\E/;
 619         }
 620         return 0;
 621 }
 622
 623 {
 624         my %dpkg_arch_output;
 625         sub dpkg_architecture_value {
 626                 my $var = shift;
 627                 if (! exists($dpkg_arch_output{$var})) {
 628                         local $_;
 629                         open(PIPE, '-|', 'dpkg-architecture')
 630                                 or error("dpkg-architecture failed");
 631                         while (<PIPE>) {
 632                                 chomp;
 633                                 my ($k, $v) = split(/=/, $_, 2);
 634                                 $dpkg_arch_output{$k} = $v;
 635                         }
 636                         close(PIPE);
 637                 }
 638                 return $dpkg_arch_output{$var};
 639         }
 640 }
 641
 642 # Returns the build architecture.
 643 sub buildarch {
 644         dpkg_architecture_value('DEB_HOST_ARCH');
 645 }
 646
 647 # Returns the build OS.
 648 sub buildos {
 649         dpkg_architecture_value("DEB_HOST_ARCH_OS");
 650 }
 651
 652 # Passed an arch and a list of arches to match against, returns true if matched
 653 {
 654         my %knownsame;
 655
 656         sub samearch {
 657                 my $arch=shift;
 658                 my @archlist=split(/\s+/,shift);
 659
 660                 foreach my $a (@archlist) {
 661                         # Avoid expensive dpkg-architecture call to compare
 662                         # with a simple architecture name. "linux-any" and
 663                         # other architecture wildcards are (currently)
 664                         # always hypenated.
 665                         if ($a !~ /-/) {
 666                                 return 1 if $arch eq $a;
 667                         }
 668                         elsif (exists $knownsame{$arch}{$a}) {
 669                                 return 1 if $knownsame{$arch}{$a};
 670                         }
 671                         elsif (system("dpkg-architecture", "-a$arch", "-i$a") == 0) {
 672                                 return $knownsame{$arch}{$a}=1;
 673                         }
 674                         else {
 675                                 $knownsame{$arch}{$a}=0;
 676                         }
 677                 }
 678
 679                 return 0;
 680         }
 681 }
 682
 683 # Returns source package name
 684 sub sourcepackage {
 685         open (CONTROL, 'debian/control') ||
 686             error("cannot read debian/control: $!\n");
 687         while (<CONTROL>) {
 688                 chomp;
 689                 s/\s+$//;
 690                 if (/^Source:\s*(.*)/) {
 691                         close CONTROL;
 692                         return $1;
 693                 }
 694         }
 695
 696         close CONTROL;
 697         error("could not find Source: line in control file.");
 698 }
 699
 700 # Returns a list of packages in the control file.
 701 # Pass "arch" or "indep" to specify arch-dependant (that will be built
 702 # for the system's arch) or independant. If nothing is specified,
 703 # returns all packages. Also, "both" returns the union of "arch" and "indep"
 704 # packages.
 705 # As a side effect, populates %package_arches and %package_types with the
 706 # types of all packages (not only those returned).
 707 my (%package_types, %package_arches);
 708 sub getpackages {
 709         my $type=shift;
 710
 711         %package_types=();
 712         %package_arches=();
 713
 714         $type="" if ! defined $type;
 715
 716         my $package="";
 717         my $arch="";
 718         my $package_type;
 719         my @list=();
 720         my %seen;
 721         open (CONTROL, 'debian/control') ||
 722                 error("cannot read debian/control: $!\n");
 723         while (<CONTROL>) {
 724                 chomp;
 725                 s/\s+$//;
 726                 if (/^Package:\s*(.*)/) {
 727                         $package=$1;
 728                         # Detect duplicate package names in the same control file.
 729                         if (! $seen{$package}) {
 730                                 $seen{$package}=1;
 731                         }
 732                         else {
 733                                 error("debian/control has a duplicate entry for $package");
 734                         }
 735                         $package_type="deb";
 736                 }
 737                 if (/^Architecture:\s*(.*)/) {
 738                         $arch=$1;
 739                 }
 740                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 741                         $package_type=$1;
 742                 }
 743
 744                 if (!$_ or eof) { # end of stanza.
 745                         if ($package) {
 746                                 $package_types{$package}=$package_type;
 747                                 $package_arches{$package}=$arch;
 748                         }
 749
 750                         if ($package &&
 751                             ((($type eq 'indep' || $type eq 'both') && $arch eq 'all') ||
 752                              (($type eq 'arch'  || $type eq 'both') && ($arch eq 'any' ||
 753                                              ($arch ne 'all' &&
 754                                               samearch(buildarch(), $arch)))) ||
 755                              ! $type)) {
 756                                 push @list, $package;
 757                                 $package="";
 758                                 $arch="";
 759                         }
 760                 }
 761         }
 762         close CONTROL;
 763
 764         return @list;
 765 }
 766
 767 # Returns the arch a package will build for.
 768 sub package_arch {
 769         my $package=shift;
 770
 771         if (! exists $package_arches{$package}) {
 772                 warning "package $package is not in control info";
 773                 return buildarch();
 774         }
 775         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 776 }
 777
 778 # Return true if a given package is really a udeb.
 779 sub is_udeb {
 780         my $package=shift;
 781
 782         if (! exists $package_types{$package}) {
 783                 warning "package $package is not in control info";
 784                 return 0;
 785         }
 786         return $package_types{$package} eq 'udeb';
 787 }
 788
 789 # Generates the filename that is used for a udeb package.
 790 sub udeb_filename {
 791         my $package=shift;
 792
 793         my $filearch=package_arch($package);
 794         isnative($package); # side effect
 795         my $version=$dh{VERSION};
 796         $version=~s/^[0-9]+://; # strip any epoch
 797         return "${package}_${version}_$filearch.udeb";
 798 }
 799
 800 # Handles #DEBHELPER# substitution in a script; also can generate a new
 801 # script from scratch if none exists but there is a .debhelper file for it.
 802 sub debhelper_script_subst {
 803         my $package=shift;
 804         my $script=shift;
 805
 806         my $tmp=tmpdir($package);
 807         my $ext=pkgext($package);
 808         my $file=pkgfile($package,$script);
 809
 810         if ($file ne '') {
 811                 if (-f "debian/$ext$script.debhelper") {
 812                         # Add this into the script, where it has #DEBHELPER#
 813                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 814                 }
 815                 else {
 816                         # Just get rid of any #DEBHELPER# in the script.
 817                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 818                 }
 819                 doit("chown","0:0","$tmp/DEBIAN/$script");
 820                 doit("chmod",755,"$tmp/DEBIAN/$script");
 821         }
 822         elsif ( -f "debian/$ext$script.debhelper" ) {
 823                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 824                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 825                 doit("chown","0:0","$tmp/DEBIAN/$script");
 826                 doit("chmod",755,"$tmp/DEBIAN/$script");
 827         }
 828 }
 829
 830 # Checks if make's jobserver is enabled via MAKEFLAGS, but
 831 # the FD used to communicate with it is actually not available.
 832 sub is_make_jobserver_unavailable {
 833         if (exists $ENV{MAKEFLAGS} &&
 834             $ENV{MAKEFLAGS} =~ /(?:^|\s)--jobserver-fds=(\d+)/) {
 835                 if (!open(my $in, "<&$1")) {
 836                         return 1; # unavailable
 837                 }
 838                 else {
 839                         close $in;
 840                         return 0; # available
 841                 }
 842         }
 843
 844         return; # no jobserver specified
 845 }
 846
 847 # Cleans out jobserver options from MAKEFLAGS.
 848 sub clean_jobserver_makeflags {
 849         if (exists $ENV{MAKEFLAGS}) {
 850                 if ($ENV{MAKEFLAGS} =~ /(?:^|\s)--jobserver-fds=(\d+)/) {
 851                         $ENV{MAKEFLAGS} =~ s/(?:^|\s)--jobserver-fds=\S+//g;
 852                         $ENV{MAKEFLAGS} =~ s/(?:^|\s)-j\b//g;
 853                 }
 854                 delete $ENV{MAKEFLAGS} if $ENV{MAKEFLAGS} =~ /^\s*$/;
 855         }
 856 }
 857
 858 1