Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2000.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell);
  18
  19 my $max_compat=6;
  20
  21 sub init {
  22         # If DH_OPTIONS is set, prepend it @ARGV.
  23         if (defined($ENV{DH_OPTIONS})) {
  24                 # Ignore leading/trailing whitespace.
  25                 $ENV{DH_OPTIONS}=~s/^\s+//;
  26                 $ENV{DH_OPTIONS}=~s/\s+$//;
  27                 unshift @ARGV,split(/\s+/,$ENV{DH_OPTIONS});
  28         }
  29
  30         # Check to see if an argument on the command line starts with a dash.
  31         # if so, we need to pass this off to the resource intensive
  32         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  33         my $parseopt=undef;
  34         my $arg;
  35         foreach $arg (@ARGV) {
  36                 if ($arg=~m/^-/) {
  37                         $parseopt=1;
  38                         last;
  39                 }
  40         }
  41         if ($parseopt) {
  42                 eval "use Debian::Debhelper::Dh_Getopt";
  43                 error($!) if $@;
  44                 %dh=Debian::Debhelper::Dh_Getopt::parseopts();
  45         }
  46
  47         # Another way to set excludes.
  48         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  49                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  50         }
  51
  52         # Generate EXCLUDE_FIND.
  53         if ($dh{EXCLUDE}) {
  54                 $dh{EXCLUDE_FIND}='';
  55                 foreach (@{$dh{EXCLUDE}}) {
  56                         my $x=$_;
  57                         $x=escape_shell($x);
  58                         $x=~s/\./\\\\./g;
  59                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  60                 }
  61                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  62         }
  63
  64         # Check to see if DH_VERBOSE environment variable was set, if so,
  65         # make sure verbose is on.
  66         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  67                 $dh{VERBOSE}=1;
  68         }
  69
  70         # Check to see if DH_NO_ACT environment variable was set, if so,
  71         # make sure no act mode is on.
  72         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  73                 $dh{NO_ACT}=1;
  74         }
  75
  76         my @allpackages=getpackages();
  77         # Get the name of the main binary package (first one listed in
  78         # debian/control). Only if the main package was not set on the
  79         # command line.
  80         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  81                 $dh{MAINPACKAGE}=$allpackages[0];
  82         }
  83
  84         # Check if packages to build have been specified, if not, fall back to
  85         # the default, doing them all.
  86         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  87                 if ($dh{DOINDEP} || $dh{DOARCH} || $dh{DOSAME}) {
  88                         error("You asked that all arch in(dep) packages be built, but there are none of that type.");
  89                 }
  90                 push @{$dh{DOPACKAGES}},@allpackages;
  91         }
  92
  93         # Check to see if -P was specified. If so, we can only act on a single
  94         # package.
  95         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  96                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  97         }
  98
  99         # Figure out which package is the first one we were instructed to build.
 100         # This package gets special treatement: files and directories specified on
 101         # the command line may affect it.
 102         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
 103
 104         # If no error handling function was specified, just propigate
 105         # errors out.
 106         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
 107                 $dh{ERROR_HANDLER}='exit \$?';
 108         }
 109 }
 110
 111 # Pass it an array containing the arguments of a shell command like would
 112 # be run by exec(). It turns that into a line like you might enter at the
 113 # shell, escaping metacharacters and quoting arguments that contain spaces.
 114 sub escape_shell {
 115         my @args=@_;
 116         my $line="";
 117         my @ret;
 118         foreach my $word (@args) {
 119                 if ($word=~/\s/) {
 120                         # Escape only a few things since it will be quoted.
 121                         # Note we use double quotes because you cannot
 122                         # escape ' in single quotes, while " can be escaped
 123                         # in double.
 124                         # This does make -V"foo bar" turn into "-Vfoo bar",
 125                         # but that will be parsed identically by the shell
 126                         # anyway..
 127                         $word=~s/([\n`\$"\\])/\\$1/g;
 128                         push @ret, "\"$word\"";
 129                 }
 130                 else {
 131                         # This list is from _Unix in a Nutshell_. (except '#')
 132                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 133                         push @ret,$word;
 134                 }
 135         }
 136         return join(' ', @ret);
 137 }
 138
 139 # Run a command, and display the command to stdout if verbose mode is on.
 140 # All commands that modifiy files in $TMP should be ran via this
 141 # function.
 142 #
 143 # Note that this cannot handle complex commands, especially anything
 144 # involving redirection. Use complex_doit instead.
 145 sub doit {
 146         verbose_print(escape_shell(@_));
 147
 148         if (! $dh{NO_ACT}) {
 149                 my $ret=system(@_);
 150                 $ret == 0 || error("command returned error code $ret");
 151         }
 152 }
 153
 154 # Run a command and display the command to stdout if verbose mode is on.
 155 # Use doit() if you can, instead of this function, because this function
 156 # forks a shell. However, this function can handle more complicated stuff
 157 # like redirection.
 158 sub complex_doit {
 159         verbose_print(join(" ",@_));
 160
 161         if (! $dh{NO_ACT}) {
 162                 # The join makes system get a scalar so it forks off a shell.
 163                 system(join(" ",@_)) == 0
 164                         || error("command returned error code");
 165         }
 166 }
 167
 168 # Run a command that may have a huge number of arguments, like xargs does.
 169 # Pass in a reference to an array containing the arguments, and then other
 170 # parameters that are the command and any parameters that should be passed to
 171 # it each time.
 172 sub xargs {
 173         my $args=shift;
 174
 175         # The kernel can accept command lines up to 20k worth of characters.
 176         my $command_max=20000; # LINUX SPECIFIC!!
 177                         # I could use POSIX::ARG_MAX, but that would be slow.
 178
 179         # Figure out length of static portion of command.
 180         my $static_length=0;
 181         foreach (@_) {
 182                 $static_length+=length($_)+1;
 183         }
 184
 185         my @collect=();
 186         my $length=$static_length;
 187         foreach (@$args) {
 188                 if (length($_) + 1 + $static_length > $command_max) {
 189                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 190                 }
 191                 $length+=length($_) + 1;
 192                 if ($length < $command_max) {
 193                         push @collect, $_;
 194                 }
 195                 else {
 196                         doit(@_,@collect) if $#collect > -1;
 197                         @collect=($_);
 198                         $length=$static_length + length($_) + 1;
 199                 }
 200         }
 201         doit(@_,@collect) if $#collect > -1;
 202 }
 203
 204 # Print something if the verbose flag is on.
 205 sub verbose_print {
 206         my $message=shift;
 207
 208         if ($dh{VERBOSE}) {
 209                 print "\t$message\n";
 210         }
 211 }
 212
 213 # Output an error message and exit.
 214 sub error {
 215         my $message=shift;
 216
 217         warning($message);
 218         exit 1;
 219 }
 220
 221 # Output a warning.
 222 sub warning {
 223         my $message=shift;
 224
 225         print STDERR basename($0).": $message\n";
 226 }
 227
 228 # Returns the basename of the argument passed to it.
 229 sub basename {
 230         my $fn=shift;
 231
 232         $fn=~s/\/$//g; # ignore trailing slashes
 233         $fn=~s:^.*/(.*?)$:$1:;
 234         return $fn;
 235 }
 236
 237 # Returns the directory name of the argument passed to it.
 238 sub dirname {
 239         my $fn=shift;
 240
 241         $fn=~s/\/$//g; # ignore trailing slashes
 242         $fn=~s:^(.*)/.*?$:$1:;
 243         return $fn;
 244 }
 245
 246 # Pass in a number, will return true iff the current compatibility level
 247 # is less than or equal to that number.
 248 {
 249         my $warned_compat=0;
 250         my $c;
 251
 252         sub compat {
 253                 my $num=shift;
 254
 255                 if (! defined $c) {
 256                         $c=1;
 257                         if (defined $ENV{DH_COMPAT}) {
 258                                 $c=$ENV{DH_COMPAT};
 259                         }
 260                         elsif (-e 'debian/compat') {
 261                                 # Try the file..
 262                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 263                                 my $l=<COMPAT_IN>;
 264                                 if (! defined $l || ! length $l) {
 265                                         warning("debian/compat is empty, assuming level $c");
 266                                 }
 267                                 else {
 268                                         chomp $l;
 269                                         $c=$l;
 270                                 }
 271                         }
 272                 }
 273
 274                 if ($c < 4 && ! $warned_compat) {
 275                         warning("Compatibility levels before 4 are deprecated.");
 276                         $warned_compat=1;
 277                 }
 278
 279                 if ($c > $max_compat) {
 280                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 281                 }
 282
 283                 return ($c <= $num);
 284         }
 285 }
 286
 287 # Pass it a name of a binary package, it returns the name of the tmp dir to
 288 # use, for that package.
 289 sub tmpdir {
 290         my $package=shift;
 291
 292         if ($dh{TMPDIR}) {
 293                 return $dh{TMPDIR};
 294         }
 295         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 296                 # This is for back-compatibility with the debian/tmp tradition.
 297                 return "debian/tmp";
 298         }
 299         else {
 300                 return "debian/$package";
 301         }
 302 }
 303
 304 # Pass this the name of a binary package, and the name of the file wanted
 305 # for the package, and it will return the actual existing filename to use.
 306 #
 307 # It tries several filenames:
 308 #   * debian/package.filename.buildarch
 309 #   * debian/package.filename
 310 #   * debian/file (if the package is the main package)
 311 # If --name was specified then tonly the first two are tried, and they must
 312 # have the name after the pacage name:
 313 #   * debian/package.name.filename.buildarch
 314 #   * debian/package.name.filename
 315 sub pkgfile {
 316         my $package=shift;
 317         my $filename=shift;
 318
 319         if (defined $dh{NAME}) {
 320                 $filename="$dh{NAME}.$filename";
 321         }
 322
 323         if (-f "debian/$package.$filename.".buildarch()) {
 324                 return "debian/$package.$filename.".buildarch();
 325         }
 326         elsif (-f "debian/$package.$filename") {
 327                 return "debian/$package.$filename";
 328         }
 329         elsif ($package eq $dh{MAINPACKAGE} && -f "debian/$filename") {
 330                 return "debian/$filename";
 331         }
 332         else {
 333                 return "";
 334         }
 335 }
 336
 337 # Pass it a name of a binary package, it returns the name to prefix to files
 338 # in debian/ for this package.
 339 sub pkgext {
 340         my $package=shift;
 341
 342         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 343                 return "";
 344         }
 345         return "$package.";
 346 }
 347
 348 # Pass it the name of a binary package, it returns the name to install
 349 # files by in eg, etc. Normally this is the same, but --name can override
 350 # it.
 351 sub pkgfilename {
 352         my $package=shift;
 353
 354         if (defined $dh{NAME}) {
 355                 return $dh{NAME};
 356         }
 357         return $package;
 358 }
 359
 360 # Returns 1 if the package is a native debian package, null otherwise.
 361 # As a side effect, sets $dh{VERSION} to the version of this package.
 362 {
 363         # Caches return code so it only needs to run dpkg-parsechangelog once.
 364         my %isnative_cache;
 365
 366         sub isnative {
 367                 my $package=shift;
 368
 369                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 370
 371                 # Make sure we look at the correct changelog.
 372                 my $isnative_changelog=pkgfile($package,"changelog");
 373                 if (! $isnative_changelog) {
 374                         $isnative_changelog="debian/changelog";
 375                 }
 376                 # Get the package version.
 377                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 378                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 379                 # Did the changelog parse fail?
 380                 if (! defined $dh{VERSION}) {
 381                         error("changelog parse failure");
 382                 }
 383
 384                 # Is this a native Debian package?
 385                 if ($dh{VERSION}=~m/.*-/) {
 386                         return $isnative_cache{$package}=0;
 387                 }
 388                 else {
 389                         return $isnative_cache{$package}=1;
 390                 }
 391         }
 392 }
 393
 394 # Automatically add a shell script snippet to a debian script.
 395 # Only works if the script has #DEBHELPER# in it.
 396 #
 397 # Parameters:
 398 # 1: package
 399 # 2: script to add to
 400 # 3: filename of snippet
 401 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 402 sub autoscript {
 403         my $package=shift;
 404         my $script=shift;
 405         my $filename=shift;
 406         my $sed=shift || "";
 407
 408         # This is the file we will modify.
 409         my $outfile="debian/".pkgext($package)."$script.debhelper";
 410
 411         # Figure out what shell script snippet to use.
 412         my $infile;
 413         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 414             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 415                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 416         }
 417         else {
 418                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 419                         $infile="/usr/share/debhelper/autoscripts/$filename";
 420                 }
 421                 else {
 422                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 423                 }
 424         }
 425
 426         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 427            && !compat(5)) {
 428                 # Add fragments to top so they run in reverse order when removing.
 429                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 430                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 431                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 432                 complex_doit("cat $outfile >> $outfile.new");
 433                 complex_doit("mv $outfile.new $outfile");
 434         }
 435         else {
 436                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 437                 complex_doit("sed \"$sed\" $infile >> $outfile");
 438                 complex_doit("echo '# End automatically added section' >> $outfile");
 439         }
 440 }
 441
 442 # Removes a whole substvar line.
 443 sub delsubstvar {
 444         my $package=shift;
 445         my $substvar=shift;
 446
 447         my $ext=pkgext($package);
 448         my $substvarfile="debian/${ext}substvars";
 449
 450         if (-e $substvarfile) {
 451                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 452                 doit("mv", "$substvarfile.new","$substvarfile");
 453         }
 454 }
 455
 456 # Adds a dependency on some package to the specified
 457 # substvar in a package's substvar's file.
 458 sub addsubstvar {
 459         my $package=shift;
 460         my $substvar=shift;
 461         my $deppackage=shift;
 462         my $verinfo=shift;
 463         my $remove=shift;
 464
 465         my $ext=pkgext($package);
 466         my $substvarfile="debian/${ext}substvars";
 467         my $str=$deppackage;
 468         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 469
 470         # Figure out what the line will look like, based on what's there
 471         # now, and what we're to add or remove.
 472         my $line="";
 473         if (-e $substvarfile) {
 474                 my %items;
 475                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 476                 while (<SUBSTVARS_IN>) {
 477                         chomp;
 478                         if (/^\Q$substvar\E=(.*)/) {
 479                                 %items = map { $_ => 1} split(", ", $1);
 480
 481                                 last;
 482                         }
 483                 }
 484                 close SUBSTVARS_IN;
 485                 if (! $remove) {
 486                         $items{$str}=1;
 487                 }
 488                 else {
 489                         delete $items{$str};
 490                 }
 491                 $line=join(", ", keys %items);
 492         }
 493         elsif (! $remove) {
 494                 $line=$str;
 495         }
 496
 497         if (length $line) {
 498                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 499                  doit("mv", "$substvarfile.new", $substvarfile);
 500         }
 501         else {
 502                 delsubstvar($package,$substvar);
 503         }
 504 }
 505
 506 # Reads in the specified file, one line at a time. splits on words,
 507 # and returns an array of arrays of the contents.
 508 # If a value is passed in as the second parameter, then glob
 509 # expansion is done in the directory specified by the parameter ("." is
 510 # frequently a good choice).
 511 sub filedoublearray {
 512         my $file=shift;
 513         my $globdir=shift;
 514
 515         my @ret;
 516         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 517         while (<DH_FARRAY_IN>) {
 518                 chomp;
 519                 # Only ignore comments and empty lines in v5 mode.
 520                 if (! compat(4)) {
 521                         next if /^#/ || /^$/;
 522                 }
 523                 my @line;
 524                 # Only do glob expansion in v3 mode.
 525                 #
 526                 # The tricky bit is that the glob expansion is done
 527                 # as if we were in the specified directory, so the
 528                 # filenames that come out are relative to it.
 529                 if (defined $globdir && ! compat(2)) {
 530                         for (map { glob "$globdir/$_" } split) {
 531                                 s#^$globdir/##;
 532                                 push @line, $_;
 533                         }
 534                 }
 535                 else {
 536                         @line = split;
 537                 }
 538                 push @ret, [@line];
 539         }
 540         close DH_FARRAY_IN;
 541
 542         return @ret;
 543 }
 544
 545 # Reads in the specified file, one word at a time, and returns an array of
 546 # the result. Can do globbing as does filedoublearray.
 547 sub filearray {
 548         return map { @$_ } filedoublearray(@_);
 549 }
 550
 551 # Passed a filename, returns true if -X says that file should be excluded.
 552 sub excludefile {
 553         my $filename = shift;
 554         foreach my $f (@{$dh{EXCLUDE}}) {
 555                 return 1 if $filename =~ /\Q$f\E/;
 556         }
 557         return 0;
 558 }
 559
 560 # Returns the build architecture. (Memoized)
 561 {
 562         my $arch;
 563
 564         sub buildarch {
 565                 return $arch if defined $arch;
 566
 567                 $arch=`dpkg-architecture -qDEB_HOST_ARCH 2>/dev/null` || error("dpkg-architecture failed");
 568                 chomp $arch;
 569                 return $arch;
 570         }
 571 }
 572
 573 # Passed an arch and a list of arches to match against, returns true if matched
 574 sub samearch {
 575         my $arch=shift;
 576         my @archlist=split(/\s+/,shift);
 577
 578         foreach my $a (@archlist) {
 579                 system("dpkg-architecture", "-a$arch", "-i$a") == 0 && return 1;
 580         }
 581
 582         return 0;
 583 }
 584
 585 # Returns a list of packages in the control file.
 586 # Must pass "arch" or "indep" or "same" to specify arch-dependant or
 587 # -independant or same arch packages. If nothing is specified, returns all
 588 # packages.
 589 # As a side effect, populates %package_arches and %package_types with the
 590 # types of all packages (not only those returned).
 591 my (%package_types, %package_arches);
 592 sub getpackages {
 593         my $type=shift;
 594
 595         %package_types=();
 596         %package_arches=();
 597
 598         $type="" if ! defined $type;
 599
 600         # Look up the build arch if we need to.
 601         my $buildarch='';
 602         if ($type eq 'same') {
 603                 $buildarch=buildarch();
 604         }
 605
 606         my $package="";
 607         my $arch="";
 608         my $package_type;
 609         my @list=();
 610         my %seen;
 611         open (CONTROL, 'debian/control') ||
 612                 error("cannot read debian/control: $!\n");
 613         while (<CONTROL>) {
 614                 chomp;
 615                 s/\s+$//;
 616                 if (/^Package:\s*(.*)/) {
 617                         $package=$1;
 618                         # Detect duplicate package names in the same control file.
 619                         if (! $seen{$package}) {
 620                                 $seen{$package}=1;
 621                         }
 622                         else {
 623                                 error("debian/control has a duplicate entry for $package");
 624                         }
 625                         $package_type="deb";
 626                 }
 627                 if (/^Architecture:\s*(.*)/) {
 628                         $arch=$1;
 629                 }
 630                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 631                         $package_type=$1;
 632                 }
 633
 634                 if (!$_ or eof) { # end of stanza.
 635                         if ($package) {
 636                                 $package_types{$package}=$package_type;
 637                                 $package_arches{$package}=$arch;
 638                         }
 639                         if ($package &&
 640                             (($type eq 'indep' && $arch eq 'all') ||
 641                              ($type eq 'arch' && $arch ne 'all') ||
 642                              ($type eq 'same' && ($arch eq 'any' || samearch($buildarch, $arch))) ||
 643                              ! $type)) {
 644                                 push @list, $package;
 645                                 $package="";
 646                                 $arch="";
 647                         }
 648                 }
 649         }
 650         close CONTROL;
 651
 652         return @list;
 653 }
 654
 655 # Returns the arch a package will build for.
 656 sub package_arch {
 657         my $package=shift;
 658
 659         if (! exists $package_arches{$package}) {
 660                 warning "package $package is not in control info";
 661                 return buildarch();
 662         }
 663         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 664 }
 665
 666 # Return true if a given package is really a udeb.
 667 sub is_udeb {
 668         my $package=shift;
 669
 670         if (! exists $package_types{$package}) {
 671                 warning "package $package is not in control info";
 672                 return 0;
 673         }
 674         return $package_types{$package} eq 'udeb';
 675 }
 676
 677 # Generates the filename that is used for a udeb package.
 678 sub udeb_filename {
 679         my $package=shift;
 680
 681         my $filearch=package_arch($package);
 682         isnative($package); # side effect
 683         my $version=$dh{VERSION};
 684         $version=~s/^[0-9]+://; # strip any epoch
 685         return "${package}_${version}_$filearch.udeb";
 686 }
 687
 688 # Handles #DEBHELPER# substitution in a script; also can generate a new
 689 # script from scratch if none exists but there is a .debhelper file for it.
 690 sub debhelper_script_subst {
 691         my $package=shift;
 692         my $script=shift;
 693
 694         my $tmp=tmpdir($package);
 695         my $ext=pkgext($package);
 696         my $file=pkgfile($package,$script);
 697
 698         if ($file ne '') {
 699                 if (-f "debian/$ext$script.debhelper") {
 700                         # Add this into the script, where it has #DEBHELPER#
 701                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 702                 }
 703                 else {
 704                         # Just get rid of any #DEBHELPER# in the script.
 705                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 706                 }
 707                 doit("chown","0:0","$tmp/DEBIAN/$script");
 708                 doit("chmod",755,"$tmp/DEBIAN/$script");
 709         }
 710         elsif ( -f "debian/$ext$script.debhelper" ) {
 711                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 712                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 713                 doit("chown","0:0","$tmp/DEBIAN/$script");
 714                 doit("chmod",755,"$tmp/DEBIAN/$script");
 715         }
 716 }
 717
 718 1