Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2000.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell);
  18
  19 my $max_compat=7;
  20
  21 sub init {
  22         # If DH_OPTIONS is set, prepend it @ARGV.
  23         if (defined($ENV{DH_OPTIONS})) {
  24                 # Ignore leading/trailing whitespace.
  25                 $ENV{DH_OPTIONS}=~s/^\s+//;
  26                 $ENV{DH_OPTIONS}=~s/\s+$//;
  27                 unshift @ARGV,split(/\s+/,$ENV{DH_OPTIONS});
  28         }
  29
  30         # Check to see if an argument on the command line starts with a dash.
  31         # if so, we need to pass this off to the resource intensive
  32         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  33         my $parseopt=undef;
  34         my $arg;
  35         foreach $arg (@ARGV) {
  36                 if ($arg=~m/^-/) {
  37                         $parseopt=1;
  38                         last;
  39                 }
  40         }
  41         if ($parseopt) {
  42                 eval "use Debian::Debhelper::Dh_Getopt";
  43                 error($!) if $@;
  44                 %dh=Debian::Debhelper::Dh_Getopt::parseopts();
  45         }
  46
  47         # Another way to set excludes.
  48         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  49                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  50         }
  51
  52         # Generate EXCLUDE_FIND.
  53         if ($dh{EXCLUDE}) {
  54                 $dh{EXCLUDE_FIND}='';
  55                 foreach (@{$dh{EXCLUDE}}) {
  56                         my $x=$_;
  57                         $x=escape_shell($x);
  58                         $x=~s/\./\\\\./g;
  59                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  60                 }
  61                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  62         }
  63
  64         # Check to see if DH_VERBOSE environment variable was set, if so,
  65         # make sure verbose is on.
  66         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  67                 $dh{VERBOSE}=1;
  68         }
  69
  70         # Check to see if DH_NO_ACT environment variable was set, if so,
  71         # make sure no act mode is on.
  72         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  73                 $dh{NO_ACT}=1;
  74         }
  75
  76         my @allpackages=getpackages();
  77         # Get the name of the main binary package (first one listed in
  78         # debian/control). Only if the main package was not set on the
  79         # command line.
  80         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  81                 $dh{MAINPACKAGE}=$allpackages[0];
  82         }
  83
  84         # Check if packages to build have been specified, if not, fall back to
  85         # the default, doing them all.
  86         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  87                 if ($dh{DOINDEP} || $dh{DOARCH} || $dh{DOSAME}) {
  88                         error("You asked that all arch in(dep) packages be built, but there are none of that type.");
  89                 }
  90                 push @{$dh{DOPACKAGES}},@allpackages;
  91         }
  92
  93         # Check to see if -P was specified. If so, we can only act on a single
  94         # package.
  95         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  96                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  97         }
  98
  99         # Figure out which package is the first one we were instructed to build.
 100         # This package gets special treatement: files and directories specified on
 101         # the command line may affect it.
 102         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
 103
 104         # If no error handling function was specified, just propigate
 105         # errors out.
 106         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
 107                 $dh{ERROR_HANDLER}='exit \$?';
 108         }
 109 }
 110
 111 # Run at exit. Add the command to the log files for the packages it acted
 112 # on, if it's exiting successfully.
 113 sub END {
 114         if ($? == 0) {
 115                 my $cmd=basename($0);
 116                 # dh_clean deletes the log, so should not recreate it at
 117                 # the end
 118                 if ($cmd ne "dh_clean" && $cmd ne "dh") {
 119                         foreach my $package (@{$dh{DOPACKAGES}}) {
 120                                 my $ext=pkgext($package);
 121                                 open(LOG, ">>", "debian/${ext}debhelper.log") || error("failed to write to log");
 122                                 print LOG $cmd."\n";
 123                                 close LOG;
 124                         }
 125                 }
 126         }
 127 }
 128
 129 # Pass it an array containing the arguments of a shell command like would
 130 # be run by exec(). It turns that into a line like you might enter at the
 131 # shell, escaping metacharacters and quoting arguments that contain spaces.
 132 sub escape_shell {
 133         my @args=@_;
 134         my $line="";
 135         my @ret;
 136         foreach my $word (@args) {
 137                 if ($word=~/\s/) {
 138                         # Escape only a few things since it will be quoted.
 139                         # Note we use double quotes because you cannot
 140                         # escape ' in single quotes, while " can be escaped
 141                         # in double.
 142                         # This does make -V"foo bar" turn into "-Vfoo bar",
 143                         # but that will be parsed identically by the shell
 144                         # anyway..
 145                         $word=~s/([\n`\$"\\])/\\$1/g;
 146                         push @ret, "\"$word\"";
 147                 }
 148                 else {
 149                         # This list is from _Unix in a Nutshell_. (except '#')
 150                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 151                         push @ret,$word;
 152                 }
 153         }
 154         return join(' ', @ret);
 155 }
 156
 157 # Run a command, and display the command to stdout if verbose mode is on.
 158 # All commands that modifiy files in $TMP should be ran via this
 159 # function.
 160 #
 161 # Note that this cannot handle complex commands, especially anything
 162 # involving redirection. Use complex_doit instead.
 163 sub doit {
 164         verbose_print(escape_shell(@_));
 165
 166         if (! $dh{NO_ACT}) {
 167                 my $ret=system(@_);
 168                 $ret == 0 || error("command returned error code $ret");
 169         }
 170 }
 171
 172 # Run a command and display the command to stdout if verbose mode is on.
 173 # Use doit() if you can, instead of this function, because this function
 174 # forks a shell. However, this function can handle more complicated stuff
 175 # like redirection.
 176 sub complex_doit {
 177         verbose_print(join(" ",@_));
 178
 179         if (! $dh{NO_ACT}) {
 180                 # The join makes system get a scalar so it forks off a shell.
 181                 system(join(" ",@_)) == 0
 182                         || error("command returned error code");
 183         }
 184 }
 185
 186 # Run a command that may have a huge number of arguments, like xargs does.
 187 # Pass in a reference to an array containing the arguments, and then other
 188 # parameters that are the command and any parameters that should be passed to
 189 # it each time.
 190 sub xargs {
 191         my $args=shift;
 192
 193         # The kernel can accept command lines up to 20k worth of characters.
 194         my $command_max=20000; # LINUX SPECIFIC!!
 195                         # I could use POSIX::ARG_MAX, but that would be slow.
 196
 197         # Figure out length of static portion of command.
 198         my $static_length=0;
 199         foreach (@_) {
 200                 $static_length+=length($_)+1;
 201         }
 202
 203         my @collect=();
 204         my $length=$static_length;
 205         foreach (@$args) {
 206                 if (length($_) + 1 + $static_length > $command_max) {
 207                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 208                 }
 209                 $length+=length($_) + 1;
 210                 if ($length < $command_max) {
 211                         push @collect, $_;
 212                 }
 213                 else {
 214                         doit(@_,@collect) if $#collect > -1;
 215                         @collect=($_);
 216                         $length=$static_length + length($_) + 1;
 217                 }
 218         }
 219         doit(@_,@collect) if $#collect > -1;
 220 }
 221
 222 # Print something if the verbose flag is on.
 223 sub verbose_print {
 224         my $message=shift;
 225
 226         if ($dh{VERBOSE}) {
 227                 print "\t$message\n";
 228         }
 229 }
 230
 231 # Output an error message and exit.
 232 sub error {
 233         my $message=shift;
 234
 235         warning($message);
 236         exit 1;
 237 }
 238
 239 # Output a warning.
 240 sub warning {
 241         my $message=shift;
 242
 243         print STDERR basename($0).": $message\n";
 244 }
 245
 246 # Returns the basename of the argument passed to it.
 247 sub basename {
 248         my $fn=shift;
 249
 250         $fn=~s/\/$//g; # ignore trailing slashes
 251         $fn=~s:^.*/(.*?)$:$1:;
 252         return $fn;
 253 }
 254
 255 # Returns the directory name of the argument passed to it.
 256 sub dirname {
 257         my $fn=shift;
 258
 259         $fn=~s/\/$//g; # ignore trailing slashes
 260         $fn=~s:^(.*)/.*?$:$1:;
 261         return $fn;
 262 }
 263
 264 # Pass in a number, will return true iff the current compatibility level
 265 # is less than or equal to that number.
 266 {
 267         my $warned_compat=0;
 268         my $c;
 269
 270         sub compat {
 271                 my $num=shift;
 272
 273                 if (! defined $c) {
 274                         $c=1;
 275                         if (defined $ENV{DH_COMPAT}) {
 276                                 $c=$ENV{DH_COMPAT};
 277                         }
 278                         elsif (-e 'debian/compat') {
 279                                 # Try the file..
 280                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 281                                 my $l=<COMPAT_IN>;
 282                                 if (! defined $l || ! length $l) {
 283                                         warning("debian/compat is empty, assuming level $c");
 284                                 }
 285                                 else {
 286                                         chomp $l;
 287                                         $c=$l;
 288                                 }
 289                         }
 290                 }
 291
 292                 if ($c < 4 && ! $warned_compat) {
 293                         warning("Compatibility levels before 4 are deprecated.");
 294                         $warned_compat=1;
 295                 }
 296
 297                 if ($c > $max_compat) {
 298                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 299                 }
 300
 301                 return ($c <= $num);
 302         }
 303 }
 304
 305 # Pass it a name of a binary package, it returns the name of the tmp dir to
 306 # use, for that package.
 307 sub tmpdir {
 308         my $package=shift;
 309
 310         if ($dh{TMPDIR}) {
 311                 return $dh{TMPDIR};
 312         }
 313         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 314                 # This is for back-compatibility with the debian/tmp tradition.
 315                 return "debian/tmp";
 316         }
 317         else {
 318                 return "debian/$package";
 319         }
 320 }
 321
 322 # Pass this the name of a binary package, and the name of the file wanted
 323 # for the package, and it will return the actual existing filename to use.
 324 #
 325 # It tries several filenames:
 326 #   * debian/package.filename.buildarch
 327 #   * debian/package.filename
 328 #   * debian/file (if the package is the main package)
 329 # If --name was specified then tonly the first two are tried, and they must
 330 # have the name after the pacage name:
 331 #   * debian/package.name.filename.buildarch
 332 #   * debian/package.name.filename
 333 sub pkgfile {
 334         my $package=shift;
 335         my $filename=shift;
 336
 337         if (defined $dh{NAME}) {
 338                 $filename="$dh{NAME}.$filename";
 339         }
 340
 341         my @try=("debian/$package.$filename.".buildarch(),
 342                  "debian/$package.$filename");
 343         if ($package eq $dh{MAINPACKAGE}) {
 344                 push @try, "debian/$filename";
 345         }
 346
 347         foreach my $file (@try) {
 348                 if (-f $file &&
 349                     (! $dh{IGNORE} || ! exists $dh{IGNORE}->{$file})) {
 350                         return $file;
 351                 }
 352
 353         }
 354
 355         return "";
 356
 357 }
 358
 359 # Pass it a name of a binary package, it returns the name to prefix to files
 360 # in debian/ for this package.
 361 sub pkgext {
 362         my $package=shift;
 363
 364         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 365                 return "";
 366         }
 367         return "$package.";
 368 }
 369
 370 # Pass it the name of a binary package, it returns the name to install
 371 # files by in eg, etc. Normally this is the same, but --name can override
 372 # it.
 373 sub pkgfilename {
 374         my $package=shift;
 375
 376         if (defined $dh{NAME}) {
 377                 return $dh{NAME};
 378         }
 379         return $package;
 380 }
 381
 382 # Returns 1 if the package is a native debian package, null otherwise.
 383 # As a side effect, sets $dh{VERSION} to the version of this package.
 384 {
 385         # Caches return code so it only needs to run dpkg-parsechangelog once.
 386         my %isnative_cache;
 387
 388         sub isnative {
 389                 my $package=shift;
 390
 391                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 392
 393                 # Make sure we look at the correct changelog.
 394                 my $isnative_changelog=pkgfile($package,"changelog");
 395                 if (! $isnative_changelog) {
 396                         $isnative_changelog="debian/changelog";
 397                 }
 398                 # Get the package version.
 399                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 400                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 401                 # Did the changelog parse fail?
 402                 if (! defined $dh{VERSION}) {
 403                         error("changelog parse failure");
 404                 }
 405
 406                 # Is this a native Debian package?
 407                 if ($dh{VERSION}=~m/.*-/) {
 408                         return $isnative_cache{$package}=0;
 409                 }
 410                 else {
 411                         return $isnative_cache{$package}=1;
 412                 }
 413         }
 414 }
 415
 416 # Automatically add a shell script snippet to a debian script.
 417 # Only works if the script has #DEBHELPER# in it.
 418 #
 419 # Parameters:
 420 # 1: package
 421 # 2: script to add to
 422 # 3: filename of snippet
 423 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 424 sub autoscript {
 425         my $package=shift;
 426         my $script=shift;
 427         my $filename=shift;
 428         my $sed=shift || "";
 429
 430         # This is the file we will modify.
 431         my $outfile="debian/".pkgext($package)."$script.debhelper";
 432
 433         # Figure out what shell script snippet to use.
 434         my $infile;
 435         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 436             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 437                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 438         }
 439         else {
 440                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 441                         $infile="/usr/share/debhelper/autoscripts/$filename";
 442                 }
 443                 else {
 444                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 445                 }
 446         }
 447
 448         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 449            && !compat(5)) {
 450                 # Add fragments to top so they run in reverse order when removing.
 451                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 452                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 453                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 454                 complex_doit("cat $outfile >> $outfile.new");
 455                 complex_doit("mv $outfile.new $outfile");
 456         }
 457         else {
 458                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 459                 complex_doit("sed \"$sed\" $infile >> $outfile");
 460                 complex_doit("echo '# End automatically added section' >> $outfile");
 461         }
 462 }
 463
 464 # Removes a whole substvar line.
 465 sub delsubstvar {
 466         my $package=shift;
 467         my $substvar=shift;
 468
 469         my $ext=pkgext($package);
 470         my $substvarfile="debian/${ext}substvars";
 471
 472         if (-e $substvarfile) {
 473                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 474                 doit("mv", "$substvarfile.new","$substvarfile");
 475         }
 476 }
 477
 478 # Adds a dependency on some package to the specified
 479 # substvar in a package's substvar's file.
 480 sub addsubstvar {
 481         my $package=shift;
 482         my $substvar=shift;
 483         my $deppackage=shift;
 484         my $verinfo=shift;
 485         my $remove=shift;
 486
 487         my $ext=pkgext($package);
 488         my $substvarfile="debian/${ext}substvars";
 489         my $str=$deppackage;
 490         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 491
 492         # Figure out what the line will look like, based on what's there
 493         # now, and what we're to add or remove.
 494         my $line="";
 495         if (-e $substvarfile) {
 496                 my %items;
 497                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 498                 while (<SUBSTVARS_IN>) {
 499                         chomp;
 500                         if (/^\Q$substvar\E=(.*)/) {
 501                                 %items = map { $_ => 1} split(", ", $1);
 502
 503                                 last;
 504                         }
 505                 }
 506                 close SUBSTVARS_IN;
 507                 if (! $remove) {
 508                         $items{$str}=1;
 509                 }
 510                 else {
 511                         delete $items{$str};
 512                 }
 513                 $line=join(", ", sort keys %items);
 514         }
 515         elsif (! $remove) {
 516                 $line=$str;
 517         }
 518
 519         if (length $line) {
 520                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 521                  doit("mv", "$substvarfile.new", $substvarfile);
 522         }
 523         else {
 524                 delsubstvar($package,$substvar);
 525         }
 526 }
 527
 528 # Reads in the specified file, one line at a time. splits on words,
 529 # and returns an array of arrays of the contents.
 530 # If a value is passed in as the second parameter, then glob
 531 # expansion is done in the directory specified by the parameter ("." is
 532 # frequently a good choice).
 533 sub filedoublearray {
 534         my $file=shift;
 535         my $globdir=shift;
 536
 537         my @ret;
 538         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 539         while (<DH_FARRAY_IN>) {
 540                 chomp;
 541                 # Only ignore comments and empty lines in v5 mode.
 542                 if (! compat(4)) {
 543                         next if /^#/ || /^$/;
 544                 }
 545                 my @line;
 546                 # Only do glob expansion in v3 mode.
 547                 #
 548                 # The tricky bit is that the glob expansion is done
 549                 # as if we were in the specified directory, so the
 550                 # filenames that come out are relative to it.
 551                 if (defined $globdir && ! compat(2)) {
 552                         for (map { glob "$globdir/$_" } split) {
 553                                 s#^$globdir/##;
 554                                 push @line, $_;
 555                         }
 556                 }
 557                 else {
 558                         @line = split;
 559                 }
 560                 push @ret, [@line];
 561         }
 562         close DH_FARRAY_IN;
 563
 564         return @ret;
 565 }
 566
 567 # Reads in the specified file, one word at a time, and returns an array of
 568 # the result. Can do globbing as does filedoublearray.
 569 sub filearray {
 570         return map { @$_ } filedoublearray(@_);
 571 }
 572
 573 # Passed a filename, returns true if -X says that file should be excluded.
 574 sub excludefile {
 575         my $filename = shift;
 576         foreach my $f (@{$dh{EXCLUDE}}) {
 577                 return 1 if $filename =~ /\Q$f\E/;
 578         }
 579         return 0;
 580 }
 581
 582 # Returns the build architecture. (Memoized)
 583 {
 584         my $arch;
 585
 586         sub buildarch {
 587                 return $arch if defined $arch;
 588
 589                 $arch=`dpkg-architecture -qDEB_HOST_ARCH 2>/dev/null` || error("dpkg-architecture failed");
 590                 chomp $arch;
 591                 return $arch;
 592         }
 593 }
 594
 595 # Passed an arch and a list of arches to match against, returns true if matched
 596 sub samearch {
 597         my $arch=shift;
 598         my @archlist=split(/\s+/,shift);
 599
 600         foreach my $a (@archlist) {
 601                 system("dpkg-architecture", "-a$arch", "-i$a") == 0 && return 1;
 602         }
 603
 604         return 0;
 605 }
 606
 607 # Returns a list of packages in the control file.
 608 # Must pass "arch" or "indep" or "same" to specify arch-dependant or
 609 # -independant or same arch packages. If nothing is specified, returns all
 610 # packages.
 611 # As a side effect, populates %package_arches and %package_types with the
 612 # types of all packages (not only those returned).
 613 my (%package_types, %package_arches);
 614 sub getpackages {
 615         my $type=shift;
 616
 617         %package_types=();
 618         %package_arches=();
 619
 620         $type="" if ! defined $type;
 621
 622         # Look up the build arch if we need to.
 623         my $buildarch='';
 624         if ($type eq 'same') {
 625                 $buildarch=buildarch();
 626         }
 627
 628         my $package="";
 629         my $arch="";
 630         my $package_type;
 631         my @list=();
 632         my %seen;
 633         open (CONTROL, 'debian/control') ||
 634                 error("cannot read debian/control: $!\n");
 635         while (<CONTROL>) {
 636                 chomp;
 637                 s/\s+$//;
 638                 if (/^Package:\s*(.*)/) {
 639                         $package=$1;
 640                         # Detect duplicate package names in the same control file.
 641                         if (! $seen{$package}) {
 642                                 $seen{$package}=1;
 643                         }
 644                         else {
 645                                 error("debian/control has a duplicate entry for $package");
 646                         }
 647                         $package_type="deb";
 648                 }
 649                 if (/^Architecture:\s*(.*)/) {
 650                         $arch=$1;
 651                 }
 652                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 653                         $package_type=$1;
 654                 }
 655
 656                 if (!$_ or eof) { # end of stanza.
 657                         if ($package) {
 658                                 $package_types{$package}=$package_type;
 659                                 $package_arches{$package}=$arch;
 660                         }
 661                         if ($package &&
 662                             (($type eq 'indep' && $arch eq 'all') ||
 663                              ($type eq 'arch' && $arch ne 'all') ||
 664                              ($type eq 'same' && ($arch eq 'any' || samearch($buildarch, $arch))) ||
 665                              ! $type)) {
 666                                 push @list, $package;
 667                                 $package="";
 668                                 $arch="";
 669                         }
 670                 }
 671         }
 672         close CONTROL;
 673
 674         return @list;
 675 }
 676
 677 # Returns the arch a package will build for.
 678 sub package_arch {
 679         my $package=shift;
 680
 681         if (! exists $package_arches{$package}) {
 682                 warning "package $package is not in control info";
 683                 return buildarch();
 684         }
 685         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 686 }
 687
 688 # Return true if a given package is really a udeb.
 689 sub is_udeb {
 690         my $package=shift;
 691
 692         if (! exists $package_types{$package}) {
 693                 warning "package $package is not in control info";
 694                 return 0;
 695         }
 696         return $package_types{$package} eq 'udeb';
 697 }
 698
 699 # Generates the filename that is used for a udeb package.
 700 sub udeb_filename {
 701         my $package=shift;
 702
 703         my $filearch=package_arch($package);
 704         isnative($package); # side effect
 705         my $version=$dh{VERSION};
 706         $version=~s/^[0-9]+://; # strip any epoch
 707         return "${package}_${version}_$filearch.udeb";
 708 }
 709
 710 # Handles #DEBHELPER# substitution in a script; also can generate a new
 711 # script from scratch if none exists but there is a .debhelper file for it.
 712 sub debhelper_script_subst {
 713         my $package=shift;
 714         my $script=shift;
 715
 716         my $tmp=tmpdir($package);
 717         my $ext=pkgext($package);
 718         my $file=pkgfile($package,$script);
 719
 720         if ($file ne '') {
 721                 if (-f "debian/$ext$script.debhelper") {
 722                         # Add this into the script, where it has #DEBHELPER#
 723                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 724                 }
 725                 else {
 726                         # Just get rid of any #DEBHELPER# in the script.
 727                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 728                 }
 729                 doit("chown","0:0","$tmp/DEBIAN/$script");
 730                 doit("chmod",755,"$tmp/DEBIAN/$script");
 731         }
 732         elsif ( -f "debian/$ext$script.debhelper" ) {
 733                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 734                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 735                 doit("chown","0:0","$tmp/DEBIAN/$script");
 736                 doit("chmod",755,"$tmp/DEBIAN/$script");
 737         }
 738 }
 739
 740 1