Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2008.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell
  18             &inhibit_log &load_log &write_log &dpkg_architecture_value
  19             &sourcepackage
  20             &is_make_jobserver_unavailable &clean_jobserver_makeflags);
  21
  22 my $max_compat=7;
  23
  24 sub init {
  25         my %params=@_;
  26
  27         # Check to see if an option line starts with a dash,
  28         # or DH_OPTIONS is set.
  29         # If so, we need to pass this off to the resource intensive
  30         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  31         if ((defined $ENV{DH_OPTIONS} && length $ENV{DH_OPTIONS}) ||
  32             (defined $ENV{DH_INTERNAL_OPTIONS} && length $ENV{DH_INTERNAL_OPTIONS}) ||
  33             grep /^-/, @ARGV) {
  34                 eval "use Debian::Debhelper::Dh_Getopt";
  35                 error($@) if $@;
  36                 Debian::Debhelper::Dh_Getopt::parseopts(%params);
  37         }
  38
  39         # Another way to set excludes.
  40         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  41                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  42         }
  43
  44         # Generate EXCLUDE_FIND.
  45         if ($dh{EXCLUDE}) {
  46                 $dh{EXCLUDE_FIND}='';
  47                 foreach (@{$dh{EXCLUDE}}) {
  48                         my $x=$_;
  49                         $x=escape_shell($x);
  50                         $x=~s/\./\\\\./g;
  51                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  52                 }
  53                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  54         }
  55
  56         # Check to see if DH_VERBOSE environment variable was set, if so,
  57         # make sure verbose is on.
  58         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  59                 $dh{VERBOSE}=1;
  60         }
  61
  62         # Check to see if DH_NO_ACT environment variable was set, if so,
  63         # make sure no act mode is on.
  64         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  65                 $dh{NO_ACT}=1;
  66         }
  67
  68         # Get the name of the main binary package (first one listed in
  69         # debian/control). Only if the main package was not set on the
  70         # command line.
  71         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  72                 my @allpackages=getpackages();
  73                 $dh{MAINPACKAGE}=$allpackages[0];
  74         }
  75
  76         # Check if packages to build have been specified, if not, fall back to
  77         # the default, building all relevant packages.
  78         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  79                 push @{$dh{DOPACKAGES}}, getpackages('both');
  80         }
  81
  82         # Check to see if -P was specified. If so, we can only act on a single
  83         # package.
  84         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  85                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  86         }
  87
  88         # Figure out which package is the first one we were instructed to build.
  89         # This package gets special treatement: files and directories specified on
  90         # the command line may affect it.
  91         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
  92
  93         # If no error handling function was specified, just propigate
  94         # errors out.
  95         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
  96                 $dh{ERROR_HANDLER}='exit \$?';
  97         }
  98 }
  99
 100 # Run at exit. Add the command to the log files for the packages it acted
 101 # on, if it's exiting successfully.
 102 my $write_log=1;
 103 sub END {
 104         if ($? == 0 && $write_log) {
 105                 write_log(basename($0), @{$dh{DOPACKAGES}});
 106         }
 107 }
 108
 109 sub load_log {
 110         my ($package, $db)=@_;
 111         my $ext=pkgext($package);
 112
 113         my @log;
 114         open(LOG, "<", "debian/${ext}debhelper.log") || return;
 115         while (<LOG>) {
 116                 chomp;
 117                 push @log, $_;
 118                 $db->{$package}{$_}=1 if defined $db;
 119         }
 120         close LOG;
 121         return @log;
 122 }
 123
 124 sub write_log {
 125         my $cmd=shift;
 126         my @packages=@_;
 127
 128         foreach my $package (@packages) {
 129                 my $ext=pkgext($package);
 130                 my $log="debian/${ext}debhelper.log";
 131                 open(LOG, ">>", $log) || error("failed to write to ${log}: $!");
 132                 print LOG $cmd."\n";
 133                 close LOG;
 134         }
 135 }
 136
 137 sub inhibit_log {
 138         $write_log=0;
 139 }
 140
 141 # Pass it an array containing the arguments of a shell command like would
 142 # be run by exec(). It turns that into a line like you might enter at the
 143 # shell, escaping metacharacters and quoting arguments that contain spaces.
 144 sub escape_shell {
 145         my @args=@_;
 146         my $line="";
 147         my @ret;
 148         foreach my $word (@args) {
 149                 if ($word=~/\s/) {
 150                         # Escape only a few things since it will be quoted.
 151                         # Note we use double quotes because you cannot
 152                         # escape ' in single quotes, while " can be escaped
 153                         # in double.
 154                         # This does make -V"foo bar" turn into "-Vfoo bar",
 155                         # but that will be parsed identically by the shell
 156                         # anyway..
 157                         $word=~s/([\n`\$"\\])/\\$1/g;
 158                         push @ret, "\"$word\"";
 159                 }
 160                 else {
 161                         # This list is from _Unix in a Nutshell_. (except '#')
 162                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 163                         push @ret,$word;
 164                 }
 165         }
 166         return join(' ', @ret);
 167 }
 168
 169 # Run a command, and display the command to stdout if verbose mode is on.
 170 # All commands that modifiy files in $TMP should be ran via this
 171 # function.
 172 #
 173 # Note that this cannot handle complex commands, especially anything
 174 # involving redirection. Use complex_doit instead.
 175 sub doit {
 176         verbose_print(escape_shell(@_));
 177
 178         if (! $dh{NO_ACT}) {
 179                 system(@_) == 0 || _error_exitcode(join(" ", @_));
 180         }
 181 }
 182
 183 # Run a command and display the command to stdout if verbose mode is on.
 184 # Use doit() if you can, instead of this function, because this function
 185 # forks a shell. However, this function can handle more complicated stuff
 186 # like redirection.
 187 sub complex_doit {
 188         verbose_print(join(" ",@_));
 189
 190         if (! $dh{NO_ACT}) {
 191                 # The join makes system get a scalar so it forks off a shell.
 192                 system(join(" ", @_)) == 0 || _error_exitcode(join(" ", @_))
 193         }
 194 }
 195
 196 sub _error_exitcode {
 197         my $command=shift;
 198         if ($? == -1) {
 199                 error("$command failed to to execute: $!");
 200         }
 201         elsif ($? & 127) {
 202                 error("$command died with signal ".($? & 127));
 203         }
 204         else {
 205                 error("$command returned exit code ".($? >> 8));
 206         }
 207 }
 208
 209 # Run a command that may have a huge number of arguments, like xargs does.
 210 # Pass in a reference to an array containing the arguments, and then other
 211 # parameters that are the command and any parameters that should be passed to
 212 # it each time.
 213 sub xargs {
 214         my $args=shift;
 215
 216         # The kernel can accept command lines up to 20k worth of characters.
 217         my $command_max=20000; # LINUX SPECIFIC!!
 218                         # I could use POSIX::ARG_MAX, but that would be slow.
 219
 220         # Figure out length of static portion of command.
 221         my $static_length=0;
 222         foreach (@_) {
 223                 $static_length+=length($_)+1;
 224         }
 225
 226         my @collect=();
 227         my $length=$static_length;
 228         foreach (@$args) {
 229                 if (length($_) + 1 + $static_length > $command_max) {
 230                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 231                 }
 232                 $length+=length($_) + 1;
 233                 if ($length < $command_max) {
 234                         push @collect, $_;
 235                 }
 236                 else {
 237                         doit(@_,@collect) if $#collect > -1;
 238                         @collect=($_);
 239                         $length=$static_length + length($_) + 1;
 240                 }
 241         }
 242         doit(@_,@collect) if $#collect > -1;
 243 }
 244
 245 # Print something if the verbose flag is on.
 246 sub verbose_print {
 247         my $message=shift;
 248
 249         if ($dh{VERBOSE}) {
 250                 print "\t$message\n";
 251         }
 252 }
 253
 254 # Output an error message and die (can be caught).
 255 sub error {
 256         my $message=shift;
 257
 258         die basename($0).": $message\n";
 259 }
 260
 261 # Output a warning.
 262 sub warning {
 263         my $message=shift;
 264
 265         print STDERR basename($0).": $message\n";
 266 }
 267
 268 # Returns the basename of the argument passed to it.
 269 sub basename {
 270         my $fn=shift;
 271
 272         $fn=~s/\/$//g; # ignore trailing slashes
 273         $fn=~s:^.*/(.*?)$:$1:;
 274         return $fn;
 275 }
 276
 277 # Returns the directory name of the argument passed to it.
 278 sub dirname {
 279         my $fn=shift;
 280
 281         $fn=~s/\/$//g; # ignore trailing slashes
 282         $fn=~s:^(.*)/.*?$:$1:;
 283         return $fn;
 284 }
 285
 286 # Pass in a number, will return true iff the current compatibility level
 287 # is less than or equal to that number.
 288 {
 289         my $warned_compat=0;
 290         my $c;
 291
 292         sub compat {
 293                 my $num=shift;
 294
 295                 if (! defined $c) {
 296                         $c=1;
 297                         if (defined $ENV{DH_COMPAT}) {
 298                                 $c=$ENV{DH_COMPAT};
 299                         }
 300                         elsif (-e 'debian/compat') {
 301                                 # Try the file..
 302                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 303                                 my $l=<COMPAT_IN>;
 304                                 close COMPAT_IN;
 305                                 if (! defined $l || ! length $l) {
 306                                         warning("debian/compat is empty, assuming level $c");
 307                                 }
 308                                 else {
 309                                         chomp $l;
 310                                         $c=$l;
 311                                 }
 312                         }
 313                 }
 314
 315                 if ($c <= 4 && ! $warned_compat) {
 316                         warning("Compatibility levels before 5 are deprecated.");
 317                         $warned_compat=1;
 318                 }
 319
 320                 if ($c > $max_compat) {
 321                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 322                 }
 323
 324                 return ($c <= $num);
 325         }
 326 }
 327
 328 # Pass it a name of a binary package, it returns the name of the tmp dir to
 329 # use, for that package.
 330 sub tmpdir {
 331         my $package=shift;
 332
 333         if ($dh{TMPDIR}) {
 334                 return $dh{TMPDIR};
 335         }
 336         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 337                 # This is for back-compatibility with the debian/tmp tradition.
 338                 return "debian/tmp";
 339         }
 340         else {
 341                 return "debian/$package";
 342         }
 343 }
 344
 345 # Pass this the name of a binary package, and the name of the file wanted
 346 # for the package, and it will return the actual existing filename to use.
 347 #
 348 # It tries several filenames:
 349 #   * debian/package.filename.buildarch
 350 #   * debian/package.filename.buildos
 351 #   * debian/package.filename
 352 #   * debian/filename (if the package is the main package)
 353 # If --name was specified then the files
 354 # must have the name after the package name:
 355 #   * debian/package.name.filename.buildarch
 356 #   * debian/package.name.filename.buildos
 357 #   * debian/package.name.filename
 358 #   * debian/name.filename (if the package is the main package)
 359 sub pkgfile {
 360         my $package=shift;
 361         my $filename=shift;
 362
 363         if (defined $dh{NAME}) {
 364                 $filename="$dh{NAME}.$filename";
 365         }
 366
 367         my @try=("debian/$package.$filename.".buildarch(),
 368                  "debian/$package.$filename.".buildos(),
 369                  "debian/$package.$filename");
 370         if ($package eq $dh{MAINPACKAGE}) {
 371                 push @try, "debian/$filename";
 372         }
 373
 374         foreach my $file (@try) {
 375                 if (-f $file &&
 376                     (! $dh{IGNORE} || ! exists $dh{IGNORE}->{$file})) {
 377                         return $file;
 378                 }
 379
 380         }
 381
 382         return "";
 383
 384 }
 385
 386 # Pass it a name of a binary package, it returns the name to prefix to files
 387 # in debian/ for this package.
 388 sub pkgext {
 389         my $package=shift;
 390
 391         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 392                 return "";
 393         }
 394         return "$package.";
 395 }
 396
 397 # Pass it the name of a binary package, it returns the name to install
 398 # files by in eg, etc. Normally this is the same, but --name can override
 399 # it.
 400 sub pkgfilename {
 401         my $package=shift;
 402
 403         if (defined $dh{NAME}) {
 404                 return $dh{NAME};
 405         }
 406         return $package;
 407 }
 408
 409 # Returns 1 if the package is a native debian package, null otherwise.
 410 # As a side effect, sets $dh{VERSION} to the version of this package.
 411 {
 412         # Caches return code so it only needs to run dpkg-parsechangelog once.
 413         my %isnative_cache;
 414
 415         sub isnative {
 416                 my $package=shift;
 417
 418                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 419
 420                 # Make sure we look at the correct changelog.
 421                 my $isnative_changelog=pkgfile($package,"changelog");
 422                 if (! $isnative_changelog) {
 423                         $isnative_changelog="debian/changelog";
 424                 }
 425                 # Get the package version.
 426                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 427                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 428                 # Did the changelog parse fail?
 429                 if (! defined $dh{VERSION}) {
 430                         error("changelog parse failure");
 431                 }
 432
 433                 # Is this a native Debian package?
 434                 if ($dh{VERSION}=~m/.*-/) {
 435                         return $isnative_cache{$package}=0;
 436                 }
 437                 else {
 438                         return $isnative_cache{$package}=1;
 439                 }
 440         }
 441 }
 442
 443 # Automatically add a shell script snippet to a debian script.
 444 # Only works if the script has #DEBHELPER# in it.
 445 #
 446 # Parameters:
 447 # 1: package
 448 # 2: script to add to
 449 # 3: filename of snippet
 450 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 451 sub autoscript {
 452         my $package=shift;
 453         my $script=shift;
 454         my $filename=shift;
 455         my $sed=shift || "";
 456
 457         # This is the file we will modify.
 458         my $outfile="debian/".pkgext($package)."$script.debhelper";
 459
 460         # Figure out what shell script snippet to use.
 461         my $infile;
 462         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 463             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 464                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 465         }
 466         else {
 467                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 468                         $infile="/usr/share/debhelper/autoscripts/$filename";
 469                 }
 470                 else {
 471                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 472                 }
 473         }
 474
 475         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 476            && !compat(5)) {
 477                 # Add fragments to top so they run in reverse order when removing.
 478                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 479                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 480                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 481                 complex_doit("cat $outfile >> $outfile.new");
 482                 complex_doit("mv $outfile.new $outfile");
 483         }
 484         else {
 485                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 486                 complex_doit("sed \"$sed\" $infile >> $outfile");
 487                 complex_doit("echo '# End automatically added section' >> $outfile");
 488         }
 489 }
 490
 491 # Removes a whole substvar line.
 492 sub delsubstvar {
 493         my $package=shift;
 494         my $substvar=shift;
 495
 496         my $ext=pkgext($package);
 497         my $substvarfile="debian/${ext}substvars";
 498
 499         if (-e $substvarfile) {
 500                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 501                 doit("mv", "$substvarfile.new","$substvarfile");
 502         }
 503 }
 504
 505 # Adds a dependency on some package to the specified
 506 # substvar in a package's substvar's file.
 507 sub addsubstvar {
 508         my $package=shift;
 509         my $substvar=shift;
 510         my $deppackage=shift;
 511         my $verinfo=shift;
 512         my $remove=shift;
 513
 514         my $ext=pkgext($package);
 515         my $substvarfile="debian/${ext}substvars";
 516         my $str=$deppackage;
 517         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 518
 519         # Figure out what the line will look like, based on what's there
 520         # now, and what we're to add or remove.
 521         my $line="";
 522         if (-e $substvarfile) {
 523                 my %items;
 524                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 525                 while (<SUBSTVARS_IN>) {
 526                         chomp;
 527                         if (/^\Q$substvar\E=(.*)/) {
 528                                 %items = map { $_ => 1} split(", ", $1);
 529
 530                                 last;
 531                         }
 532                 }
 533                 close SUBSTVARS_IN;
 534                 if (! $remove) {
 535                         $items{$str}=1;
 536                 }
 537                 else {
 538                         delete $items{$str};
 539                 }
 540                 $line=join(", ", sort keys %items);
 541         }
 542         elsif (! $remove) {
 543                 $line=$str;
 544         }
 545
 546         if (length $line) {
 547                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 548                  doit("mv", "$substvarfile.new", $substvarfile);
 549         }
 550         else {
 551                 delsubstvar($package,$substvar);
 552         }
 553 }
 554
 555 # Reads in the specified file, one line at a time. splits on words,
 556 # and returns an array of arrays of the contents.
 557 # If a value is passed in as the second parameter, then glob
 558 # expansion is done in the directory specified by the parameter ("." is
 559 # frequently a good choice).
 560 sub filedoublearray {
 561         my $file=shift;
 562         my $globdir=shift;
 563
 564         my @ret;
 565         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 566         while (<DH_FARRAY_IN>) {
 567                 chomp;
 568                 # Only ignore comments and empty lines in v5 mode.
 569                 if (! compat(4)) {
 570                         next if /^#/ || /^$/;
 571                 }
 572                 my @line;
 573                 # Only do glob expansion in v3 mode.
 574                 #
 575                 # The tricky bit is that the glob expansion is done
 576                 # as if we were in the specified directory, so the
 577                 # filenames that come out are relative to it.
 578                 if (defined $globdir && ! compat(2)) {
 579                         foreach (map { glob "$globdir/$_" } split) {
 580                                 s#^$globdir/##;
 581                                 push @line, $_;
 582                         }
 583                 }
 584                 else {
 585                         @line = split;
 586                 }
 587                 push @ret, [@line];
 588         }
 589         close DH_FARRAY_IN;
 590
 591         return @ret;
 592 }
 593
 594 # Reads in the specified file, one word at a time, and returns an array of
 595 # the result. Can do globbing as does filedoublearray.
 596 sub filearray {
 597         return map { @$_ } filedoublearray(@_);
 598 }
 599
 600 # Passed a filename, returns true if -X says that file should be excluded.
 601 sub excludefile {
 602         my $filename = shift;
 603         foreach my $f (@{$dh{EXCLUDE}}) {
 604                 return 1 if $filename =~ /\Q$f\E/;
 605         }
 606         return 0;
 607 }
 608
 609 {
 610         my %dpkg_arch_output;
 611         sub dpkg_architecture_value {
 612                 my $var = shift;
 613                 if (! exists($dpkg_arch_output{$var})) {
 614                         local $_;
 615                         open(PIPE, '-|', 'dpkg-architecture')
 616                                 or error("dpkg-architecture failed");
 617                         while (<PIPE>) {
 618                                 chomp;
 619                                 my ($k, $v) = split(/=/, $_, 2);
 620                                 $dpkg_arch_output{$k} = $v;
 621                         }
 622                         close(PIPE);
 623                 }
 624                 return $dpkg_arch_output{$var};
 625         }
 626 }
 627
 628 # Returns the build architecture.
 629 sub buildarch {
 630         dpkg_architecture_value('DEB_HOST_ARCH');
 631 }
 632
 633 # Returns the build OS.
 634 sub buildos {
 635         dpkg_architecture_value("DEB_HOST_ARCH_OS");
 636 }
 637
 638 # Passed an arch and a list of arches to match against, returns true if matched
 639 {
 640         my %knownsame;
 641
 642         sub samearch {
 643                 my $arch=shift;
 644                 my @archlist=split(/\s+/,shift);
 645
 646                 foreach my $a (@archlist) {
 647                         # Avoid expensive dpkg-architecture call to compare
 648                         # with a simple architecture name. "linux-any" and
 649                         # other architecture wildcards are (currently)
 650                         # always hypenated.
 651                         if ($a !~ /-/) {
 652                                 return 1 if $arch eq $a;
 653                         }
 654                         elsif (exists $knownsame{$arch}{$a}) {
 655                                 return 1 if $knownsame{$arch}{$a};
 656                         }
 657                         elsif (system("dpkg-architecture", "-a$arch", "-i$a") == 0) {
 658                                 return $knownsame{$arch}{$a}=1;
 659                         }
 660                         else {
 661                                 $knownsame{$arch}{$a}=0;
 662                         }
 663                 }
 664
 665                 return 0;
 666         }
 667 }
 668
 669 # Returns source package name
 670 sub sourcepackage {
 671         open (CONTROL, 'debian/control') ||
 672             error("cannot read debian/control: $!\n");
 673         while (<CONTROL>) {
 674                 chomp;
 675                 s/\s+$//;
 676                 if (/^Source:\s*(.*)/) {
 677                         close CONTROL;
 678                         return $1;
 679                 }
 680         }
 681
 682         close CONTROL;
 683         error("could not find Source: line in control file.");
 684 }
 685
 686 # Returns a list of packages in the control file.
 687 # Pass "arch" or "indep" to specify arch-dependant (that will be built
 688 # for the system's arch) or independant. If nothing is specified,
 689 # returns all packages. Also, "both" returns the union of "arch" and "indep"
 690 # packages.
 691 # As a side effect, populates %package_arches and %package_types with the
 692 # types of all packages (not only those returned).
 693 my (%package_types, %package_arches);
 694 sub getpackages {
 695         my $type=shift;
 696
 697         %package_types=();
 698         %package_arches=();
 699
 700         $type="" if ! defined $type;
 701
 702         my $package="";
 703         my $arch="";
 704         my $package_type;
 705         my @list=();
 706         my %seen;
 707         open (CONTROL, 'debian/control') ||
 708                 error("cannot read debian/control: $!\n");
 709         while (<CONTROL>) {
 710                 chomp;
 711                 s/\s+$//;
 712                 if (/^Package:\s*(.*)/) {
 713                         $package=$1;
 714                         # Detect duplicate package names in the same control file.
 715                         if (! $seen{$package}) {
 716                                 $seen{$package}=1;
 717                         }
 718                         else {
 719                                 error("debian/control has a duplicate entry for $package");
 720                         }
 721                         $package_type="deb";
 722                 }
 723                 if (/^Architecture:\s*(.*)/) {
 724                         $arch=$1;
 725                 }
 726                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 727                         $package_type=$1;
 728                 }
 729
 730                 if (!$_ or eof) { # end of stanza.
 731                         if ($package) {
 732                                 $package_types{$package}=$package_type;
 733                                 $package_arches{$package}=$arch;
 734                         }
 735
 736                         if ($package &&
 737                             ((($type eq 'indep' || $type eq 'both') && $arch eq 'all') ||
 738                              (($type eq 'arch'  || $type eq 'both') && ($arch eq 'any' ||
 739                                              ($arch ne 'all' &&
 740                                               samearch(buildarch(), $arch)))) ||
 741                              ! $type)) {
 742                                 push @list, $package;
 743                                 $package="";
 744                                 $arch="";
 745                         }
 746                 }
 747         }
 748         close CONTROL;
 749
 750         return @list;
 751 }
 752
 753 # Returns the arch a package will build for.
 754 sub package_arch {
 755         my $package=shift;
 756
 757         if (! exists $package_arches{$package}) {
 758                 warning "package $package is not in control info";
 759                 return buildarch();
 760         }
 761         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 762 }
 763
 764 # Return true if a given package is really a udeb.
 765 sub is_udeb {
 766         my $package=shift;
 767
 768         if (! exists $package_types{$package}) {
 769                 warning "package $package is not in control info";
 770                 return 0;
 771         }
 772         return $package_types{$package} eq 'udeb';
 773 }
 774
 775 # Generates the filename that is used for a udeb package.
 776 sub udeb_filename {
 777         my $package=shift;
 778
 779         my $filearch=package_arch($package);
 780         isnative($package); # side effect
 781         my $version=$dh{VERSION};
 782         $version=~s/^[0-9]+://; # strip any epoch
 783         return "${package}_${version}_$filearch.udeb";
 784 }
 785
 786 # Handles #DEBHELPER# substitution in a script; also can generate a new
 787 # script from scratch if none exists but there is a .debhelper file for it.
 788 sub debhelper_script_subst {
 789         my $package=shift;
 790         my $script=shift;
 791
 792         my $tmp=tmpdir($package);
 793         my $ext=pkgext($package);
 794         my $file=pkgfile($package,$script);
 795
 796         if ($file ne '') {
 797                 if (-f "debian/$ext$script.debhelper") {
 798                         # Add this into the script, where it has #DEBHELPER#
 799                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 800                 }
 801                 else {
 802                         # Just get rid of any #DEBHELPER# in the script.
 803                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 804                 }
 805                 doit("chown","0:0","$tmp/DEBIAN/$script");
 806                 doit("chmod",755,"$tmp/DEBIAN/$script");
 807         }
 808         elsif ( -f "debian/$ext$script.debhelper" ) {
 809                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 810                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 811                 doit("chown","0:0","$tmp/DEBIAN/$script");
 812                 doit("chmod",755,"$tmp/DEBIAN/$script");
 813         }
 814 }
 815
 816 # Checks if make's jobserver is enabled via MAKEFLAGS, but
 817 # the FD used to communicate with it is actually not available.
 818 sub is_make_jobserver_unavailable {
 819         if (exists $ENV{MAKEFLAGS} &&
 820             $ENV{MAKEFLAGS} =~ /(?:^|\s)--jobserver-fds=(\d+)/) {
 821                 if (!open(my $in, "<&$1")) {
 822                         return 1; # unavailable
 823                 }
 824                 else {
 825                         close $in;
 826                         return 0; # available
 827                 }
 828         }
 829
 830         return; # no jobserver specified
 831 }
 832
 833 # Cleans out jobserver options from MAKEFLAGS.
 834 sub clean_jobserver_makeflags {
 835         if (exists $ENV{MAKEFLAGS}) {
 836                 if ($ENV{MAKEFLAGS} =~ /(?:^|\s)--jobserver-fds=(\d+)/) {
 837                         $ENV{MAKEFLAGS} =~ s/(?:^|\s)--jobserver-fds=\S+//g;
 838                         $ENV{MAKEFLAGS} =~ s/(?:^|\s)-j\b//g;
 839                 }
 840                 delete $ENV{MAKEFLAGS} if $ENV{MAKEFLAGS} =~ /^\s*$/;
 841         }
 842 }
 843
 844 1