Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2008.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell
  18             &inhibit_log &load_log);
  19
  20 my $max_compat=7;
  21
  22 sub init {
  23         my %params=@_;
  24
  25         # Check to see if an option line starts with a dash,
  26         # or DH_OPTIONS is set.
  27         # If so, we need to pass this off to the resource intensive
  28         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  29         if ((defined $ENV{DH_OPTIONS} && length $ENV{DH_OPTIONS}) ||
  30             (defined $ENV{DH_INTERNAL_OPTIONS} && length $ENV{DH_INTERNAL_OPTIONS}) ||
  31             grep /^-/, @ARGV) {
  32                 eval "use Debian::Debhelper::Dh_Getopt";
  33                 error($@) if $@;
  34                 Debian::Debhelper::Dh_Getopt::parseopts($params{options});
  35         }
  36
  37         # Another way to set excludes.
  38         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  39                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  40         }
  41
  42         # Generate EXCLUDE_FIND.
  43         if ($dh{EXCLUDE}) {
  44                 $dh{EXCLUDE_FIND}='';
  45                 foreach (@{$dh{EXCLUDE}}) {
  46                         my $x=$_;
  47                         $x=escape_shell($x);
  48                         $x=~s/\./\\\\./g;
  49                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  50                 }
  51                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  52         }
  53
  54         # Check to see if DH_VERBOSE environment variable was set, if so,
  55         # make sure verbose is on.
  56         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  57                 $dh{VERBOSE}=1;
  58         }
  59
  60         # Check to see if DH_NO_ACT environment variable was set, if so,
  61         # make sure no act mode is on.
  62         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  63                 $dh{NO_ACT}=1;
  64         }
  65
  66         my @allpackages=getpackages();
  67         # Get the name of the main binary package (first one listed in
  68         # debian/control). Only if the main package was not set on the
  69         # command line.
  70         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  71                 $dh{MAINPACKAGE}=$allpackages[0];
  72         }
  73
  74         # Check if packages to build have been specified, if not, fall back to
  75         # the default, doing them all.
  76         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  77                 push @{$dh{DOPACKAGES}},@allpackages;
  78         }
  79
  80         # Check to see if -P was specified. If so, we can only act on a single
  81         # package.
  82         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  83                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  84         }
  85
  86         # Figure out which package is the first one we were instructed to build.
  87         # This package gets special treatement: files and directories specified on
  88         # the command line may affect it.
  89         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
  90
  91         # If no error handling function was specified, just propigate
  92         # errors out.
  93         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
  94                 $dh{ERROR_HANDLER}='exit \$?';
  95         }
  96 }
  97
  98 # Run at exit. Add the command to the log files for the packages it acted
  99 # on, if it's exiting successfully.
 100 my $write_log=1;
 101 sub END {
 102         if ($? == 0 && $write_log) {
 103                 write_log(basename($0), @{$dh{DOPACKAGES}});
 104         }
 105 }
 106
 107 sub load_log {
 108         my ($package, $db)=@_;
 109         my $ext=pkgext($package);
 110
 111         my @log;
 112         open(LOG, "<", "debian/${ext}debhelper.log") || return;
 113         while (<LOG>) {
 114                 chomp;
 115                 push @log, $_;
 116                 $db->{$package}{$_}=1 if (defined $db);
 117         }
 118         close LOG;
 119         return @log;
 120 }
 121
 122 sub write_log {
 123         my $cmd=shift;
 124         my @packages=@_;
 125
 126         foreach my $package (@packages) {
 127                 my $ext=pkgext($package);
 128                 my $log="debian/${ext}debhelper.log";
 129                 open(LOG, ">>", $log) || error("failed to write to ${log}: $!");
 130                 print LOG $cmd."\n";
 131                 close LOG;
 132         }
 133 }
 134
 135 sub inhibit_log {
 136         $write_log=0;
 137 }
 138
 139 # Pass it an array containing the arguments of a shell command like would
 140 # be run by exec(). It turns that into a line like you might enter at the
 141 # shell, escaping metacharacters and quoting arguments that contain spaces.
 142 sub escape_shell {
 143         my @args=@_;
 144         my $line="";
 145         my @ret;
 146         foreach my $word (@args) {
 147                 if ($word=~/\s/) {
 148                         # Escape only a few things since it will be quoted.
 149                         # Note we use double quotes because you cannot
 150                         # escape ' in single quotes, while " can be escaped
 151                         # in double.
 152                         # This does make -V"foo bar" turn into "-Vfoo bar",
 153                         # but that will be parsed identically by the shell
 154                         # anyway..
 155                         $word=~s/([\n`\$"\\])/\\$1/g;
 156                         push @ret, "\"$word\"";
 157                 }
 158                 else {
 159                         # This list is from _Unix in a Nutshell_. (except '#')
 160                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 161                         push @ret,$word;
 162                 }
 163         }
 164         return join(' ', @ret);
 165 }
 166
 167 # Run a command, and display the command to stdout if verbose mode is on.
 168 # All commands that modifiy files in $TMP should be ran via this
 169 # function.
 170 #
 171 # Note that this cannot handle complex commands, especially anything
 172 # involving redirection. Use complex_doit instead.
 173 sub doit {
 174         verbose_print(escape_shell(@_));
 175
 176         if (! $dh{NO_ACT}) {
 177                 system(@_) == 0 || _error_exitcode($_[0]);
 178         }
 179 }
 180
 181 # Run a command and display the command to stdout if verbose mode is on.
 182 # Use doit() if you can, instead of this function, because this function
 183 # forks a shell. However, this function can handle more complicated stuff
 184 # like redirection.
 185 sub complex_doit {
 186         verbose_print(join(" ",@_));
 187
 188         if (! $dh{NO_ACT}) {
 189                 # The join makes system get a scalar so it forks off a shell.
 190                 system(join(" ", @_)) == 0 || _error_exitcode(join(" ", @_))
 191         }
 192 }
 193
 194 sub _error_exitcode {
 195         my $command=shift;
 196         if ($? == -1) {
 197                 error("$command failed to to execute: $!");
 198         }
 199         elsif ($? & 127) {
 200                 error("$command died with signal ".($? & 127));
 201         }
 202         else {
 203                 error("$command returned exit code ".($? >> 8));
 204         }
 205 }
 206
 207 # Run a command that may have a huge number of arguments, like xargs does.
 208 # Pass in a reference to an array containing the arguments, and then other
 209 # parameters that are the command and any parameters that should be passed to
 210 # it each time.
 211 sub xargs {
 212         my $args=shift;
 213
 214         # The kernel can accept command lines up to 20k worth of characters.
 215         my $command_max=20000; # LINUX SPECIFIC!!
 216                         # I could use POSIX::ARG_MAX, but that would be slow.
 217
 218         # Figure out length of static portion of command.
 219         my $static_length=0;
 220         foreach (@_) {
 221                 $static_length+=length($_)+1;
 222         }
 223
 224         my @collect=();
 225         my $length=$static_length;
 226         foreach (@$args) {
 227                 if (length($_) + 1 + $static_length > $command_max) {
 228                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 229                 }
 230                 $length+=length($_) + 1;
 231                 if ($length < $command_max) {
 232                         push @collect, $_;
 233                 }
 234                 else {
 235                         doit(@_,@collect) if $#collect > -1;
 236                         @collect=($_);
 237                         $length=$static_length + length($_) + 1;
 238                 }
 239         }
 240         doit(@_,@collect) if $#collect > -1;
 241 }
 242
 243 # Print something if the verbose flag is on.
 244 sub verbose_print {
 245         my $message=shift;
 246
 247         if ($dh{VERBOSE}) {
 248                 print "\t$message\n";
 249         }
 250 }
 251
 252 # Output an error message and exit.
 253 sub error {
 254         my $message=shift;
 255
 256         warning($message);
 257         exit 1;
 258 }
 259
 260 # Output a warning.
 261 sub warning {
 262         my $message=shift;
 263
 264         print STDERR basename($0).": $message\n";
 265 }
 266
 267 # Returns the basename of the argument passed to it.
 268 sub basename {
 269         my $fn=shift;
 270
 271         $fn=~s/\/$//g; # ignore trailing slashes
 272         $fn=~s:^.*/(.*?)$:$1:;
 273         return $fn;
 274 }
 275
 276 # Returns the directory name of the argument passed to it.
 277 sub dirname {
 278         my $fn=shift;
 279
 280         $fn=~s/\/$//g; # ignore trailing slashes
 281         $fn=~s:^(.*)/.*?$:$1:;
 282         return $fn;
 283 }
 284
 285 # Pass in a number, will return true iff the current compatibility level
 286 # is less than or equal to that number.
 287 {
 288         my $warned_compat=0;
 289         my $c;
 290
 291         sub compat {
 292                 my $num=shift;
 293
 294                 if (! defined $c) {
 295                         $c=1;
 296                         if (defined $ENV{DH_COMPAT}) {
 297                                 $c=$ENV{DH_COMPAT};
 298                         }
 299                         elsif (-e 'debian/compat') {
 300                                 # Try the file..
 301                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 302                                 my $l=<COMPAT_IN>;
 303                                 if (! defined $l || ! length $l) {
 304                                         warning("debian/compat is empty, assuming level $c");
 305                                 }
 306                                 else {
 307                                         chomp $l;
 308                                         $c=$l;
 309                                 }
 310                         }
 311                 }
 312
 313                 if ($c < 4 && ! $warned_compat) {
 314                         warning("Compatibility levels before 5 are deprecated.");
 315                         $warned_compat=1;
 316                 }
 317
 318                 if ($c > $max_compat) {
 319                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 320                 }
 321
 322                 return ($c <= $num);
 323         }
 324 }
 325
 326 # Pass it a name of a binary package, it returns the name of the tmp dir to
 327 # use, for that package.
 328 sub tmpdir {
 329         my $package=shift;
 330
 331         if ($dh{TMPDIR}) {
 332                 return $dh{TMPDIR};
 333         }
 334         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 335                 # This is for back-compatibility with the debian/tmp tradition.
 336                 return "debian/tmp";
 337         }
 338         else {
 339                 return "debian/$package";
 340         }
 341 }
 342
 343 # Pass this the name of a binary package, and the name of the file wanted
 344 # for the package, and it will return the actual existing filename to use.
 345 #
 346 # It tries several filenames:
 347 #   * debian/package.filename.buildarch
 348 #   * debian/package.filename
 349 #   * debian/file (if the package is the main package)
 350 # If --name was specified then tonly the first two are tried, and they must
 351 # have the name after the pacage name:
 352 #   * debian/package.name.filename.buildarch
 353 #   * debian/package.name.filename
 354 sub pkgfile {
 355         my $package=shift;
 356         my $filename=shift;
 357
 358         if (defined $dh{NAME}) {
 359                 $filename="$dh{NAME}.$filename";
 360         }
 361
 362         my @try=("debian/$package.$filename.".buildarch(),
 363                  "debian/$package.$filename");
 364         if ($package eq $dh{MAINPACKAGE}) {
 365                 push @try, "debian/$filename";
 366         }
 367
 368         foreach my $file (@try) {
 369                 if (-f $file &&
 370                     (! $dh{IGNORE} || ! exists $dh{IGNORE}->{$file})) {
 371                         return $file;
 372                 }
 373
 374         }
 375
 376         return "";
 377
 378 }
 379
 380 # Pass it a name of a binary package, it returns the name to prefix to files
 381 # in debian/ for this package.
 382 sub pkgext {
 383         my $package=shift;
 384
 385         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 386                 return "";
 387         }
 388         return "$package.";
 389 }
 390
 391 # Pass it the name of a binary package, it returns the name to install
 392 # files by in eg, etc. Normally this is the same, but --name can override
 393 # it.
 394 sub pkgfilename {
 395         my $package=shift;
 396
 397         if (defined $dh{NAME}) {
 398                 return $dh{NAME};
 399         }
 400         return $package;
 401 }
 402
 403 # Returns 1 if the package is a native debian package, null otherwise.
 404 # As a side effect, sets $dh{VERSION} to the version of this package.
 405 {
 406         # Caches return code so it only needs to run dpkg-parsechangelog once.
 407         my %isnative_cache;
 408
 409         sub isnative {
 410                 my $package=shift;
 411
 412                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 413
 414                 # Make sure we look at the correct changelog.
 415                 my $isnative_changelog=pkgfile($package,"changelog");
 416                 if (! $isnative_changelog) {
 417                         $isnative_changelog="debian/changelog";
 418                 }
 419                 # Get the package version.
 420                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 421                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 422                 # Did the changelog parse fail?
 423                 if (! defined $dh{VERSION}) {
 424                         error("changelog parse failure");
 425                 }
 426
 427                 # Is this a native Debian package?
 428                 if ($dh{VERSION}=~m/.*-/) {
 429                         return $isnative_cache{$package}=0;
 430                 }
 431                 else {
 432                         return $isnative_cache{$package}=1;
 433                 }
 434         }
 435 }
 436
 437 # Automatically add a shell script snippet to a debian script.
 438 # Only works if the script has #DEBHELPER# in it.
 439 #
 440 # Parameters:
 441 # 1: package
 442 # 2: script to add to
 443 # 3: filename of snippet
 444 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 445 sub autoscript {
 446         my $package=shift;
 447         my $script=shift;
 448         my $filename=shift;
 449         my $sed=shift || "";
 450
 451         # This is the file we will modify.
 452         my $outfile="debian/".pkgext($package)."$script.debhelper";
 453
 454         # Figure out what shell script snippet to use.
 455         my $infile;
 456         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 457             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 458                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 459         }
 460         else {
 461                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 462                         $infile="/usr/share/debhelper/autoscripts/$filename";
 463                 }
 464                 else {
 465                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 466                 }
 467         }
 468
 469         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 470            && !compat(5)) {
 471                 # Add fragments to top so they run in reverse order when removing.
 472                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 473                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 474                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 475                 complex_doit("cat $outfile >> $outfile.new");
 476                 complex_doit("mv $outfile.new $outfile");
 477         }
 478         else {
 479                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 480                 complex_doit("sed \"$sed\" $infile >> $outfile");
 481                 complex_doit("echo '# End automatically added section' >> $outfile");
 482         }
 483 }
 484
 485 # Removes a whole substvar line.
 486 sub delsubstvar {
 487         my $package=shift;
 488         my $substvar=shift;
 489
 490         my $ext=pkgext($package);
 491         my $substvarfile="debian/${ext}substvars";
 492
 493         if (-e $substvarfile) {
 494                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 495                 doit("mv", "$substvarfile.new","$substvarfile");
 496         }
 497 }
 498
 499 # Adds a dependency on some package to the specified
 500 # substvar in a package's substvar's file.
 501 sub addsubstvar {
 502         my $package=shift;
 503         my $substvar=shift;
 504         my $deppackage=shift;
 505         my $verinfo=shift;
 506         my $remove=shift;
 507
 508         my $ext=pkgext($package);
 509         my $substvarfile="debian/${ext}substvars";
 510         my $str=$deppackage;
 511         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 512
 513         # Figure out what the line will look like, based on what's there
 514         # now, and what we're to add or remove.
 515         my $line="";
 516         if (-e $substvarfile) {
 517                 my %items;
 518                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 519                 while (<SUBSTVARS_IN>) {
 520                         chomp;
 521                         if (/^\Q$substvar\E=(.*)/) {
 522                                 %items = map { $_ => 1} split(", ", $1);
 523
 524                                 last;
 525                         }
 526                 }
 527                 close SUBSTVARS_IN;
 528                 if (! $remove) {
 529                         $items{$str}=1;
 530                 }
 531                 else {
 532                         delete $items{$str};
 533                 }
 534                 $line=join(", ", sort keys %items);
 535         }
 536         elsif (! $remove) {
 537                 $line=$str;
 538         }
 539
 540         if (length $line) {
 541                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 542                  doit("mv", "$substvarfile.new", $substvarfile);
 543         }
 544         else {
 545                 delsubstvar($package,$substvar);
 546         }
 547 }
 548
 549 # Reads in the specified file, one line at a time. splits on words,
 550 # and returns an array of arrays of the contents.
 551 # If a value is passed in as the second parameter, then glob
 552 # expansion is done in the directory specified by the parameter ("." is
 553 # frequently a good choice).
 554 sub filedoublearray {
 555         my $file=shift;
 556         my $globdir=shift;
 557
 558         my @ret;
 559         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 560         while (<DH_FARRAY_IN>) {
 561                 chomp;
 562                 # Only ignore comments and empty lines in v5 mode.
 563                 if (! compat(4)) {
 564                         next if /^#/ || /^$/;
 565                 }
 566                 my @line;
 567                 # Only do glob expansion in v3 mode.
 568                 #
 569                 # The tricky bit is that the glob expansion is done
 570                 # as if we were in the specified directory, so the
 571                 # filenames that come out are relative to it.
 572                 if (defined $globdir && ! compat(2)) {
 573                         for (map { glob "$globdir/$_" } split) {
 574                                 s#^$globdir/##;
 575                                 push @line, $_;
 576                         }
 577                 }
 578                 else {
 579                         @line = split;
 580                 }
 581                 push @ret, [@line];
 582         }
 583         close DH_FARRAY_IN;
 584
 585         return @ret;
 586 }
 587
 588 # Reads in the specified file, one word at a time, and returns an array of
 589 # the result. Can do globbing as does filedoublearray.
 590 sub filearray {
 591         return map { @$_ } filedoublearray(@_);
 592 }
 593
 594 # Passed a filename, returns true if -X says that file should be excluded.
 595 sub excludefile {
 596         my $filename = shift;
 597         foreach my $f (@{$dh{EXCLUDE}}) {
 598                 return 1 if $filename =~ /\Q$f\E/;
 599         }
 600         return 0;
 601 }
 602
 603 # Returns the build architecture. (Memoized)
 604 {
 605         my $arch;
 606
 607         sub buildarch {
 608                 return $arch if defined $arch;
 609
 610                 $arch=`dpkg-architecture -qDEB_HOST_ARCH 2>/dev/null` || error("dpkg-architecture failed");
 611                 chomp $arch;
 612                 return $arch;
 613         }
 614 }
 615
 616 # Passed an arch and a list of arches to match against, returns true if matched
 617 sub samearch {
 618         my $arch=shift;
 619         my @archlist=split(/\s+/,shift);
 620
 621         foreach my $a (@archlist) {
 622                 system("dpkg-architecture", "-a$arch", "-i$a") == 0 && return 1;
 623         }
 624
 625         return 0;
 626 }
 627
 628 # Returns a list of packages in the control file.
 629 # Must pass "arch" or "indep" or "same" to specify arch-dependant or
 630 # -independant or same arch packages. If nothing is specified, returns all
 631 # packages.
 632 # As a side effect, populates %package_arches and %package_types with the
 633 # types of all packages (not only those returned).
 634 my (%package_types, %package_arches);
 635 sub getpackages {
 636         my $type=shift;
 637
 638         %package_types=();
 639         %package_arches=();
 640
 641         $type="" if ! defined $type;
 642
 643         # Look up the build arch if we need to.
 644         my $buildarch='';
 645         if ($type eq 'same') {
 646                 $buildarch=buildarch();
 647         }
 648
 649         my $package="";
 650         my $arch="";
 651         my $package_type;
 652         my @list=();
 653         my %seen;
 654         open (CONTROL, 'debian/control') ||
 655                 error("cannot read debian/control: $!\n");
 656         while (<CONTROL>) {
 657                 chomp;
 658                 s/\s+$//;
 659                 if (/^Package:\s*(.*)/) {
 660                         $package=$1;
 661                         # Detect duplicate package names in the same control file.
 662                         if (! $seen{$package}) {
 663                                 $seen{$package}=1;
 664                         }
 665                         else {
 666                                 error("debian/control has a duplicate entry for $package");
 667                         }
 668                         $package_type="deb";
 669                 }
 670                 if (/^Architecture:\s*(.*)/) {
 671                         $arch=$1;
 672                 }
 673                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 674                         $package_type=$1;
 675                 }
 676
 677                 if (!$_ or eof) { # end of stanza.
 678                         if ($package) {
 679                                 $package_types{$package}=$package_type;
 680                                 $package_arches{$package}=$arch;
 681                         }
 682                         if ($package &&
 683                             (($type eq 'indep' && $arch eq 'all') ||
 684                              ($type eq 'arch' && $arch ne 'all') ||
 685                              ($type eq 'same' && ($arch eq 'any' || samearch($buildarch, $arch))) ||
 686                              ! $type)) {
 687                                 push @list, $package;
 688                                 $package="";
 689                                 $arch="";
 690                         }
 691                 }
 692         }
 693         close CONTROL;
 694
 695         return @list;
 696 }
 697
 698 # Returns the arch a package will build for.
 699 sub package_arch {
 700         my $package=shift;
 701
 702         if (! exists $package_arches{$package}) {
 703                 warning "package $package is not in control info";
 704                 return buildarch();
 705         }
 706         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 707 }
 708
 709 # Return true if a given package is really a udeb.
 710 sub is_udeb {
 711         my $package=shift;
 712
 713         if (! exists $package_types{$package}) {
 714                 warning "package $package is not in control info";
 715                 return 0;
 716         }
 717         return $package_types{$package} eq 'udeb';
 718 }
 719
 720 # Generates the filename that is used for a udeb package.
 721 sub udeb_filename {
 722         my $package=shift;
 723
 724         my $filearch=package_arch($package);
 725         isnative($package); # side effect
 726         my $version=$dh{VERSION};
 727         $version=~s/^[0-9]+://; # strip any epoch
 728         return "${package}_${version}_$filearch.udeb";
 729 }
 730
 731 # Handles #DEBHELPER# substitution in a script; also can generate a new
 732 # script from scratch if none exists but there is a .debhelper file for it.
 733 sub debhelper_script_subst {
 734         my $package=shift;
 735         my $script=shift;
 736
 737         my $tmp=tmpdir($package);
 738         my $ext=pkgext($package);
 739         my $file=pkgfile($package,$script);
 740
 741         if ($file ne '') {
 742                 if (-f "debian/$ext$script.debhelper") {
 743                         # Add this into the script, where it has #DEBHELPER#
 744                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 745                 }
 746                 else {
 747                         # Just get rid of any #DEBHELPER# in the script.
 748                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 749                 }
 750                 doit("chown","0:0","$tmp/DEBIAN/$script");
 751                 doit("chmod",755,"$tmp/DEBIAN/$script");
 752         }
 753         elsif ( -f "debian/$ext$script.debhelper" ) {
 754                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 755                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 756                 doit("chown","0:0","$tmp/DEBIAN/$script");
 757                 doit("chmod",755,"$tmp/DEBIAN/$script");
 758         }
 759 }
 760
 761 1