Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2008.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell
  18             &inhibit_log &load_log &write_log &dpkg_architecture_value
  19             &sourcepackage
  20             &is_make_jobserver_unavailable &clean_jobserver_makeflags);
  21
  22 my $max_compat=8;
  23
  24 sub init {
  25         my %params=@_;
  26
  27         # Check to see if an option line starts with a dash,
  28         # or DH_OPTIONS is set.
  29         # If so, we need to pass this off to the resource intensive
  30         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  31         if ((defined $ENV{DH_OPTIONS} && length $ENV{DH_OPTIONS}) ||
  32             (defined $ENV{DH_INTERNAL_OPTIONS} && length $ENV{DH_INTERNAL_OPTIONS}) ||
  33             grep /^-/, @ARGV) {
  34                 eval "use Debian::Debhelper::Dh_Getopt";
  35                 error($@) if $@;
  36                 Debian::Debhelper::Dh_Getopt::parseopts(%params);
  37         }
  38
  39         # Another way to set excludes.
  40         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  41                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  42         }
  43
  44         # Generate EXCLUDE_FIND.
  45         if ($dh{EXCLUDE}) {
  46                 $dh{EXCLUDE_FIND}='';
  47                 foreach (@{$dh{EXCLUDE}}) {
  48                         my $x=$_;
  49                         $x=escape_shell($x);
  50                         $x=~s/\./\\\\./g;
  51                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  52                 }
  53                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  54         }
  55
  56         # Check to see if DH_VERBOSE environment variable was set, if so,
  57         # make sure verbose is on.
  58         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  59                 $dh{VERBOSE}=1;
  60         }
  61
  62         # Check to see if DH_NO_ACT environment variable was set, if so,
  63         # make sure no act mode is on.
  64         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  65                 $dh{NO_ACT}=1;
  66         }
  67
  68         # Get the name of the main binary package (first one listed in
  69         # debian/control). Only if the main package was not set on the
  70         # command line.
  71         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  72                 my @allpackages=getpackages();
  73                 $dh{MAINPACKAGE}=$allpackages[0];
  74         }
  75
  76         # Check if packages to build have been specified, if not, fall back to
  77         # the default, building all relevant packages.
  78         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  79                 push @{$dh{DOPACKAGES}}, getpackages('both');
  80         }
  81
  82         # Check to see if -P was specified. If so, we can only act on a single
  83         # package.
  84         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  85                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  86         }
  87
  88         # Figure out which package is the first one we were instructed to build.
  89         # This package gets special treatement: files and directories specified on
  90         # the command line may affect it.
  91         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
  92
  93         # If no error handling function was specified, just propigate
  94         # errors out.
  95         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
  96                 $dh{ERROR_HANDLER}='exit \$?';
  97         }
  98 }
  99
 100 # Run at exit. Add the command to the log files for the packages it acted
 101 # on, if it's exiting successfully.
 102 my $write_log=1;
 103 sub END {
 104         if ($? == 0 && $write_log) {
 105                 write_log(basename($0), @{$dh{DOPACKAGES}});
 106         }
 107 }
 108
 109 sub load_log {
 110         my ($package, $db)=@_;
 111         my $ext=pkgext($package);
 112
 113         my @log;
 114         open(LOG, "<", "debian/${ext}debhelper.log") || return;
 115         while (<LOG>) {
 116                 chomp;
 117                 push @log, $_;
 118                 $db->{$package}{$_}=1 if defined $db;
 119         }
 120         close LOG;
 121         return @log;
 122 }
 123
 124 sub write_log {
 125         my $cmd=shift;
 126         my @packages=@_;
 127
 128         return if defined $ENV{DH_INHIBIT_LOG} && $cmd eq $ENV{DH_INHIBIT_LOG};
 129
 130         foreach my $package (@packages) {
 131                 my $ext=pkgext($package);
 132                 my $log="debian/${ext}debhelper.log";
 133                 open(LOG, ">>", $log) || error("failed to write to ${log}: $!");
 134                 print LOG $cmd."\n";
 135                 close LOG;
 136         }
 137 }
 138
 139 sub inhibit_log {
 140         $write_log=0;
 141 }
 142
 143 # Pass it an array containing the arguments of a shell command like would
 144 # be run by exec(). It turns that into a line like you might enter at the
 145 # shell, escaping metacharacters and quoting arguments that contain spaces.
 146 sub escape_shell {
 147         my @args=@_;
 148         my $line="";
 149         my @ret;
 150         foreach my $word (@args) {
 151                 if ($word=~/\s/) {
 152                         # Escape only a few things since it will be quoted.
 153                         # Note we use double quotes because you cannot
 154                         # escape ' in single quotes, while " can be escaped
 155                         # in double.
 156                         # This does make -V"foo bar" turn into "-Vfoo bar",
 157                         # but that will be parsed identically by the shell
 158                         # anyway..
 159                         $word=~s/([\n`\$"\\])/\\$1/g;
 160                         push @ret, "\"$word\"";
 161                 }
 162                 else {
 163                         # This list is from _Unix in a Nutshell_. (except '#')
 164                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 165                         push @ret,$word;
 166                 }
 167         }
 168         return join(' ', @ret);
 169 }
 170
 171 # Run a command, and display the command to stdout if verbose mode is on.
 172 # All commands that modifiy files in $TMP should be ran via this
 173 # function.
 174 #
 175 # Note that this cannot handle complex commands, especially anything
 176 # involving redirection. Use complex_doit instead.
 177 sub doit {
 178         verbose_print(escape_shell(@_));
 179
 180         if (! $dh{NO_ACT}) {
 181                 system(@_) == 0 || _error_exitcode(join(" ", @_));
 182         }
 183 }
 184
 185 # Run a command and display the command to stdout if verbose mode is on.
 186 # Use doit() if you can, instead of this function, because this function
 187 # forks a shell. However, this function can handle more complicated stuff
 188 # like redirection.
 189 sub complex_doit {
 190         verbose_print(join(" ",@_));
 191
 192         if (! $dh{NO_ACT}) {
 193                 # The join makes system get a scalar so it forks off a shell.
 194                 system(join(" ", @_)) == 0 || _error_exitcode(join(" ", @_))
 195         }
 196 }
 197
 198 sub _error_exitcode {
 199         my $command=shift;
 200         if ($? == -1) {
 201                 error("$command failed to to execute: $!");
 202         }
 203         elsif ($? & 127) {
 204                 error("$command died with signal ".($? & 127));
 205         }
 206         else {
 207                 error("$command returned exit code ".($? >> 8));
 208         }
 209 }
 210
 211 # Run a command that may have a huge number of arguments, like xargs does.
 212 # Pass in a reference to an array containing the arguments, and then other
 213 # parameters that are the command and any parameters that should be passed to
 214 # it each time.
 215 sub xargs {
 216         my $args=shift;
 217
 218         # The kernel can accept command lines up to 20k worth of characters.
 219         my $command_max=20000; # LINUX SPECIFIC!!
 220                         # (And obsolete; it's bigger now.)
 221                         # I could use POSIX::ARG_MAX, but that would be slow.
 222
 223         # Figure out length of static portion of command.
 224         my $static_length=0;
 225         foreach (@_) {
 226                 $static_length+=length($_)+1;
 227         }
 228
 229         my @collect=();
 230         my $length=$static_length;
 231         foreach (@$args) {
 232                 if (length($_) + 1 + $static_length > $command_max) {
 233                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 234                 }
 235                 $length+=length($_) + 1;
 236                 if ($length < $command_max) {
 237                         push @collect, $_;
 238                 }
 239                 else {
 240                         doit(@_,@collect) if $#collect > -1;
 241                         @collect=($_);
 242                         $length=$static_length + length($_) + 1;
 243                 }
 244         }
 245         doit(@_,@collect) if $#collect > -1;
 246 }
 247
 248 # Print something if the verbose flag is on.
 249 sub verbose_print {
 250         my $message=shift;
 251
 252         if ($dh{VERBOSE}) {
 253                 print "\t$message\n";
 254         }
 255 }
 256
 257 # Output an error message and die (can be caught).
 258 sub error {
 259         my $message=shift;
 260
 261         die basename($0).": $message\n";
 262 }
 263
 264 # Output a warning.
 265 sub warning {
 266         my $message=shift;
 267
 268         print STDERR basename($0).": $message\n";
 269 }
 270
 271 # Returns the basename of the argument passed to it.
 272 sub basename {
 273         my $fn=shift;
 274
 275         $fn=~s/\/$//g; # ignore trailing slashes
 276         $fn=~s:^.*/(.*?)$:$1:;
 277         return $fn;
 278 }
 279
 280 # Returns the directory name of the argument passed to it.
 281 sub dirname {
 282         my $fn=shift;
 283
 284         $fn=~s/\/$//g; # ignore trailing slashes
 285         $fn=~s:^(.*)/.*?$:$1:;
 286         return $fn;
 287 }
 288
 289 # Pass in a number, will return true iff the current compatibility level
 290 # is less than or equal to that number.
 291 {
 292         my $warned_compat=0;
 293         my $c;
 294
 295         sub compat {
 296                 my $num=shift;
 297
 298                 if (! defined $c) {
 299                         $c=1;
 300                         if (defined $ENV{DH_COMPAT}) {
 301                                 $c=$ENV{DH_COMPAT};
 302                         }
 303                         elsif (-e 'debian/compat') {
 304                                 # Try the file..
 305                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 306                                 my $l=<COMPAT_IN>;
 307                                 close COMPAT_IN;
 308                                 if (! defined $l || ! length $l) {
 309                                         warning("debian/compat is empty, assuming level $c");
 310                                 }
 311                                 else {
 312                                         chomp $l;
 313                                         $c=$l;
 314                                 }
 315                         }
 316                 }
 317
 318                 if ($c <= 4 && ! $warned_compat) {
 319                         warning("Compatibility levels before 5 are deprecated.");
 320                         $warned_compat=1;
 321                 }
 322
 323                 if ($c > $max_compat) {
 324                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 325                 }
 326
 327                 return ($c <= $num);
 328         }
 329 }
 330
 331 # Pass it a name of a binary package, it returns the name of the tmp dir to
 332 # use, for that package.
 333 sub tmpdir {
 334         my $package=shift;
 335
 336         if ($dh{TMPDIR}) {
 337                 return $dh{TMPDIR};
 338         }
 339         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 340                 # This is for back-compatibility with the debian/tmp tradition.
 341                 return "debian/tmp";
 342         }
 343         else {
 344                 return "debian/$package";
 345         }
 346 }
 347
 348 # Pass this the name of a binary package, and the name of the file wanted
 349 # for the package, and it will return the actual existing filename to use.
 350 #
 351 # It tries several filenames:
 352 #   * debian/package.filename.buildarch
 353 #   * debian/package.filename.buildos
 354 #   * debian/package.filename
 355 #   * debian/filename (if the package is the main package)
 356 # If --name was specified then the files
 357 # must have the name after the package name:
 358 #   * debian/package.name.filename.buildarch
 359 #   * debian/package.name.filename.buildos
 360 #   * debian/package.name.filename
 361 #   * debian/name.filename (if the package is the main package)
 362 sub pkgfile {
 363         my $package=shift;
 364         my $filename=shift;
 365
 366         if (defined $dh{NAME}) {
 367                 $filename="$dh{NAME}.$filename";
 368         }
 369
 370         # First, check for files ending in buildarch and buildos.
 371         my $match;
 372         foreach my $file (glob("debian/$package.$filename.*")) {
 373                 next if ! -f $file;
 374                 next if $dh{IGNORE} && exists $dh{IGNORE}->{$file};
 375                 if ($file eq "debian/$package.$filename.".buildarch()) {
 376                         $match=$file;
 377                         # buildarch files are used in preference to buildos files.
 378                         last;
 379                 }
 380                 elsif ($file eq "debian/$package.$filename.".buildos()) {
 381                         $match=$file;
 382                 }
 383         }
 384         return $match if defined $match;
 385
 386         my @try=("debian/$package.$filename");
 387         if ($package eq $dh{MAINPACKAGE}) {
 388                 push @try, "debian/$filename";
 389         }
 390
 391         foreach my $file (@try) {
 392                 if (-f $file &&
 393                     (! $dh{IGNORE} || ! exists $dh{IGNORE}->{$file})) {
 394                         return $file;
 395                 }
 396
 397         }
 398
 399         return "";
 400
 401 }
 402
 403 # Pass it a name of a binary package, it returns the name to prefix to files
 404 # in debian/ for this package.
 405 sub pkgext {
 406         my $package=shift;
 407
 408         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 409                 return "";
 410         }
 411         return "$package.";
 412 }
 413
 414 # Pass it the name of a binary package, it returns the name to install
 415 # files by in eg, etc. Normally this is the same, but --name can override
 416 # it.
 417 sub pkgfilename {
 418         my $package=shift;
 419
 420         if (defined $dh{NAME}) {
 421                 return $dh{NAME};
 422         }
 423         return $package;
 424 }
 425
 426 # Returns 1 if the package is a native debian package, null otherwise.
 427 # As a side effect, sets $dh{VERSION} to the version of this package.
 428 {
 429         # Caches return code so it only needs to run dpkg-parsechangelog once.
 430         my %isnative_cache;
 431
 432         sub isnative {
 433                 my $package=shift;
 434
 435                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 436
 437                 # Make sure we look at the correct changelog.
 438                 my $isnative_changelog=pkgfile($package,"changelog");
 439                 if (! $isnative_changelog) {
 440                         $isnative_changelog="debian/changelog";
 441                 }
 442                 # Get the package version.
 443                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 444                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 445                 # Did the changelog parse fail?
 446                 if (! defined $dh{VERSION}) {
 447                         error("changelog parse failure");
 448                 }
 449
 450                 # Is this a native Debian package?
 451                 if ($dh{VERSION}=~m/.*-/) {
 452                         return $isnative_cache{$package}=0;
 453                 }
 454                 else {
 455                         return $isnative_cache{$package}=1;
 456                 }
 457         }
 458 }
 459
 460 # Automatically add a shell script snippet to a debian script.
 461 # Only works if the script has #DEBHELPER# in it.
 462 #
 463 # Parameters:
 464 # 1: package
 465 # 2: script to add to
 466 # 3: filename of snippet
 467 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 468 sub autoscript {
 469         my $package=shift;
 470         my $script=shift;
 471         my $filename=shift;
 472         my $sed=shift || "";
 473
 474         # This is the file we will modify.
 475         my $outfile="debian/".pkgext($package)."$script.debhelper";
 476
 477         # Figure out what shell script snippet to use.
 478         my $infile;
 479         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 480             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 481                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 482         }
 483         else {
 484                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 485                         $infile="/usr/share/debhelper/autoscripts/$filename";
 486                 }
 487                 else {
 488                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 489                 }
 490         }
 491
 492         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 493            && !compat(5)) {
 494                 # Add fragments to top so they run in reverse order when removing.
 495                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 496                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 497                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 498                 complex_doit("cat $outfile >> $outfile.new");
 499                 complex_doit("mv $outfile.new $outfile");
 500         }
 501         else {
 502                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 503                 complex_doit("sed \"$sed\" $infile >> $outfile");
 504                 complex_doit("echo '# End automatically added section' >> $outfile");
 505         }
 506 }
 507
 508 # Removes a whole substvar line.
 509 sub delsubstvar {
 510         my $package=shift;
 511         my $substvar=shift;
 512
 513         my $ext=pkgext($package);
 514         my $substvarfile="debian/${ext}substvars";
 515
 516         if (-e $substvarfile) {
 517                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 518                 doit("mv", "$substvarfile.new","$substvarfile");
 519         }
 520 }
 521
 522 # Adds a dependency on some package to the specified
 523 # substvar in a package's substvar's file.
 524 sub addsubstvar {
 525         my $package=shift;
 526         my $substvar=shift;
 527         my $deppackage=shift;
 528         my $verinfo=shift;
 529         my $remove=shift;
 530
 531         my $ext=pkgext($package);
 532         my $substvarfile="debian/${ext}substvars";
 533         my $str=$deppackage;
 534         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 535
 536         # Figure out what the line will look like, based on what's there
 537         # now, and what we're to add or remove.
 538         my $line="";
 539         if (-e $substvarfile) {
 540                 my %items;
 541                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 542                 while (<SUBSTVARS_IN>) {
 543                         chomp;
 544                         if (/^\Q$substvar\E=(.*)/) {
 545                                 %items = map { $_ => 1} split(", ", $1);
 546
 547                                 last;
 548                         }
 549                 }
 550                 close SUBSTVARS_IN;
 551                 if (! $remove) {
 552                         $items{$str}=1;
 553                 }
 554                 else {
 555                         delete $items{$str};
 556                 }
 557                 $line=join(", ", sort keys %items);
 558         }
 559         elsif (! $remove) {
 560                 $line=$str;
 561         }
 562
 563         if (length $line) {
 564                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 565                  doit("mv", "$substvarfile.new", $substvarfile);
 566         }
 567         else {
 568                 delsubstvar($package,$substvar);
 569         }
 570 }
 571
 572 # Reads in the specified file, one line at a time. splits on words,
 573 # and returns an array of arrays of the contents.
 574 # If a value is passed in as the second parameter, then glob
 575 # expansion is done in the directory specified by the parameter ("." is
 576 # frequently a good choice).
 577 sub filedoublearray {
 578         my $file=shift;
 579         my $globdir=shift;
 580
 581         my @ret;
 582         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 583         while (<DH_FARRAY_IN>) {
 584                 chomp;
 585                 # Only ignore comments and empty lines in v5 mode.
 586                 if (! compat(4)) {
 587                         next if /^#/ || /^$/;
 588                 }
 589                 my @line;
 590                 # Only do glob expansion in v3 mode.
 591                 #
 592                 # The tricky bit is that the glob expansion is done
 593                 # as if we were in the specified directory, so the
 594                 # filenames that come out are relative to it.
 595                 if (defined $globdir && ! compat(2)) {
 596                         foreach (map { glob "$globdir/$_" } split) {
 597                                 s#^$globdir/##;
 598                                 push @line, $_;
 599                         }
 600                 }
 601                 else {
 602                         @line = split;
 603                 }
 604                 push @ret, [@line];
 605         }
 606         close DH_FARRAY_IN;
 607
 608         return @ret;
 609 }
 610
 611 # Reads in the specified file, one word at a time, and returns an array of
 612 # the result. Can do globbing as does filedoublearray.
 613 sub filearray {
 614         return map { @$_ } filedoublearray(@_);
 615 }
 616
 617 # Passed a filename, returns true if -X says that file should be excluded.
 618 sub excludefile {
 619         my $filename = shift;
 620         foreach my $f (@{$dh{EXCLUDE}}) {
 621                 return 1 if $filename =~ /\Q$f\E/;
 622         }
 623         return 0;
 624 }
 625
 626 {
 627         my %dpkg_arch_output;
 628         sub dpkg_architecture_value {
 629                 my $var = shift;
 630                 if (! exists($dpkg_arch_output{$var})) {
 631                         local $_;
 632                         open(PIPE, '-|', 'dpkg-architecture')
 633                                 or error("dpkg-architecture failed");
 634                         while (<PIPE>) {
 635                                 chomp;
 636                                 my ($k, $v) = split(/=/, $_, 2);
 637                                 $dpkg_arch_output{$k} = $v;
 638                         }
 639                         close(PIPE);
 640                 }
 641                 return $dpkg_arch_output{$var};
 642         }
 643 }
 644
 645 # Returns the build architecture.
 646 sub buildarch {
 647         dpkg_architecture_value('DEB_HOST_ARCH');
 648 }
 649
 650 # Returns the build OS.
 651 sub buildos {
 652         dpkg_architecture_value("DEB_HOST_ARCH_OS");
 653 }
 654
 655 # Passed an arch and a list of arches to match against, returns true if matched
 656 {
 657         my %knownsame;
 658
 659         sub samearch {
 660                 my $arch=shift;
 661                 my @archlist=split(/\s+/,shift);
 662
 663                 foreach my $a (@archlist) {
 664                         # Avoid expensive dpkg-architecture call to compare
 665                         # with a simple architecture name. "linux-any" and
 666                         # other architecture wildcards are (currently)
 667                         # always hypenated.
 668                         if ($a !~ /-/) {
 669                                 return 1 if $arch eq $a;
 670                         }
 671                         elsif (exists $knownsame{$arch}{$a}) {
 672                                 return 1 if $knownsame{$arch}{$a};
 673                         }
 674                         elsif (system("dpkg-architecture", "-a$arch", "-i$a") == 0) {
 675                                 return $knownsame{$arch}{$a}=1;
 676                         }
 677                         else {
 678                                 $knownsame{$arch}{$a}=0;
 679                         }
 680                 }
 681
 682                 return 0;
 683         }
 684 }
 685
 686 # Returns source package name
 687 sub sourcepackage {
 688         open (CONTROL, 'debian/control') ||
 689             error("cannot read debian/control: $!\n");
 690         while (<CONTROL>) {
 691                 chomp;
 692                 s/\s+$//;
 693                 if (/^Source:\s*(.*)/) {
 694                         close CONTROL;
 695                         return $1;
 696                 }
 697         }
 698
 699         close CONTROL;
 700         error("could not find Source: line in control file.");
 701 }
 702
 703 # Returns a list of packages in the control file.
 704 # Pass "arch" or "indep" to specify arch-dependant (that will be built
 705 # for the system's arch) or independant. If nothing is specified,
 706 # returns all packages. Also, "both" returns the union of "arch" and "indep"
 707 # packages.
 708 # As a side effect, populates %package_arches and %package_types with the
 709 # types of all packages (not only those returned).
 710 my (%package_types, %package_arches);
 711 sub getpackages {
 712         my $type=shift;
 713
 714         %package_types=();
 715         %package_arches=();
 716
 717         $type="" if ! defined $type;
 718
 719         my $package="";
 720         my $arch="";
 721         my $package_type;
 722         my @list=();
 723         my %seen;
 724         open (CONTROL, 'debian/control') ||
 725                 error("cannot read debian/control: $!\n");
 726         while (<CONTROL>) {
 727                 chomp;
 728                 s/\s+$//;
 729                 if (/^Package:\s*(.*)/) {
 730                         $package=$1;
 731                         # Detect duplicate package names in the same control file.
 732                         if (! $seen{$package}) {
 733                                 $seen{$package}=1;
 734                         }
 735                         else {
 736                                 error("debian/control has a duplicate entry for $package");
 737                         }
 738                         $package_type="deb";
 739                 }
 740                 if (/^Architecture:\s*(.*)/) {
 741                         $arch=$1;
 742                 }
 743                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 744                         $package_type=$1;
 745                 }
 746
 747                 if (!$_ or eof) { # end of stanza.
 748                         if ($package) {
 749                                 $package_types{$package}=$package_type;
 750                                 $package_arches{$package}=$arch;
 751                         }
 752
 753                         if ($package &&
 754                             ((($type eq 'indep' || $type eq 'both') && $arch eq 'all') ||
 755                              (($type eq 'arch'  || $type eq 'both') && ($arch eq 'any' ||
 756                                              ($arch ne 'all' &&
 757                                               samearch(buildarch(), $arch)))) ||
 758                              ! $type)) {
 759                                 push @list, $package;
 760                                 $package="";
 761                                 $arch="";
 762                         }
 763                 }
 764         }
 765         close CONTROL;
 766
 767         return @list;
 768 }
 769
 770 # Returns the arch a package will build for.
 771 sub package_arch {
 772         my $package=shift;
 773
 774         if (! exists $package_arches{$package}) {
 775                 warning "package $package is not in control info";
 776                 return buildarch();
 777         }
 778         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 779 }
 780
 781 # Return true if a given package is really a udeb.
 782 sub is_udeb {
 783         my $package=shift;
 784
 785         if (! exists $package_types{$package}) {
 786                 warning "package $package is not in control info";
 787                 return 0;
 788         }
 789         return $package_types{$package} eq 'udeb';
 790 }
 791
 792 # Generates the filename that is used for a udeb package.
 793 sub udeb_filename {
 794         my $package=shift;
 795
 796         my $filearch=package_arch($package);
 797         isnative($package); # side effect
 798         my $version=$dh{VERSION};
 799         $version=~s/^[0-9]+://; # strip any epoch
 800         return "${package}_${version}_$filearch.udeb";
 801 }
 802
 803 # Handles #DEBHELPER# substitution in a script; also can generate a new
 804 # script from scratch if none exists but there is a .debhelper file for it.
 805 sub debhelper_script_subst {
 806         my $package=shift;
 807         my $script=shift;
 808
 809         my $tmp=tmpdir($package);
 810         my $ext=pkgext($package);
 811         my $file=pkgfile($package,$script);
 812
 813         if ($file ne '') {
 814                 if (-f "debian/$ext$script.debhelper") {
 815                         # Add this into the script, where it has #DEBHELPER#
 816                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 817                 }
 818                 else {
 819                         # Just get rid of any #DEBHELPER# in the script.
 820                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 821                 }
 822                 doit("chown","0:0","$tmp/DEBIAN/$script");
 823                 doit("chmod",755,"$tmp/DEBIAN/$script");
 824         }
 825         elsif ( -f "debian/$ext$script.debhelper" ) {
 826                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 827                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 828                 doit("chown","0:0","$tmp/DEBIAN/$script");
 829                 doit("chmod",755,"$tmp/DEBIAN/$script");
 830         }
 831 }
 832
 833 # Checks if make's jobserver is enabled via MAKEFLAGS, but
 834 # the FD used to communicate with it is actually not available.
 835 sub is_make_jobserver_unavailable {
 836         if (exists $ENV{MAKEFLAGS} &&
 837             $ENV{MAKEFLAGS} =~ /(?:^|\s)--jobserver-fds=(\d+)/) {
 838                 if (!open(my $in, "<&$1")) {
 839                         return 1; # unavailable
 840                 }
 841                 else {
 842                         close $in;
 843                         return 0; # available
 844                 }
 845         }
 846
 847         return; # no jobserver specified
 848 }
 849
 850 # Cleans out jobserver options from MAKEFLAGS.
 851 sub clean_jobserver_makeflags {
 852         if (exists $ENV{MAKEFLAGS}) {
 853                 if ($ENV{MAKEFLAGS} =~ /(?:^|\s)--jobserver-fds=(\d+)/) {
 854                         $ENV{MAKEFLAGS} =~ s/(?:^|\s)--jobserver-fds=\S+//g;
 855                         $ENV{MAKEFLAGS} =~ s/(?:^|\s)-j\b//g;
 856                 }
 857                 delete $ENV{MAKEFLAGS} if $ENV{MAKEFLAGS} =~ /^\s*$/;
 858         }
 859 }
 860
 861 1