Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2008.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell
  18             &inhibit_log &load_log &write_log &commit_override_log
  19             &dpkg_architecture_value &sourcepackage
  20             &is_make_jobserver_unavailable &clean_jobserver_makeflags
  21             &cross_command &set_buildflags);
  22
  23 my $max_compat=9;
  24
  25 sub init {
  26         my %params=@_;
  27
  28         # Check to see if an option line starts with a dash,
  29         # or DH_OPTIONS is set.
  30         # If so, we need to pass this off to the resource intensive
  31         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  32         if ((defined $ENV{DH_OPTIONS} && length $ENV{DH_OPTIONS}) ||
  33             (defined $ENV{DH_INTERNAL_OPTIONS} && length $ENV{DH_INTERNAL_OPTIONS}) ||
  34             grep /^-/, @ARGV) {
  35                 eval "use Debian::Debhelper::Dh_Getopt";
  36                 error($@) if $@;
  37                 Debian::Debhelper::Dh_Getopt::parseopts(%params);
  38         }
  39
  40         # Another way to set excludes.
  41         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  42                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  43         }
  44
  45         # Generate EXCLUDE_FIND.
  46         if ($dh{EXCLUDE}) {
  47                 $dh{EXCLUDE_FIND}='';
  48                 foreach (@{$dh{EXCLUDE}}) {
  49                         my $x=$_;
  50                         $x=escape_shell($x);
  51                         $x=~s/\./\\\\./g;
  52                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  53                 }
  54                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  55         }
  56
  57         # Check to see if DH_VERBOSE environment variable was set, if so,
  58         # make sure verbose is on.
  59         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  60                 $dh{VERBOSE}=1;
  61         }
  62
  63         # Check to see if DH_NO_ACT environment variable was set, if so,
  64         # make sure no act mode is on.
  65         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  66                 $dh{NO_ACT}=1;
  67         }
  68
  69         # Get the name of the main binary package (first one listed in
  70         # debian/control). Only if the main package was not set on the
  71         # command line.
  72         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  73                 my @allpackages=getpackages();
  74                 $dh{MAINPACKAGE}=$allpackages[0];
  75         }
  76
  77         # Check if packages to build have been specified, if not, fall back to
  78         # the default, building all relevant packages.
  79         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  80                 push @{$dh{DOPACKAGES}}, getpackages('both');
  81         }
  82
  83         # Check to see if -P was specified. If so, we can only act on a single
  84         # package.
  85         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  86                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  87         }
  88
  89         # Figure out which package is the first one we were instructed to build.
  90         # This package gets special treatement: files and directories specified on
  91         # the command line may affect it.
  92         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
  93
  94         # If no error handling function was specified, just propigate
  95         # errors out.
  96         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
  97                 $dh{ERROR_HANDLER}='exit \$?';
  98         }
  99 }
 100
 101 # Run at exit. Add the command to the log files for the packages it acted
 102 # on, if it's exiting successfully.
 103 my $write_log=1;
 104 sub END {
 105         if ($? == 0 && $write_log) {
 106                 write_log(basename($0), @{$dh{DOPACKAGES}});
 107         }
 108 }
 109
 110 sub logfile {
 111         my $package=shift;
 112         my $ext=pkgext($package);
 113         return "debian/${ext}debhelper.log"
 114 }
 115
 116 sub add_override {
 117         my $line=shift;
 118         $line="override_$ENV{DH_INTERNAL_OVERRIDE} $line"
 119                 if defined $ENV{DH_INTERNAL_OVERRIDE};
 120         return $line;
 121 }
 122
 123 sub remove_override {
 124         my $line=shift;
 125         $line=~s/^\Qoverride_$ENV{DH_INTERNAL_OVERRIDE}\E\s+//
 126                 if defined $ENV{DH_INTERNAL_OVERRIDE};
 127         return $line;
 128 }
 129
 130 sub load_log {
 131         my ($package, $db)=@_;
 132
 133         my @log;
 134         open(LOG, "<", logfile($package)) || return;
 135         while (<LOG>) {
 136                 chomp;
 137                 my $command=remove_override($_);
 138                 push @log, $command;
 139                 $db->{$package}{$command}=1 if defined $db;
 140         }
 141         close LOG;
 142         return @log;
 143 }
 144
 145 sub write_log {
 146         my $cmd=shift;
 147         my @packages=@_;
 148
 149         foreach my $package (@packages) {
 150                 my $log=logfile($package);
 151                 open(LOG, ">>", $log) || error("failed to write to ${log}: $!");
 152                 print LOG add_override($cmd)."\n";
 153                 close LOG;
 154         }
 155 }
 156
 157 sub commit_override_log {
 158         my @packages=@_;
 159
 160         foreach my $package (@packages) {
 161                 my @log=map { remove_override($_) } load_log($package);
 162                 my $log=logfile($package);
 163                 open(LOG, ">", $log) || error("failed to write to ${log}: $!");
 164                 print LOG $_."\n" foreach @log;
 165                 close LOG;
 166         }
 167 }
 168
 169 sub inhibit_log {
 170         $write_log=0;
 171 }
 172
 173 # Pass it an array containing the arguments of a shell command like would
 174 # be run by exec(). It turns that into a line like you might enter at the
 175 # shell, escaping metacharacters and quoting arguments that contain spaces.
 176 sub escape_shell {
 177         my @args=@_;
 178         my $line="";
 179         my @ret;
 180         foreach my $word (@args) {
 181                 if ($word=~/\s/) {
 182                         # Escape only a few things since it will be quoted.
 183                         # Note we use double quotes because you cannot
 184                         # escape ' in single quotes, while " can be escaped
 185                         # in double.
 186                         # This does make -V"foo bar" turn into "-Vfoo bar",
 187                         # but that will be parsed identically by the shell
 188                         # anyway..
 189                         $word=~s/([\n`\$"\\])/\\$1/g;
 190                         push @ret, "\"$word\"";
 191                 }
 192                 else {
 193                         # This list is from _Unix in a Nutshell_. (except '#')
 194                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 195                         push @ret,$word;
 196                 }
 197         }
 198         return join(' ', @ret);
 199 }
 200
 201 # Run a command, and display the command to stdout if verbose mode is on.
 202 # All commands that modifiy files in $TMP should be ran via this
 203 # function.
 204 #
 205 # Note that this cannot handle complex commands, especially anything
 206 # involving redirection. Use complex_doit instead.
 207 sub doit {
 208         verbose_print(escape_shell(@_));
 209
 210         if (! $dh{NO_ACT}) {
 211                 system(@_) == 0 || _error_exitcode(join(" ", @_));
 212         }
 213 }
 214
 215 # Run a command and display the command to stdout if verbose mode is on.
 216 # Use doit() if you can, instead of this function, because this function
 217 # forks a shell. However, this function can handle more complicated stuff
 218 # like redirection.
 219 sub complex_doit {
 220         verbose_print(join(" ",@_));
 221
 222         if (! $dh{NO_ACT}) {
 223                 # The join makes system get a scalar so it forks off a shell.
 224                 system(join(" ", @_)) == 0 || _error_exitcode(join(" ", @_))
 225         }
 226 }
 227
 228 sub _error_exitcode {
 229         my $command=shift;
 230         if ($? == -1) {
 231                 error("$command failed to to execute: $!");
 232         }
 233         elsif ($? & 127) {
 234                 error("$command died with signal ".($? & 127));
 235         }
 236         else {
 237                 error("$command returned exit code ".($? >> 8));
 238         }
 239 }
 240
 241 # Run a command that may have a huge number of arguments, like xargs does.
 242 # Pass in a reference to an array containing the arguments, and then other
 243 # parameters that are the command and any parameters that should be passed to
 244 # it each time.
 245 sub xargs {
 246         my $args=shift;
 247
 248         # The kernel can accept command lines up to 20k worth of characters.
 249         my $command_max=20000; # LINUX SPECIFIC!!
 250                         # (And obsolete; it's bigger now.)
 251                         # I could use POSIX::ARG_MAX, but that would be slow.
 252
 253         # Figure out length of static portion of command.
 254         my $static_length=0;
 255         foreach (@_) {
 256                 $static_length+=length($_)+1;
 257         }
 258
 259         my @collect=();
 260         my $length=$static_length;
 261         foreach (@$args) {
 262                 if (length($_) + 1 + $static_length > $command_max) {
 263                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 264                 }
 265                 $length+=length($_) + 1;
 266                 if ($length < $command_max) {
 267                         push @collect, $_;
 268                 }
 269                 else {
 270                         doit(@_,@collect) if $#collect > -1;
 271                         @collect=($_);
 272                         $length=$static_length + length($_) + 1;
 273                 }
 274         }
 275         doit(@_,@collect) if $#collect > -1;
 276 }
 277
 278 # Print something if the verbose flag is on.
 279 sub verbose_print {
 280         my $message=shift;
 281
 282         if ($dh{VERBOSE}) {
 283                 print "\t$message\n";
 284         }
 285 }
 286
 287 # Output an error message and die (can be caught).
 288 sub error {
 289         my $message=shift;
 290
 291         die basename($0).": $message\n";
 292 }
 293
 294 # Output a warning.
 295 sub warning {
 296         my $message=shift;
 297
 298         print STDERR basename($0).": $message\n";
 299 }
 300
 301 # Returns the basename of the argument passed to it.
 302 sub basename {
 303         my $fn=shift;
 304
 305         $fn=~s/\/$//g; # ignore trailing slashes
 306         $fn=~s:^.*/(.*?)$:$1:;
 307         return $fn;
 308 }
 309
 310 # Returns the directory name of the argument passed to it.
 311 sub dirname {
 312         my $fn=shift;
 313
 314         $fn=~s/\/$//g; # ignore trailing slashes
 315         $fn=~s:^(.*)/.*?$:$1:;
 316         return $fn;
 317 }
 318
 319 # Pass in a number, will return true iff the current compatibility level
 320 # is less than or equal to that number.
 321 {
 322         my $warned_compat=0;
 323         my $c;
 324
 325         sub compat {
 326                 my $num=shift;
 327
 328                 if (! defined $c) {
 329                         $c=1;
 330                         if (defined $ENV{DH_COMPAT}) {
 331                                 $c=$ENV{DH_COMPAT};
 332                         }
 333                         elsif (-e 'debian/compat') {
 334                                 # Try the file..
 335                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 336                                 my $l=<COMPAT_IN>;
 337                                 close COMPAT_IN;
 338                                 if (! defined $l || ! length $l) {
 339                                         warning("debian/compat is empty, assuming level $c");
 340                                 }
 341                                 else {
 342                                         chomp $l;
 343                                         $c=$l;
 344                                 }
 345                         }
 346                 }
 347
 348                 if ($c <= 4 && ! $warned_compat) {
 349                         warning("Compatibility levels before 5 are deprecated.");
 350                         $warned_compat=1;
 351                 }
 352
 353                 if ($c > $max_compat) {
 354                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 355                 }
 356
 357                 return ($c <= $num);
 358         }
 359 }
 360
 361 # Pass it a name of a binary package, it returns the name of the tmp dir to
 362 # use, for that package.
 363 sub tmpdir {
 364         my $package=shift;
 365
 366         if ($dh{TMPDIR}) {
 367                 return $dh{TMPDIR};
 368         }
 369         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 370                 # This is for back-compatibility with the debian/tmp tradition.
 371                 return "debian/tmp";
 372         }
 373         else {
 374                 return "debian/$package";
 375         }
 376 }
 377
 378 # Pass this the name of a binary package, and the name of the file wanted
 379 # for the package, and it will return the actual existing filename to use.
 380 #
 381 # It tries several filenames:
 382 #   * debian/package.filename.buildarch
 383 #   * debian/package.filename.buildos
 384 #   * debian/package.filename
 385 #   * debian/filename (if the package is the main package)
 386 # If --name was specified then the files
 387 # must have the name after the package name:
 388 #   * debian/package.name.filename.buildarch
 389 #   * debian/package.name.filename.buildos
 390 #   * debian/package.name.filename
 391 #   * debian/name.filename (if the package is the main package)
 392 sub pkgfile {
 393         my $package=shift;
 394         my $filename=shift;
 395
 396         if (defined $dh{NAME}) {
 397                 $filename="$dh{NAME}.$filename";
 398         }
 399
 400         # First, check for files ending in buildarch and buildos.
 401         my $match;
 402         foreach my $file (glob("debian/$package.$filename.*")) {
 403                 next if ! -f $file;
 404                 next if $dh{IGNORE} && exists $dh{IGNORE}->{$file};
 405                 if ($file eq "debian/$package.$filename.".buildarch()) {
 406                         $match=$file;
 407                         # buildarch files are used in preference to buildos files.
 408                         last;
 409                 }
 410                 elsif ($file eq "debian/$package.$filename.".buildos()) {
 411                         $match=$file;
 412                 }
 413         }
 414         return $match if defined $match;
 415
 416         my @try=("debian/$package.$filename");
 417         if ($package eq $dh{MAINPACKAGE}) {
 418                 push @try, "debian/$filename";
 419         }
 420
 421         foreach my $file (@try) {
 422                 if (-f $file &&
 423                     (! $dh{IGNORE} || ! exists $dh{IGNORE}->{$file})) {
 424                         return $file;
 425                 }
 426
 427         }
 428
 429         return "";
 430
 431 }
 432
 433 # Pass it a name of a binary package, it returns the name to prefix to files
 434 # in debian/ for this package.
 435 sub pkgext {
 436         my $package=shift;
 437
 438         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 439                 return "";
 440         }
 441         return "$package.";
 442 }
 443
 444 # Pass it the name of a binary package, it returns the name to install
 445 # files by in eg, etc. Normally this is the same, but --name can override
 446 # it.
 447 sub pkgfilename {
 448         my $package=shift;
 449
 450         if (defined $dh{NAME}) {
 451                 return $dh{NAME};
 452         }
 453         return $package;
 454 }
 455
 456 # Returns 1 if the package is a native debian package, null otherwise.
 457 # As a side effect, sets $dh{VERSION} to the version of this package.
 458 {
 459         # Caches return code so it only needs to run dpkg-parsechangelog once.
 460         my %isnative_cache;
 461
 462         sub isnative {
 463                 my $package=shift;
 464
 465                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 466
 467                 # Make sure we look at the correct changelog.
 468                 my $isnative_changelog=pkgfile($package,"changelog");
 469                 if (! $isnative_changelog) {
 470                         $isnative_changelog="debian/changelog";
 471                 }
 472                 # Get the package version.
 473                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 474                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 475                 # Did the changelog parse fail?
 476                 if (! defined $dh{VERSION}) {
 477                         error("changelog parse failure");
 478                 }
 479
 480                 # Is this a native Debian package?
 481                 if ($dh{VERSION}=~m/.*-/) {
 482                         return $isnative_cache{$package}=0;
 483                 }
 484                 else {
 485                         return $isnative_cache{$package}=1;
 486                 }
 487         }
 488 }
 489
 490 # Automatically add a shell script snippet to a debian script.
 491 # Only works if the script has #DEBHELPER# in it.
 492 #
 493 # Parameters:
 494 # 1: package
 495 # 2: script to add to
 496 # 3: filename of snippet
 497 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 498 sub autoscript {
 499         my $package=shift;
 500         my $script=shift;
 501         my $filename=shift;
 502         my $sed=shift || "";
 503
 504         # This is the file we will modify.
 505         my $outfile="debian/".pkgext($package)."$script.debhelper";
 506
 507         # Figure out what shell script snippet to use.
 508         my $infile;
 509         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 510             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 511                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 512         }
 513         else {
 514                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 515                         $infile="/usr/share/debhelper/autoscripts/$filename";
 516                 }
 517                 else {
 518                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 519                 }
 520         }
 521
 522         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 523            && !compat(5)) {
 524                 # Add fragments to top so they run in reverse order when removing.
 525                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 526                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 527                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 528                 complex_doit("cat $outfile >> $outfile.new");
 529                 complex_doit("mv $outfile.new $outfile");
 530         }
 531         else {
 532                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 533                 complex_doit("sed \"$sed\" $infile >> $outfile");
 534                 complex_doit("echo '# End automatically added section' >> $outfile");
 535         }
 536 }
 537
 538 # Removes a whole substvar line.
 539 sub delsubstvar {
 540         my $package=shift;
 541         my $substvar=shift;
 542
 543         my $ext=pkgext($package);
 544         my $substvarfile="debian/${ext}substvars";
 545
 546         if (-e $substvarfile) {
 547                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 548                 doit("mv", "$substvarfile.new","$substvarfile");
 549         }
 550 }
 551
 552 # Adds a dependency on some package to the specified
 553 # substvar in a package's substvar's file.
 554 sub addsubstvar {
 555         my $package=shift;
 556         my $substvar=shift;
 557         my $deppackage=shift;
 558         my $verinfo=shift;
 559         my $remove=shift;
 560
 561         my $ext=pkgext($package);
 562         my $substvarfile="debian/${ext}substvars";
 563         my $str=$deppackage;
 564         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 565
 566         # Figure out what the line will look like, based on what's there
 567         # now, and what we're to add or remove.
 568         my $line="";
 569         if (-e $substvarfile) {
 570                 my %items;
 571                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 572                 while (<SUBSTVARS_IN>) {
 573                         chomp;
 574                         if (/^\Q$substvar\E=(.*)/) {
 575                                 %items = map { $_ => 1} split(", ", $1);
 576
 577                                 last;
 578                         }
 579                 }
 580                 close SUBSTVARS_IN;
 581                 if (! $remove) {
 582                         $items{$str}=1;
 583                 }
 584                 else {
 585                         delete $items{$str};
 586                 }
 587                 $line=join(", ", sort keys %items);
 588         }
 589         elsif (! $remove) {
 590                 $line=$str;
 591         }
 592
 593         if (length $line) {
 594                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 595                  doit("mv", "$substvarfile.new", $substvarfile);
 596         }
 597         else {
 598                 delsubstvar($package,$substvar);
 599         }
 600 }
 601
 602 # Reads in the specified file, one line at a time. splits on words,
 603 # and returns an array of arrays of the contents.
 604 # If a value is passed in as the second parameter, then glob
 605 # expansion is done in the directory specified by the parameter ("." is
 606 # frequently a good choice).
 607 sub filedoublearray {
 608         my $file=shift;
 609         my $globdir=shift;
 610
 611         my @ret;
 612         open (DH_FARRAY_IN, $file) || error("cannot read $file: $!");
 613         while (<DH_FARRAY_IN>) {
 614                 chomp;
 615                 # Only ignore comments and empty lines in v5 mode.
 616                 if (! compat(4)) {
 617                         next if /^#/ || /^$/;
 618                 }
 619                 my @line;
 620                 # Only do glob expansion in v3 mode.
 621                 #
 622                 # The tricky bit is that the glob expansion is done
 623                 # as if we were in the specified directory, so the
 624                 # filenames that come out are relative to it.
 625                 if (defined $globdir && ! compat(2)) {
 626                         foreach (map { glob "$globdir/$_" } split) {
 627                                 s#^$globdir/##;
 628                                 push @line, $_;
 629                         }
 630                 }
 631                 else {
 632                         @line = split;
 633                 }
 634                 push @ret, [@line];
 635         }
 636         close DH_FARRAY_IN;
 637
 638         return @ret;
 639 }
 640
 641 # Reads in the specified file, one word at a time, and returns an array of
 642 # the result. Can do globbing as does filedoublearray.
 643 sub filearray {
 644         return map { @$_ } filedoublearray(@_);
 645 }
 646
 647 # Passed a filename, returns true if -X says that file should be excluded.
 648 sub excludefile {
 649         my $filename = shift;
 650         foreach my $f (@{$dh{EXCLUDE}}) {
 651                 return 1 if $filename =~ /\Q$f\E/;
 652         }
 653         return 0;
 654 }
 655
 656 {
 657         my %dpkg_arch_output;
 658         sub dpkg_architecture_value {
 659                 my $var = shift;
 660                 if (! exists($dpkg_arch_output{$var})) {
 661                         local $_;
 662                         open(PIPE, '-|', 'dpkg-architecture')
 663                                 or error("dpkg-architecture failed");
 664                         while (<PIPE>) {
 665                                 chomp;
 666                                 my ($k, $v) = split(/=/, $_, 2);
 667                                 $dpkg_arch_output{$k} = $v;
 668                         }
 669                         close(PIPE);
 670                 }
 671                 return $dpkg_arch_output{$var};
 672         }
 673 }
 674
 675 # Returns the build architecture.
 676 sub buildarch {
 677         dpkg_architecture_value('DEB_HOST_ARCH');
 678 }
 679
 680 # Returns the build OS.
 681 sub buildos {
 682         dpkg_architecture_value("DEB_HOST_ARCH_OS");
 683 }
 684
 685 # Passed an arch and a list of arches to match against, returns true if matched
 686 {
 687         my %knownsame;
 688
 689         sub samearch {
 690                 my $arch=shift;
 691                 my @archlist=split(/\s+/,shift);
 692
 693                 foreach my $a (@archlist) {
 694                         # Avoid expensive dpkg-architecture call to compare
 695                         # with a simple architecture name. "linux-any" and
 696                         # other architecture wildcards are (currently)
 697                         # always hypenated.
 698                         if ($a !~ /-/) {
 699                                 return 1 if $arch eq $a;
 700                         }
 701                         elsif (exists $knownsame{$arch}{$a}) {
 702                                 return 1 if $knownsame{$arch}{$a};
 703                         }
 704                         elsif (system("dpkg-architecture", "-a$arch", "-i$a") == 0) {
 705                                 return $knownsame{$arch}{$a}=1;
 706                         }
 707                         else {
 708                                 $knownsame{$arch}{$a}=0;
 709                         }
 710                 }
 711
 712                 return 0;
 713         }
 714 }
 715
 716 # Returns source package name
 717 sub sourcepackage {
 718         open (CONTROL, 'debian/control') ||
 719             error("cannot read debian/control: $!\n");
 720         while (<CONTROL>) {
 721                 chomp;
 722                 s/\s+$//;
 723                 if (/^Source:\s*(.*)/) {
 724                         close CONTROL;
 725                         return $1;
 726                 }
 727         }
 728
 729         close CONTROL;
 730         error("could not find Source: line in control file.");
 731 }
 732
 733 # Returns a list of packages in the control file.
 734 # Pass "arch" or "indep" to specify arch-dependant (that will be built
 735 # for the system's arch) or independant. If nothing is specified,
 736 # returns all packages. Also, "both" returns the union of "arch" and "indep"
 737 # packages.
 738 # As a side effect, populates %package_arches and %package_types with the
 739 # types of all packages (not only those returned).
 740 my (%package_types, %package_arches);
 741 sub getpackages {
 742         my $type=shift;
 743
 744         %package_types=();
 745         %package_arches=();
 746
 747         $type="" if ! defined $type;
 748
 749         my $package="";
 750         my $arch="";
 751         my $package_type;
 752         my @list=();
 753         my %seen;
 754         open (CONTROL, 'debian/control') ||
 755                 error("cannot read debian/control: $!\n");
 756         while (<CONTROL>) {
 757                 chomp;
 758                 s/\s+$//;
 759                 if (/^Package:\s*(.*)/) {
 760                         $package=$1;
 761                         # Detect duplicate package names in the same control file.
 762                         if (! $seen{$package}) {
 763                                 $seen{$package}=1;
 764                         }
 765                         else {
 766                                 error("debian/control has a duplicate entry for $package");
 767                         }
 768                         $package_type="deb";
 769                 }
 770                 if (/^Architecture:\s*(.*)/) {
 771                         $arch=$1;
 772                 }
 773                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 774                         $package_type=$1;
 775                 }
 776
 777                 if (!$_ or eof) { # end of stanza.
 778                         if ($package) {
 779                                 $package_types{$package}=$package_type;
 780                                 $package_arches{$package}=$arch;
 781                         }
 782
 783                         if ($package &&
 784                             ((($type eq 'indep' || $type eq 'both') && $arch eq 'all') ||
 785                              (($type eq 'arch'  || $type eq 'both') && ($arch eq 'any' ||
 786                                              ($arch ne 'all' &&
 787                                               samearch(buildarch(), $arch)))) ||
 788                              ! $type)) {
 789                                 push @list, $package;
 790                                 $package="";
 791                                 $arch="";
 792                         }
 793                 }
 794         }
 795         close CONTROL;
 796
 797         return @list;
 798 }
 799
 800 # Returns the arch a package will build for.
 801 sub package_arch {
 802         my $package=shift;
 803
 804         if (! exists $package_arches{$package}) {
 805                 warning "package $package is not in control info";
 806                 return buildarch();
 807         }
 808         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 809 }
 810
 811 # Return true if a given package is really a udeb.
 812 sub is_udeb {
 813         my $package=shift;
 814
 815         if (! exists $package_types{$package}) {
 816                 warning "package $package is not in control info";
 817                 return 0;
 818         }
 819         return $package_types{$package} eq 'udeb';
 820 }
 821
 822 # Generates the filename that is used for a udeb package.
 823 sub udeb_filename {
 824         my $package=shift;
 825
 826         my $filearch=package_arch($package);
 827         isnative($package); # side effect
 828         my $version=$dh{VERSION};
 829         $version=~s/^[0-9]+://; # strip any epoch
 830         return "${package}_${version}_$filearch.udeb";
 831 }
 832
 833 # Handles #DEBHELPER# substitution in a script; also can generate a new
 834 # script from scratch if none exists but there is a .debhelper file for it.
 835 sub debhelper_script_subst {
 836         my $package=shift;
 837         my $script=shift;
 838
 839         my $tmp=tmpdir($package);
 840         my $ext=pkgext($package);
 841         my $file=pkgfile($package,$script);
 842
 843         if ($file ne '') {
 844                 if (-f "debian/$ext$script.debhelper") {
 845                         # Add this into the script, where it has #DEBHELPER#
 846                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 847                 }
 848                 else {
 849                         # Just get rid of any #DEBHELPER# in the script.
 850                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 851                 }
 852                 doit("chown","0:0","$tmp/DEBIAN/$script");
 853                 doit("chmod",755,"$tmp/DEBIAN/$script");
 854         }
 855         elsif ( -f "debian/$ext$script.debhelper" ) {
 856                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 857                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 858                 doit("chown","0:0","$tmp/DEBIAN/$script");
 859                 doit("chmod",755,"$tmp/DEBIAN/$script");
 860         }
 861 }
 862
 863 # Checks if make's jobserver is enabled via MAKEFLAGS, but
 864 # the FD used to communicate with it is actually not available.
 865 sub is_make_jobserver_unavailable {
 866         if (exists $ENV{MAKEFLAGS} &&
 867             $ENV{MAKEFLAGS} =~ /(?:^|\s)--jobserver-fds=(\d+)/) {
 868                 if (!open(my $in, "<&$1")) {
 869                         return 1; # unavailable
 870                 }
 871                 else {
 872                         close $in;
 873                         return 0; # available
 874                 }
 875         }
 876
 877         return; # no jobserver specified
 878 }
 879
 880 # Cleans out jobserver options from MAKEFLAGS.
 881 sub clean_jobserver_makeflags {
 882         if (exists $ENV{MAKEFLAGS}) {
 883                 if ($ENV{MAKEFLAGS} =~ /(?:^|\s)--jobserver-fds=(\d+)/) {
 884                         $ENV{MAKEFLAGS} =~ s/(?:^|\s)--jobserver-fds=\S+//g;
 885                         $ENV{MAKEFLAGS} =~ s/(?:^|\s)-j\b//g;
 886                 }
 887                 delete $ENV{MAKEFLAGS} if $ENV{MAKEFLAGS} =~ /^\s*$/;
 888         }
 889 }
 890
 891 # If cross-compiling, returns appropriate cross version of command.
 892 sub cross_command {
 893         my $command=shift;
 894         if (dpkg_architecture_value("DEB_BUILD_GNU_TYPE")
 895             ne dpkg_architecture_value("DEB_HOST_GNU_TYPE")) {
 896                 return dpkg_architecture_value("DEB_HOST_GNU_TYPE")."-$command";
 897         }
 898         else {
 899                 return $command;
 900         }
 901 }
 902
 903 # Sets environment variables from dpkg-buildflags. Avoids changing
 904 # any existing environment variables.
 905 sub set_buildflags {
 906         # optimisation
 907         return if $ENV{DH_INTERNAL_BUILDFLAGS};
 908         $ENV{DH_INTERNAL_BUILDFLAGS}=1;
 909
 910         eval "use Dpkg::BuildFlags";
 911         if ($@) {
 912                 warning "unable to load build flags: $@";
 913         }
 914
 915         my $buildflags = Dpkg::BuildFlags->new();
 916         $buildflags->load_config();
 917         foreach my $flag ($buildflags->list()) {
 918                 next unless $flag =~ /^[A-Z]/; # Skip flags starting with lowercase
 919                 if (! exists $ENV{$flag}) {
 920                         $ENV{$flag} = $buildflags->get($flag);
 921                 }
 922         }
 923 }
 924
 925 1