Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2008.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell
  18             &inhibit_log);
  19
  20 my $max_compat=7;
  21
  22 sub init {
  23         my %params=@_;
  24
  25         # Check to see if an option line starts with a dash,
  26         # or DH_OPTIONS is set.
  27         # If so, we need to pass this off to the resource intensive
  28         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  29         if ((defined $ENV{DH_OPTIONS} && length $ENV{DH_OPTIONS}) ||
  30             (defined $ENV{DH_INTERNAL_OPTIONS} && length $ENV{DH_INTERNAL_OPTIONS}) ||
  31             grep /^-/, @ARGV) {
  32                 eval "use Debian::Debhelper::Dh_Getopt";
  33                 error($@) if $@;
  34                 Debian::Debhelper::Dh_Getopt::parseopts($params{options});
  35         }
  36
  37         # Another way to set excludes.
  38         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  39                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  40         }
  41
  42         # Generate EXCLUDE_FIND.
  43         if ($dh{EXCLUDE}) {
  44                 $dh{EXCLUDE_FIND}='';
  45                 foreach (@{$dh{EXCLUDE}}) {
  46                         my $x=$_;
  47                         $x=escape_shell($x);
  48                         $x=~s/\./\\\\./g;
  49                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  50                 }
  51                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  52         }
  53
  54         # Check to see if DH_VERBOSE environment variable was set, if so,
  55         # make sure verbose is on.
  56         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  57                 $dh{VERBOSE}=1;
  58         }
  59
  60         # Check to see if DH_NO_ACT environment variable was set, if so,
  61         # make sure no act mode is on.
  62         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  63                 $dh{NO_ACT}=1;
  64         }
  65
  66         my @allpackages=getpackages();
  67         # Get the name of the main binary package (first one listed in
  68         # debian/control). Only if the main package was not set on the
  69         # command line.
  70         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  71                 $dh{MAINPACKAGE}=$allpackages[0];
  72         }
  73
  74         # Check if packages to build have been specified, if not, fall back to
  75         # the default, doing them all.
  76         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  77                 if ($dh{DOINDEP} || $dh{DOARCH} || $dh{DOSAME}) {
  78                         error("You asked that all arch in(dep) packages be built, but there are none of that type.");
  79                 }
  80                 push @{$dh{DOPACKAGES}},@allpackages;
  81         }
  82
  83         # Check to see if -P was specified. If so, we can only act on a single
  84         # package.
  85         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  86                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  87         }
  88
  89         # Figure out which package is the first one we were instructed to build.
  90         # This package gets special treatement: files and directories specified on
  91         # the command line may affect it.
  92         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
  93
  94         # If no error handling function was specified, just propigate
  95         # errors out.
  96         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
  97                 $dh{ERROR_HANDLER}='exit \$?';
  98         }
  99 }
 100
 101 # Run at exit. Add the command to the log files for the packages it acted
 102 # on, if it's exiting successfully.
 103 my $write_log=1;
 104 sub END {
 105         if ($? == 0 && $write_log) {
 106                 write_log(basename($0), @{$dh{DOPACKAGES}});
 107         }
 108 }
 109
 110 sub write_log {
 111         my $cmd=shift;
 112         my @packages=@_;
 113
 114         foreach my $package (@packages) {
 115                 my $ext=pkgext($package);
 116                 my $log="debian/${ext}debhelper.log";
 117                 open(LOG, ">>", $log) || error("failed to write to ${log}: $!");
 118                 print LOG $cmd."\n";
 119                 close LOG;
 120         }
 121 }
 122
 123 sub inhibit_log {
 124         $write_log=0;
 125 }
 126
 127 # Pass it an array containing the arguments of a shell command like would
 128 # be run by exec(). It turns that into a line like you might enter at the
 129 # shell, escaping metacharacters and quoting arguments that contain spaces.
 130 sub escape_shell {
 131         my @args=@_;
 132         my $line="";
 133         my @ret;
 134         foreach my $word (@args) {
 135                 if ($word=~/\s/) {
 136                         # Escape only a few things since it will be quoted.
 137                         # Note we use double quotes because you cannot
 138                         # escape ' in single quotes, while " can be escaped
 139                         # in double.
 140                         # This does make -V"foo bar" turn into "-Vfoo bar",
 141                         # but that will be parsed identically by the shell
 142                         # anyway..
 143                         $word=~s/([\n`\$"\\])/\\$1/g;
 144                         push @ret, "\"$word\"";
 145                 }
 146                 else {
 147                         # This list is from _Unix in a Nutshell_. (except '#')
 148                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 149                         push @ret,$word;
 150                 }
 151         }
 152         return join(' ', @ret);
 153 }
 154
 155 # Run a command, and display the command to stdout if verbose mode is on.
 156 # All commands that modifiy files in $TMP should be ran via this
 157 # function.
 158 #
 159 # Note that this cannot handle complex commands, especially anything
 160 # involving redirection. Use complex_doit instead.
 161 sub doit {
 162         verbose_print(escape_shell(@_));
 163
 164         if (! $dh{NO_ACT}) {
 165                 my $ret=system(@_);
 166                 $ret == 0 || error("command returned error code $ret");
 167         }
 168 }
 169
 170 # Run a command and display the command to stdout if verbose mode is on.
 171 # Use doit() if you can, instead of this function, because this function
 172 # forks a shell. However, this function can handle more complicated stuff
 173 # like redirection.
 174 sub complex_doit {
 175         verbose_print(join(" ",@_));
 176
 177         if (! $dh{NO_ACT}) {
 178                 # The join makes system get a scalar so it forks off a shell.
 179                 system(join(" ",@_)) == 0
 180                         || error("command returned error code");
 181         }
 182 }
 183
 184 # Run a command that may have a huge number of arguments, like xargs does.
 185 # Pass in a reference to an array containing the arguments, and then other
 186 # parameters that are the command and any parameters that should be passed to
 187 # it each time.
 188 sub xargs {
 189         my $args=shift;
 190
 191         # The kernel can accept command lines up to 20k worth of characters.
 192         my $command_max=20000; # LINUX SPECIFIC!!
 193                         # I could use POSIX::ARG_MAX, but that would be slow.
 194
 195         # Figure out length of static portion of command.
 196         my $static_length=0;
 197         foreach (@_) {
 198                 $static_length+=length($_)+1;
 199         }
 200
 201         my @collect=();
 202         my $length=$static_length;
 203         foreach (@$args) {
 204                 if (length($_) + 1 + $static_length > $command_max) {
 205                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 206                 }
 207                 $length+=length($_) + 1;
 208                 if ($length < $command_max) {
 209                         push @collect, $_;
 210                 }
 211                 else {
 212                         doit(@_,@collect) if $#collect > -1;
 213                         @collect=($_);
 214                         $length=$static_length + length($_) + 1;
 215                 }
 216         }
 217         doit(@_,@collect) if $#collect > -1;
 218 }
 219
 220 # Print something if the verbose flag is on.
 221 sub verbose_print {
 222         my $message=shift;
 223
 224         if ($dh{VERBOSE}) {
 225                 print "\t$message\n";
 226         }
 227 }
 228
 229 # Output an error message and exit.
 230 sub error {
 231         my $message=shift;
 232
 233         warning($message);
 234         exit 1;
 235 }
 236
 237 # Output a warning.
 238 sub warning {
 239         my $message=shift;
 240
 241         print STDERR basename($0).": $message\n";
 242 }
 243
 244 # Returns the basename of the argument passed to it.
 245 sub basename {
 246         my $fn=shift;
 247
 248         $fn=~s/\/$//g; # ignore trailing slashes
 249         $fn=~s:^.*/(.*?)$:$1:;
 250         return $fn;
 251 }
 252
 253 # Returns the directory name of the argument passed to it.
 254 sub dirname {
 255         my $fn=shift;
 256
 257         $fn=~s/\/$//g; # ignore trailing slashes
 258         $fn=~s:^(.*)/.*?$:$1:;
 259         return $fn;
 260 }
 261
 262 # Pass in a number, will return true iff the current compatibility level
 263 # is less than or equal to that number.
 264 {
 265         my $warned_compat=0;
 266         my $c;
 267
 268         sub compat {
 269                 my $num=shift;
 270
 271                 if (! defined $c) {
 272                         $c=1;
 273                         if (defined $ENV{DH_COMPAT}) {
 274                                 $c=$ENV{DH_COMPAT};
 275                         }
 276                         elsif (-e 'debian/compat') {
 277                                 # Try the file..
 278                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 279                                 my $l=<COMPAT_IN>;
 280                                 if (! defined $l || ! length $l) {
 281                                         warning("debian/compat is empty, assuming level $c");
 282                                 }
 283                                 else {
 284                                         chomp $l;
 285                                         $c=$l;
 286                                 }
 287                         }
 288                 }
 289
 290                 if ($c < 4 && ! $warned_compat) {
 291                         warning("Compatibility levels before 4 are deprecated.");
 292                         $warned_compat=1;
 293                 }
 294
 295                 if ($c > $max_compat) {
 296                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 297                 }
 298
 299                 return ($c <= $num);
 300         }
 301 }
 302
 303 # Pass it a name of a binary package, it returns the name of the tmp dir to
 304 # use, for that package.
 305 sub tmpdir {
 306         my $package=shift;
 307
 308         if ($dh{TMPDIR}) {
 309                 return $dh{TMPDIR};
 310         }
 311         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 312                 # This is for back-compatibility with the debian/tmp tradition.
 313                 return "debian/tmp";
 314         }
 315         else {
 316                 return "debian/$package";
 317         }
 318 }
 319
 320 # Pass this the name of a binary package, and the name of the file wanted
 321 # for the package, and it will return the actual existing filename to use.
 322 #
 323 # It tries several filenames:
 324 #   * debian/package.filename.buildarch
 325 #   * debian/package.filename
 326 #   * debian/file (if the package is the main package)
 327 # If --name was specified then tonly the first two are tried, and they must
 328 # have the name after the pacage name:
 329 #   * debian/package.name.filename.buildarch
 330 #   * debian/package.name.filename
 331 sub pkgfile {
 332         my $package=shift;
 333         my $filename=shift;
 334
 335         if (defined $dh{NAME}) {
 336                 $filename="$dh{NAME}.$filename";
 337         }
 338
 339         my @try=("debian/$package.$filename.".buildarch(),
 340                  "debian/$package.$filename");
 341         if ($package eq $dh{MAINPACKAGE}) {
 342                 push @try, "debian/$filename";
 343         }
 344
 345         foreach my $file (@try) {
 346                 if (-f $file &&
 347                     (! $dh{IGNORE} || ! exists $dh{IGNORE}->{$file})) {
 348                         return $file;
 349                 }
 350
 351         }
 352
 353         return "";
 354
 355 }
 356
 357 # Pass it a name of a binary package, it returns the name to prefix to files
 358 # in debian/ for this package.
 359 sub pkgext {
 360         my $package=shift;
 361
 362         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 363                 return "";
 364         }
 365         return "$package.";
 366 }
 367
 368 # Pass it the name of a binary package, it returns the name to install
 369 # files by in eg, etc. Normally this is the same, but --name can override
 370 # it.
 371 sub pkgfilename {
 372         my $package=shift;
 373
 374         if (defined $dh{NAME}) {
 375                 return $dh{NAME};
 376         }
 377         return $package;
 378 }
 379
 380 # Returns 1 if the package is a native debian package, null otherwise.
 381 # As a side effect, sets $dh{VERSION} to the version of this package.
 382 {
 383         # Caches return code so it only needs to run dpkg-parsechangelog once.
 384         my %isnative_cache;
 385
 386         sub isnative {
 387                 my $package=shift;
 388
 389                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 390
 391                 # Make sure we look at the correct changelog.
 392                 my $isnative_changelog=pkgfile($package,"changelog");
 393                 if (! $isnative_changelog) {
 394                         $isnative_changelog="debian/changelog";
 395                 }
 396                 # Get the package version.
 397                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 398                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 399                 # Did the changelog parse fail?
 400                 if (! defined $dh{VERSION}) {
 401                         error("changelog parse failure");
 402                 }
 403
 404                 # Is this a native Debian package?
 405                 if ($dh{VERSION}=~m/.*-/) {
 406                         return $isnative_cache{$package}=0;
 407                 }
 408                 else {
 409                         return $isnative_cache{$package}=1;
 410                 }
 411         }
 412 }
 413
 414 # Automatically add a shell script snippet to a debian script.
 415 # Only works if the script has #DEBHELPER# in it.
 416 #
 417 # Parameters:
 418 # 1: package
 419 # 2: script to add to
 420 # 3: filename of snippet
 421 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 422 sub autoscript {
 423         my $package=shift;
 424         my $script=shift;
 425         my $filename=shift;
 426         my $sed=shift || "";
 427
 428         # This is the file we will modify.
 429         my $outfile="debian/".pkgext($package)."$script.debhelper";
 430
 431         # Figure out what shell script snippet to use.
 432         my $infile;
 433         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 434             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 435                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 436         }
 437         else {
 438                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 439                         $infile="/usr/share/debhelper/autoscripts/$filename";
 440                 }
 441                 else {
 442                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 443                 }
 444         }
 445
 446         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 447            && !compat(5)) {
 448                 # Add fragments to top so they run in reverse order when removing.
 449                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 450                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 451                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 452                 complex_doit("cat $outfile >> $outfile.new");
 453                 complex_doit("mv $outfile.new $outfile");
 454         }
 455         else {
 456                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 457                 complex_doit("sed \"$sed\" $infile >> $outfile");
 458                 complex_doit("echo '# End automatically added section' >> $outfile");
 459         }
 460 }
 461
 462 # Removes a whole substvar line.
 463 sub delsubstvar {
 464         my $package=shift;
 465         my $substvar=shift;
 466
 467         my $ext=pkgext($package);
 468         my $substvarfile="debian/${ext}substvars";
 469
 470         if (-e $substvarfile) {
 471                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 472                 doit("mv", "$substvarfile.new","$substvarfile");
 473         }
 474 }
 475
 476 # Adds a dependency on some package to the specified
 477 # substvar in a package's substvar's file.
 478 sub addsubstvar {
 479         my $package=shift;
 480         my $substvar=shift;
 481         my $deppackage=shift;
 482         my $verinfo=shift;
 483         my $remove=shift;
 484
 485         my $ext=pkgext($package);
 486         my $substvarfile="debian/${ext}substvars";
 487         my $str=$deppackage;
 488         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 489
 490         # Figure out what the line will look like, based on what's there
 491         # now, and what we're to add or remove.
 492         my $line="";
 493         if (-e $substvarfile) {
 494                 my %items;
 495                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 496                 while (<SUBSTVARS_IN>) {
 497                         chomp;
 498                         if (/^\Q$substvar\E=(.*)/) {
 499                                 %items = map { $_ => 1} split(", ", $1);
 500
 501                                 last;
 502                         }
 503                 }
 504                 close SUBSTVARS_IN;
 505                 if (! $remove) {
 506                         $items{$str}=1;
 507                 }
 508                 else {
 509                         delete $items{$str};
 510                 }
 511                 $line=join(", ", sort keys %items);
 512         }
 513         elsif (! $remove) {
 514                 $line=$str;
 515         }
 516
 517         if (length $line) {
 518                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 519                  doit("mv", "$substvarfile.new", $substvarfile);
 520         }
 521         else {
 522                 delsubstvar($package,$substvar);
 523         }
 524 }
 525
 526 # Reads in the specified file, one line at a time. splits on words,
 527 # and returns an array of arrays of the contents.
 528 # If a value is passed in as the second parameter, then glob
 529 # expansion is done in the directory specified by the parameter ("." is
 530 # frequently a good choice).
 531 sub filedoublearray {
 532         my $file=shift;
 533         my $globdir=shift;
 534
 535         my @ret;
 536         open (DH_FARRAY_IN, $file) || error("cannot read $file: $1");
 537         while (<DH_FARRAY_IN>) {
 538                 chomp;
 539                 # Only ignore comments and empty lines in v5 mode.
 540                 if (! compat(4)) {
 541                         next if /^#/ || /^$/;
 542                 }
 543                 my @line;
 544                 # Only do glob expansion in v3 mode.
 545                 #
 546                 # The tricky bit is that the glob expansion is done
 547                 # as if we were in the specified directory, so the
 548                 # filenames that come out are relative to it.
 549                 if (defined $globdir && ! compat(2)) {
 550                         for (map { glob "$globdir/$_" } split) {
 551                                 s#^$globdir/##;
 552                                 push @line, $_;
 553                         }
 554                 }
 555                 else {
 556                         @line = split;
 557                 }
 558                 push @ret, [@line];
 559         }
 560         close DH_FARRAY_IN;
 561
 562         return @ret;
 563 }
 564
 565 # Reads in the specified file, one word at a time, and returns an array of
 566 # the result. Can do globbing as does filedoublearray.
 567 sub filearray {
 568         return map { @$_ } filedoublearray(@_);
 569 }
 570
 571 # Passed a filename, returns true if -X says that file should be excluded.
 572 sub excludefile {
 573         my $filename = shift;
 574         foreach my $f (@{$dh{EXCLUDE}}) {
 575                 return 1 if $filename =~ /\Q$f\E/;
 576         }
 577         return 0;
 578 }
 579
 580 # Returns the build architecture. (Memoized)
 581 {
 582         my $arch;
 583
 584         sub buildarch {
 585                 return $arch if defined $arch;
 586
 587                 $arch=`dpkg-architecture -qDEB_HOST_ARCH 2>/dev/null` || error("dpkg-architecture failed");
 588                 chomp $arch;
 589                 return $arch;
 590         }
 591 }
 592
 593 # Passed an arch and a list of arches to match against, returns true if matched
 594 sub samearch {
 595         my $arch=shift;
 596         my @archlist=split(/\s+/,shift);
 597
 598         foreach my $a (@archlist) {
 599                 system("dpkg-architecture", "-a$arch", "-i$a") == 0 && return 1;
 600         }
 601
 602         return 0;
 603 }
 604
 605 # Returns a list of packages in the control file.
 606 # Must pass "arch" or "indep" or "same" to specify arch-dependant or
 607 # -independant or same arch packages. If nothing is specified, returns all
 608 # packages.
 609 # As a side effect, populates %package_arches and %package_types with the
 610 # types of all packages (not only those returned).
 611 my (%package_types, %package_arches);
 612 sub getpackages {
 613         my $type=shift;
 614
 615         %package_types=();
 616         %package_arches=();
 617
 618         $type="" if ! defined $type;
 619
 620         # Look up the build arch if we need to.
 621         my $buildarch='';
 622         if ($type eq 'same') {
 623                 $buildarch=buildarch();
 624         }
 625
 626         my $package="";
 627         my $arch="";
 628         my $package_type;
 629         my @list=();
 630         my %seen;
 631         open (CONTROL, 'debian/control') ||
 632                 error("cannot read debian/control: $!\n");
 633         while (<CONTROL>) {
 634                 chomp;
 635                 s/\s+$//;
 636                 if (/^Package:\s*(.*)/) {
 637                         $package=$1;
 638                         # Detect duplicate package names in the same control file.
 639                         if (! $seen{$package}) {
 640                                 $seen{$package}=1;
 641                         }
 642                         else {
 643                                 error("debian/control has a duplicate entry for $package");
 644                         }
 645                         $package_type="deb";
 646                 }
 647                 if (/^Architecture:\s*(.*)/) {
 648                         $arch=$1;
 649                 }
 650                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 651                         $package_type=$1;
 652                 }
 653
 654                 if (!$_ or eof) { # end of stanza.
 655                         if ($package) {
 656                                 $package_types{$package}=$package_type;
 657                                 $package_arches{$package}=$arch;
 658                         }
 659                         if ($package &&
 660                             (($type eq 'indep' && $arch eq 'all') ||
 661                              ($type eq 'arch' && $arch ne 'all') ||
 662                              ($type eq 'same' && ($arch eq 'any' || samearch($buildarch, $arch))) ||
 663                              ! $type)) {
 664                                 push @list, $package;
 665                                 $package="";
 666                                 $arch="";
 667                         }
 668                 }
 669         }
 670         close CONTROL;
 671
 672         return @list;
 673 }
 674
 675 # Returns the arch a package will build for.
 676 sub package_arch {
 677         my $package=shift;
 678
 679         if (! exists $package_arches{$package}) {
 680                 warning "package $package is not in control info";
 681                 return buildarch();
 682         }
 683         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 684 }
 685
 686 # Return true if a given package is really a udeb.
 687 sub is_udeb {
 688         my $package=shift;
 689
 690         if (! exists $package_types{$package}) {
 691                 warning "package $package is not in control info";
 692                 return 0;
 693         }
 694         return $package_types{$package} eq 'udeb';
 695 }
 696
 697 # Generates the filename that is used for a udeb package.
 698 sub udeb_filename {
 699         my $package=shift;
 700
 701         my $filearch=package_arch($package);
 702         isnative($package); # side effect
 703         my $version=$dh{VERSION};
 704         $version=~s/^[0-9]+://; # strip any epoch
 705         return "${package}_${version}_$filearch.udeb";
 706 }
 707
 708 # Handles #DEBHELPER# substitution in a script; also can generate a new
 709 # script from scratch if none exists but there is a .debhelper file for it.
 710 sub debhelper_script_subst {
 711         my $package=shift;
 712         my $script=shift;
 713
 714         my $tmp=tmpdir($package);
 715         my $ext=pkgext($package);
 716         my $file=pkgfile($package,$script);
 717
 718         if ($file ne '') {
 719                 if (-f "debian/$ext$script.debhelper") {
 720                         # Add this into the script, where it has #DEBHELPER#
 721                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 722                 }
 723                 else {
 724                         # Just get rid of any #DEBHELPER# in the script.
 725                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 726                 }
 727                 doit("chown","0:0","$tmp/DEBIAN/$script");
 728                 doit("chmod",755,"$tmp/DEBIAN/$script");
 729         }
 730         elsif ( -f "debian/$ext$script.debhelper" ) {
 731                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 732                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 733                 doit("chown","0:0","$tmp/DEBIAN/$script");
 734                 doit("chmod",755,"$tmp/DEBIAN/$script");
 735         }
 736 }
 737
 738 1