Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2008.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell
  18             &inhibit_log);
  19
  20 my $max_compat=7;
  21
  22 sub init {
  23         my %params=@_;
  24
  25         # Check to see if an option line starts with a dash,
  26         # or DH_OPTIONS is set.
  27         # If so, we need to pass this off to the resource intensive
  28         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  29         if ((defined $ENV{DH_OPTIONS} && length $ENV{DH_OPTIONS}) ||
  30             (defined $ENV{DH_INTERNAL_OPTIONS} && length $ENV{DH_INTERNAL_OPTIONS}) ||
  31             grep /^-/, @ARGV) {
  32                 eval "use Debian::Debhelper::Dh_Getopt";
  33                 error($@) if $@;
  34                 Debian::Debhelper::Dh_Getopt::parseopts($params{options});
  35         }
  36
  37         # Another way to set excludes.
  38         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  39                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  40         }
  41
  42         # Generate EXCLUDE_FIND.
  43         if ($dh{EXCLUDE}) {
  44                 $dh{EXCLUDE_FIND}='';
  45                 foreach (@{$dh{EXCLUDE}}) {
  46                         my $x=$_;
  47                         $x=escape_shell($x);
  48                         $x=~s/\./\\\\./g;
  49                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  50                 }
  51                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  52         }
  53
  54         # Check to see if DH_VERBOSE environment variable was set, if so,
  55         # make sure verbose is on.
  56         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  57                 $dh{VERBOSE}=1;
  58         }
  59
  60         # Check to see if DH_NO_ACT environment variable was set, if so,
  61         # make sure no act mode is on.
  62         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  63                 $dh{NO_ACT}=1;
  64         }
  65
  66         my @allpackages=getpackages();
  67         # Get the name of the main binary package (first one listed in
  68         # debian/control). Only if the main package was not set on the
  69         # command line.
  70         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  71                 $dh{MAINPACKAGE}=$allpackages[0];
  72         }
  73
  74         # Check if packages to build have been specified, if not, fall back to
  75         # the default, doing them all.
  76         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  77                 push @{$dh{DOPACKAGES}},@allpackages;
  78         }
  79
  80         # Check to see if -P was specified. If so, we can only act on a single
  81         # package.
  82         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  83                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  84         }
  85
  86         # Figure out which package is the first one we were instructed to build.
  87         # This package gets special treatement: files and directories specified on
  88         # the command line may affect it.
  89         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
  90
  91         # If no error handling function was specified, just propigate
  92         # errors out.
  93         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
  94                 $dh{ERROR_HANDLER}='exit \$?';
  95         }
  96 }
  97
  98 # Run at exit. Add the command to the log files for the packages it acted
  99 # on, if it's exiting successfully.
 100 my $write_log=1;
 101 sub END {
 102         if ($? == 0 && $write_log) {
 103                 write_log(basename($0), @{$dh{DOPACKAGES}});
 104         }
 105 }
 106
 107 sub write_log {
 108         my $cmd=shift;
 109         my @packages=@_;
 110
 111         foreach my $package (@packages) {
 112                 my $ext=pkgext($package);
 113                 my $log="debian/${ext}debhelper.log";
 114                 open(LOG, ">>", $log) || error("failed to write to ${log}: $!");
 115                 print LOG $cmd."\n";
 116                 close LOG;
 117         }
 118 }
 119
 120 sub inhibit_log {
 121         $write_log=0;
 122 }
 123
 124 # Pass it an array containing the arguments of a shell command like would
 125 # be run by exec(). It turns that into a line like you might enter at the
 126 # shell, escaping metacharacters and quoting arguments that contain spaces.
 127 sub escape_shell {
 128         my @args=@_;
 129         my $line="";
 130         my @ret;
 131         foreach my $word (@args) {
 132                 if ($word=~/\s/) {
 133                         # Escape only a few things since it will be quoted.
 134                         # Note we use double quotes because you cannot
 135                         # escape ' in single quotes, while " can be escaped
 136                         # in double.
 137                         # This does make -V"foo bar" turn into "-Vfoo bar",
 138                         # but that will be parsed identically by the shell
 139                         # anyway..
 140                         $word=~s/([\n`\$"\\])/\\$1/g;
 141                         push @ret, "\"$word\"";
 142                 }
 143                 else {
 144                         # This list is from _Unix in a Nutshell_. (except '#')
 145                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 146                         push @ret,$word;
 147                 }
 148         }
 149         return join(' ', @ret);
 150 }
 151
 152 # Run a command, and display the command to stdout if verbose mode is on.
 153 # All commands that modifiy files in $TMP should be ran via this
 154 # function.
 155 #
 156 # Note that this cannot handle complex commands, especially anything
 157 # involving redirection. Use complex_doit instead.
 158 sub doit {
 159         verbose_print(escape_shell(@_));
 160
 161         if (! $dh{NO_ACT}) {
 162                 system(@_) == 0 || _error_exitcode($_[0]);
 163         }
 164 }
 165
 166 # Run a command and display the command to stdout if verbose mode is on.
 167 # Use doit() if you can, instead of this function, because this function
 168 # forks a shell. However, this function can handle more complicated stuff
 169 # like redirection.
 170 sub complex_doit {
 171         verbose_print(join(" ",@_));
 172
 173         if (! $dh{NO_ACT}) {
 174                 # The join makes system get a scalar so it forks off a shell.
 175                 system(join(" ", @_)) == 0 || _error_exitcode(join(" ", @_))
 176         }
 177 }
 178
 179 sub _error_exitcode {
 180         my $command=shift;
 181         if ($? == -1) {
 182                 error("$command failed to to execute: $!");
 183         }
 184         elsif ($? & 127) {
 185                 error("$command died with signal ".($? & 127));
 186         }
 187         else {
 188                 error("$command returned exit code ".($? >> 8));
 189         }
 190 }
 191
 192 # Run a command that may have a huge number of arguments, like xargs does.
 193 # Pass in a reference to an array containing the arguments, and then other
 194 # parameters that are the command and any parameters that should be passed to
 195 # it each time.
 196 sub xargs {
 197         my $args=shift;
 198
 199         # The kernel can accept command lines up to 20k worth of characters.
 200         my $command_max=20000; # LINUX SPECIFIC!!
 201                         # I could use POSIX::ARG_MAX, but that would be slow.
 202
 203         # Figure out length of static portion of command.
 204         my $static_length=0;
 205         foreach (@_) {
 206                 $static_length+=length($_)+1;
 207         }
 208
 209         my @collect=();
 210         my $length=$static_length;
 211         foreach (@$args) {
 212                 if (length($_) + 1 + $static_length > $command_max) {
 213                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 214                 }
 215                 $length+=length($_) + 1;
 216                 if ($length < $command_max) {
 217                         push @collect, $_;
 218                 }
 219                 else {
 220                         doit(@_,@collect) if $#collect > -1;
 221                         @collect=($_);
 222                         $length=$static_length + length($_) + 1;
 223                 }
 224         }
 225         doit(@_,@collect) if $#collect > -1;
 226 }
 227
 228 # Print something if the verbose flag is on.
 229 sub verbose_print {
 230         my $message=shift;
 231
 232         if ($dh{VERBOSE}) {
 233                 print "\t$message\n";
 234         }
 235 }
 236
 237 # Output an error message and exit.
 238 sub error {
 239         my $message=shift;
 240
 241         warning($message);
 242         exit 1;
 243 }
 244
 245 # Output a warning.
 246 sub warning {
 247         my $message=shift;
 248
 249         print STDERR basename($0).": $message\n";
 250 }
 251
 252 # Returns the basename of the argument passed to it.
 253 sub basename {
 254         my $fn=shift;
 255
 256         $fn=~s/\/$//g; # ignore trailing slashes
 257         $fn=~s:^.*/(.*?)$:$1:;
 258         return $fn;
 259 }
 260
 261 # Returns the directory name of the argument passed to it.
 262 sub dirname {
 263         my $fn=shift;
 264
 265         $fn=~s/\/$//g; # ignore trailing slashes
 266         $fn=~s:^(.*)/.*?$:$1:;
 267         return $fn;
 268 }
 269
 270 # Pass in a number, will return true iff the current compatibility level
 271 # is less than or equal to that number.
 272 {
 273         my $warned_compat=0;
 274         my $c;
 275
 276         sub compat {
 277                 my $num=shift;
 278
 279                 if (! defined $c) {
 280                         $c=1;
 281                         if (defined $ENV{DH_COMPAT}) {
 282                                 $c=$ENV{DH_COMPAT};
 283                         }
 284                         elsif (-e 'debian/compat') {
 285                                 # Try the file..
 286                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 287                                 my $l=<COMPAT_IN>;
 288                                 if (! defined $l || ! length $l) {
 289                                         warning("debian/compat is empty, assuming level $c");
 290                                 }
 291                                 else {
 292                                         chomp $l;
 293                                         $c=$l;
 294                                 }
 295                         }
 296                 }
 297
 298                 if ($c < 4 && ! $warned_compat) {
 299                         warning("Compatibility levels before 5 are deprecated.");
 300                         $warned_compat=1;
 301                 }
 302
 303                 if ($c > $max_compat) {
 304                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 305                 }
 306
 307                 return ($c <= $num);
 308         }
 309 }
 310
 311 # Pass it a name of a binary package, it returns the name of the tmp dir to
 312 # use, for that package.
 313 sub tmpdir {
 314         my $package=shift;
 315
 316         if ($dh{TMPDIR}) {
 317                 return $dh{TMPDIR};
 318         }
 319         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 320                 # This is for back-compatibility with the debian/tmp tradition.
 321                 return "debian/tmp";
 322         }
 323         else {
 324                 return "debian/$package";
 325         }
 326 }
 327
 328 # Pass this the name of a binary package, and the name of the file wanted
 329 # for the package, and it will return the actual existing filename to use.
 330 #
 331 # It tries several filenames:
 332 #   * debian/package.filename.buildarch
 333 #   * debian/package.filename
 334 #   * debian/file (if the package is the main package)
 335 # If --name was specified then tonly the first two are tried, and they must
 336 # have the name after the pacage name:
 337 #   * debian/package.name.filename.buildarch
 338 #   * debian/package.name.filename
 339 sub pkgfile {
 340         my $package=shift;
 341         my $filename=shift;
 342
 343         if (defined $dh{NAME}) {
 344                 $filename="$dh{NAME}.$filename";
 345         }
 346
 347         my @try=("debian/$package.$filename.".buildarch(),
 348                  "debian/$package.$filename");
 349         if ($package eq $dh{MAINPACKAGE}) {
 350                 push @try, "debian/$filename";
 351         }
 352
 353         foreach my $file (@try) {
 354                 if (-f $file &&
 355                     (! $dh{IGNORE} || ! exists $dh{IGNORE}->{$file})) {
 356                         return $file;
 357                 }
 358
 359         }
 360
 361         return "";
 362
 363 }
 364
 365 # Pass it a name of a binary package, it returns the name to prefix to files
 366 # in debian/ for this package.
 367 sub pkgext {
 368         my $package=shift;
 369
 370         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 371                 return "";
 372         }
 373         return "$package.";
 374 }
 375
 376 # Pass it the name of a binary package, it returns the name to install
 377 # files by in eg, etc. Normally this is the same, but --name can override
 378 # it.
 379 sub pkgfilename {
 380         my $package=shift;
 381
 382         if (defined $dh{NAME}) {
 383                 return $dh{NAME};
 384         }
 385         return $package;
 386 }
 387
 388 # Returns 1 if the package is a native debian package, null otherwise.
 389 # As a side effect, sets $dh{VERSION} to the version of this package.
 390 {
 391         # Caches return code so it only needs to run dpkg-parsechangelog once.
 392         my %isnative_cache;
 393
 394         sub isnative {
 395                 my $package=shift;
 396
 397                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 398
 399                 # Make sure we look at the correct changelog.
 400                 my $isnative_changelog=pkgfile($package,"changelog");
 401                 if (! $isnative_changelog) {
 402                         $isnative_changelog="debian/changelog";
 403                 }
 404                 # Get the package version.
 405                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 406                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 407                 # Did the changelog parse fail?
 408                 if (! defined $dh{VERSION}) {
 409                         error("changelog parse failure");
 410                 }
 411
 412                 # Is this a native Debian package?
 413                 if ($dh{VERSION}=~m/.*-/) {
 414                         return $isnative_cache{$package}=0;
 415                 }
 416                 else {
 417                         return $isnative_cache{$package}=1;
 418                 }
 419         }
 420 }
 421
 422 # Automatically add a shell script snippet to a debian script.
 423 # Only works if the script has #DEBHELPER# in it.
 424 #
 425 # Parameters:
 426 # 1: package
 427 # 2: script to add to
 428 # 3: filename of snippet
 429 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 430 sub autoscript {
 431         my $package=shift;
 432         my $script=shift;
 433         my $filename=shift;
 434         my $sed=shift || "";
 435
 436         # This is the file we will modify.
 437         my $outfile="debian/".pkgext($package)."$script.debhelper";
 438
 439         # Figure out what shell script snippet to use.
 440         my $infile;
 441         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 442             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 443                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 444         }
 445         else {
 446                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 447                         $infile="/usr/share/debhelper/autoscripts/$filename";
 448                 }
 449                 else {
 450                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 451                 }
 452         }
 453
 454         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 455            && !compat(5)) {
 456                 # Add fragments to top so they run in reverse order when removing.
 457                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 458                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 459                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 460                 complex_doit("cat $outfile >> $outfile.new");
 461                 complex_doit("mv $outfile.new $outfile");
 462         }
 463         else {
 464                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 465                 complex_doit("sed \"$sed\" $infile >> $outfile");
 466                 complex_doit("echo '# End automatically added section' >> $outfile");
 467         }
 468 }
 469
 470 # Removes a whole substvar line.
 471 sub delsubstvar {
 472         my $package=shift;
 473         my $substvar=shift;
 474
 475         my $ext=pkgext($package);
 476         my $substvarfile="debian/${ext}substvars";
 477
 478         if (-e $substvarfile) {
 479                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 480                 doit("mv", "$substvarfile.new","$substvarfile");
 481         }
 482 }
 483
 484 # Adds a dependency on some package to the specified
 485 # substvar in a package's substvar's file.
 486 sub addsubstvar {
 487         my $package=shift;
 488         my $substvar=shift;
 489         my $deppackage=shift;
 490         my $verinfo=shift;
 491         my $remove=shift;
 492
 493         my $ext=pkgext($package);
 494         my $substvarfile="debian/${ext}substvars";
 495         my $str=$deppackage;
 496         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 497
 498         # Figure out what the line will look like, based on what's there
 499         # now, and what we're to add or remove.
 500         my $line="";
 501         if (-e $substvarfile) {
 502                 my %items;
 503                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 504                 while (<SUBSTVARS_IN>) {
 505                         chomp;
 506                         if (/^\Q$substvar\E=(.*)/) {
 507                                 %items = map { $_ => 1} split(", ", $1);
 508
 509                                 last;
 510                         }
 511                 }
 512                 close SUBSTVARS_IN;
 513                 if (! $remove) {
 514                         $items{$str}=1;
 515                 }
 516                 else {
 517                         delete $items{$str};
 518                 }
 519                 $line=join(", ", sort keys %items);
 520         }
 521         elsif (! $remove) {
 522                 $line=$str;
 523         }
 524
 525         if (length $line) {
 526                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 527                  doit("mv", "$substvarfile.new", $substvarfile);
 528         }
 529         else {
 530                 delsubstvar($package,$substvar);
 531         }
 532 }
 533
 534 # Reads in the specified file, one line at a time. splits on words,
 535 # and returns an array of arrays of the contents.
 536 # If a value is passed in as the second parameter, then glob
 537 # expansion is done in the directory specified by the parameter ("." is
 538 # frequently a good choice).
 539 sub filedoublearray {
 540         my $file=shift;
 541         my $globdir=shift;
 542
 543         my @ret;
 544         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 545         while (<DH_FARRAY_IN>) {
 546                 chomp;
 547                 # Only ignore comments and empty lines in v5 mode.
 548                 if (! compat(4)) {
 549                         next if /^#/ || /^$/;
 550                 }
 551                 my @line;
 552                 # Only do glob expansion in v3 mode.
 553                 #
 554                 # The tricky bit is that the glob expansion is done
 555                 # as if we were in the specified directory, so the
 556                 # filenames that come out are relative to it.
 557                 if (defined $globdir && ! compat(2)) {
 558                         for (map { glob "$globdir/$_" } split) {
 559                                 s#^$globdir/##;
 560                                 push @line, $_;
 561                         }
 562                 }
 563                 else {
 564                         @line = split;
 565                 }
 566                 push @ret, [@line];
 567         }
 568         close DH_FARRAY_IN;
 569
 570         return @ret;
 571 }
 572
 573 # Reads in the specified file, one word at a time, and returns an array of
 574 # the result. Can do globbing as does filedoublearray.
 575 sub filearray {
 576         return map { @$_ } filedoublearray(@_);
 577 }
 578
 579 # Passed a filename, returns true if -X says that file should be excluded.
 580 sub excludefile {
 581         my $filename = shift;
 582         foreach my $f (@{$dh{EXCLUDE}}) {
 583                 return 1 if $filename =~ /\Q$f\E/;
 584         }
 585         return 0;
 586 }
 587
 588 # Returns the build architecture. (Memoized)
 589 {
 590         my $arch;
 591
 592         sub buildarch {
 593                 return $arch if defined $arch;
 594
 595                 $arch=`dpkg-architecture -qDEB_HOST_ARCH 2>/dev/null` || error("dpkg-architecture failed");
 596                 chomp $arch;
 597                 return $arch;
 598         }
 599 }
 600
 601 # Passed an arch and a list of arches to match against, returns true if matched
 602 sub samearch {
 603         my $arch=shift;
 604         my @archlist=split(/\s+/,shift);
 605
 606         foreach my $a (@archlist) {
 607                 system("dpkg-architecture", "-a$arch", "-i$a") == 0 && return 1;
 608         }
 609
 610         return 0;
 611 }
 612
 613 # Returns a list of packages in the control file.
 614 # Must pass "arch" or "indep" or "same" to specify arch-dependant or
 615 # -independant or same arch packages. If nothing is specified, returns all
 616 # packages.
 617 # As a side effect, populates %package_arches and %package_types with the
 618 # types of all packages (not only those returned).
 619 my (%package_types, %package_arches);
 620 sub getpackages {
 621         my $type=shift;
 622
 623         %package_types=();
 624         %package_arches=();
 625
 626         $type="" if ! defined $type;
 627
 628         # Look up the build arch if we need to.
 629         my $buildarch='';
 630         if ($type eq 'same') {
 631                 $buildarch=buildarch();
 632         }
 633
 634         my $package="";
 635         my $arch="";
 636         my $package_type;
 637         my @list=();
 638         my %seen;
 639         open (CONTROL, 'debian/control') ||
 640                 error("cannot read debian/control: $!\n");
 641         while (<CONTROL>) {
 642                 chomp;
 643                 s/\s+$//;
 644                 if (/^Package:\s*(.*)/) {
 645                         $package=$1;
 646                         # Detect duplicate package names in the same control file.
 647                         if (! $seen{$package}) {
 648                                 $seen{$package}=1;
 649                         }
 650                         else {
 651                                 error("debian/control has a duplicate entry for $package");
 652                         }
 653                         $package_type="deb";
 654                 }
 655                 if (/^Architecture:\s*(.*)/) {
 656                         $arch=$1;
 657                 }
 658                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 659                         $package_type=$1;
 660                 }
 661
 662                 if (!$_ or eof) { # end of stanza.
 663                         if ($package) {
 664                                 $package_types{$package}=$package_type;
 665                                 $package_arches{$package}=$arch;
 666                         }
 667                         if ($package &&
 668                             (($type eq 'indep' && $arch eq 'all') ||
 669                              ($type eq 'arch' && $arch ne 'all') ||
 670                              ($type eq 'same' && ($arch eq 'any' || samearch($buildarch, $arch))) ||
 671                              ! $type)) {
 672                                 push @list, $package;
 673                                 $package="";
 674                                 $arch="";
 675                         }
 676                 }
 677         }
 678         close CONTROL;
 679
 680         return @list;
 681 }
 682
 683 # Returns the arch a package will build for.
 684 sub package_arch {
 685         my $package=shift;
 686
 687         if (! exists $package_arches{$package}) {
 688                 warning "package $package is not in control info";
 689                 return buildarch();
 690         }
 691         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 692 }
 693
 694 # Return true if a given package is really a udeb.
 695 sub is_udeb {
 696         my $package=shift;
 697
 698         if (! exists $package_types{$package}) {
 699                 warning "package $package is not in control info";
 700                 return 0;
 701         }
 702         return $package_types{$package} eq 'udeb';
 703 }
 704
 705 # Generates the filename that is used for a udeb package.
 706 sub udeb_filename {
 707         my $package=shift;
 708
 709         my $filearch=package_arch($package);
 710         isnative($package); # side effect
 711         my $version=$dh{VERSION};
 712         $version=~s/^[0-9]+://; # strip any epoch
 713         return "${package}_${version}_$filearch.udeb";
 714 }
 715
 716 # Handles #DEBHELPER# substitution in a script; also can generate a new
 717 # script from scratch if none exists but there is a .debhelper file for it.
 718 sub debhelper_script_subst {
 719         my $package=shift;
 720         my $script=shift;
 721
 722         my $tmp=tmpdir($package);
 723         my $ext=pkgext($package);
 724         my $file=pkgfile($package,$script);
 725
 726         if ($file ne '') {
 727                 if (-f "debian/$ext$script.debhelper") {
 728                         # Add this into the script, where it has #DEBHELPER#
 729                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 730                 }
 731                 else {
 732                         # Just get rid of any #DEBHELPER# in the script.
 733                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 734                 }
 735                 doit("chown","0:0","$tmp/DEBIAN/$script");
 736                 doit("chmod",755,"$tmp/DEBIAN/$script");
 737         }
 738         elsif ( -f "debian/$ext$script.debhelper" ) {
 739                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 740                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 741                 doit("chown","0:0","$tmp/DEBIAN/$script");
 742                 doit("chmod",755,"$tmp/DEBIAN/$script");
 743         }
 744 }
 745
 746 1