Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2008.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell
  18             &inhibit_log &load_log &write_log &dpkg_architecture_value
  19             &sourcepackage);
  20
  21 my $max_compat=7;
  22
  23 sub init {
  24         my %params=@_;
  25
  26         # Check to see if an option line starts with a dash,
  27         # or DH_OPTIONS is set.
  28         # If so, we need to pass this off to the resource intensive
  29         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  30         if ((defined $ENV{DH_OPTIONS} && length $ENV{DH_OPTIONS}) ||
  31             (defined $ENV{DH_INTERNAL_OPTIONS} && length $ENV{DH_INTERNAL_OPTIONS}) ||
  32             grep /^-/, @ARGV) {
  33                 eval "use Debian::Debhelper::Dh_Getopt";
  34                 error($@) if $@;
  35                 Debian::Debhelper::Dh_Getopt::parseopts($params{options});
  36         }
  37
  38         # Another way to set excludes.
  39         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  40                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  41         }
  42
  43         # Generate EXCLUDE_FIND.
  44         if ($dh{EXCLUDE}) {
  45                 $dh{EXCLUDE_FIND}='';
  46                 foreach (@{$dh{EXCLUDE}}) {
  47                         my $x=$_;
  48                         $x=escape_shell($x);
  49                         $x=~s/\./\\\\./g;
  50                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  51                 }
  52                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  53         }
  54
  55         # Check to see if DH_VERBOSE environment variable was set, if so,
  56         # make sure verbose is on.
  57         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  58                 $dh{VERBOSE}=1;
  59         }
  60
  61         # Check to see if DH_NO_ACT environment variable was set, if so,
  62         # make sure no act mode is on.
  63         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  64                 $dh{NO_ACT}=1;
  65         }
  66
  67         my @allpackages=getpackages();
  68         # Get the name of the main binary package (first one listed in
  69         # debian/control). Only if the main package was not set on the
  70         # command line.
  71         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  72                 $dh{MAINPACKAGE}=$allpackages[0];
  73         }
  74
  75         # Check if packages to build have been specified, if not, fall back to
  76         # the default, doing them all.
  77         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  78                 push @{$dh{DOPACKAGES}},@allpackages;
  79         }
  80
  81         # Check to see if -P was specified. If so, we can only act on a single
  82         # package.
  83         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  84                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  85         }
  86
  87         # Figure out which package is the first one we were instructed to build.
  88         # This package gets special treatement: files and directories specified on
  89         # the command line may affect it.
  90         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
  91
  92         # If no error handling function was specified, just propigate
  93         # errors out.
  94         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
  95                 $dh{ERROR_HANDLER}='exit \$?';
  96         }
  97 }
  98
  99 # Run at exit. Add the command to the log files for the packages it acted
 100 # on, if it's exiting successfully.
 101 my $write_log=1;
 102 sub END {
 103         if ($? == 0 && $write_log) {
 104                 write_log(basename($0), @{$dh{DOPACKAGES}});
 105         }
 106 }
 107
 108 sub load_log {
 109         my ($package, $db)=@_;
 110         my $ext=pkgext($package);
 111
 112         my @log;
 113         open(LOG, "<", "debian/${ext}debhelper.log") || return;
 114         while (<LOG>) {
 115                 chomp;
 116                 push @log, $_;
 117                 $db->{$package}{$_}=1 if defined $db;
 118         }
 119         close LOG;
 120         return @log;
 121 }
 122
 123 sub write_log {
 124         my $cmd=shift;
 125         my @packages=@_;
 126
 127         foreach my $package (@packages) {
 128                 my $ext=pkgext($package);
 129                 my $log="debian/${ext}debhelper.log";
 130                 open(LOG, ">>", $log) || error("failed to write to ${log}: $!");
 131                 print LOG $cmd."\n";
 132                 close LOG;
 133         }
 134 }
 135
 136 sub inhibit_log {
 137         $write_log=0;
 138 }
 139
 140 # Pass it an array containing the arguments of a shell command like would
 141 # be run by exec(). It turns that into a line like you might enter at the
 142 # shell, escaping metacharacters and quoting arguments that contain spaces.
 143 sub escape_shell {
 144         my @args=@_;
 145         my $line="";
 146         my @ret;
 147         foreach my $word (@args) {
 148                 if ($word=~/\s/) {
 149                         # Escape only a few things since it will be quoted.
 150                         # Note we use double quotes because you cannot
 151                         # escape ' in single quotes, while " can be escaped
 152                         # in double.
 153                         # This does make -V"foo bar" turn into "-Vfoo bar",
 154                         # but that will be parsed identically by the shell
 155                         # anyway..
 156                         $word=~s/([\n`\$"\\])/\\$1/g;
 157                         push @ret, "\"$word\"";
 158                 }
 159                 else {
 160                         # This list is from _Unix in a Nutshell_. (except '#')
 161                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 162                         push @ret,$word;
 163                 }
 164         }
 165         return join(' ', @ret);
 166 }
 167
 168 # Run a command, and display the command to stdout if verbose mode is on.
 169 # All commands that modifiy files in $TMP should be ran via this
 170 # function.
 171 #
 172 # Note that this cannot handle complex commands, especially anything
 173 # involving redirection. Use complex_doit instead.
 174 sub doit {
 175         verbose_print(escape_shell(@_));
 176
 177         if (! $dh{NO_ACT}) {
 178                 system(@_) == 0 || _error_exitcode($_[0]);
 179         }
 180 }
 181
 182 # Run a command and display the command to stdout if verbose mode is on.
 183 # Use doit() if you can, instead of this function, because this function
 184 # forks a shell. However, this function can handle more complicated stuff
 185 # like redirection.
 186 sub complex_doit {
 187         verbose_print(join(" ",@_));
 188
 189         if (! $dh{NO_ACT}) {
 190                 # The join makes system get a scalar so it forks off a shell.
 191                 system(join(" ", @_)) == 0 || _error_exitcode(join(" ", @_))
 192         }
 193 }
 194
 195 sub _error_exitcode {
 196         my $command=shift;
 197         if ($? == -1) {
 198                 error("$command failed to to execute: $!");
 199         }
 200         elsif ($? & 127) {
 201                 error("$command died with signal ".($? & 127));
 202         }
 203         else {
 204                 error("$command returned exit code ".($? >> 8));
 205         }
 206 }
 207
 208 # Run a command that may have a huge number of arguments, like xargs does.
 209 # Pass in a reference to an array containing the arguments, and then other
 210 # parameters that are the command and any parameters that should be passed to
 211 # it each time.
 212 sub xargs {
 213         my $args=shift;
 214
 215         # The kernel can accept command lines up to 20k worth of characters.
 216         my $command_max=20000; # LINUX SPECIFIC!!
 217                         # I could use POSIX::ARG_MAX, but that would be slow.
 218
 219         # Figure out length of static portion of command.
 220         my $static_length=0;
 221         foreach (@_) {
 222                 $static_length+=length($_)+1;
 223         }
 224
 225         my @collect=();
 226         my $length=$static_length;
 227         foreach (@$args) {
 228                 if (length($_) + 1 + $static_length > $command_max) {
 229                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 230                 }
 231                 $length+=length($_) + 1;
 232                 if ($length < $command_max) {
 233                         push @collect, $_;
 234                 }
 235                 else {
 236                         doit(@_,@collect) if $#collect > -1;
 237                         @collect=($_);
 238                         $length=$static_length + length($_) + 1;
 239                 }
 240         }
 241         doit(@_,@collect) if $#collect > -1;
 242 }
 243
 244 # Print something if the verbose flag is on.
 245 sub verbose_print {
 246         my $message=shift;
 247
 248         if ($dh{VERBOSE}) {
 249                 print "\t$message\n";
 250         }
 251 }
 252
 253 # Output an error message and exit.
 254 sub error {
 255         my $message=shift;
 256
 257         warning($message);
 258         exit 1;
 259 }
 260
 261 # Output a warning.
 262 sub warning {
 263         my $message=shift;
 264
 265         print STDERR basename($0).": $message\n";
 266 }
 267
 268 # Returns the basename of the argument passed to it.
 269 sub basename {
 270         my $fn=shift;
 271
 272         $fn=~s/\/$//g; # ignore trailing slashes
 273         $fn=~s:^.*/(.*?)$:$1:;
 274         return $fn;
 275 }
 276
 277 # Returns the directory name of the argument passed to it.
 278 sub dirname {
 279         my $fn=shift;
 280
 281         $fn=~s/\/$//g; # ignore trailing slashes
 282         $fn=~s:^(.*)/.*?$:$1:;
 283         return $fn;
 284 }
 285
 286 # Pass in a number, will return true iff the current compatibility level
 287 # is less than or equal to that number.
 288 {
 289         my $warned_compat=0;
 290         my $c;
 291
 292         sub compat {
 293                 my $num=shift;
 294
 295                 if (! defined $c) {
 296                         $c=1;
 297                         if (defined $ENV{DH_COMPAT}) {
 298                                 $c=$ENV{DH_COMPAT};
 299                         }
 300                         elsif (-e 'debian/compat') {
 301                                 # Try the file..
 302                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 303                                 my $l=<COMPAT_IN>;
 304                                 close COMPAT_IN;
 305                                 if (! defined $l || ! length $l) {
 306                                         warning("debian/compat is empty, assuming level $c");
 307                                 }
 308                                 else {
 309                                         chomp $l;
 310                                         $c=$l;
 311                                 }
 312                         }
 313                 }
 314
 315                 if ($c < 4 && ! $warned_compat) {
 316                         warning("Compatibility levels before 5 are deprecated.");
 317                         $warned_compat=1;
 318                 }
 319
 320                 if ($c > $max_compat) {
 321                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 322                 }
 323
 324                 return ($c <= $num);
 325         }
 326 }
 327
 328 # Pass it a name of a binary package, it returns the name of the tmp dir to
 329 # use, for that package.
 330 sub tmpdir {
 331         my $package=shift;
 332
 333         if ($dh{TMPDIR}) {
 334                 return $dh{TMPDIR};
 335         }
 336         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 337                 # This is for back-compatibility with the debian/tmp tradition.
 338                 return "debian/tmp";
 339         }
 340         else {
 341                 return "debian/$package";
 342         }
 343 }
 344
 345 # Pass this the name of a binary package, and the name of the file wanted
 346 # for the package, and it will return the actual existing filename to use.
 347 #
 348 # It tries several filenames:
 349 #   * debian/package.filename.buildarch
 350 #   * debian/package.filename
 351 #   * debian/file (if the package is the main package)
 352 # If --name was specified then tonly the first two are tried, and they must
 353 # have the name after the pacage name:
 354 #   * debian/package.name.filename.buildarch
 355 #   * debian/package.name.filename
 356 sub pkgfile {
 357         my $package=shift;
 358         my $filename=shift;
 359
 360         if (defined $dh{NAME}) {
 361                 $filename="$dh{NAME}.$filename";
 362         }
 363
 364         my @try=("debian/$package.$filename.".buildarch(),
 365                  "debian/$package.$filename");
 366         if ($package eq $dh{MAINPACKAGE}) {
 367                 push @try, "debian/$filename";
 368         }
 369
 370         foreach my $file (@try) {
 371                 if (-f $file &&
 372                     (! $dh{IGNORE} || ! exists $dh{IGNORE}->{$file})) {
 373                         return $file;
 374                 }
 375
 376         }
 377
 378         return "";
 379
 380 }
 381
 382 # Pass it a name of a binary package, it returns the name to prefix to files
 383 # in debian/ for this package.
 384 sub pkgext {
 385         my $package=shift;
 386
 387         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 388                 return "";
 389         }
 390         return "$package.";
 391 }
 392
 393 # Pass it the name of a binary package, it returns the name to install
 394 # files by in eg, etc. Normally this is the same, but --name can override
 395 # it.
 396 sub pkgfilename {
 397         my $package=shift;
 398
 399         if (defined $dh{NAME}) {
 400                 return $dh{NAME};
 401         }
 402         return $package;
 403 }
 404
 405 # Returns 1 if the package is a native debian package, null otherwise.
 406 # As a side effect, sets $dh{VERSION} to the version of this package.
 407 {
 408         # Caches return code so it only needs to run dpkg-parsechangelog once.
 409         my %isnative_cache;
 410
 411         sub isnative {
 412                 my $package=shift;
 413
 414                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 415
 416                 # Make sure we look at the correct changelog.
 417                 my $isnative_changelog=pkgfile($package,"changelog");
 418                 if (! $isnative_changelog) {
 419                         $isnative_changelog="debian/changelog";
 420                 }
 421                 # Get the package version.
 422                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 423                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 424                 # Did the changelog parse fail?
 425                 if (! defined $dh{VERSION}) {
 426                         error("changelog parse failure");
 427                 }
 428
 429                 # Is this a native Debian package?
 430                 if ($dh{VERSION}=~m/.*-/) {
 431                         return $isnative_cache{$package}=0;
 432                 }
 433                 else {
 434                         return $isnative_cache{$package}=1;
 435                 }
 436         }
 437 }
 438
 439 # Automatically add a shell script snippet to a debian script.
 440 # Only works if the script has #DEBHELPER# in it.
 441 #
 442 # Parameters:
 443 # 1: package
 444 # 2: script to add to
 445 # 3: filename of snippet
 446 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 447 sub autoscript {
 448         my $package=shift;
 449         my $script=shift;
 450         my $filename=shift;
 451         my $sed=shift || "";
 452
 453         # This is the file we will modify.
 454         my $outfile="debian/".pkgext($package)."$script.debhelper";
 455
 456         # Figure out what shell script snippet to use.
 457         my $infile;
 458         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 459             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 460                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 461         }
 462         else {
 463                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 464                         $infile="/usr/share/debhelper/autoscripts/$filename";
 465                 }
 466                 else {
 467                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 468                 }
 469         }
 470
 471         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 472            && !compat(5)) {
 473                 # Add fragments to top so they run in reverse order when removing.
 474                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 475                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 476                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 477                 complex_doit("cat $outfile >> $outfile.new");
 478                 complex_doit("mv $outfile.new $outfile");
 479         }
 480         else {
 481                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 482                 complex_doit("sed \"$sed\" $infile >> $outfile");
 483                 complex_doit("echo '# End automatically added section' >> $outfile");
 484         }
 485 }
 486
 487 # Removes a whole substvar line.
 488 sub delsubstvar {
 489         my $package=shift;
 490         my $substvar=shift;
 491
 492         my $ext=pkgext($package);
 493         my $substvarfile="debian/${ext}substvars";
 494
 495         if (-e $substvarfile) {
 496                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 497                 doit("mv", "$substvarfile.new","$substvarfile");
 498         }
 499 }
 500
 501 # Adds a dependency on some package to the specified
 502 # substvar in a package's substvar's file.
 503 sub addsubstvar {
 504         my $package=shift;
 505         my $substvar=shift;
 506         my $deppackage=shift;
 507         my $verinfo=shift;
 508         my $remove=shift;
 509
 510         my $ext=pkgext($package);
 511         my $substvarfile="debian/${ext}substvars";
 512         my $str=$deppackage;
 513         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 514
 515         # Figure out what the line will look like, based on what's there
 516         # now, and what we're to add or remove.
 517         my $line="";
 518         if (-e $substvarfile) {
 519                 my %items;
 520                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 521                 while (<SUBSTVARS_IN>) {
 522                         chomp;
 523                         if (/^\Q$substvar\E=(.*)/) {
 524                                 %items = map { $_ => 1} split(", ", $1);
 525
 526                                 last;
 527                         }
 528                 }
 529                 close SUBSTVARS_IN;
 530                 if (! $remove) {
 531                         $items{$str}=1;
 532                 }
 533                 else {
 534                         delete $items{$str};
 535                 }
 536                 $line=join(", ", sort keys %items);
 537         }
 538         elsif (! $remove) {
 539                 $line=$str;
 540         }
 541
 542         if (length $line) {
 543                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 544                  doit("mv", "$substvarfile.new", $substvarfile);
 545         }
 546         else {
 547                 delsubstvar($package,$substvar);
 548         }
 549 }
 550
 551 # Reads in the specified file, one line at a time. splits on words,
 552 # and returns an array of arrays of the contents.
 553 # If a value is passed in as the second parameter, then glob
 554 # expansion is done in the directory specified by the parameter ("." is
 555 # frequently a good choice).
 556 sub filedoublearray {
 557         my $file=shift;
 558         my $globdir=shift;
 559
 560         my @ret;
 561         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 562         while (<DH_FARRAY_IN>) {
 563                 chomp;
 564                 # Only ignore comments and empty lines in v5 mode.
 565                 if (! compat(4)) {
 566                         next if /^#/ || /^$/;
 567                 }
 568                 my @line;
 569                 # Only do glob expansion in v3 mode.
 570                 #
 571                 # The tricky bit is that the glob expansion is done
 572                 # as if we were in the specified directory, so the
 573                 # filenames that come out are relative to it.
 574                 if (defined $globdir && ! compat(2)) {
 575                         for (map { glob "$globdir/$_" } split) {
 576                                 s#^$globdir/##;
 577                                 push @line, $_;
 578                         }
 579                 }
 580                 else {
 581                         @line = split;
 582                 }
 583                 push @ret, [@line];
 584         }
 585         close DH_FARRAY_IN;
 586
 587         return @ret;
 588 }
 589
 590 # Reads in the specified file, one word at a time, and returns an array of
 591 # the result. Can do globbing as does filedoublearray.
 592 sub filearray {
 593         return map { @$_ } filedoublearray(@_);
 594 }
 595
 596 # Passed a filename, returns true if -X says that file should be excluded.
 597 sub excludefile {
 598         my $filename = shift;
 599         foreach my $f (@{$dh{EXCLUDE}}) {
 600                 return 1 if $filename =~ /\Q$f\E/;
 601         }
 602         return 0;
 603 }
 604
 605 sub dpkg_architecture_value {
 606         my $var = shift;
 607         my $value=`dpkg-architecture -q$var 2>/dev/null` || error("dpkg-architecture failed");
 608         chomp $value;
 609         return $value;
 610 }
 611
 612 # Returns the build architecture. (Memoized)
 613 {
 614         my $arch;
 615
 616         sub buildarch {
 617                 if (!defined $arch) {
 618                     $arch=dpkg_architecture_value('DEB_HOST_ARCH');
 619                 }
 620                 return $arch;
 621         }
 622 }
 623
 624 # Passed an arch and a list of arches to match against, returns true if matched
 625 sub samearch {
 626         my $arch=shift;
 627         my @archlist=split(/\s+/,shift);
 628
 629         foreach my $a (@archlist) {
 630                 system("dpkg-architecture", "-a$arch", "-i$a") == 0 && return 1;
 631         }
 632
 633         return 0;
 634 }
 635
 636 # Returns source package name
 637 sub sourcepackage {
 638         open (CONTROL, 'debian/control') ||
 639             error("cannot read debian/control: $!\n");
 640         while (<CONTROL>) {
 641                 chomp;
 642                 s/\s+$//;
 643                 if (/^Source:\s*(.*)/) {
 644                         close CONTROL;
 645                         return $1;
 646                 }
 647         }
 648
 649         close CONTROL;
 650         error("could not find Source: line in control file.");
 651 }
 652
 653 # Returns a list of packages in the control file.
 654 # Must pass "arch" or "indep" or "same" to specify arch-dependant or
 655 # -independant or same arch packages. If nothing is specified, returns all
 656 # packages.
 657 # As a side effect, populates %package_arches and %package_types with the
 658 # types of all packages (not only those returned).
 659 my (%package_types, %package_arches);
 660 sub getpackages {
 661         my $type=shift;
 662
 663         %package_types=();
 664         %package_arches=();
 665
 666         $type="" if ! defined $type;
 667
 668         # Look up the build arch if we need to.
 669         my $buildarch='';
 670         if ($type eq 'same') {
 671                 $buildarch=buildarch();
 672         }
 673
 674         my $package="";
 675         my $arch="";
 676         my $package_type;
 677         my @list=();
 678         my %seen;
 679         open (CONTROL, 'debian/control') ||
 680                 error("cannot read debian/control: $!\n");
 681         while (<CONTROL>) {
 682                 chomp;
 683                 s/\s+$//;
 684                 if (/^Package:\s*(.*)/) {
 685                         $package=$1;
 686                         # Detect duplicate package names in the same control file.
 687                         if (! $seen{$package}) {
 688                                 $seen{$package}=1;
 689                         }
 690                         else {
 691                                 error("debian/control has a duplicate entry for $package");
 692                         }
 693                         $package_type="deb";
 694                 }
 695                 if (/^Architecture:\s*(.*)/) {
 696                         $arch=$1;
 697                 }
 698                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 699                         $package_type=$1;
 700                 }
 701
 702                 if (!$_ or eof) { # end of stanza.
 703                         if ($package) {
 704                                 $package_types{$package}=$package_type;
 705                                 $package_arches{$package}=$arch;
 706                         }
 707                         if ($package &&
 708                             (($type eq 'indep' && $arch eq 'all') ||
 709                              ($type eq 'arch' && $arch ne 'all') ||
 710                              ($type eq 'same' && ($arch eq 'any' || samearch($buildarch, $arch))) ||
 711                              ! $type)) {
 712                                 push @list, $package;
 713                                 $package="";
 714                                 $arch="";
 715                         }
 716                 }
 717         }
 718         close CONTROL;
 719
 720         return @list;
 721 }
 722
 723 # Returns the arch a package will build for.
 724 sub package_arch {
 725         my $package=shift;
 726
 727         if (! exists $package_arches{$package}) {
 728                 warning "package $package is not in control info";
 729                 return buildarch();
 730         }
 731         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 732 }
 733
 734 # Return true if a given package is really a udeb.
 735 sub is_udeb {
 736         my $package=shift;
 737
 738         if (! exists $package_types{$package}) {
 739                 warning "package $package is not in control info";
 740                 return 0;
 741         }
 742         return $package_types{$package} eq 'udeb';
 743 }
 744
 745 # Generates the filename that is used for a udeb package.
 746 sub udeb_filename {
 747         my $package=shift;
 748
 749         my $filearch=package_arch($package);
 750         isnative($package); # side effect
 751         my $version=$dh{VERSION};
 752         $version=~s/^[0-9]+://; # strip any epoch
 753         return "${package}_${version}_$filearch.udeb";
 754 }
 755
 756 # Handles #DEBHELPER# substitution in a script; also can generate a new
 757 # script from scratch if none exists but there is a .debhelper file for it.
 758 sub debhelper_script_subst {
 759         my $package=shift;
 760         my $script=shift;
 761
 762         my $tmp=tmpdir($package);
 763         my $ext=pkgext($package);
 764         my $file=pkgfile($package,$script);
 765
 766         if ($file ne '') {
 767                 if (-f "debian/$ext$script.debhelper") {
 768                         # Add this into the script, where it has #DEBHELPER#
 769                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 770                 }
 771                 else {
 772                         # Just get rid of any #DEBHELPER# in the script.
 773                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 774                 }
 775                 doit("chown","0:0","$tmp/DEBIAN/$script");
 776                 doit("chmod",755,"$tmp/DEBIAN/$script");
 777         }
 778         elsif ( -f "debian/$ext$script.debhelper" ) {
 779                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 780                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 781                 doit("chown","0:0","$tmp/DEBIAN/$script");
 782                 doit("chmod",755,"$tmp/DEBIAN/$script");
 783         }
 784 }
 785
 786 1