Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2008.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell
  18             &inhibit_log &load_log &write_log &dpkg_architecture_value
  19             &sourcepackage);
  20
  21 my $max_compat=7;
  22
  23 sub init {
  24         my %params=@_;
  25
  26         # Check to see if an option line starts with a dash,
  27         # or DH_OPTIONS is set.
  28         # If so, we need to pass this off to the resource intensive
  29         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  30         if ((defined $ENV{DH_OPTIONS} && length $ENV{DH_OPTIONS}) ||
  31             (defined $ENV{DH_INTERNAL_OPTIONS} && length $ENV{DH_INTERNAL_OPTIONS}) ||
  32             grep /^-/, @ARGV) {
  33                 eval "use Debian::Debhelper::Dh_Getopt";
  34                 error($@) if $@;
  35                 Debian::Debhelper::Dh_Getopt::parseopts($params{options});
  36         }
  37
  38         # Another way to set excludes.
  39         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  40                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  41         }
  42
  43         # Generate EXCLUDE_FIND.
  44         if ($dh{EXCLUDE}) {
  45                 $dh{EXCLUDE_FIND}='';
  46                 foreach (@{$dh{EXCLUDE}}) {
  47                         my $x=$_;
  48                         $x=escape_shell($x);
  49                         $x=~s/\./\\\\./g;
  50                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  51                 }
  52                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  53         }
  54
  55         # Check to see if DH_VERBOSE environment variable was set, if so,
  56         # make sure verbose is on.
  57         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  58                 $dh{VERBOSE}=1;
  59         }
  60
  61         # Check to see if DH_NO_ACT environment variable was set, if so,
  62         # make sure no act mode is on.
  63         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  64                 $dh{NO_ACT}=1;
  65         }
  66
  67         my @allpackages=getpackages();
  68         # Get the name of the main binary package (first one listed in
  69         # debian/control). Only if the main package was not set on the
  70         # command line.
  71         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  72                 $dh{MAINPACKAGE}=$allpackages[0];
  73         }
  74
  75         # Check if packages to build have been specified, if not, fall back to
  76         # the default, doing them all.
  77         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  78                 push @{$dh{DOPACKAGES}},@allpackages;
  79         }
  80
  81         # Check to see if -P was specified. If so, we can only act on a single
  82         # package.
  83         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  84                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  85         }
  86
  87         # Figure out which package is the first one we were instructed to build.
  88         # This package gets special treatement: files and directories specified on
  89         # the command line may affect it.
  90         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
  91
  92         # If no error handling function was specified, just propigate
  93         # errors out.
  94         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
  95                 $dh{ERROR_HANDLER}='exit \$?';
  96         }
  97 }
  98
  99 # Run at exit. Add the command to the log files for the packages it acted
 100 # on, if it's exiting successfully.
 101 my $write_log=1;
 102 sub END {
 103         if ($? == 0 && $write_log) {
 104                 write_log(basename($0), @{$dh{DOPACKAGES}});
 105         }
 106 }
 107
 108 sub load_log {
 109         my ($package, $db)=@_;
 110         my $ext=pkgext($package);
 111
 112         my @log;
 113         open(LOG, "<", "debian/${ext}debhelper.log") || return;
 114         while (<LOG>) {
 115                 chomp;
 116                 push @log, $_;
 117                 $db->{$package}{$_}=1 if defined $db;
 118         }
 119         close LOG;
 120         return @log;
 121 }
 122
 123 sub write_log {
 124         my $cmd=shift;
 125         my @packages=@_;
 126
 127         foreach my $package (@packages) {
 128                 my $ext=pkgext($package);
 129                 my $log="debian/${ext}debhelper.log";
 130                 open(LOG, ">>", $log) || error("failed to write to ${log}: $!");
 131                 print LOG $cmd."\n";
 132                 close LOG;
 133         }
 134 }
 135
 136 sub inhibit_log {
 137         $write_log=0;
 138 }
 139
 140 # Pass it an array containing the arguments of a shell command like would
 141 # be run by exec(). It turns that into a line like you might enter at the
 142 # shell, escaping metacharacters and quoting arguments that contain spaces.
 143 sub escape_shell {
 144         my @args=@_;
 145         my $line="";
 146         my @ret;
 147         foreach my $word (@args) {
 148                 if ($word=~/\s/) {
 149                         # Escape only a few things since it will be quoted.
 150                         # Note we use double quotes because you cannot
 151                         # escape ' in single quotes, while " can be escaped
 152                         # in double.
 153                         # This does make -V"foo bar" turn into "-Vfoo bar",
 154                         # but that will be parsed identically by the shell
 155                         # anyway..
 156                         $word=~s/([\n`\$"\\])/\\$1/g;
 157                         push @ret, "\"$word\"";
 158                 }
 159                 else {
 160                         # This list is from _Unix in a Nutshell_. (except '#')
 161                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 162                         push @ret,$word;
 163                 }
 164         }
 165         return join(' ', @ret);
 166 }
 167
 168 # Run a command, and display the command to stdout if verbose mode is on.
 169 # All commands that modifiy files in $TMP should be ran via this
 170 # function.
 171 #
 172 # Note that this cannot handle complex commands, especially anything
 173 # involving redirection. Use complex_doit instead.
 174 sub doit {
 175         verbose_print(escape_shell(@_));
 176
 177         if (! $dh{NO_ACT}) {
 178                 system(@_) == 0 || _error_exitcode(join(" ", @_));
 179         }
 180 }
 181
 182 # Run a command and display the command to stdout if verbose mode is on.
 183 # Use doit() if you can, instead of this function, because this function
 184 # forks a shell. However, this function can handle more complicated stuff
 185 # like redirection.
 186 sub complex_doit {
 187         verbose_print(join(" ",@_));
 188
 189         if (! $dh{NO_ACT}) {
 190                 # The join makes system get a scalar so it forks off a shell.
 191                 system(join(" ", @_)) == 0 || _error_exitcode(join(" ", @_))
 192         }
 193 }
 194
 195 sub _error_exitcode {
 196         my $command=shift;
 197         if ($? == -1) {
 198                 error("$command failed to to execute: $!");
 199         }
 200         elsif ($? & 127) {
 201                 error("$command died with signal ".($? & 127));
 202         }
 203         else {
 204                 error("$command returned exit code ".($? >> 8));
 205         }
 206 }
 207
 208 # Run a command that may have a huge number of arguments, like xargs does.
 209 # Pass in a reference to an array containing the arguments, and then other
 210 # parameters that are the command and any parameters that should be passed to
 211 # it each time.
 212 sub xargs {
 213         my $args=shift;
 214
 215         # The kernel can accept command lines up to 20k worth of characters.
 216         my $command_max=20000; # LINUX SPECIFIC!!
 217                         # I could use POSIX::ARG_MAX, but that would be slow.
 218
 219         # Figure out length of static portion of command.
 220         my $static_length=0;
 221         foreach (@_) {
 222                 $static_length+=length($_)+1;
 223         }
 224
 225         my @collect=();
 226         my $length=$static_length;
 227         foreach (@$args) {
 228                 if (length($_) + 1 + $static_length > $command_max) {
 229                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 230                 }
 231                 $length+=length($_) + 1;
 232                 if ($length < $command_max) {
 233                         push @collect, $_;
 234                 }
 235                 else {
 236                         doit(@_,@collect) if $#collect > -1;
 237                         @collect=($_);
 238                         $length=$static_length + length($_) + 1;
 239                 }
 240         }
 241         doit(@_,@collect) if $#collect > -1;
 242 }
 243
 244 # Print something if the verbose flag is on.
 245 sub verbose_print {
 246         my $message=shift;
 247
 248         if ($dh{VERBOSE}) {
 249                 print "\t$message\n";
 250         }
 251 }
 252
 253 # Output an error message and exit.
 254 sub error {
 255         my $message=shift;
 256
 257         warning($message);
 258         exit 1;
 259 }
 260
 261 # Output a warning.
 262 sub warning {
 263         my $message=shift;
 264
 265         print STDERR basename($0).": $message\n";
 266 }
 267
 268 # Returns the basename of the argument passed to it.
 269 sub basename {
 270         my $fn=shift;
 271
 272         $fn=~s/\/$//g; # ignore trailing slashes
 273         $fn=~s:^.*/(.*?)$:$1:;
 274         return $fn;
 275 }
 276
 277 # Returns the directory name of the argument passed to it.
 278 sub dirname {
 279         my $fn=shift;
 280
 281         $fn=~s/\/$//g; # ignore trailing slashes
 282         $fn=~s:^(.*)/.*?$:$1:;
 283         return $fn;
 284 }
 285
 286 # Pass in a number, will return true iff the current compatibility level
 287 # is less than or equal to that number.
 288 {
 289         my $warned_compat=0;
 290         my $c;
 291
 292         sub compat {
 293                 my $num=shift;
 294
 295                 if (! defined $c) {
 296                         $c=1;
 297                         if (defined $ENV{DH_COMPAT}) {
 298                                 $c=$ENV{DH_COMPAT};
 299                         }
 300                         elsif (-e 'debian/compat') {
 301                                 # Try the file..
 302                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 303                                 my $l=<COMPAT_IN>;
 304                                 close COMPAT_IN;
 305                                 if (! defined $l || ! length $l) {
 306                                         warning("debian/compat is empty, assuming level $c");
 307                                 }
 308                                 else {
 309                                         chomp $l;
 310                                         $c=$l;
 311                                 }
 312                         }
 313                 }
 314
 315                 if ($c < 4 && ! $warned_compat) {
 316                         warning("Compatibility levels before 5 are deprecated.");
 317                         $warned_compat=1;
 318                 }
 319
 320                 if ($c > $max_compat) {
 321                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 322                 }
 323
 324                 return ($c <= $num);
 325         }
 326 }
 327
 328 # Pass it a name of a binary package, it returns the name of the tmp dir to
 329 # use, for that package.
 330 sub tmpdir {
 331         my $package=shift;
 332
 333         if ($dh{TMPDIR}) {
 334                 return $dh{TMPDIR};
 335         }
 336         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 337                 # This is for back-compatibility with the debian/tmp tradition.
 338                 return "debian/tmp";
 339         }
 340         else {
 341                 return "debian/$package";
 342         }
 343 }
 344
 345 # Pass this the name of a binary package, and the name of the file wanted
 346 # for the package, and it will return the actual existing filename to use.
 347 #
 348 # It tries several filenames:
 349 #   * debian/package.filename.buildarch
 350 #   * debian/package.filename.buildos
 351 #   * debian/package.filename
 352 #   * debian/filename (if the package is the main package)
 353 # If --name was specified then the files
 354 # must have the name after the package name:
 355 #   * debian/package.name.filename.buildarch
 356 #   * debian/package.name.filename.buildos
 357 #   * debian/package.name.filename
 358 #   * debian/name.filename (if the package is the main package)
 359 sub pkgfile {
 360         my $package=shift;
 361         my $filename=shift;
 362
 363         if (defined $dh{NAME}) {
 364                 $filename="$dh{NAME}.$filename";
 365         }
 366
 367         my @try=("debian/$package.$filename.".buildarch(),
 368                  "debian/$package.$filename.".buildos(),
 369                  "debian/$package.$filename");
 370         if ($package eq $dh{MAINPACKAGE}) {
 371                 push @try, "debian/$filename";
 372         }
 373
 374         foreach my $file (@try) {
 375                 if (-f $file &&
 376                     (! $dh{IGNORE} || ! exists $dh{IGNORE}->{$file})) {
 377                         return $file;
 378                 }
 379
 380         }
 381
 382         return "";
 383
 384 }
 385
 386 # Pass it a name of a binary package, it returns the name to prefix to files
 387 # in debian/ for this package.
 388 sub pkgext {
 389         my $package=shift;
 390
 391         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 392                 return "";
 393         }
 394         return "$package.";
 395 }
 396
 397 # Pass it the name of a binary package, it returns the name to install
 398 # files by in eg, etc. Normally this is the same, but --name can override
 399 # it.
 400 sub pkgfilename {
 401         my $package=shift;
 402
 403         if (defined $dh{NAME}) {
 404                 return $dh{NAME};
 405         }
 406         return $package;
 407 }
 408
 409 # Returns 1 if the package is a native debian package, null otherwise.
 410 # As a side effect, sets $dh{VERSION} to the version of this package.
 411 {
 412         # Caches return code so it only needs to run dpkg-parsechangelog once.
 413         my %isnative_cache;
 414
 415         sub isnative {
 416                 my $package=shift;
 417
 418                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 419
 420                 # Make sure we look at the correct changelog.
 421                 my $isnative_changelog=pkgfile($package,"changelog");
 422                 if (! $isnative_changelog) {
 423                         $isnative_changelog="debian/changelog";
 424                 }
 425                 # Get the package version.
 426                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 427                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 428                 # Did the changelog parse fail?
 429                 if (! defined $dh{VERSION}) {
 430                         error("changelog parse failure");
 431                 }
 432
 433                 # Is this a native Debian package?
 434                 if ($dh{VERSION}=~m/.*-/) {
 435                         return $isnative_cache{$package}=0;
 436                 }
 437                 else {
 438                         return $isnative_cache{$package}=1;
 439                 }
 440         }
 441 }
 442
 443 # Automatically add a shell script snippet to a debian script.
 444 # Only works if the script has #DEBHELPER# in it.
 445 #
 446 # Parameters:
 447 # 1: package
 448 # 2: script to add to
 449 # 3: filename of snippet
 450 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 451 sub autoscript {
 452         my $package=shift;
 453         my $script=shift;
 454         my $filename=shift;
 455         my $sed=shift || "";
 456
 457         # This is the file we will modify.
 458         my $outfile="debian/".pkgext($package)."$script.debhelper";
 459
 460         # Figure out what shell script snippet to use.
 461         my $infile;
 462         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 463             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 464                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 465         }
 466         else {
 467                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 468                         $infile="/usr/share/debhelper/autoscripts/$filename";
 469                 }
 470                 else {
 471                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 472                 }
 473         }
 474
 475         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 476            && !compat(5)) {
 477                 # Add fragments to top so they run in reverse order when removing.
 478                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 479                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 480                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 481                 complex_doit("cat $outfile >> $outfile.new");
 482                 complex_doit("mv $outfile.new $outfile");
 483         }
 484         else {
 485                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 486                 complex_doit("sed \"$sed\" $infile >> $outfile");
 487                 complex_doit("echo '# End automatically added section' >> $outfile");
 488         }
 489 }
 490
 491 # Removes a whole substvar line.
 492 sub delsubstvar {
 493         my $package=shift;
 494         my $substvar=shift;
 495
 496         my $ext=pkgext($package);
 497         my $substvarfile="debian/${ext}substvars";
 498
 499         if (-e $substvarfile) {
 500                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 501                 doit("mv", "$substvarfile.new","$substvarfile");
 502         }
 503 }
 504
 505 # Adds a dependency on some package to the specified
 506 # substvar in a package's substvar's file.
 507 sub addsubstvar {
 508         my $package=shift;
 509         my $substvar=shift;
 510         my $deppackage=shift;
 511         my $verinfo=shift;
 512         my $remove=shift;
 513
 514         my $ext=pkgext($package);
 515         my $substvarfile="debian/${ext}substvars";
 516         my $str=$deppackage;
 517         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 518
 519         # Figure out what the line will look like, based on what's there
 520         # now, and what we're to add or remove.
 521         my $line="";
 522         if (-e $substvarfile) {
 523                 my %items;
 524                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 525                 while (<SUBSTVARS_IN>) {
 526                         chomp;
 527                         if (/^\Q$substvar\E=(.*)/) {
 528                                 %items = map { $_ => 1} split(", ", $1);
 529
 530                                 last;
 531                         }
 532                 }
 533                 close SUBSTVARS_IN;
 534                 if (! $remove) {
 535                         $items{$str}=1;
 536                 }
 537                 else {
 538                         delete $items{$str};
 539                 }
 540                 $line=join(", ", sort keys %items);
 541         }
 542         elsif (! $remove) {
 543                 $line=$str;
 544         }
 545
 546         if (length $line) {
 547                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 548                  doit("mv", "$substvarfile.new", $substvarfile);
 549         }
 550         else {
 551                 delsubstvar($package,$substvar);
 552         }
 553 }
 554
 555 # Reads in the specified file, one line at a time. splits on words,
 556 # and returns an array of arrays of the contents.
 557 # If a value is passed in as the second parameter, then glob
 558 # expansion is done in the directory specified by the parameter ("." is
 559 # frequently a good choice).
 560 sub filedoublearray {
 561         my $file=shift;
 562         my $globdir=shift;
 563
 564         my @ret;
 565         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 566         while (<DH_FARRAY_IN>) {
 567                 chomp;
 568                 # Only ignore comments and empty lines in v5 mode.
 569                 if (! compat(4)) {
 570                         next if /^#/ || /^$/;
 571                 }
 572                 my @line;
 573                 # Only do glob expansion in v3 mode.
 574                 #
 575                 # The tricky bit is that the glob expansion is done
 576                 # as if we were in the specified directory, so the
 577                 # filenames that come out are relative to it.
 578                 if (defined $globdir && ! compat(2)) {
 579                         for (map { glob "$globdir/$_" } split) {
 580                                 s#^$globdir/##;
 581                                 push @line, $_;
 582                         }
 583                 }
 584                 else {
 585                         @line = split;
 586                 }
 587                 push @ret, [@line];
 588         }
 589         close DH_FARRAY_IN;
 590
 591         return @ret;
 592 }
 593
 594 # Reads in the specified file, one word at a time, and returns an array of
 595 # the result. Can do globbing as does filedoublearray.
 596 sub filearray {
 597         return map { @$_ } filedoublearray(@_);
 598 }
 599
 600 # Passed a filename, returns true if -X says that file should be excluded.
 601 sub excludefile {
 602         my $filename = shift;
 603         foreach my $f (@{$dh{EXCLUDE}}) {
 604                 return 1 if $filename =~ /\Q$f\E/;
 605         }
 606         return 0;
 607 }
 608
 609 sub dpkg_architecture_value {
 610         my $var = shift;
 611         my $value=`dpkg-architecture -q$var` || error("dpkg-architecture failed");
 612         chomp $value;
 613         return $value;
 614 }
 615
 616 # Returns the build architecture. (Memoized)
 617 {
 618         my $arch;
 619
 620         sub buildarch {
 621                 if (!defined $arch) {
 622                     $arch=dpkg_architecture_value('DEB_HOST_ARCH');
 623                 }
 624                 return $arch;
 625         }
 626 }
 627
 628 # Returns the build OS. (Memoized)
 629 {
 630         my $os;
 631
 632         sub buildos {
 633                 if (!defined $os) {
 634                         $os=dpkg_architecture_value("DEB_HOST_ARCH_OS");
 635                 }
 636                 return $os;
 637         }
 638 }
 639
 640 # Passed an arch and a list of arches to match against, returns true if matched
 641 sub samearch {
 642         my $arch=shift;
 643         my @archlist=split(/\s+/,shift);
 644
 645         foreach my $a (@archlist) {
 646                 system("dpkg-architecture", "-a$arch", "-i$a") == 0 && return 1;
 647         }
 648
 649         return 0;
 650 }
 651
 652 # Returns source package name
 653 sub sourcepackage {
 654         open (CONTROL, 'debian/control') ||
 655             error("cannot read debian/control: $!\n");
 656         while (<CONTROL>) {
 657                 chomp;
 658                 s/\s+$//;
 659                 if (/^Source:\s*(.*)/) {
 660                         close CONTROL;
 661                         return $1;
 662                 }
 663         }
 664
 665         close CONTROL;
 666         error("could not find Source: line in control file.");
 667 }
 668
 669 # Returns a list of packages in the control file.
 670 # Pass "arch" or "indep" to specify arch-dependant or
 671 # independant. If nothing is specified, returns all packages.
 672 # As a side effect, populates %package_arches and %package_types with the
 673 # types of all packages (not only those returned).
 674 my (%package_types, %package_arches);
 675 sub getpackages {
 676         my $type=shift;
 677
 678         %package_types=();
 679         %package_arches=();
 680
 681         $type="" if ! defined $type;
 682
 683         my $package="";
 684         my $arch="";
 685         my $package_type;
 686         my @list=();
 687         my %seen;
 688         open (CONTROL, 'debian/control') ||
 689                 error("cannot read debian/control: $!\n");
 690         while (<CONTROL>) {
 691                 chomp;
 692                 s/\s+$//;
 693                 if (/^Package:\s*(.*)/) {
 694                         $package=$1;
 695                         # Detect duplicate package names in the same control file.
 696                         if (! $seen{$package}) {
 697                                 $seen{$package}=1;
 698                         }
 699                         else {
 700                                 error("debian/control has a duplicate entry for $package");
 701                         }
 702                         $package_type="deb";
 703                 }
 704                 if (/^Architecture:\s*(.*)/) {
 705                         $arch=$1;
 706                 }
 707                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 708                         $package_type=$1;
 709                 }
 710
 711                 if (!$_ or eof) { # end of stanza.
 712                         if ($package) {
 713                                 $package_types{$package}=$package_type;
 714                                 $package_arches{$package}=$arch;
 715                         }
 716
 717                         if ($package &&
 718                             (($type eq 'indep' && $arch eq 'all') ||
 719                              ($type eq 'arch' && ($arch eq 'any' ||
 720                                              ($arch ne 'all' &&
 721                                               samearch(buildarch(), $arch)))) ||
 722                              ! $type)) {
 723                                 push @list, $package;
 724                                 $package="";
 725                                 $arch="";
 726                         }
 727                 }
 728         }
 729         close CONTROL;
 730
 731         return @list;
 732 }
 733
 734 # Returns the arch a package will build for.
 735 sub package_arch {
 736         my $package=shift;
 737
 738         if (! exists $package_arches{$package}) {
 739                 warning "package $package is not in control info";
 740                 return buildarch();
 741         }
 742         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 743 }
 744
 745 # Return true if a given package is really a udeb.
 746 sub is_udeb {
 747         my $package=shift;
 748
 749         if (! exists $package_types{$package}) {
 750                 warning "package $package is not in control info";
 751                 return 0;
 752         }
 753         return $package_types{$package} eq 'udeb';
 754 }
 755
 756 # Generates the filename that is used for a udeb package.
 757 sub udeb_filename {
 758         my $package=shift;
 759
 760         my $filearch=package_arch($package);
 761         isnative($package); # side effect
 762         my $version=$dh{VERSION};
 763         $version=~s/^[0-9]+://; # strip any epoch
 764         return "${package}_${version}_$filearch.udeb";
 765 }
 766
 767 # Handles #DEBHELPER# substitution in a script; also can generate a new
 768 # script from scratch if none exists but there is a .debhelper file for it.
 769 sub debhelper_script_subst {
 770         my $package=shift;
 771         my $script=shift;
 772
 773         my $tmp=tmpdir($package);
 774         my $ext=pkgext($package);
 775         my $file=pkgfile($package,$script);
 776
 777         if ($file ne '') {
 778                 if (-f "debian/$ext$script.debhelper") {
 779                         # Add this into the script, where it has #DEBHELPER#
 780                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 781                 }
 782                 else {
 783                         # Just get rid of any #DEBHELPER# in the script.
 784                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 785                 }
 786                 doit("chown","0:0","$tmp/DEBIAN/$script");
 787                 doit("chmod",755,"$tmp/DEBIAN/$script");
 788         }
 789         elsif ( -f "debian/$ext$script.debhelper" ) {
 790                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 791                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 792                 doit("chown","0:0","$tmp/DEBIAN/$script");
 793                 doit("chmod",755,"$tmp/DEBIAN/$script");
 794         }
 795 }
 796
 797 1