Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2008.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell
  18             &inhibit_log &load_log &write_log);
  19
  20 my $max_compat=7;
  21
  22 sub init {
  23         my %params=@_;
  24
  25         # Check to see if an option line starts with a dash,
  26         # or DH_OPTIONS is set.
  27         # If so, we need to pass this off to the resource intensive
  28         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  29         if ((defined $ENV{DH_OPTIONS} && length $ENV{DH_OPTIONS}) ||
  30             (defined $ENV{DH_INTERNAL_OPTIONS} && length $ENV{DH_INTERNAL_OPTIONS}) ||
  31             grep /^-/, @ARGV) {
  32                 eval "use Debian::Debhelper::Dh_Getopt";
  33                 error($@) if $@;
  34                 Debian::Debhelper::Dh_Getopt::parseopts($params{options});
  35         }
  36
  37         # Another way to set excludes.
  38         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  39                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  40         }
  41
  42         # Generate EXCLUDE_FIND.
  43         if ($dh{EXCLUDE}) {
  44                 $dh{EXCLUDE_FIND}='';
  45                 foreach (@{$dh{EXCLUDE}}) {
  46                         my $x=$_;
  47                         $x=escape_shell($x);
  48                         $x=~s/\./\\\\./g;
  49                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  50                 }
  51                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  52         }
  53
  54         # Check to see if DH_VERBOSE environment variable was set, if so,
  55         # make sure verbose is on.
  56         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  57                 $dh{VERBOSE}=1;
  58         }
  59
  60         # Check to see if DH_NO_ACT environment variable was set, if so,
  61         # make sure no act mode is on.
  62         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  63                 $dh{NO_ACT}=1;
  64         }
  65
  66         my @allpackages=getpackages();
  67         # Get the name of the main binary package (first one listed in
  68         # debian/control). Only if the main package was not set on the
  69         # command line.
  70         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  71                 $dh{MAINPACKAGE}=$allpackages[0];
  72         }
  73
  74         # Check if packages to build have been specified, if not, fall back to
  75         # the default, doing them all.
  76         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  77                 push @{$dh{DOPACKAGES}},@allpackages;
  78         }
  79
  80         # Check to see if -P was specified. If so, we can only act on a single
  81         # package.
  82         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  83                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  84         }
  85
  86         # Figure out which package is the first one we were instructed to build.
  87         # This package gets special treatement: files and directories specified on
  88         # the command line may affect it.
  89         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
  90
  91         # If no error handling function was specified, just propigate
  92         # errors out.
  93         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
  94                 $dh{ERROR_HANDLER}='exit \$?';
  95         }
  96 }
  97
  98 # Run at exit. Add the command to the log files for the packages it acted
  99 # on, if it's exiting successfully.
 100 my $write_log=1;
 101 sub END {
 102         if ($? == 0 && $write_log) {
 103                 write_log(basename($0), @{$dh{DOPACKAGES}});
 104         }
 105 }
 106
 107 sub load_log {
 108         my ($package, $db)=@_;
 109         my $ext=pkgext($package);
 110
 111         my @log;
 112         open(LOG, "<", "debian/${ext}debhelper.log") || return;
 113         while (<LOG>) {
 114                 chomp;
 115                 push @log, $_;
 116                 $db->{$package}{$_}=1 if defined $db;
 117         }
 118         close LOG;
 119         return @log;
 120 }
 121
 122 sub write_log {
 123         my $cmd=shift;
 124         my @packages=@_;
 125
 126         foreach my $package (@packages) {
 127                 my $ext=pkgext($package);
 128                 my $log="debian/${ext}debhelper.log";
 129                 open(LOG, ">>", $log) || error("failed to write to ${log}: $!");
 130                 print LOG $cmd."\n";
 131                 close LOG;
 132         }
 133 }
 134
 135 sub inhibit_log {
 136         $write_log=0;
 137 }
 138
 139 # Pass it an array containing the arguments of a shell command like would
 140 # be run by exec(). It turns that into a line like you might enter at the
 141 # shell, escaping metacharacters and quoting arguments that contain spaces.
 142 sub escape_shell {
 143         my @args=@_;
 144         my $line="";
 145         my @ret;
 146         foreach my $word (@args) {
 147                 if ($word=~/\s/) {
 148                         # Escape only a few things since it will be quoted.
 149                         # Note we use double quotes because you cannot
 150                         # escape ' in single quotes, while " can be escaped
 151                         # in double.
 152                         # This does make -V"foo bar" turn into "-Vfoo bar",
 153                         # but that will be parsed identically by the shell
 154                         # anyway..
 155                         $word=~s/([\n`\$"\\])/\\$1/g;
 156                         push @ret, "\"$word\"";
 157                 }
 158                 else {
 159                         # This list is from _Unix in a Nutshell_. (except '#')
 160                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 161                         push @ret,$word;
 162                 }
 163         }
 164         return join(' ', @ret);
 165 }
 166
 167 # Run a command, and display the command to stdout if verbose mode is on.
 168 # All commands that modifiy files in $TMP should be ran via this
 169 # function.
 170 #
 171 # Note that this cannot handle complex commands, especially anything
 172 # involving redirection. Use complex_doit instead.
 173 sub doit {
 174         verbose_print(escape_shell(@_));
 175
 176         if (! $dh{NO_ACT}) {
 177                 system(@_) == 0 || _error_exitcode($_[0]);
 178         }
 179 }
 180
 181 # Run a command and display the command to stdout if verbose mode is on.
 182 # Use doit() if you can, instead of this function, because this function
 183 # forks a shell. However, this function can handle more complicated stuff
 184 # like redirection.
 185 sub complex_doit {
 186         verbose_print(join(" ",@_));
 187
 188         if (! $dh{NO_ACT}) {
 189                 # The join makes system get a scalar so it forks off a shell.
 190                 system(join(" ", @_)) == 0 || _error_exitcode(join(" ", @_))
 191         }
 192 }
 193
 194 sub _error_exitcode {
 195         my $command=shift;
 196         if ($? == -1) {
 197                 error("$command failed to to execute: $!");
 198         }
 199         elsif ($? & 127) {
 200                 error("$command died with signal ".($? & 127));
 201         }
 202         else {
 203                 error("$command returned exit code ".($? >> 8));
 204         }
 205 }
 206
 207 # Run a command that may have a huge number of arguments, like xargs does.
 208 # Pass in a reference to an array containing the arguments, and then other
 209 # parameters that are the command and any parameters that should be passed to
 210 # it each time.
 211 sub xargs {
 212         my $args=shift;
 213
 214         # The kernel can accept command lines up to 20k worth of characters.
 215         my $command_max=20000; # LINUX SPECIFIC!!
 216                         # I could use POSIX::ARG_MAX, but that would be slow.
 217
 218         # Figure out length of static portion of command.
 219         my $static_length=0;
 220         foreach (@_) {
 221                 $static_length+=length($_)+1;
 222         }
 223
 224         my @collect=();
 225         my $length=$static_length;
 226         foreach (@$args) {
 227                 if (length($_) + 1 + $static_length > $command_max) {
 228                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 229                 }
 230                 $length+=length($_) + 1;
 231                 if ($length < $command_max) {
 232                         push @collect, $_;
 233                 }
 234                 else {
 235                         doit(@_,@collect) if $#collect > -1;
 236                         @collect=($_);
 237                         $length=$static_length + length($_) + 1;
 238                 }
 239         }
 240         doit(@_,@collect) if $#collect > -1;
 241 }
 242
 243 # Print something if the verbose flag is on.
 244 sub verbose_print {
 245         my $message=shift;
 246
 247         if ($dh{VERBOSE}) {
 248                 print "\t$message\n";
 249         }
 250 }
 251
 252 # Output an error message and exit.
 253 sub error {
 254         my $message=shift;
 255
 256         warning($message);
 257         exit 1;
 258 }
 259
 260 # Output a warning.
 261 sub warning {
 262         my $message=shift;
 263
 264         print STDERR basename($0).": $message\n";
 265 }
 266
 267 # Returns the basename of the argument passed to it.
 268 sub basename {
 269         my $fn=shift;
 270
 271         $fn=~s/\/$//g; # ignore trailing slashes
 272         $fn=~s:^.*/(.*?)$:$1:;
 273         return $fn;
 274 }
 275
 276 # Returns the directory name of the argument passed to it.
 277 sub dirname {
 278         my $fn=shift;
 279
 280         $fn=~s/\/$//g; # ignore trailing slashes
 281         $fn=~s:^(.*)/.*?$:$1:;
 282         return $fn;
 283 }
 284
 285 # Pass in a number, will return true iff the current compatibility level
 286 # is less than or equal to that number.
 287 {
 288         my $warned_compat=0;
 289         my $c;
 290
 291         sub compat {
 292                 my $num=shift;
 293
 294                 if (! defined $c) {
 295                         $c=1;
 296                         if (defined $ENV{DH_COMPAT}) {
 297                                 $c=$ENV{DH_COMPAT};
 298                         }
 299                         elsif (-e 'debian/compat') {
 300                                 # Try the file..
 301                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 302                                 my $l=<COMPAT_IN>;
 303                                 close COMPAT_IN;
 304                                 if (! defined $l || ! length $l) {
 305                                         warning("debian/compat is empty, assuming level $c");
 306                                 }
 307                                 else {
 308                                         chomp $l;
 309                                         $c=$l;
 310                                 }
 311                         }
 312                 }
 313
 314                 if ($c < 4 && ! $warned_compat) {
 315                         warning("Compatibility levels before 5 are deprecated.");
 316                         $warned_compat=1;
 317                 }
 318
 319                 if ($c > $max_compat) {
 320                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 321                 }
 322
 323                 return ($c <= $num);
 324         }
 325 }
 326
 327 # Pass it a name of a binary package, it returns the name of the tmp dir to
 328 # use, for that package.
 329 sub tmpdir {
 330         my $package=shift;
 331
 332         if ($dh{TMPDIR}) {
 333                 return $dh{TMPDIR};
 334         }
 335         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 336                 # This is for back-compatibility with the debian/tmp tradition.
 337                 return "debian/tmp";
 338         }
 339         else {
 340                 return "debian/$package";
 341         }
 342 }
 343
 344 # Pass this the name of a binary package, and the name of the file wanted
 345 # for the package, and it will return the actual existing filename to use.
 346 #
 347 # It tries several filenames:
 348 #   * debian/package.filename.buildarch
 349 #   * debian/package.filename
 350 #   * debian/file (if the package is the main package)
 351 # If --name was specified then tonly the first two are tried, and they must
 352 # have the name after the pacage name:
 353 #   * debian/package.name.filename.buildarch
 354 #   * debian/package.name.filename
 355 sub pkgfile {
 356         my $package=shift;
 357         my $filename=shift;
 358
 359         if (defined $dh{NAME}) {
 360                 $filename="$dh{NAME}.$filename";
 361         }
 362
 363         my @try=("debian/$package.$filename.".buildarch(),
 364                  "debian/$package.$filename");
 365         if ($package eq $dh{MAINPACKAGE}) {
 366                 push @try, "debian/$filename";
 367         }
 368
 369         foreach my $file (@try) {
 370                 if (-f $file &&
 371                     (! $dh{IGNORE} || ! exists $dh{IGNORE}->{$file})) {
 372                         return $file;
 373                 }
 374
 375         }
 376
 377         return "";
 378
 379 }
 380
 381 # Pass it a name of a binary package, it returns the name to prefix to files
 382 # in debian/ for this package.
 383 sub pkgext {
 384         my $package=shift;
 385
 386         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 387                 return "";
 388         }
 389         return "$package.";
 390 }
 391
 392 # Pass it the name of a binary package, it returns the name to install
 393 # files by in eg, etc. Normally this is the same, but --name can override
 394 # it.
 395 sub pkgfilename {
 396         my $package=shift;
 397
 398         if (defined $dh{NAME}) {
 399                 return $dh{NAME};
 400         }
 401         return $package;
 402 }
 403
 404 # Returns 1 if the package is a native debian package, null otherwise.
 405 # As a side effect, sets $dh{VERSION} to the version of this package.
 406 {
 407         # Caches return code so it only needs to run dpkg-parsechangelog once.
 408         my %isnative_cache;
 409
 410         sub isnative {
 411                 my $package=shift;
 412
 413                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 414
 415                 # Make sure we look at the correct changelog.
 416                 my $isnative_changelog=pkgfile($package,"changelog");
 417                 if (! $isnative_changelog) {
 418                         $isnative_changelog="debian/changelog";
 419                 }
 420                 # Get the package version.
 421                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 422                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 423                 # Did the changelog parse fail?
 424                 if (! defined $dh{VERSION}) {
 425                         error("changelog parse failure");
 426                 }
 427
 428                 # Is this a native Debian package?
 429                 if ($dh{VERSION}=~m/.*-/) {
 430                         return $isnative_cache{$package}=0;
 431                 }
 432                 else {
 433                         return $isnative_cache{$package}=1;
 434                 }
 435         }
 436 }
 437
 438 # Automatically add a shell script snippet to a debian script.
 439 # Only works if the script has #DEBHELPER# in it.
 440 #
 441 # Parameters:
 442 # 1: package
 443 # 2: script to add to
 444 # 3: filename of snippet
 445 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 446 sub autoscript {
 447         my $package=shift;
 448         my $script=shift;
 449         my $filename=shift;
 450         my $sed=shift || "";
 451
 452         # This is the file we will modify.
 453         my $outfile="debian/".pkgext($package)."$script.debhelper";
 454
 455         # Figure out what shell script snippet to use.
 456         my $infile;
 457         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 458             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 459                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 460         }
 461         else {
 462                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 463                         $infile="/usr/share/debhelper/autoscripts/$filename";
 464                 }
 465                 else {
 466                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 467                 }
 468         }
 469
 470         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 471            && !compat(5)) {
 472                 # Add fragments to top so they run in reverse order when removing.
 473                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 474                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 475                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 476                 complex_doit("cat $outfile >> $outfile.new");
 477                 complex_doit("mv $outfile.new $outfile");
 478         }
 479         else {
 480                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 481                 complex_doit("sed \"$sed\" $infile >> $outfile");
 482                 complex_doit("echo '# End automatically added section' >> $outfile");
 483         }
 484 }
 485
 486 # Removes a whole substvar line.
 487 sub delsubstvar {
 488         my $package=shift;
 489         my $substvar=shift;
 490
 491         my $ext=pkgext($package);
 492         my $substvarfile="debian/${ext}substvars";
 493
 494         if (-e $substvarfile) {
 495                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 496                 doit("mv", "$substvarfile.new","$substvarfile");
 497         }
 498 }
 499
 500 # Adds a dependency on some package to the specified
 501 # substvar in a package's substvar's file.
 502 sub addsubstvar {
 503         my $package=shift;
 504         my $substvar=shift;
 505         my $deppackage=shift;
 506         my $verinfo=shift;
 507         my $remove=shift;
 508
 509         my $ext=pkgext($package);
 510         my $substvarfile="debian/${ext}substvars";
 511         my $str=$deppackage;
 512         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 513
 514         # Figure out what the line will look like, based on what's there
 515         # now, and what we're to add or remove.
 516         my $line="";
 517         if (-e $substvarfile) {
 518                 my %items;
 519                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 520                 while (<SUBSTVARS_IN>) {
 521                         chomp;
 522                         if (/^\Q$substvar\E=(.*)/) {
 523                                 %items = map { $_ => 1} split(", ", $1);
 524
 525                                 last;
 526                         }
 527                 }
 528                 close SUBSTVARS_IN;
 529                 if (! $remove) {
 530                         $items{$str}=1;
 531                 }
 532                 else {
 533                         delete $items{$str};
 534                 }
 535                 $line=join(", ", sort keys %items);
 536         }
 537         elsif (! $remove) {
 538                 $line=$str;
 539         }
 540
 541         if (length $line) {
 542                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 543                  doit("mv", "$substvarfile.new", $substvarfile);
 544         }
 545         else {
 546                 delsubstvar($package,$substvar);
 547         }
 548 }
 549
 550 # Reads in the specified file, one line at a time. splits on words,
 551 # and returns an array of arrays of the contents.
 552 # If a value is passed in as the second parameter, then glob
 553 # expansion is done in the directory specified by the parameter ("." is
 554 # frequently a good choice).
 555 sub filedoublearray {
 556         my $file=shift;
 557         my $globdir=shift;
 558
 559         my @ret;
 560         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 561         while (<DH_FARRAY_IN>) {
 562                 chomp;
 563                 # Only ignore comments and empty lines in v5 mode.
 564                 if (! compat(4)) {
 565                         next if /^#/ || /^$/;
 566                 }
 567                 my @line;
 568                 # Only do glob expansion in v3 mode.
 569                 #
 570                 # The tricky bit is that the glob expansion is done
 571                 # as if we were in the specified directory, so the
 572                 # filenames that come out are relative to it.
 573                 if (defined $globdir && ! compat(2)) {
 574                         for (map { glob "$globdir/$_" } split) {
 575                                 s#^$globdir/##;
 576                                 push @line, $_;
 577                         }
 578                 }
 579                 else {
 580                         @line = split;
 581                 }
 582                 push @ret, [@line];
 583         }
 584         close DH_FARRAY_IN;
 585
 586         return @ret;
 587 }
 588
 589 # Reads in the specified file, one word at a time, and returns an array of
 590 # the result. Can do globbing as does filedoublearray.
 591 sub filearray {
 592         return map { @$_ } filedoublearray(@_);
 593 }
 594
 595 # Passed a filename, returns true if -X says that file should be excluded.
 596 sub excludefile {
 597         my $filename = shift;
 598         foreach my $f (@{$dh{EXCLUDE}}) {
 599                 return 1 if $filename =~ /\Q$f\E/;
 600         }
 601         return 0;
 602 }
 603
 604 # Returns the build architecture. (Memoized)
 605 {
 606         my $arch;
 607
 608         sub buildarch {
 609                 return $arch if defined $arch;
 610
 611                 $arch=`dpkg-architecture -qDEB_HOST_ARCH 2>/dev/null` || error("dpkg-architecture failed");
 612                 chomp $arch;
 613                 return $arch;
 614         }
 615 }
 616
 617 # Passed an arch and a list of arches to match against, returns true if matched
 618 sub samearch {
 619         my $arch=shift;
 620         my @archlist=split(/\s+/,shift);
 621
 622         foreach my $a (@archlist) {
 623                 system("dpkg-architecture", "-a$arch", "-i$a") == 0 && return 1;
 624         }
 625
 626         return 0;
 627 }
 628
 629 # Returns a list of packages in the control file.
 630 # Must pass "arch" or "indep" or "same" to specify arch-dependant or
 631 # -independant or same arch packages. If nothing is specified, returns all
 632 # packages.
 633 # As a side effect, populates %package_arches and %package_types with the
 634 # types of all packages (not only those returned).
 635 my (%package_types, %package_arches);
 636 sub getpackages {
 637         my $type=shift;
 638
 639         %package_types=();
 640         %package_arches=();
 641
 642         $type="" if ! defined $type;
 643
 644         # Look up the build arch if we need to.
 645         my $buildarch='';
 646         if ($type eq 'same') {
 647                 $buildarch=buildarch();
 648         }
 649
 650         my $package="";
 651         my $arch="";
 652         my $package_type;
 653         my @list=();
 654         my %seen;
 655         open (CONTROL, 'debian/control') ||
 656                 error("cannot read debian/control: $!\n");
 657         while (<CONTROL>) {
 658                 chomp;
 659                 s/\s+$//;
 660                 if (/^Package:\s*(.*)/) {
 661                         $package=$1;
 662                         # Detect duplicate package names in the same control file.
 663                         if (! $seen{$package}) {
 664                                 $seen{$package}=1;
 665                         }
 666                         else {
 667                                 error("debian/control has a duplicate entry for $package");
 668                         }
 669                         $package_type="deb";
 670                 }
 671                 if (/^Architecture:\s*(.*)/) {
 672                         $arch=$1;
 673                 }
 674                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 675                         $package_type=$1;
 676                 }
 677
 678                 if (!$_ or eof) { # end of stanza.
 679                         if ($package) {
 680                                 $package_types{$package}=$package_type;
 681                                 $package_arches{$package}=$arch;
 682                         }
 683                         if ($package &&
 684                             (($type eq 'indep' && $arch eq 'all') ||
 685                              ($type eq 'arch' && $arch ne 'all') ||
 686                              ($type eq 'same' && ($arch eq 'any' || samearch($buildarch, $arch))) ||
 687                              ! $type)) {
 688                                 push @list, $package;
 689                                 $package="";
 690                                 $arch="";
 691                         }
 692                 }
 693         }
 694         close CONTROL;
 695
 696         return @list;
 697 }
 698
 699 # Returns the arch a package will build for.
 700 sub package_arch {
 701         my $package=shift;
 702
 703         if (! exists $package_arches{$package}) {
 704                 warning "package $package is not in control info";
 705                 return buildarch();
 706         }
 707         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 708 }
 709
 710 # Return true if a given package is really a udeb.
 711 sub is_udeb {
 712         my $package=shift;
 713
 714         if (! exists $package_types{$package}) {
 715                 warning "package $package is not in control info";
 716                 return 0;
 717         }
 718         return $package_types{$package} eq 'udeb';
 719 }
 720
 721 # Generates the filename that is used for a udeb package.
 722 sub udeb_filename {
 723         my $package=shift;
 724
 725         my $filearch=package_arch($package);
 726         isnative($package); # side effect
 727         my $version=$dh{VERSION};
 728         $version=~s/^[0-9]+://; # strip any epoch
 729         return "${package}_${version}_$filearch.udeb";
 730 }
 731
 732 # Handles #DEBHELPER# substitution in a script; also can generate a new
 733 # script from scratch if none exists but there is a .debhelper file for it.
 734 sub debhelper_script_subst {
 735         my $package=shift;
 736         my $script=shift;
 737
 738         my $tmp=tmpdir($package);
 739         my $ext=pkgext($package);
 740         my $file=pkgfile($package,$script);
 741
 742         if ($file ne '') {
 743                 if (-f "debian/$ext$script.debhelper") {
 744                         # Add this into the script, where it has #DEBHELPER#
 745                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 746                 }
 747                 else {
 748                         # Just get rid of any #DEBHELPER# in the script.
 749                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 750                 }
 751                 doit("chown","0:0","$tmp/DEBIAN/$script");
 752                 doit("chmod",755,"$tmp/DEBIAN/$script");
 753         }
 754         elsif ( -f "debian/$ext$script.debhelper" ) {
 755                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 756                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 757                 doit("chown","0:0","$tmp/DEBIAN/$script");
 758                 doit("chmod",755,"$tmp/DEBIAN/$script");
 759         }
 760 }
 761
 762 1