Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2000.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell
  18             &inhibit_log);
  19
  20 my $max_compat=7;
  21
  22 sub init {
  23         # If DH_OPTIONS is set, prepend it @ARGV.
  24         if (defined($ENV{DH_OPTIONS})) {
  25                 # Ignore leading/trailing whitespace.
  26                 $ENV{DH_OPTIONS}=~s/^\s+//;
  27                 $ENV{DH_OPTIONS}=~s/\s+$//;
  28                 unshift @ARGV,split(/\s+/,$ENV{DH_OPTIONS});
  29         }
  30
  31         # Check to see if an argument on the command line starts with a dash.
  32         # if so, we need to pass this off to the resource intensive
  33         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  34         my $parseopt=undef;
  35         my $arg;
  36         foreach $arg (@ARGV) {
  37                 if ($arg=~m/^-/) {
  38                         $parseopt=1;
  39                         last;
  40                 }
  41         }
  42         if ($parseopt) {
  43                 eval "use Debian::Debhelper::Dh_Getopt";
  44                 error($!) if $@;
  45                 %dh=Debian::Debhelper::Dh_Getopt::parseopts();
  46         }
  47
  48         # Another way to set excludes.
  49         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  50                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  51         }
  52
  53         # Generate EXCLUDE_FIND.
  54         if ($dh{EXCLUDE}) {
  55                 $dh{EXCLUDE_FIND}='';
  56                 foreach (@{$dh{EXCLUDE}}) {
  57                         my $x=$_;
  58                         $x=escape_shell($x);
  59                         $x=~s/\./\\\\./g;
  60                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  61                 }
  62                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  63         }
  64
  65         # Check to see if DH_VERBOSE environment variable was set, if so,
  66         # make sure verbose is on.
  67         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  68                 $dh{VERBOSE}=1;
  69         }
  70
  71         # Check to see if DH_NO_ACT environment variable was set, if so,
  72         # make sure no act mode is on.
  73         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  74                 $dh{NO_ACT}=1;
  75         }
  76
  77         my @allpackages=getpackages();
  78         # Get the name of the main binary package (first one listed in
  79         # debian/control). Only if the main package was not set on the
  80         # command line.
  81         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  82                 $dh{MAINPACKAGE}=$allpackages[0];
  83         }
  84
  85         # Check if packages to build have been specified, if not, fall back to
  86         # the default, doing them all.
  87         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  88                 if ($dh{DOINDEP} || $dh{DOARCH} || $dh{DOSAME}) {
  89                         error("You asked that all arch in(dep) packages be built, but there are none of that type.");
  90                 }
  91                 push @{$dh{DOPACKAGES}},@allpackages;
  92         }
  93
  94         # Check to see if -P was specified. If so, we can only act on a single
  95         # package.
  96         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  97                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  98         }
  99
 100         # Figure out which package is the first one we were instructed to build.
 101         # This package gets special treatement: files and directories specified on
 102         # the command line may affect it.
 103         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
 104
 105         # If no error handling function was specified, just propigate
 106         # errors out.
 107         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
 108                 $dh{ERROR_HANDLER}='exit \$?';
 109         }
 110 }
 111
 112 # Run at exit. Add the command to the log files for the packages it acted
 113 # on, if it's exiting successfully.
 114 my $write_log=1;
 115 sub END {
 116         if ($? == 0 && $write_log) {
 117                 my $cmd=basename($0);
 118                 foreach my $package (@{$dh{DOPACKAGES}}) {
 119                         my $ext=pkgext($package);
 120                         open(LOG, ">>", "debian/${ext}debhelper.log") || error("failed to write to log");
 121                         print LOG $cmd."\n";
 122                         close LOG;
 123                 }
 124         }
 125 }
 126
 127 sub inhibit_log {
 128         $write_log=0;
 129 }
 130
 131 # Pass it an array containing the arguments of a shell command like would
 132 # be run by exec(). It turns that into a line like you might enter at the
 133 # shell, escaping metacharacters and quoting arguments that contain spaces.
 134 sub escape_shell {
 135         my @args=@_;
 136         my $line="";
 137         my @ret;
 138         foreach my $word (@args) {
 139                 if ($word=~/\s/) {
 140                         # Escape only a few things since it will be quoted.
 141                         # Note we use double quotes because you cannot
 142                         # escape ' in single quotes, while " can be escaped
 143                         # in double.
 144                         # This does make -V"foo bar" turn into "-Vfoo bar",
 145                         # but that will be parsed identically by the shell
 146                         # anyway..
 147                         $word=~s/([\n`\$"\\])/\\$1/g;
 148                         push @ret, "\"$word\"";
 149                 }
 150                 else {
 151                         # This list is from _Unix in a Nutshell_. (except '#')
 152                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 153                         push @ret,$word;
 154                 }
 155         }
 156         return join(' ', @ret);
 157 }
 158
 159 # Run a command, and display the command to stdout if verbose mode is on.
 160 # All commands that modifiy files in $TMP should be ran via this
 161 # function.
 162 #
 163 # Note that this cannot handle complex commands, especially anything
 164 # involving redirection. Use complex_doit instead.
 165 sub doit {
 166         verbose_print(escape_shell(@_));
 167
 168         if (! $dh{NO_ACT}) {
 169                 my $ret=system(@_);
 170                 $ret == 0 || error("command returned error code $ret");
 171         }
 172 }
 173
 174 # Run a command and display the command to stdout if verbose mode is on.
 175 # Use doit() if you can, instead of this function, because this function
 176 # forks a shell. However, this function can handle more complicated stuff
 177 # like redirection.
 178 sub complex_doit {
 179         verbose_print(join(" ",@_));
 180
 181         if (! $dh{NO_ACT}) {
 182                 # The join makes system get a scalar so it forks off a shell.
 183                 system(join(" ",@_)) == 0
 184                         || error("command returned error code");
 185         }
 186 }
 187
 188 # Run a command that may have a huge number of arguments, like xargs does.
 189 # Pass in a reference to an array containing the arguments, and then other
 190 # parameters that are the command and any parameters that should be passed to
 191 # it each time.
 192 sub xargs {
 193         my $args=shift;
 194
 195         # The kernel can accept command lines up to 20k worth of characters.
 196         my $command_max=20000; # LINUX SPECIFIC!!
 197                         # I could use POSIX::ARG_MAX, but that would be slow.
 198
 199         # Figure out length of static portion of command.
 200         my $static_length=0;
 201         foreach (@_) {
 202                 $static_length+=length($_)+1;
 203         }
 204
 205         my @collect=();
 206         my $length=$static_length;
 207         foreach (@$args) {
 208                 if (length($_) + 1 + $static_length > $command_max) {
 209                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 210                 }
 211                 $length+=length($_) + 1;
 212                 if ($length < $command_max) {
 213                         push @collect, $_;
 214                 }
 215                 else {
 216                         doit(@_,@collect) if $#collect > -1;
 217                         @collect=($_);
 218                         $length=$static_length + length($_) + 1;
 219                 }
 220         }
 221         doit(@_,@collect) if $#collect > -1;
 222 }
 223
 224 # Print something if the verbose flag is on.
 225 sub verbose_print {
 226         my $message=shift;
 227
 228         if ($dh{VERBOSE}) {
 229                 print "\t$message\n";
 230         }
 231 }
 232
 233 # Output an error message and exit.
 234 sub error {
 235         my $message=shift;
 236
 237         warning($message);
 238         exit 1;
 239 }
 240
 241 # Output a warning.
 242 sub warning {
 243         my $message=shift;
 244
 245         print STDERR basename($0).": $message\n";
 246 }
 247
 248 # Returns the basename of the argument passed to it.
 249 sub basename {
 250         my $fn=shift;
 251
 252         $fn=~s/\/$//g; # ignore trailing slashes
 253         $fn=~s:^.*/(.*?)$:$1:;
 254         return $fn;
 255 }
 256
 257 # Returns the directory name of the argument passed to it.
 258 sub dirname {
 259         my $fn=shift;
 260
 261         $fn=~s/\/$//g; # ignore trailing slashes
 262         $fn=~s:^(.*)/.*?$:$1:;
 263         return $fn;
 264 }
 265
 266 # Pass in a number, will return true iff the current compatibility level
 267 # is less than or equal to that number.
 268 {
 269         my $warned_compat=0;
 270         my $c;
 271
 272         sub compat {
 273                 my $num=shift;
 274
 275                 if (! defined $c) {
 276                         $c=1;
 277                         if (defined $ENV{DH_COMPAT}) {
 278                                 $c=$ENV{DH_COMPAT};
 279                         }
 280                         elsif (-e 'debian/compat') {
 281                                 # Try the file..
 282                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 283                                 my $l=<COMPAT_IN>;
 284                                 if (! defined $l || ! length $l) {
 285                                         warning("debian/compat is empty, assuming level $c");
 286                                 }
 287                                 else {
 288                                         chomp $l;
 289                                         $c=$l;
 290                                 }
 291                         }
 292                 }
 293
 294                 if ($c < 4 && ! $warned_compat) {
 295                         warning("Compatibility levels before 4 are deprecated.");
 296                         $warned_compat=1;
 297                 }
 298
 299                 if ($c > $max_compat) {
 300                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 301                 }
 302
 303                 return ($c <= $num);
 304         }
 305 }
 306
 307 # Pass it a name of a binary package, it returns the name of the tmp dir to
 308 # use, for that package.
 309 sub tmpdir {
 310         my $package=shift;
 311
 312         if ($dh{TMPDIR}) {
 313                 return $dh{TMPDIR};
 314         }
 315         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 316                 # This is for back-compatibility with the debian/tmp tradition.
 317                 return "debian/tmp";
 318         }
 319         else {
 320                 return "debian/$package";
 321         }
 322 }
 323
 324 # Pass this the name of a binary package, and the name of the file wanted
 325 # for the package, and it will return the actual existing filename to use.
 326 #
 327 # It tries several filenames:
 328 #   * debian/package.filename.buildarch
 329 #   * debian/package.filename
 330 #   * debian/file (if the package is the main package)
 331 # If --name was specified then tonly the first two are tried, and they must
 332 # have the name after the pacage name:
 333 #   * debian/package.name.filename.buildarch
 334 #   * debian/package.name.filename
 335 sub pkgfile {
 336         my $package=shift;
 337         my $filename=shift;
 338
 339         if (defined $dh{NAME}) {
 340                 $filename="$dh{NAME}.$filename";
 341         }
 342
 343         my @try=("debian/$package.$filename.".buildarch(),
 344                  "debian/$package.$filename");
 345         if ($package eq $dh{MAINPACKAGE}) {
 346                 push @try, "debian/$filename";
 347         }
 348
 349         foreach my $file (@try) {
 350                 if (-f $file &&
 351                     (! $dh{IGNORE} || ! exists $dh{IGNORE}->{$file})) {
 352                         return $file;
 353                 }
 354
 355         }
 356
 357         return "";
 358
 359 }
 360
 361 # Pass it a name of a binary package, it returns the name to prefix to files
 362 # in debian/ for this package.
 363 sub pkgext {
 364         my $package=shift;
 365
 366         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 367                 return "";
 368         }
 369         return "$package.";
 370 }
 371
 372 # Pass it the name of a binary package, it returns the name to install
 373 # files by in eg, etc. Normally this is the same, but --name can override
 374 # it.
 375 sub pkgfilename {
 376         my $package=shift;
 377
 378         if (defined $dh{NAME}) {
 379                 return $dh{NAME};
 380         }
 381         return $package;
 382 }
 383
 384 # Returns 1 if the package is a native debian package, null otherwise.
 385 # As a side effect, sets $dh{VERSION} to the version of this package.
 386 {
 387         # Caches return code so it only needs to run dpkg-parsechangelog once.
 388         my %isnative_cache;
 389
 390         sub isnative {
 391                 my $package=shift;
 392
 393                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 394
 395                 # Make sure we look at the correct changelog.
 396                 my $isnative_changelog=pkgfile($package,"changelog");
 397                 if (! $isnative_changelog) {
 398                         $isnative_changelog="debian/changelog";
 399                 }
 400                 # Get the package version.
 401                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 402                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 403                 # Did the changelog parse fail?
 404                 if (! defined $dh{VERSION}) {
 405                         error("changelog parse failure");
 406                 }
 407
 408                 # Is this a native Debian package?
 409                 if ($dh{VERSION}=~m/.*-/) {
 410                         return $isnative_cache{$package}=0;
 411                 }
 412                 else {
 413                         return $isnative_cache{$package}=1;
 414                 }
 415         }
 416 }
 417
 418 # Automatically add a shell script snippet to a debian script.
 419 # Only works if the script has #DEBHELPER# in it.
 420 #
 421 # Parameters:
 422 # 1: package
 423 # 2: script to add to
 424 # 3: filename of snippet
 425 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 426 sub autoscript {
 427         my $package=shift;
 428         my $script=shift;
 429         my $filename=shift;
 430         my $sed=shift || "";
 431
 432         # This is the file we will modify.
 433         my $outfile="debian/".pkgext($package)."$script.debhelper";
 434
 435         # Figure out what shell script snippet to use.
 436         my $infile;
 437         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 438             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 439                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 440         }
 441         else {
 442                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 443                         $infile="/usr/share/debhelper/autoscripts/$filename";
 444                 }
 445                 else {
 446                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 447                 }
 448         }
 449
 450         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 451            && !compat(5)) {
 452                 # Add fragments to top so they run in reverse order when removing.
 453                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 454                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 455                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 456                 complex_doit("cat $outfile >> $outfile.new");
 457                 complex_doit("mv $outfile.new $outfile");
 458         }
 459         else {
 460                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 461                 complex_doit("sed \"$sed\" $infile >> $outfile");
 462                 complex_doit("echo '# End automatically added section' >> $outfile");
 463         }
 464 }
 465
 466 # Removes a whole substvar line.
 467 sub delsubstvar {
 468         my $package=shift;
 469         my $substvar=shift;
 470
 471         my $ext=pkgext($package);
 472         my $substvarfile="debian/${ext}substvars";
 473
 474         if (-e $substvarfile) {
 475                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 476                 doit("mv", "$substvarfile.new","$substvarfile");
 477         }
 478 }
 479
 480 # Adds a dependency on some package to the specified
 481 # substvar in a package's substvar's file.
 482 sub addsubstvar {
 483         my $package=shift;
 484         my $substvar=shift;
 485         my $deppackage=shift;
 486         my $verinfo=shift;
 487         my $remove=shift;
 488
 489         my $ext=pkgext($package);
 490         my $substvarfile="debian/${ext}substvars";
 491         my $str=$deppackage;
 492         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 493
 494         # Figure out what the line will look like, based on what's there
 495         # now, and what we're to add or remove.
 496         my $line="";
 497         if (-e $substvarfile) {
 498                 my %items;
 499                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 500                 while (<SUBSTVARS_IN>) {
 501                         chomp;
 502                         if (/^\Q$substvar\E=(.*)/) {
 503                                 %items = map { $_ => 1} split(", ", $1);
 504
 505                                 last;
 506                         }
 507                 }
 508                 close SUBSTVARS_IN;
 509                 if (! $remove) {
 510                         $items{$str}=1;
 511                 }
 512                 else {
 513                         delete $items{$str};
 514                 }
 515                 $line=join(", ", sort keys %items);
 516         }
 517         elsif (! $remove) {
 518                 $line=$str;
 519         }
 520
 521         if (length $line) {
 522                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 523                  doit("mv", "$substvarfile.new", $substvarfile);
 524         }
 525         else {
 526                 delsubstvar($package,$substvar);
 527         }
 528 }
 529
 530 # Reads in the specified file, one line at a time. splits on words,
 531 # and returns an array of arrays of the contents.
 532 # If a value is passed in as the second parameter, then glob
 533 # expansion is done in the directory specified by the parameter ("." is
 534 # frequently a good choice).
 535 sub filedoublearray {
 536         my $file=shift;
 537         my $globdir=shift;
 538
 539         my @ret;
 540         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 541         while (<DH_FARRAY_IN>) {
 542                 chomp;
 543                 # Only ignore comments and empty lines in v5 mode.
 544                 if (! compat(4)) {
 545                         next if /^#/ || /^$/;
 546                 }
 547                 my @line;
 548                 # Only do glob expansion in v3 mode.
 549                 #
 550                 # The tricky bit is that the glob expansion is done
 551                 # as if we were in the specified directory, so the
 552                 # filenames that come out are relative to it.
 553                 if (defined $globdir && ! compat(2)) {
 554                         for (map { glob "$globdir/$_" } split) {
 555                                 s#^$globdir/##;
 556                                 push @line, $_;
 557                         }
 558                 }
 559                 else {
 560                         @line = split;
 561                 }
 562                 push @ret, [@line];
 563         }
 564         close DH_FARRAY_IN;
 565
 566         return @ret;
 567 }
 568
 569 # Reads in the specified file, one word at a time, and returns an array of
 570 # the result. Can do globbing as does filedoublearray.
 571 sub filearray {
 572         return map { @$_ } filedoublearray(@_);
 573 }
 574
 575 # Passed a filename, returns true if -X says that file should be excluded.
 576 sub excludefile {
 577         my $filename = shift;
 578         foreach my $f (@{$dh{EXCLUDE}}) {
 579                 return 1 if $filename =~ /\Q$f\E/;
 580         }
 581         return 0;
 582 }
 583
 584 # Returns the build architecture. (Memoized)
 585 {
 586         my $arch;
 587
 588         sub buildarch {
 589                 return $arch if defined $arch;
 590
 591                 $arch=`dpkg-architecture -qDEB_HOST_ARCH 2>/dev/null` || error("dpkg-architecture failed");
 592                 chomp $arch;
 593                 return $arch;
 594         }
 595 }
 596
 597 # Passed an arch and a list of arches to match against, returns true if matched
 598 sub samearch {
 599         my $arch=shift;
 600         my @archlist=split(/\s+/,shift);
 601
 602         foreach my $a (@archlist) {
 603                 system("dpkg-architecture", "-a$arch", "-i$a") == 0 && return 1;
 604         }
 605
 606         return 0;
 607 }
 608
 609 # Returns a list of packages in the control file.
 610 # Must pass "arch" or "indep" or "same" to specify arch-dependant or
 611 # -independant or same arch packages. If nothing is specified, returns all
 612 # packages.
 613 # As a side effect, populates %package_arches and %package_types with the
 614 # types of all packages (not only those returned).
 615 my (%package_types, %package_arches);
 616 sub getpackages {
 617         my $type=shift;
 618
 619         %package_types=();
 620         %package_arches=();
 621
 622         $type="" if ! defined $type;
 623
 624         # Look up the build arch if we need to.
 625         my $buildarch='';
 626         if ($type eq 'same') {
 627                 $buildarch=buildarch();
 628         }
 629
 630         my $package="";
 631         my $arch="";
 632         my $package_type;
 633         my @list=();
 634         my %seen;
 635         open (CONTROL, 'debian/control') ||
 636                 error("cannot read debian/control: $!\n");
 637         while (<CONTROL>) {
 638                 chomp;
 639                 s/\s+$//;
 640                 if (/^Package:\s*(.*)/) {
 641                         $package=$1;
 642                         # Detect duplicate package names in the same control file.
 643                         if (! $seen{$package}) {
 644                                 $seen{$package}=1;
 645                         }
 646                         else {
 647                                 error("debian/control has a duplicate entry for $package");
 648                         }
 649                         $package_type="deb";
 650                 }
 651                 if (/^Architecture:\s*(.*)/) {
 652                         $arch=$1;
 653                 }
 654                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 655                         $package_type=$1;
 656                 }
 657
 658                 if (!$_ or eof) { # end of stanza.
 659                         if ($package) {
 660                                 $package_types{$package}=$package_type;
 661                                 $package_arches{$package}=$arch;
 662                         }
 663                         if ($package &&
 664                             (($type eq 'indep' && $arch eq 'all') ||
 665                              ($type eq 'arch' && $arch ne 'all') ||
 666                              ($type eq 'same' && ($arch eq 'any' || samearch($buildarch, $arch))) ||
 667                              ! $type)) {
 668                                 push @list, $package;
 669                                 $package="";
 670                                 $arch="";
 671                         }
 672                 }
 673         }
 674         close CONTROL;
 675
 676         return @list;
 677 }
 678
 679 # Returns the arch a package will build for.
 680 sub package_arch {
 681         my $package=shift;
 682
 683         if (! exists $package_arches{$package}) {
 684                 warning "package $package is not in control info";
 685                 return buildarch();
 686         }
 687         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 688 }
 689
 690 # Return true if a given package is really a udeb.
 691 sub is_udeb {
 692         my $package=shift;
 693
 694         if (! exists $package_types{$package}) {
 695                 warning "package $package is not in control info";
 696                 return 0;
 697         }
 698         return $package_types{$package} eq 'udeb';
 699 }
 700
 701 # Generates the filename that is used for a udeb package.
 702 sub udeb_filename {
 703         my $package=shift;
 704
 705         my $filearch=package_arch($package);
 706         isnative($package); # side effect
 707         my $version=$dh{VERSION};
 708         $version=~s/^[0-9]+://; # strip any epoch
 709         return "${package}_${version}_$filearch.udeb";
 710 }
 711
 712 # Handles #DEBHELPER# substitution in a script; also can generate a new
 713 # script from scratch if none exists but there is a .debhelper file for it.
 714 sub debhelper_script_subst {
 715         my $package=shift;
 716         my $script=shift;
 717
 718         my $tmp=tmpdir($package);
 719         my $ext=pkgext($package);
 720         my $file=pkgfile($package,$script);
 721
 722         if ($file ne '') {
 723                 if (-f "debian/$ext$script.debhelper") {
 724                         # Add this into the script, where it has #DEBHELPER#
 725                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 726                 }
 727                 else {
 728                         # Just get rid of any #DEBHELPER# in the script.
 729                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 730                 }
 731                 doit("chown","0:0","$tmp/DEBIAN/$script");
 732                 doit("chmod",755,"$tmp/DEBIAN/$script");
 733         }
 734         elsif ( -f "debian/$ext$script.debhelper" ) {
 735                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 736                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 737                 doit("chown","0:0","$tmp/DEBIAN/$script");
 738                 doit("chmod",755,"$tmp/DEBIAN/$script");
 739         }
 740 }
 741
 742 1