Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2008.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell
  18             &inhibit_log);
  19
  20 my $max_compat=7;
  21
  22 sub init {
  23         my %params=@_;
  24
  25         # If DH_OPTIONS is set, prepend it @ARGV.
  26         if (defined($ENV{DH_OPTIONS})) {
  27                 # Ignore leading/trailing whitespace.
  28                 $ENV{DH_OPTIONS}=~s/^\s+//;
  29                 $ENV{DH_OPTIONS}=~s/\s+$//;
  30                 unshift @ARGV,split(/\s+/,$ENV{DH_OPTIONS});
  31         }
  32
  33         # Check to see if an argument on the command line starts with a dash.
  34         # if so, we need to pass this off to the resource intensive
  35         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  36         my $parseopt=undef;
  37         my $arg;
  38         foreach $arg (@ARGV) {
  39                 if ($arg=~m/^-/) {
  40                         $parseopt=1;
  41                         last;
  42                 }
  43         }
  44         if ($parseopt) {
  45                 eval "use Debian::Debhelper::Dh_Getopt";
  46                 error($!) if $@;
  47                 Debian::Debhelper::Dh_Getopt::parseopts($params{options});
  48         }
  49
  50         # Another way to set excludes.
  51         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  52                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  53         }
  54
  55         # Generate EXCLUDE_FIND.
  56         if ($dh{EXCLUDE}) {
  57                 $dh{EXCLUDE_FIND}='';
  58                 foreach (@{$dh{EXCLUDE}}) {
  59                         my $x=$_;
  60                         $x=escape_shell($x);
  61                         $x=~s/\./\\\\./g;
  62                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  63                 }
  64                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  65         }
  66
  67         # Check to see if DH_VERBOSE environment variable was set, if so,
  68         # make sure verbose is on.
  69         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  70                 $dh{VERBOSE}=1;
  71         }
  72
  73         # Check to see if DH_NO_ACT environment variable was set, if so,
  74         # make sure no act mode is on.
  75         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  76                 $dh{NO_ACT}=1;
  77         }
  78
  79         my @allpackages=getpackages();
  80         # Get the name of the main binary package (first one listed in
  81         # debian/control). Only if the main package was not set on the
  82         # command line.
  83         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  84                 $dh{MAINPACKAGE}=$allpackages[0];
  85         }
  86
  87         # Check if packages to build have been specified, if not, fall back to
  88         # the default, doing them all.
  89         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  90                 if ($dh{DOINDEP} || $dh{DOARCH} || $dh{DOSAME}) {
  91                         error("You asked that all arch in(dep) packages be built, but there are none of that type.");
  92                 }
  93                 push @{$dh{DOPACKAGES}},@allpackages;
  94         }
  95
  96         # Check to see if -P was specified. If so, we can only act on a single
  97         # package.
  98         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  99                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
 100         }
 101
 102         # Figure out which package is the first one we were instructed to build.
 103         # This package gets special treatement: files and directories specified on
 104         # the command line may affect it.
 105         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
 106
 107         # If no error handling function was specified, just propigate
 108         # errors out.
 109         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
 110                 $dh{ERROR_HANDLER}='exit \$?';
 111         }
 112 }
 113
 114 # Run at exit. Add the command to the log files for the packages it acted
 115 # on, if it's exiting successfully.
 116 my $write_log=1;
 117 sub END {
 118         if ($? == 0 && $write_log) {
 119                 my $cmd=basename($0);
 120                 foreach my $package (@{$dh{DOPACKAGES}}) {
 121                         my $ext=pkgext($package);
 122                         my $log="debian/${ext}debhelper.log";
 123                         open(LOG, ">>", $log) || error("failed to write to ${log}: $!");
 124                         print LOG $cmd."\n";
 125                         close LOG;
 126                 }
 127         }
 128 }
 129
 130 sub inhibit_log {
 131         $write_log=0;
 132 }
 133
 134 # Pass it an array containing the arguments of a shell command like would
 135 # be run by exec(). It turns that into a line like you might enter at the
 136 # shell, escaping metacharacters and quoting arguments that contain spaces.
 137 sub escape_shell {
 138         my @args=@_;
 139         my $line="";
 140         my @ret;
 141         foreach my $word (@args) {
 142                 if ($word=~/\s/) {
 143                         # Escape only a few things since it will be quoted.
 144                         # Note we use double quotes because you cannot
 145                         # escape ' in single quotes, while " can be escaped
 146                         # in double.
 147                         # This does make -V"foo bar" turn into "-Vfoo bar",
 148                         # but that will be parsed identically by the shell
 149                         # anyway..
 150                         $word=~s/([\n`\$"\\])/\\$1/g;
 151                         push @ret, "\"$word\"";
 152                 }
 153                 else {
 154                         # This list is from _Unix in a Nutshell_. (except '#')
 155                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 156                         push @ret,$word;
 157                 }
 158         }
 159         return join(' ', @ret);
 160 }
 161
 162 # Run a command, and display the command to stdout if verbose mode is on.
 163 # All commands that modifiy files in $TMP should be ran via this
 164 # function.
 165 #
 166 # Note that this cannot handle complex commands, especially anything
 167 # involving redirection. Use complex_doit instead.
 168 sub doit {
 169         verbose_print(escape_shell(@_));
 170
 171         if (! $dh{NO_ACT}) {
 172                 my $ret=system(@_);
 173                 $ret == 0 || error("command returned error code $ret");
 174         }
 175 }
 176
 177 # Run a command and display the command to stdout if verbose mode is on.
 178 # Use doit() if you can, instead of this function, because this function
 179 # forks a shell. However, this function can handle more complicated stuff
 180 # like redirection.
 181 sub complex_doit {
 182         verbose_print(join(" ",@_));
 183
 184         if (! $dh{NO_ACT}) {
 185                 # The join makes system get a scalar so it forks off a shell.
 186                 system(join(" ",@_)) == 0
 187                         || error("command returned error code");
 188         }
 189 }
 190
 191 # Run a command that may have a huge number of arguments, like xargs does.
 192 # Pass in a reference to an array containing the arguments, and then other
 193 # parameters that are the command and any parameters that should be passed to
 194 # it each time.
 195 sub xargs {
 196         my $args=shift;
 197
 198         # The kernel can accept command lines up to 20k worth of characters.
 199         my $command_max=20000; # LINUX SPECIFIC!!
 200                         # I could use POSIX::ARG_MAX, but that would be slow.
 201
 202         # Figure out length of static portion of command.
 203         my $static_length=0;
 204         foreach (@_) {
 205                 $static_length+=length($_)+1;
 206         }
 207
 208         my @collect=();
 209         my $length=$static_length;
 210         foreach (@$args) {
 211                 if (length($_) + 1 + $static_length > $command_max) {
 212                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 213                 }
 214                 $length+=length($_) + 1;
 215                 if ($length < $command_max) {
 216                         push @collect, $_;
 217                 }
 218                 else {
 219                         doit(@_,@collect) if $#collect > -1;
 220                         @collect=($_);
 221                         $length=$static_length + length($_) + 1;
 222                 }
 223         }
 224         doit(@_,@collect) if $#collect > -1;
 225 }
 226
 227 # Print something if the verbose flag is on.
 228 sub verbose_print {
 229         my $message=shift;
 230
 231         if ($dh{VERBOSE}) {
 232                 print "\t$message\n";
 233         }
 234 }
 235
 236 # Output an error message and exit.
 237 sub error {
 238         my $message=shift;
 239
 240         warning($message);
 241         exit 1;
 242 }
 243
 244 # Output a warning.
 245 sub warning {
 246         my $message=shift;
 247
 248         print STDERR basename($0).": $message\n";
 249 }
 250
 251 # Returns the basename of the argument passed to it.
 252 sub basename {
 253         my $fn=shift;
 254
 255         $fn=~s/\/$//g; # ignore trailing slashes
 256         $fn=~s:^.*/(.*?)$:$1:;
 257         return $fn;
 258 }
 259
 260 # Returns the directory name of the argument passed to it.
 261 sub dirname {
 262         my $fn=shift;
 263
 264         $fn=~s/\/$//g; # ignore trailing slashes
 265         $fn=~s:^(.*)/.*?$:$1:;
 266         return $fn;
 267 }
 268
 269 # Pass in a number, will return true iff the current compatibility level
 270 # is less than or equal to that number.
 271 {
 272         my $warned_compat=0;
 273         my $c;
 274
 275         sub compat {
 276                 my $num=shift;
 277
 278                 if (! defined $c) {
 279                         $c=1;
 280                         if (defined $ENV{DH_COMPAT}) {
 281                                 $c=$ENV{DH_COMPAT};
 282                         }
 283                         elsif (-e 'debian/compat') {
 284                                 # Try the file..
 285                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 286                                 my $l=<COMPAT_IN>;
 287                                 if (! defined $l || ! length $l) {
 288                                         warning("debian/compat is empty, assuming level $c");
 289                                 }
 290                                 else {
 291                                         chomp $l;
 292                                         $c=$l;
 293                                 }
 294                         }
 295                 }
 296
 297                 if ($c < 4 && ! $warned_compat) {
 298                         warning("Compatibility levels before 4 are deprecated.");
 299                         $warned_compat=1;
 300                 }
 301
 302                 if ($c > $max_compat) {
 303                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 304                 }
 305
 306                 return ($c <= $num);
 307         }
 308 }
 309
 310 # Pass it a name of a binary package, it returns the name of the tmp dir to
 311 # use, for that package.
 312 sub tmpdir {
 313         my $package=shift;
 314
 315         if ($dh{TMPDIR}) {
 316                 return $dh{TMPDIR};
 317         }
 318         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 319                 # This is for back-compatibility with the debian/tmp tradition.
 320                 return "debian/tmp";
 321         }
 322         else {
 323                 return "debian/$package";
 324         }
 325 }
 326
 327 # Pass this the name of a binary package, and the name of the file wanted
 328 # for the package, and it will return the actual existing filename to use.
 329 #
 330 # It tries several filenames:
 331 #   * debian/package.filename.buildarch
 332 #   * debian/package.filename
 333 #   * debian/file (if the package is the main package)
 334 # If --name was specified then tonly the first two are tried, and they must
 335 # have the name after the pacage name:
 336 #   * debian/package.name.filename.buildarch
 337 #   * debian/package.name.filename
 338 sub pkgfile {
 339         my $package=shift;
 340         my $filename=shift;
 341
 342         if (defined $dh{NAME}) {
 343                 $filename="$dh{NAME}.$filename";
 344         }
 345
 346         my @try=("debian/$package.$filename.".buildarch(),
 347                  "debian/$package.$filename");
 348         if ($package eq $dh{MAINPACKAGE}) {
 349                 push @try, "debian/$filename";
 350         }
 351
 352         foreach my $file (@try) {
 353                 if (-f $file &&
 354                     (! $dh{IGNORE} || ! exists $dh{IGNORE}->{$file})) {
 355                         return $file;
 356                 }
 357
 358         }
 359
 360         return "";
 361
 362 }
 363
 364 # Pass it a name of a binary package, it returns the name to prefix to files
 365 # in debian/ for this package.
 366 sub pkgext {
 367         my $package=shift;
 368
 369         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 370                 return "";
 371         }
 372         return "$package.";
 373 }
 374
 375 # Pass it the name of a binary package, it returns the name to install
 376 # files by in eg, etc. Normally this is the same, but --name can override
 377 # it.
 378 sub pkgfilename {
 379         my $package=shift;
 380
 381         if (defined $dh{NAME}) {
 382                 return $dh{NAME};
 383         }
 384         return $package;
 385 }
 386
 387 # Returns 1 if the package is a native debian package, null otherwise.
 388 # As a side effect, sets $dh{VERSION} to the version of this package.
 389 {
 390         # Caches return code so it only needs to run dpkg-parsechangelog once.
 391         my %isnative_cache;
 392
 393         sub isnative {
 394                 my $package=shift;
 395
 396                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 397
 398                 # Make sure we look at the correct changelog.
 399                 my $isnative_changelog=pkgfile($package,"changelog");
 400                 if (! $isnative_changelog) {
 401                         $isnative_changelog="debian/changelog";
 402                 }
 403                 # Get the package version.
 404                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 405                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 406                 # Did the changelog parse fail?
 407                 if (! defined $dh{VERSION}) {
 408                         error("changelog parse failure");
 409                 }
 410
 411                 # Is this a native Debian package?
 412                 if ($dh{VERSION}=~m/.*-/) {
 413                         return $isnative_cache{$package}=0;
 414                 }
 415                 else {
 416                         return $isnative_cache{$package}=1;
 417                 }
 418         }
 419 }
 420
 421 # Automatically add a shell script snippet to a debian script.
 422 # Only works if the script has #DEBHELPER# in it.
 423 #
 424 # Parameters:
 425 # 1: package
 426 # 2: script to add to
 427 # 3: filename of snippet
 428 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 429 sub autoscript {
 430         my $package=shift;
 431         my $script=shift;
 432         my $filename=shift;
 433         my $sed=shift || "";
 434
 435         # This is the file we will modify.
 436         my $outfile="debian/".pkgext($package)."$script.debhelper";
 437
 438         # Figure out what shell script snippet to use.
 439         my $infile;
 440         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 441             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 442                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 443         }
 444         else {
 445                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 446                         $infile="/usr/share/debhelper/autoscripts/$filename";
 447                 }
 448                 else {
 449                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 450                 }
 451         }
 452
 453         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 454            && !compat(5)) {
 455                 # Add fragments to top so they run in reverse order when removing.
 456                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 457                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 458                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 459                 complex_doit("cat $outfile >> $outfile.new");
 460                 complex_doit("mv $outfile.new $outfile");
 461         }
 462         else {
 463                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 464                 complex_doit("sed \"$sed\" $infile >> $outfile");
 465                 complex_doit("echo '# End automatically added section' >> $outfile");
 466         }
 467 }
 468
 469 # Removes a whole substvar line.
 470 sub delsubstvar {
 471         my $package=shift;
 472         my $substvar=shift;
 473
 474         my $ext=pkgext($package);
 475         my $substvarfile="debian/${ext}substvars";
 476
 477         if (-e $substvarfile) {
 478                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 479                 doit("mv", "$substvarfile.new","$substvarfile");
 480         }
 481 }
 482
 483 # Adds a dependency on some package to the specified
 484 # substvar in a package's substvar's file.
 485 sub addsubstvar {
 486         my $package=shift;
 487         my $substvar=shift;
 488         my $deppackage=shift;
 489         my $verinfo=shift;
 490         my $remove=shift;
 491
 492         my $ext=pkgext($package);
 493         my $substvarfile="debian/${ext}substvars";
 494         my $str=$deppackage;
 495         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 496
 497         # Figure out what the line will look like, based on what's there
 498         # now, and what we're to add or remove.
 499         my $line="";
 500         if (-e $substvarfile) {
 501                 my %items;
 502                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 503                 while (<SUBSTVARS_IN>) {
 504                         chomp;
 505                         if (/^\Q$substvar\E=(.*)/) {
 506                                 %items = map { $_ => 1} split(", ", $1);
 507
 508                                 last;
 509                         }
 510                 }
 511                 close SUBSTVARS_IN;
 512                 if (! $remove) {
 513                         $items{$str}=1;
 514                 }
 515                 else {
 516                         delete $items{$str};
 517                 }
 518                 $line=join(", ", sort keys %items);
 519         }
 520         elsif (! $remove) {
 521                 $line=$str;
 522         }
 523
 524         if (length $line) {
 525                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 526                  doit("mv", "$substvarfile.new", $substvarfile);
 527         }
 528         else {
 529                 delsubstvar($package,$substvar);
 530         }
 531 }
 532
 533 # Reads in the specified file, one line at a time. splits on words,
 534 # and returns an array of arrays of the contents.
 535 # If a value is passed in as the second parameter, then glob
 536 # expansion is done in the directory specified by the parameter ("." is
 537 # frequently a good choice).
 538 sub filedoublearray {
 539         my $file=shift;
 540         my $globdir=shift;
 541
 542         my @ret;
 543         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 544         while (<DH_FARRAY_IN>) {
 545                 chomp;
 546                 # Only ignore comments and empty lines in v5 mode.
 547                 if (! compat(4)) {
 548                         next if /^#/ || /^$/;
 549                 }
 550                 my @line;
 551                 # Only do glob expansion in v3 mode.
 552                 #
 553                 # The tricky bit is that the glob expansion is done
 554                 # as if we were in the specified directory, so the
 555                 # filenames that come out are relative to it.
 556                 if (defined $globdir && ! compat(2)) {
 557                         for (map { glob "$globdir/$_" } split) {
 558                                 s#^$globdir/##;
 559                                 push @line, $_;
 560                         }
 561                 }
 562                 else {
 563                         @line = split;
 564                 }
 565                 push @ret, [@line];
 566         }
 567         close DH_FARRAY_IN;
 568
 569         return @ret;
 570 }
 571
 572 # Reads in the specified file, one word at a time, and returns an array of
 573 # the result. Can do globbing as does filedoublearray.
 574 sub filearray {
 575         return map { @$_ } filedoublearray(@_);
 576 }
 577
 578 # Passed a filename, returns true if -X says that file should be excluded.
 579 sub excludefile {
 580         my $filename = shift;
 581         foreach my $f (@{$dh{EXCLUDE}}) {
 582                 return 1 if $filename =~ /\Q$f\E/;
 583         }
 584         return 0;
 585 }
 586
 587 # Returns the build architecture. (Memoized)
 588 {
 589         my $arch;
 590
 591         sub buildarch {
 592                 return $arch if defined $arch;
 593
 594                 $arch=`dpkg-architecture -qDEB_HOST_ARCH 2>/dev/null` || error("dpkg-architecture failed");
 595                 chomp $arch;
 596                 return $arch;
 597         }
 598 }
 599
 600 # Passed an arch and a list of arches to match against, returns true if matched
 601 sub samearch {
 602         my $arch=shift;
 603         my @archlist=split(/\s+/,shift);
 604
 605         foreach my $a (@archlist) {
 606                 system("dpkg-architecture", "-a$arch", "-i$a") == 0 && return 1;
 607         }
 608
 609         return 0;
 610 }
 611
 612 # Returns a list of packages in the control file.
 613 # Must pass "arch" or "indep" or "same" to specify arch-dependant or
 614 # -independant or same arch packages. If nothing is specified, returns all
 615 # packages.
 616 # As a side effect, populates %package_arches and %package_types with the
 617 # types of all packages (not only those returned).
 618 my (%package_types, %package_arches);
 619 sub getpackages {
 620         my $type=shift;
 621
 622         %package_types=();
 623         %package_arches=();
 624
 625         $type="" if ! defined $type;
 626
 627         # Look up the build arch if we need to.
 628         my $buildarch='';
 629         if ($type eq 'same') {
 630                 $buildarch=buildarch();
 631         }
 632
 633         my $package="";
 634         my $arch="";
 635         my $package_type;
 636         my @list=();
 637         my %seen;
 638         open (CONTROL, 'debian/control') ||
 639                 error("cannot read debian/control: $!\n");
 640         while (<CONTROL>) {
 641                 chomp;
 642                 s/\s+$//;
 643                 if (/^Package:\s*(.*)/) {
 644                         $package=$1;
 645                         # Detect duplicate package names in the same control file.
 646                         if (! $seen{$package}) {
 647                                 $seen{$package}=1;
 648                         }
 649                         else {
 650                                 error("debian/control has a duplicate entry for $package");
 651                         }
 652                         $package_type="deb";
 653                 }
 654                 if (/^Architecture:\s*(.*)/) {
 655                         $arch=$1;
 656                 }
 657                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 658                         $package_type=$1;
 659                 }
 660
 661                 if (!$_ or eof) { # end of stanza.
 662                         if ($package) {
 663                                 $package_types{$package}=$package_type;
 664                                 $package_arches{$package}=$arch;
 665                         }
 666                         if ($package &&
 667                             (($type eq 'indep' && $arch eq 'all') ||
 668                              ($type eq 'arch' && $arch ne 'all') ||
 669                              ($type eq 'same' && ($arch eq 'any' || samearch($buildarch, $arch))) ||
 670                              ! $type)) {
 671                                 push @list, $package;
 672                                 $package="";
 673                                 $arch="";
 674                         }
 675                 }
 676         }
 677         close CONTROL;
 678
 679         return @list;
 680 }
 681
 682 # Returns the arch a package will build for.
 683 sub package_arch {
 684         my $package=shift;
 685
 686         if (! exists $package_arches{$package}) {
 687                 warning "package $package is not in control info";
 688                 return buildarch();
 689         }
 690         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 691 }
 692
 693 # Return true if a given package is really a udeb.
 694 sub is_udeb {
 695         my $package=shift;
 696
 697         if (! exists $package_types{$package}) {
 698                 warning "package $package is not in control info";
 699                 return 0;
 700         }
 701         return $package_types{$package} eq 'udeb';
 702 }
 703
 704 # Generates the filename that is used for a udeb package.
 705 sub udeb_filename {
 706         my $package=shift;
 707
 708         my $filearch=package_arch($package);
 709         isnative($package); # side effect
 710         my $version=$dh{VERSION};
 711         $version=~s/^[0-9]+://; # strip any epoch
 712         return "${package}_${version}_$filearch.udeb";
 713 }
 714
 715 # Handles #DEBHELPER# substitution in a script; also can generate a new
 716 # script from scratch if none exists but there is a .debhelper file for it.
 717 sub debhelper_script_subst {
 718         my $package=shift;
 719         my $script=shift;
 720
 721         my $tmp=tmpdir($package);
 722         my $ext=pkgext($package);
 723         my $file=pkgfile($package,$script);
 724
 725         if ($file ne '') {
 726                 if (-f "debian/$ext$script.debhelper") {
 727                         # Add this into the script, where it has #DEBHELPER#
 728                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 729                 }
 730                 else {
 731                         # Just get rid of any #DEBHELPER# in the script.
 732                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 733                 }
 734                 doit("chown","0:0","$tmp/DEBIAN/$script");
 735                 doit("chmod",755,"$tmp/DEBIAN/$script");
 736         }
 737         elsif ( -f "debian/$ext$script.debhelper" ) {
 738                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 739                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 740                 doit("chown","0:0","$tmp/DEBIAN/$script");
 741                 doit("chmod",755,"$tmp/DEBIAN/$script");
 742         }
 743 }
 744
 745 1