Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2008.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell
  18             &inhibit_log &load_log &write_log &dpkg_architecture_value
  19             &sourcepackage
  20             &is_make_jobserver_unavailable &clean_jobserver_makeflags);
  21
  22 my $max_compat=8;
  23
  24 sub init {
  25         my %params=@_;
  26
  27         # Check to see if an option line starts with a dash,
  28         # or DH_OPTIONS is set.
  29         # If so, we need to pass this off to the resource intensive
  30         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  31         if ((defined $ENV{DH_OPTIONS} && length $ENV{DH_OPTIONS}) ||
  32             (defined $ENV{DH_INTERNAL_OPTIONS} && length $ENV{DH_INTERNAL_OPTIONS}) ||
  33             grep /^-/, @ARGV) {
  34                 eval "use Debian::Debhelper::Dh_Getopt";
  35                 error($@) if $@;
  36                 Debian::Debhelper::Dh_Getopt::parseopts(%params);
  37         }
  38
  39         # Another way to set excludes.
  40         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  41                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  42         }
  43
  44         # Generate EXCLUDE_FIND.
  45         if ($dh{EXCLUDE}) {
  46                 $dh{EXCLUDE_FIND}='';
  47                 foreach (@{$dh{EXCLUDE}}) {
  48                         my $x=$_;
  49                         $x=escape_shell($x);
  50                         $x=~s/\./\\\\./g;
  51                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  52                 }
  53                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  54         }
  55
  56         # Check to see if DH_VERBOSE environment variable was set, if so,
  57         # make sure verbose is on.
  58         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  59                 $dh{VERBOSE}=1;
  60         }
  61
  62         # Check to see if DH_NO_ACT environment variable was set, if so,
  63         # make sure no act mode is on.
  64         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  65                 $dh{NO_ACT}=1;
  66         }
  67
  68         # Get the name of the main binary package (first one listed in
  69         # debian/control). Only if the main package was not set on the
  70         # command line.
  71         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  72                 my @allpackages=getpackages();
  73                 $dh{MAINPACKAGE}=$allpackages[0];
  74         }
  75
  76         # Check if packages to build have been specified, if not, fall back to
  77         # the default, building all relevant packages.
  78         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  79                 push @{$dh{DOPACKAGES}}, getpackages('both');
  80         }
  81
  82         # Check to see if -P was specified. If so, we can only act on a single
  83         # package.
  84         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  85                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  86         }
  87
  88         # Figure out which package is the first one we were instructed to build.
  89         # This package gets special treatement: files and directories specified on
  90         # the command line may affect it.
  91         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
  92
  93         # If no error handling function was specified, just propigate
  94         # errors out.
  95         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
  96                 $dh{ERROR_HANDLER}='exit \$?';
  97         }
  98 }
  99
 100 # Run at exit. Add the command to the log files for the packages it acted
 101 # on, if it's exiting successfully.
 102 my $write_log=1;
 103 sub END {
 104         if ($? == 0 && $write_log) {
 105                 write_log(basename($0), @{$dh{DOPACKAGES}});
 106         }
 107 }
 108
 109 sub load_log {
 110         my ($package, $db)=@_;
 111         my $ext=pkgext($package);
 112
 113         my @log;
 114         open(LOG, "<", "debian/${ext}debhelper.log") || return;
 115         while (<LOG>) {
 116                 chomp;
 117                 push @log, $_;
 118                 $db->{$package}{$_}=1 if defined $db;
 119         }
 120         close LOG;
 121         return @log;
 122 }
 123
 124 sub write_log {
 125         my $cmd=shift;
 126         my @packages=@_;
 127
 128         foreach my $package (@packages) {
 129                 my $ext=pkgext($package);
 130                 my $log="debian/${ext}debhelper.log";
 131                 open(LOG, ">>", $log) || error("failed to write to ${log}: $!");
 132                 print LOG $cmd."\n";
 133                 close LOG;
 134         }
 135 }
 136
 137 sub inhibit_log {
 138         $write_log=0;
 139 }
 140
 141 # Pass it an array containing the arguments of a shell command like would
 142 # be run by exec(). It turns that into a line like you might enter at the
 143 # shell, escaping metacharacters and quoting arguments that contain spaces.
 144 sub escape_shell {
 145         my @args=@_;
 146         my $line="";
 147         my @ret;
 148         foreach my $word (@args) {
 149                 if ($word=~/\s/) {
 150                         # Escape only a few things since it will be quoted.
 151                         # Note we use double quotes because you cannot
 152                         # escape ' in single quotes, while " can be escaped
 153                         # in double.
 154                         # This does make -V"foo bar" turn into "-Vfoo bar",
 155                         # but that will be parsed identically by the shell
 156                         # anyway..
 157                         $word=~s/([\n`\$"\\])/\\$1/g;
 158                         push @ret, "\"$word\"";
 159                 }
 160                 else {
 161                         # This list is from _Unix in a Nutshell_. (except '#')
 162                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 163                         push @ret,$word;
 164                 }
 165         }
 166         return join(' ', @ret);
 167 }
 168
 169 # Run a command, and display the command to stdout if verbose mode is on.
 170 # All commands that modifiy files in $TMP should be ran via this
 171 # function.
 172 #
 173 # Note that this cannot handle complex commands, especially anything
 174 # involving redirection. Use complex_doit instead.
 175 sub doit {
 176         verbose_print(escape_shell(@_));
 177
 178         if (! $dh{NO_ACT}) {
 179                 system(@_) == 0 || _error_exitcode(join(" ", @_));
 180         }
 181 }
 182
 183 # Run a command and display the command to stdout if verbose mode is on.
 184 # Use doit() if you can, instead of this function, because this function
 185 # forks a shell. However, this function can handle more complicated stuff
 186 # like redirection.
 187 sub complex_doit {
 188         verbose_print(join(" ",@_));
 189
 190         if (! $dh{NO_ACT}) {
 191                 # The join makes system get a scalar so it forks off a shell.
 192                 system(join(" ", @_)) == 0 || _error_exitcode(join(" ", @_))
 193         }
 194 }
 195
 196 sub _error_exitcode {
 197         my $command=shift;
 198         if ($? == -1) {
 199                 error("$command failed to to execute: $!");
 200         }
 201         elsif ($? & 127) {
 202                 error("$command died with signal ".($? & 127));
 203         }
 204         else {
 205                 error("$command returned exit code ".($? >> 8));
 206         }
 207 }
 208
 209 # Run a command that may have a huge number of arguments, like xargs does.
 210 # Pass in a reference to an array containing the arguments, and then other
 211 # parameters that are the command and any parameters that should be passed to
 212 # it each time.
 213 sub xargs {
 214         my $args=shift;
 215
 216         # The kernel can accept command lines up to 20k worth of characters.
 217         my $command_max=20000; # LINUX SPECIFIC!!
 218                         # (And obsolete; it's bigger now.)
 219                         # I could use POSIX::ARG_MAX, but that would be slow.
 220
 221         # Figure out length of static portion of command.
 222         my $static_length=0;
 223         foreach (@_) {
 224                 $static_length+=length($_)+1;
 225         }
 226
 227         my @collect=();
 228         my $length=$static_length;
 229         foreach (@$args) {
 230                 if (length($_) + 1 + $static_length > $command_max) {
 231                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 232                 }
 233                 $length+=length($_) + 1;
 234                 if ($length < $command_max) {
 235                         push @collect, $_;
 236                 }
 237                 else {
 238                         doit(@_,@collect) if $#collect > -1;
 239                         @collect=($_);
 240                         $length=$static_length + length($_) + 1;
 241                 }
 242         }
 243         doit(@_,@collect) if $#collect > -1;
 244 }
 245
 246 # Print something if the verbose flag is on.
 247 sub verbose_print {
 248         my $message=shift;
 249
 250         if ($dh{VERBOSE}) {
 251                 print "\t$message\n";
 252         }
 253 }
 254
 255 # Output an error message and die (can be caught).
 256 sub error {
 257         my $message=shift;
 258
 259         die basename($0).": $message\n";
 260 }
 261
 262 # Output a warning.
 263 sub warning {
 264         my $message=shift;
 265
 266         print STDERR basename($0).": $message\n";
 267 }
 268
 269 # Returns the basename of the argument passed to it.
 270 sub basename {
 271         my $fn=shift;
 272
 273         $fn=~s/\/$//g; # ignore trailing slashes
 274         $fn=~s:^.*/(.*?)$:$1:;
 275         return $fn;
 276 }
 277
 278 # Returns the directory name of the argument passed to it.
 279 sub dirname {
 280         my $fn=shift;
 281
 282         $fn=~s/\/$//g; # ignore trailing slashes
 283         $fn=~s:^(.*)/.*?$:$1:;
 284         return $fn;
 285 }
 286
 287 # Pass in a number, will return true iff the current compatibility level
 288 # is less than or equal to that number.
 289 {
 290         my $warned_compat=0;
 291         my $c;
 292
 293         sub compat {
 294                 my $num=shift;
 295
 296                 if (! defined $c) {
 297                         $c=1;
 298                         if (defined $ENV{DH_COMPAT}) {
 299                                 $c=$ENV{DH_COMPAT};
 300                         }
 301                         elsif (-e 'debian/compat') {
 302                                 # Try the file..
 303                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 304                                 my $l=<COMPAT_IN>;
 305                                 close COMPAT_IN;
 306                                 if (! defined $l || ! length $l) {
 307                                         warning("debian/compat is empty, assuming level $c");
 308                                 }
 309                                 else {
 310                                         chomp $l;
 311                                         $c=$l;
 312                                 }
 313                         }
 314                 }
 315
 316                 if ($c <= 4 && ! $warned_compat) {
 317                         warning("Compatibility levels before 5 are deprecated.");
 318                         $warned_compat=1;
 319                 }
 320
 321                 if ($c > $max_compat) {
 322                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 323                 }
 324
 325                 return ($c <= $num);
 326         }
 327 }
 328
 329 # Pass it a name of a binary package, it returns the name of the tmp dir to
 330 # use, for that package.
 331 sub tmpdir {
 332         my $package=shift;
 333
 334         if ($dh{TMPDIR}) {
 335                 return $dh{TMPDIR};
 336         }
 337         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 338                 # This is for back-compatibility with the debian/tmp tradition.
 339                 return "debian/tmp";
 340         }
 341         else {
 342                 return "debian/$package";
 343         }
 344 }
 345
 346 # Pass this the name of a binary package, and the name of the file wanted
 347 # for the package, and it will return the actual existing filename to use.
 348 #
 349 # It tries several filenames:
 350 #   * debian/package.filename.buildarch
 351 #   * debian/package.filename.buildos
 352 #   * debian/package.filename
 353 #   * debian/filename (if the package is the main package)
 354 # If --name was specified then the files
 355 # must have the name after the package name:
 356 #   * debian/package.name.filename.buildarch
 357 #   * debian/package.name.filename.buildos
 358 #   * debian/package.name.filename
 359 #   * debian/name.filename (if the package is the main package)
 360 sub pkgfile {
 361         my $package=shift;
 362         my $filename=shift;
 363
 364         if (defined $dh{NAME}) {
 365                 $filename="$dh{NAME}.$filename";
 366         }
 367
 368         # First, check for files ending in buildarch and buildos.
 369         my $match;
 370         foreach my $file (glob("debian/$package.$filename.*")) {
 371                 next if ! -f $file;
 372                 next if $dh{IGNORE} && exists $dh{IGNORE}->{$file};
 373                 if ($file eq "debian/$package.$filename.".buildarch()) {
 374                         $match=$file;
 375                         # buildarch files are used in preference to buildos files.
 376                         last;
 377                 }
 378                 elsif ($file eq "debian/$package.$filename.".buildos()) {
 379                         $match=$file;
 380                 }
 381         }
 382         return $match if defined $match;
 383
 384         my @try=("debian/$package.$filename");
 385         if ($package eq $dh{MAINPACKAGE}) {
 386                 push @try, "debian/$filename";
 387         }
 388
 389         foreach my $file (@try) {
 390                 if (-f $file &&
 391                     (! $dh{IGNORE} || ! exists $dh{IGNORE}->{$file})) {
 392                         return $file;
 393                 }
 394
 395         }
 396
 397         return "";
 398
 399 }
 400
 401 # Pass it a name of a binary package, it returns the name to prefix to files
 402 # in debian/ for this package.
 403 sub pkgext {
 404         my $package=shift;
 405
 406         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 407                 return "";
 408         }
 409         return "$package.";
 410 }
 411
 412 # Pass it the name of a binary package, it returns the name to install
 413 # files by in eg, etc. Normally this is the same, but --name can override
 414 # it.
 415 sub pkgfilename {
 416         my $package=shift;
 417
 418         if (defined $dh{NAME}) {
 419                 return $dh{NAME};
 420         }
 421         return $package;
 422 }
 423
 424 # Returns 1 if the package is a native debian package, null otherwise.
 425 # As a side effect, sets $dh{VERSION} to the version of this package.
 426 {
 427         # Caches return code so it only needs to run dpkg-parsechangelog once.
 428         my %isnative_cache;
 429
 430         sub isnative {
 431                 my $package=shift;
 432
 433                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 434
 435                 # Make sure we look at the correct changelog.
 436                 my $isnative_changelog=pkgfile($package,"changelog");
 437                 if (! $isnative_changelog) {
 438                         $isnative_changelog="debian/changelog";
 439                 }
 440                 # Get the package version.
 441                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 442                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 443                 # Did the changelog parse fail?
 444                 if (! defined $dh{VERSION}) {
 445                         error("changelog parse failure");
 446                 }
 447
 448                 # Is this a native Debian package?
 449                 if ($dh{VERSION}=~m/.*-/) {
 450                         return $isnative_cache{$package}=0;
 451                 }
 452                 else {
 453                         return $isnative_cache{$package}=1;
 454                 }
 455         }
 456 }
 457
 458 # Automatically add a shell script snippet to a debian script.
 459 # Only works if the script has #DEBHELPER# in it.
 460 #
 461 # Parameters:
 462 # 1: package
 463 # 2: script to add to
 464 # 3: filename of snippet
 465 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 466 sub autoscript {
 467         my $package=shift;
 468         my $script=shift;
 469         my $filename=shift;
 470         my $sed=shift || "";
 471
 472         # This is the file we will modify.
 473         my $outfile="debian/".pkgext($package)."$script.debhelper";
 474
 475         # Figure out what shell script snippet to use.
 476         my $infile;
 477         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 478             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 479                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 480         }
 481         else {
 482                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 483                         $infile="/usr/share/debhelper/autoscripts/$filename";
 484                 }
 485                 else {
 486                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 487                 }
 488         }
 489
 490         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 491            && !compat(5)) {
 492                 # Add fragments to top so they run in reverse order when removing.
 493                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 494                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 495                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 496                 complex_doit("cat $outfile >> $outfile.new");
 497                 complex_doit("mv $outfile.new $outfile");
 498         }
 499         else {
 500                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 501                 complex_doit("sed \"$sed\" $infile >> $outfile");
 502                 complex_doit("echo '# End automatically added section' >> $outfile");
 503         }
 504 }
 505
 506 # Removes a whole substvar line.
 507 sub delsubstvar {
 508         my $package=shift;
 509         my $substvar=shift;
 510
 511         my $ext=pkgext($package);
 512         my $substvarfile="debian/${ext}substvars";
 513
 514         if (-e $substvarfile) {
 515                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 516                 doit("mv", "$substvarfile.new","$substvarfile");
 517         }
 518 }
 519
 520 # Adds a dependency on some package to the specified
 521 # substvar in a package's substvar's file.
 522 sub addsubstvar {
 523         my $package=shift;
 524         my $substvar=shift;
 525         my $deppackage=shift;
 526         my $verinfo=shift;
 527         my $remove=shift;
 528
 529         my $ext=pkgext($package);
 530         my $substvarfile="debian/${ext}substvars";
 531         my $str=$deppackage;
 532         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 533
 534         # Figure out what the line will look like, based on what's there
 535         # now, and what we're to add or remove.
 536         my $line="";
 537         if (-e $substvarfile) {
 538                 my %items;
 539                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 540                 while (<SUBSTVARS_IN>) {
 541                         chomp;
 542                         if (/^\Q$substvar\E=(.*)/) {
 543                                 %items = map { $_ => 1} split(", ", $1);
 544
 545                                 last;
 546                         }
 547                 }
 548                 close SUBSTVARS_IN;
 549                 if (! $remove) {
 550                         $items{$str}=1;
 551                 }
 552                 else {
 553                         delete $items{$str};
 554                 }
 555                 $line=join(", ", sort keys %items);
 556         }
 557         elsif (! $remove) {
 558                 $line=$str;
 559         }
 560
 561         if (length $line) {
 562                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 563                  doit("mv", "$substvarfile.new", $substvarfile);
 564         }
 565         else {
 566                 delsubstvar($package,$substvar);
 567         }
 568 }
 569
 570 # Reads in the specified file, one line at a time. splits on words,
 571 # and returns an array of arrays of the contents.
 572 # If a value is passed in as the second parameter, then glob
 573 # expansion is done in the directory specified by the parameter ("." is
 574 # frequently a good choice).
 575 sub filedoublearray {
 576         my $file=shift;
 577         my $globdir=shift;
 578
 579         my @ret;
 580         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 581         while (<DH_FARRAY_IN>) {
 582                 chomp;
 583                 # Only ignore comments and empty lines in v5 mode.
 584                 if (! compat(4)) {
 585                         next if /^#/ || /^$/;
 586                 }
 587                 my @line;
 588                 # Only do glob expansion in v3 mode.
 589                 #
 590                 # The tricky bit is that the glob expansion is done
 591                 # as if we were in the specified directory, so the
 592                 # filenames that come out are relative to it.
 593                 if (defined $globdir && ! compat(2)) {
 594                         foreach (map { glob "$globdir/$_" } split) {
 595                                 s#^$globdir/##;
 596                                 push @line, $_;
 597                         }
 598                 }
 599                 else {
 600                         @line = split;
 601                 }
 602                 push @ret, [@line];
 603         }
 604         close DH_FARRAY_IN;
 605
 606         return @ret;
 607 }
 608
 609 # Reads in the specified file, one word at a time, and returns an array of
 610 # the result. Can do globbing as does filedoublearray.
 611 sub filearray {
 612         return map { @$_ } filedoublearray(@_);
 613 }
 614
 615 # Passed a filename, returns true if -X says that file should be excluded.
 616 sub excludefile {
 617         my $filename = shift;
 618         foreach my $f (@{$dh{EXCLUDE}}) {
 619                 return 1 if $filename =~ /\Q$f\E/;
 620         }
 621         return 0;
 622 }
 623
 624 {
 625         my %dpkg_arch_output;
 626         sub dpkg_architecture_value {
 627                 my $var = shift;
 628                 if (! exists($dpkg_arch_output{$var})) {
 629                         local $_;
 630                         open(PIPE, '-|', 'dpkg-architecture')
 631                                 or error("dpkg-architecture failed");
 632                         while (<PIPE>) {
 633                                 chomp;
 634                                 my ($k, $v) = split(/=/, $_, 2);
 635                                 $dpkg_arch_output{$k} = $v;
 636                         }
 637                         close(PIPE);
 638                 }
 639                 return $dpkg_arch_output{$var};
 640         }
 641 }
 642
 643 # Returns the build architecture.
 644 sub buildarch {
 645         dpkg_architecture_value('DEB_HOST_ARCH');
 646 }
 647
 648 # Returns the build OS.
 649 sub buildos {
 650         dpkg_architecture_value("DEB_HOST_ARCH_OS");
 651 }
 652
 653 # Passed an arch and a list of arches to match against, returns true if matched
 654 {
 655         my %knownsame;
 656
 657         sub samearch {
 658                 my $arch=shift;
 659                 my @archlist=split(/\s+/,shift);
 660
 661                 foreach my $a (@archlist) {
 662                         # Avoid expensive dpkg-architecture call to compare
 663                         # with a simple architecture name. "linux-any" and
 664                         # other architecture wildcards are (currently)
 665                         # always hypenated.
 666                         if ($a !~ /-/) {
 667                                 return 1 if $arch eq $a;
 668                         }
 669                         elsif (exists $knownsame{$arch}{$a}) {
 670                                 return 1 if $knownsame{$arch}{$a};
 671                         }
 672                         elsif (system("dpkg-architecture", "-a$arch", "-i$a") == 0) {
 673                                 return $knownsame{$arch}{$a}=1;
 674                         }
 675                         else {
 676                                 $knownsame{$arch}{$a}=0;
 677                         }
 678                 }
 679
 680                 return 0;
 681         }
 682 }
 683
 684 # Returns source package name
 685 sub sourcepackage {
 686         open (CONTROL, 'debian/control') ||
 687             error("cannot read debian/control: $!\n");
 688         while (<CONTROL>) {
 689                 chomp;
 690                 s/\s+$//;
 691                 if (/^Source:\s*(.*)/) {
 692                         close CONTROL;
 693                         return $1;
 694                 }
 695         }
 696
 697         close CONTROL;
 698         error("could not find Source: line in control file.");
 699 }
 700
 701 # Returns a list of packages in the control file.
 702 # Pass "arch" or "indep" to specify arch-dependant (that will be built
 703 # for the system's arch) or independant. If nothing is specified,
 704 # returns all packages. Also, "both" returns the union of "arch" and "indep"
 705 # packages.
 706 # As a side effect, populates %package_arches and %package_types with the
 707 # types of all packages (not only those returned).
 708 my (%package_types, %package_arches);
 709 sub getpackages {
 710         my $type=shift;
 711
 712         %package_types=();
 713         %package_arches=();
 714
 715         $type="" if ! defined $type;
 716
 717         my $package="";
 718         my $arch="";
 719         my $package_type;
 720         my @list=();
 721         my %seen;
 722         open (CONTROL, 'debian/control') ||
 723                 error("cannot read debian/control: $!\n");
 724         while (<CONTROL>) {
 725                 chomp;
 726                 s/\s+$//;
 727                 if (/^Package:\s*(.*)/) {
 728                         $package=$1;
 729                         # Detect duplicate package names in the same control file.
 730                         if (! $seen{$package}) {
 731                                 $seen{$package}=1;
 732                         }
 733                         else {
 734                                 error("debian/control has a duplicate entry for $package");
 735                         }
 736                         $package_type="deb";
 737                 }
 738                 if (/^Architecture:\s*(.*)/) {
 739                         $arch=$1;
 740                 }
 741                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 742                         $package_type=$1;
 743                 }
 744
 745                 if (!$_ or eof) { # end of stanza.
 746                         if ($package) {
 747                                 $package_types{$package}=$package_type;
 748                                 $package_arches{$package}=$arch;
 749                         }
 750
 751                         if ($package &&
 752                             ((($type eq 'indep' || $type eq 'both') && $arch eq 'all') ||
 753                              (($type eq 'arch'  || $type eq 'both') && ($arch eq 'any' ||
 754                                              ($arch ne 'all' &&
 755                                               samearch(buildarch(), $arch)))) ||
 756                              ! $type)) {
 757                                 push @list, $package;
 758                                 $package="";
 759                                 $arch="";
 760                         }
 761                 }
 762         }
 763         close CONTROL;
 764
 765         return @list;
 766 }
 767
 768 # Returns the arch a package will build for.
 769 sub package_arch {
 770         my $package=shift;
 771
 772         if (! exists $package_arches{$package}) {
 773                 warning "package $package is not in control info";
 774                 return buildarch();
 775         }
 776         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 777 }
 778
 779 # Return true if a given package is really a udeb.
 780 sub is_udeb {
 781         my $package=shift;
 782
 783         if (! exists $package_types{$package}) {
 784                 warning "package $package is not in control info";
 785                 return 0;
 786         }
 787         return $package_types{$package} eq 'udeb';
 788 }
 789
 790 # Generates the filename that is used for a udeb package.
 791 sub udeb_filename {
 792         my $package=shift;
 793
 794         my $filearch=package_arch($package);
 795         isnative($package); # side effect
 796         my $version=$dh{VERSION};
 797         $version=~s/^[0-9]+://; # strip any epoch
 798         return "${package}_${version}_$filearch.udeb";
 799 }
 800
 801 # Handles #DEBHELPER# substitution in a script; also can generate a new
 802 # script from scratch if none exists but there is a .debhelper file for it.
 803 sub debhelper_script_subst {
 804         my $package=shift;
 805         my $script=shift;
 806
 807         my $tmp=tmpdir($package);
 808         my $ext=pkgext($package);
 809         my $file=pkgfile($package,$script);
 810
 811         if ($file ne '') {
 812                 if (-f "debian/$ext$script.debhelper") {
 813                         # Add this into the script, where it has #DEBHELPER#
 814                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 815                 }
 816                 else {
 817                         # Just get rid of any #DEBHELPER# in the script.
 818                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 819                 }
 820                 doit("chown","0:0","$tmp/DEBIAN/$script");
 821                 doit("chmod",755,"$tmp/DEBIAN/$script");
 822         }
 823         elsif ( -f "debian/$ext$script.debhelper" ) {
 824                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 825                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 826                 doit("chown","0:0","$tmp/DEBIAN/$script");
 827                 doit("chmod",755,"$tmp/DEBIAN/$script");
 828         }
 829 }
 830
 831 # Checks if make's jobserver is enabled via MAKEFLAGS, but
 832 # the FD used to communicate with it is actually not available.
 833 sub is_make_jobserver_unavailable {
 834         if (exists $ENV{MAKEFLAGS} &&
 835             $ENV{MAKEFLAGS} =~ /(?:^|\s)--jobserver-fds=(\d+)/) {
 836                 if (!open(my $in, "<&$1")) {
 837                         return 1; # unavailable
 838                 }
 839                 else {
 840                         close $in;
 841                         return 0; # available
 842                 }
 843         }
 844
 845         return; # no jobserver specified
 846 }
 847
 848 # Cleans out jobserver options from MAKEFLAGS.
 849 sub clean_jobserver_makeflags {
 850         if (exists $ENV{MAKEFLAGS}) {
 851                 if ($ENV{MAKEFLAGS} =~ /(?:^|\s)--jobserver-fds=(\d+)/) {
 852                         $ENV{MAKEFLAGS} =~ s/(?:^|\s)--jobserver-fds=\S+//g;
 853                         $ENV{MAKEFLAGS} =~ s/(?:^|\s)-j\b//g;
 854                 }
 855                 delete $ENV{MAKEFLAGS} if $ENV{MAKEFLAGS} =~ /^\s*$/;
 856         }
 857 }
 858
 859 1