Debian/Debhelper/Dh_Lib.pm

   1 #!/usr/bin/perl -w
   2 #
   3 # Library functions for debhelper programs, perl version.
   4 #
   5 # Joey Hess, GPL copyright 1997-2008.
   6
   7 package Debian::Debhelper::Dh_Lib;
   8 use strict;
   9
  10 use Exporter;
  11 use vars qw(@ISA @EXPORT %dh);
  12 @ISA=qw(Exporter);
  13 @EXPORT=qw(&init &doit &complex_doit &verbose_print &error &warning &tmpdir
  14             &pkgfile &pkgext &pkgfilename &isnative &autoscript &filearray
  15             &filedoublearray &getpackages &basename &dirname &xargs %dh
  16             &compat &addsubstvar &delsubstvar &excludefile &package_arch
  17             &is_udeb &udeb_filename &debhelper_script_subst &escape_shell
  18             &inhibit_log &load_log &write_log &commit_override_log
  19             &dpkg_architecture_value &sourcepackage
  20             &is_make_jobserver_unavailable &clean_jobserver_makeflags
  21             &cross_command &set_buildflags &get_buildoption);
  22
  23 my $max_compat=9;
  24
  25 sub init {
  26         my %params=@_;
  27
  28         # Check to see if an option line starts with a dash,
  29         # or DH_OPTIONS is set.
  30         # If so, we need to pass this off to the resource intensive
  31         # Getopt::Long, which I'd prefer to avoid loading at all if possible.
  32         if ((defined $ENV{DH_OPTIONS} && length $ENV{DH_OPTIONS}) ||
  33             (defined $ENV{DH_INTERNAL_OPTIONS} && length $ENV{DH_INTERNAL_OPTIONS}) ||
  34             grep /^-/, @ARGV) {
  35                 eval "use Debian::Debhelper::Dh_Getopt";
  36                 error($@) if $@;
  37                 Debian::Debhelper::Dh_Getopt::parseopts(%params);
  38         }
  39
  40         # Another way to set excludes.
  41         if (exists $ENV{DH_ALWAYS_EXCLUDE} && length $ENV{DH_ALWAYS_EXCLUDE}) {
  42                 push @{$dh{EXCLUDE}}, split(":", $ENV{DH_ALWAYS_EXCLUDE});
  43         }
  44
  45         # Generate EXCLUDE_FIND.
  46         if ($dh{EXCLUDE}) {
  47                 $dh{EXCLUDE_FIND}='';
  48                 foreach (@{$dh{EXCLUDE}}) {
  49                         my $x=$_;
  50                         $x=escape_shell($x);
  51                         $x=~s/\./\\\\./g;
  52                         $dh{EXCLUDE_FIND}.="-regex .\\*$x.\\* -or ";
  53                 }
  54                 $dh{EXCLUDE_FIND}=~s/ -or $//;
  55         }
  56
  57         # Check to see if DH_VERBOSE environment variable was set, if so,
  58         # make sure verbose is on.
  59         if (defined $ENV{DH_VERBOSE} && $ENV{DH_VERBOSE} ne "") {
  60                 $dh{VERBOSE}=1;
  61         }
  62
  63         # Check to see if DH_NO_ACT environment variable was set, if so,
  64         # make sure no act mode is on.
  65         if (defined $ENV{DH_NO_ACT} && $ENV{DH_NO_ACT} ne "") {
  66                 $dh{NO_ACT}=1;
  67         }
  68
  69         # Get the name of the main binary package (first one listed in
  70         # debian/control). Only if the main package was not set on the
  71         # command line.
  72         if (! exists $dh{MAINPACKAGE} || ! defined $dh{MAINPACKAGE}) {
  73                 my @allpackages=getpackages();
  74                 $dh{MAINPACKAGE}=$allpackages[0];
  75         }
  76
  77         # Check if packages to build have been specified, if not, fall back to
  78         # the default, building all relevant packages.
  79         if (! defined $dh{DOPACKAGES} || ! @{$dh{DOPACKAGES}}) {
  80                 push @{$dh{DOPACKAGES}}, getpackages('both');
  81         }
  82
  83         # Check to see if -P was specified. If so, we can only act on a single
  84         # package.
  85         if ($dh{TMPDIR} && $#{$dh{DOPACKAGES}} > 0) {
  86                 error("-P was specified, but multiple packages would be acted on (".join(",",@{$dh{DOPACKAGES}}).").");
  87         }
  88
  89         # Figure out which package is the first one we were instructed to build.
  90         # This package gets special treatement: files and directories specified on
  91         # the command line may affect it.
  92         $dh{FIRSTPACKAGE}=${$dh{DOPACKAGES}}[0];
  93
  94         # If no error handling function was specified, just propigate
  95         # errors out.
  96         if (! exists $dh{ERROR_HANDLER} || ! defined $dh{ERROR_HANDLER}) {
  97                 $dh{ERROR_HANDLER}='exit \$?';
  98         }
  99 }
 100
 101 # Run at exit. Add the command to the log files for the packages it acted
 102 # on, if it's exiting successfully.
 103 my $write_log=1;
 104 sub END {
 105         if ($? == 0 && $write_log) {
 106                 write_log(basename($0), @{$dh{DOPACKAGES}});
 107         }
 108 }
 109
 110 sub logfile {
 111         my $package=shift;
 112         my $ext=pkgext($package);
 113         return "debian/${ext}debhelper.log"
 114 }
 115
 116 sub add_override {
 117         my $line=shift;
 118         $line="override_$ENV{DH_INTERNAL_OVERRIDE} $line"
 119                 if defined $ENV{DH_INTERNAL_OVERRIDE};
 120         return $line;
 121 }
 122
 123 sub remove_override {
 124         my $line=shift;
 125         $line=~s/^\Qoverride_$ENV{DH_INTERNAL_OVERRIDE}\E\s+//
 126                 if defined $ENV{DH_INTERNAL_OVERRIDE};
 127         return $line;
 128 }
 129
 130 sub load_log {
 131         my ($package, $db)=@_;
 132
 133         my @log;
 134         open(LOG, "<", logfile($package)) || return;
 135         while (<LOG>) {
 136                 chomp;
 137                 my $command=remove_override($_);
 138                 push @log, $command;
 139                 $db->{$package}{$command}=1 if defined $db;
 140         }
 141         close LOG;
 142         return @log;
 143 }
 144
 145 sub write_log {
 146         my $cmd=shift;
 147         my @packages=@_;
 148
 149         return if $dh{NO_ACT};
 150
 151         foreach my $package (@packages) {
 152                 my $log=logfile($package);
 153                 open(LOG, ">>", $log) || error("failed to write to ${log}: $!");
 154                 print LOG add_override($cmd)."\n";
 155                 close LOG;
 156         }
 157 }
 158
 159 sub commit_override_log {
 160         my @packages=@_;
 161
 162         return if $dh{NO_ACT};
 163
 164         foreach my $package (@packages) {
 165                 my @log=map { remove_override($_) } load_log($package);
 166                 my $log=logfile($package);
 167                 open(LOG, ">", $log) || error("failed to write to ${log}: $!");
 168                 print LOG $_."\n" foreach @log;
 169                 close LOG;
 170         }
 171 }
 172
 173 sub inhibit_log {
 174         $write_log=0;
 175 }
 176
 177 # Pass it an array containing the arguments of a shell command like would
 178 # be run by exec(). It turns that into a line like you might enter at the
 179 # shell, escaping metacharacters and quoting arguments that contain spaces.
 180 sub escape_shell {
 181         my @args=@_;
 182         my $line="";
 183         my @ret;
 184         foreach my $word (@args) {
 185                 if ($word=~/\s/) {
 186                         # Escape only a few things since it will be quoted.
 187                         # Note we use double quotes because you cannot
 188                         # escape ' in single quotes, while " can be escaped
 189                         # in double.
 190                         # This does make -V"foo bar" turn into "-Vfoo bar",
 191                         # but that will be parsed identically by the shell
 192                         # anyway..
 193                         $word=~s/([\n`\$"\\])/\\$1/g;
 194                         push @ret, "\"$word\"";
 195                 }
 196                 else {
 197                         # This list is from _Unix in a Nutshell_. (except '#')
 198                         $word=~s/([\s!"\$()*+#;<>?@\[\]\\`|~])/\\$1/g;
 199                         push @ret,$word;
 200                 }
 201         }
 202         return join(' ', @ret);
 203 }
 204
 205 # Run a command, and display the command to stdout if verbose mode is on.
 206 # All commands that modifiy files in $TMP should be ran via this
 207 # function.
 208 #
 209 # Note that this cannot handle complex commands, especially anything
 210 # involving redirection. Use complex_doit instead.
 211 sub doit {
 212         verbose_print(escape_shell(@_));
 213
 214         if (! $dh{NO_ACT}) {
 215                 system(@_) == 0 || _error_exitcode(join(" ", @_));
 216         }
 217 }
 218
 219 # Run a command and display the command to stdout if verbose mode is on.
 220 # Use doit() if you can, instead of this function, because this function
 221 # forks a shell. However, this function can handle more complicated stuff
 222 # like redirection.
 223 sub complex_doit {
 224         verbose_print(join(" ",@_));
 225
 226         if (! $dh{NO_ACT}) {
 227                 # The join makes system get a scalar so it forks off a shell.
 228                 system(join(" ", @_)) == 0 || _error_exitcode(join(" ", @_))
 229         }
 230 }
 231
 232 sub _error_exitcode {
 233         my $command=shift;
 234         if ($? == -1) {
 235                 error("$command failed to to execute: $!");
 236         }
 237         elsif ($? & 127) {
 238                 error("$command died with signal ".($? & 127));
 239         }
 240         else {
 241                 error("$command returned exit code ".($? >> 8));
 242         }
 243 }
 244
 245 # Run a command that may have a huge number of arguments, like xargs does.
 246 # Pass in a reference to an array containing the arguments, and then other
 247 # parameters that are the command and any parameters that should be passed to
 248 # it each time.
 249 sub xargs {
 250         my $args=shift;
 251
 252         # The kernel can accept command lines up to 20k worth of characters.
 253         my $command_max=20000; # LINUX SPECIFIC!!
 254                         # (And obsolete; it's bigger now.)
 255                         # I could use POSIX::ARG_MAX, but that would be slow.
 256
 257         # Figure out length of static portion of command.
 258         my $static_length=0;
 259         foreach (@_) {
 260                 $static_length+=length($_)+1;
 261         }
 262
 263         my @collect=();
 264         my $length=$static_length;
 265         foreach (@$args) {
 266                 if (length($_) + 1 + $static_length > $command_max) {
 267                         error("This command is greater than the maximum command size allowed by the kernel, and cannot be split up further. What on earth are you doing? \"@_ $_\"");
 268                 }
 269                 $length+=length($_) + 1;
 270                 if ($length < $command_max) {
 271                         push @collect, $_;
 272                 }
 273                 else {
 274                         doit(@_,@collect) if $#collect > -1;
 275                         @collect=($_);
 276                         $length=$static_length + length($_) + 1;
 277                 }
 278         }
 279         doit(@_,@collect) if $#collect > -1;
 280 }
 281
 282 # Print something if the verbose flag is on.
 283 sub verbose_print {
 284         my $message=shift;
 285
 286         if ($dh{VERBOSE}) {
 287                 print "\t$message\n";
 288         }
 289 }
 290
 291 # Output an error message and die (can be caught).
 292 sub error {
 293         my $message=shift;
 294
 295         die basename($0).": $message\n";
 296 }
 297
 298 # Output a warning.
 299 sub warning {
 300         my $message=shift;
 301
 302         print STDERR basename($0).": $message\n";
 303 }
 304
 305 # Returns the basename of the argument passed to it.
 306 sub basename {
 307         my $fn=shift;
 308
 309         $fn=~s/\/$//g; # ignore trailing slashes
 310         $fn=~s:^.*/(.*?)$:$1:;
 311         return $fn;
 312 }
 313
 314 # Returns the directory name of the argument passed to it.
 315 sub dirname {
 316         my $fn=shift;
 317
 318         $fn=~s/\/$//g; # ignore trailing slashes
 319         $fn=~s:^(.*)/.*?$:$1:;
 320         return $fn;
 321 }
 322
 323 # Pass in a number, will return true iff the current compatibility level
 324 # is less than or equal to that number.
 325 {
 326         my $warned_compat=0;
 327         my $c;
 328
 329         sub compat {
 330                 my $num=shift;
 331                 my $nowarn=shift;
 332
 333                 if (! defined $c) {
 334                         $c=1;
 335                         if (defined $ENV{DH_COMPAT}) {
 336                                 $c=$ENV{DH_COMPAT};
 337                         }
 338                         elsif (-e 'debian/compat') {
 339                                 # Try the file..
 340                                 open (COMPAT_IN, "debian/compat") || error "debian/compat: $!";
 341                                 my $l=<COMPAT_IN>;
 342                                 close COMPAT_IN;
 343                                 if (! defined $l || ! length $l) {
 344                                         warning("debian/compat is empty, assuming level $c");
 345                                 }
 346                                 else {
 347                                         chomp $l;
 348                                         $c=$l;
 349                                 }
 350                         }
 351                 }
 352
 353                 if ($c <= 4 && ! $warned_compat && ! $nowarn) {
 354                         warning("Compatibility levels before 5 are deprecated.");
 355                         $warned_compat=1;
 356                 }
 357
 358                 if ($c > $max_compat) {
 359                         error("Sorry, but $max_compat is the highest compatibility level supported by this debhelper.");
 360                 }
 361
 362                 return ($c <= $num);
 363         }
 364 }
 365
 366 # Pass it a name of a binary package, it returns the name of the tmp dir to
 367 # use, for that package.
 368 sub tmpdir {
 369         my $package=shift;
 370
 371         if ($dh{TMPDIR}) {
 372                 return $dh{TMPDIR};
 373         }
 374         elsif (compat(1) && $package eq $dh{MAINPACKAGE}) {
 375                 # This is for back-compatibility with the debian/tmp tradition.
 376                 return "debian/tmp";
 377         }
 378         else {
 379                 return "debian/$package";
 380         }
 381 }
 382
 383 # Pass this the name of a binary package, and the name of the file wanted
 384 # for the package, and it will return the actual existing filename to use.
 385 #
 386 # It tries several filenames:
 387 #   * debian/package.filename.buildarch
 388 #   * debian/package.filename.buildos
 389 #   * debian/package.filename
 390 #   * debian/filename (if the package is the main package)
 391 # If --name was specified then the files
 392 # must have the name after the package name:
 393 #   * debian/package.name.filename.buildarch
 394 #   * debian/package.name.filename.buildos
 395 #   * debian/package.name.filename
 396 #   * debian/name.filename (if the package is the main package)
 397 sub pkgfile {
 398         my $package=shift;
 399         my $filename=shift;
 400
 401         if (defined $dh{NAME}) {
 402                 $filename="$dh{NAME}.$filename";
 403         }
 404
 405         # First, check for files ending in buildarch and buildos.
 406         my $match;
 407         foreach my $file (glob("debian/$package.$filename.*")) {
 408                 next if ! -f $file;
 409                 next if $dh{IGNORE} && exists $dh{IGNORE}->{$file};
 410                 if ($file eq "debian/$package.$filename.".buildarch()) {
 411                         $match=$file;
 412                         # buildarch files are used in preference to buildos files.
 413                         last;
 414                 }
 415                 elsif ($file eq "debian/$package.$filename.".buildos()) {
 416                         $match=$file;
 417                 }
 418         }
 419         return $match if defined $match;
 420
 421         my @try=("debian/$package.$filename");
 422         if ($package eq $dh{MAINPACKAGE}) {
 423                 push @try, "debian/$filename";
 424         }
 425
 426         foreach my $file (@try) {
 427                 if (-f $file &&
 428                     (! $dh{IGNORE} || ! exists $dh{IGNORE}->{$file})) {
 429                         return $file;
 430                 }
 431
 432         }
 433
 434         return "";
 435
 436 }
 437
 438 # Pass it a name of a binary package, it returns the name to prefix to files
 439 # in debian/ for this package.
 440 sub pkgext {
 441         my $package=shift;
 442
 443         if (compat(1) and $package eq $dh{MAINPACKAGE}) {
 444                 return "";
 445         }
 446         return "$package.";
 447 }
 448
 449 # Pass it the name of a binary package, it returns the name to install
 450 # files by in eg, etc. Normally this is the same, but --name can override
 451 # it.
 452 sub pkgfilename {
 453         my $package=shift;
 454
 455         if (defined $dh{NAME}) {
 456                 return $dh{NAME};
 457         }
 458         return $package;
 459 }
 460
 461 # Returns 1 if the package is a native debian package, null otherwise.
 462 # As a side effect, sets $dh{VERSION} to the version of this package.
 463 {
 464         # Caches return code so it only needs to run dpkg-parsechangelog once.
 465         my %isnative_cache;
 466
 467         sub isnative {
 468                 my $package=shift;
 469
 470                 return $isnative_cache{$package} if defined $isnative_cache{$package};
 471
 472                 # Make sure we look at the correct changelog.
 473                 my $isnative_changelog=pkgfile($package,"changelog");
 474                 if (! $isnative_changelog) {
 475                         $isnative_changelog="debian/changelog";
 476                 }
 477                 # Get the package version.
 478                 my $version=`dpkg-parsechangelog -l$isnative_changelog`;
 479                 ($dh{VERSION})=$version=~m/Version:\s*(.*)/m;
 480                 # Did the changelog parse fail?
 481                 if (! defined $dh{VERSION}) {
 482                         error("changelog parse failure");
 483                 }
 484
 485                 # Is this a native Debian package?
 486                 if ($dh{VERSION}=~m/.*-/) {
 487                         return $isnative_cache{$package}=0;
 488                 }
 489                 else {
 490                         return $isnative_cache{$package}=1;
 491                 }
 492         }
 493 }
 494
 495 # Automatically add a shell script snippet to a debian script.
 496 # Only works if the script has #DEBHELPER# in it.
 497 #
 498 # Parameters:
 499 # 1: package
 500 # 2: script to add to
 501 # 3: filename of snippet
 502 # 4: sed to run on the snippet. Ie, s/#PACKAGE#/$PACKAGE/
 503 sub autoscript {
 504         my $package=shift;
 505         my $script=shift;
 506         my $filename=shift;
 507         my $sed=shift || "";
 508
 509         # This is the file we will modify.
 510         my $outfile="debian/".pkgext($package)."$script.debhelper";
 511
 512         # Figure out what shell script snippet to use.
 513         my $infile;
 514         if (defined($ENV{DH_AUTOSCRIPTDIR}) &&
 515             -e "$ENV{DH_AUTOSCRIPTDIR}/$filename") {
 516                 $infile="$ENV{DH_AUTOSCRIPTDIR}/$filename";
 517         }
 518         else {
 519                 if (-e "/usr/share/debhelper/autoscripts/$filename") {
 520                         $infile="/usr/share/debhelper/autoscripts/$filename";
 521                 }
 522                 else {
 523                         error("/usr/share/debhelper/autoscripts/$filename does not exist");
 524                 }
 525         }
 526
 527         if (-e $outfile && ($script eq 'postrm' || $script eq 'prerm')
 528            && !compat(5)) {
 529                 # Add fragments to top so they run in reverse order when removing.
 530                 complex_doit("echo \"# Automatically added by ".basename($0)."\"> $outfile.new");
 531                 complex_doit("sed \"$sed\" $infile >> $outfile.new");
 532                 complex_doit("echo '# End automatically added section' >> $outfile.new");
 533                 complex_doit("cat $outfile >> $outfile.new");
 534                 complex_doit("mv $outfile.new $outfile");
 535         }
 536         else {
 537                 complex_doit("echo \"# Automatically added by ".basename($0)."\">> $outfile");
 538                 complex_doit("sed \"$sed\" $infile >> $outfile");
 539                 complex_doit("echo '# End automatically added section' >> $outfile");
 540         }
 541 }
 542
 543 # Removes a whole substvar line.
 544 sub delsubstvar {
 545         my $package=shift;
 546         my $substvar=shift;
 547
 548         my $ext=pkgext($package);
 549         my $substvarfile="debian/${ext}substvars";
 550
 551         if (-e $substvarfile) {
 552                 complex_doit("grep -s -v '^${substvar}=' $substvarfile > $substvarfile.new || true");
 553                 doit("mv", "$substvarfile.new","$substvarfile");
 554         }
 555 }
 556
 557 # Adds a dependency on some package to the specified
 558 # substvar in a package's substvar's file.
 559 sub addsubstvar {
 560         my $package=shift;
 561         my $substvar=shift;
 562         my $deppackage=shift;
 563         my $verinfo=shift;
 564         my $remove=shift;
 565
 566         my $ext=pkgext($package);
 567         my $substvarfile="debian/${ext}substvars";
 568         my $str=$deppackage;
 569         $str.=" ($verinfo)" if defined $verinfo && length $verinfo;
 570
 571         # Figure out what the line will look like, based on what's there
 572         # now, and what we're to add or remove.
 573         my $line="";
 574         if (-e $substvarfile) {
 575                 my %items;
 576                 open(SUBSTVARS_IN, "$substvarfile") || error "read $substvarfile: $!";
 577                 while (<SUBSTVARS_IN>) {
 578                         chomp;
 579                         if (/^\Q$substvar\E=(.*)/) {
 580                                 %items = map { $_ => 1} split(", ", $1);
 581
 582                                 last;
 583                         }
 584                 }
 585                 close SUBSTVARS_IN;
 586                 if (! $remove) {
 587                         $items{$str}=1;
 588                 }
 589                 else {
 590                         delete $items{$str};
 591                 }
 592                 $line=join(", ", sort keys %items);
 593         }
 594         elsif (! $remove) {
 595                 $line=$str;
 596         }
 597
 598         if (length $line) {
 599                  complex_doit("(grep -s -v ${substvar} $substvarfile; echo ".escape_shell("${substvar}=$line").") > $substvarfile.new");
 600                  doit("mv", "$substvarfile.new", $substvarfile);
 601         }
 602         else {
 603                 delsubstvar($package,$substvar);
 604         }
 605 }
 606
 607 # Reads in the specified file, one line at a time. splits on words,
 608 # and returns an array of arrays of the contents.
 609 # If a value is passed in as the second parameter, then glob
 610 # expansion is done in the directory specified by the parameter ("." is
 611 # frequently a good choice).
 612 sub filedoublearray {
 613         my $file=shift;
 614         my $globdir=shift;
 615
 616         my $x=-x $file;
 617         if ($x) {
 618                 require Cwd;
 619                 my $cmd=Cwd::abs_path($file);
 620                 open (DH_FARRAY_IN, "$cmd |") || error("cannot run $file: $!");
 621         }
 622         else {
 623                 open (DH_FARRAY_IN, $file) || error("cannot read $file: $!");
 624         }
 625
 626         my @ret;
 627         while (<DH_FARRAY_IN>) {
 628                 chomp;
 629                 # Only ignore comments and empty lines in v5 mode.
 630                 if (! compat(4) && ! $x)  {
 631                         next if /^#/ || /^$/;
 632                 }
 633                 my @line;
 634                 # Only do glob expansion in v3 mode.
 635                 #
 636                 # The tricky bit is that the glob expansion is done
 637                 # as if we were in the specified directory, so the
 638                 # filenames that come out are relative to it.
 639                 if (defined $globdir && ! compat(2) && ! $x) {
 640                         foreach (map { glob "$globdir/$_" } split) {
 641                                 s#^$globdir/##;
 642                                 push @line, $_;
 643                         }
 644                 }
 645                 else {
 646                         @line = split;
 647                 }
 648                 push @ret, [@line];
 649         }
 650
 651         close DH_FARRAY_IN || error("problem reading $file: $!");
 652
 653         return @ret;
 654 }
 655
 656 # Reads in the specified file, one word at a time, and returns an array of
 657 # the result. Can do globbing as does filedoublearray.
 658 sub filearray {
 659         return map { @$_ } filedoublearray(@_);
 660 }
 661
 662 # Passed a filename, returns true if -X says that file should be excluded.
 663 sub excludefile {
 664         my $filename = shift;
 665         foreach my $f (@{$dh{EXCLUDE}}) {
 666                 return 1 if $filename =~ /\Q$f\E/;
 667         }
 668         return 0;
 669 }
 670
 671 {
 672         my %dpkg_arch_output;
 673         sub dpkg_architecture_value {
 674                 my $var = shift;
 675                 if (! exists($dpkg_arch_output{$var})) {
 676                         local $_;
 677                         open(PIPE, '-|', 'dpkg-architecture')
 678                                 or error("dpkg-architecture failed");
 679                         while (<PIPE>) {
 680                                 chomp;
 681                                 my ($k, $v) = split(/=/, $_, 2);
 682                                 $dpkg_arch_output{$k} = $v;
 683                         }
 684                         close(PIPE);
 685                 }
 686                 return $dpkg_arch_output{$var};
 687         }
 688 }
 689
 690 # Returns the build architecture.
 691 sub buildarch {
 692         dpkg_architecture_value('DEB_HOST_ARCH');
 693 }
 694
 695 # Returns the build OS.
 696 sub buildos {
 697         dpkg_architecture_value("DEB_HOST_ARCH_OS");
 698 }
 699
 700 # Passed an arch and a list of arches to match against, returns true if matched
 701 {
 702         my %knownsame;
 703
 704         sub samearch {
 705                 my $arch=shift;
 706                 my @archlist=split(/\s+/,shift);
 707
 708                 foreach my $a (@archlist) {
 709                         # Avoid expensive dpkg-architecture call to compare
 710                         # with a simple architecture name. "linux-any" and
 711                         # other architecture wildcards are (currently)
 712                         # always hypenated.
 713                         if ($a !~ /-/) {
 714                                 return 1 if $arch eq $a;
 715                         }
 716                         elsif (exists $knownsame{$arch}{$a}) {
 717                                 return 1 if $knownsame{$arch}{$a};
 718                         }
 719                         elsif (system("dpkg-architecture", "-a$arch", "-i$a") == 0) {
 720                                 return $knownsame{$arch}{$a}=1;
 721                         }
 722                         else {
 723                                 $knownsame{$arch}{$a}=0;
 724                         }
 725                 }
 726
 727                 return 0;
 728         }
 729 }
 730
 731 # Returns source package name
 732 sub sourcepackage {
 733         open (CONTROL, 'debian/control') ||
 734             error("cannot read debian/control: $!\n");
 735         while (<CONTROL>) {
 736                 chomp;
 737                 s/\s+$//;
 738                 if (/^Source:\s*(.*)/) {
 739                         close CONTROL;
 740                         return $1;
 741                 }
 742         }
 743
 744         close CONTROL;
 745         error("could not find Source: line in control file.");
 746 }
 747
 748 # Returns a list of packages in the control file.
 749 # Pass "arch" or "indep" to specify arch-dependant (that will be built
 750 # for the system's arch) or independant. If nothing is specified,
 751 # returns all packages. Also, "both" returns the union of "arch" and "indep"
 752 # packages.
 753 # As a side effect, populates %package_arches and %package_types with the
 754 # types of all packages (not only those returned).
 755 my (%package_types, %package_arches);
 756 sub getpackages {
 757         my $type=shift;
 758
 759         %package_types=();
 760         %package_arches=();
 761
 762         $type="" if ! defined $type;
 763
 764         my $package="";
 765         my $arch="";
 766         my $package_type;
 767         my @list=();
 768         my %seen;
 769         open (CONTROL, 'debian/control') ||
 770                 error("cannot read debian/control: $!\n");
 771         while (<CONTROL>) {
 772                 chomp;
 773                 s/\s+$//;
 774                 if (/^Package:\s*(.*)/) {
 775                         $package=$1;
 776                         # Detect duplicate package names in the same control file.
 777                         if (! $seen{$package}) {
 778                                 $seen{$package}=1;
 779                         }
 780                         else {
 781                                 error("debian/control has a duplicate entry for $package");
 782                         }
 783                         $package_type="deb";
 784                 }
 785                 if (/^Architecture:\s*(.*)/) {
 786                         $arch=$1;
 787                 }
 788                 if (/^(?:X[BC]*-)?Package-Type:\s*(.*)/) {
 789                         $package_type=$1;
 790                 }
 791
 792                 if (!$_ or eof) { # end of stanza.
 793                         if ($package) {
 794                                 $package_types{$package}=$package_type;
 795                                 $package_arches{$package}=$arch;
 796                         }
 797
 798                         if ($package &&
 799                             ((($type eq 'indep' || $type eq 'both') && $arch eq 'all') ||
 800                              (($type eq 'arch'  || $type eq 'both') && ($arch eq 'any' ||
 801                                              ($arch ne 'all' &&
 802                                               samearch(buildarch(), $arch)))) ||
 803                              ! $type)) {
 804                                 push @list, $package;
 805                                 $package="";
 806                                 $arch="";
 807                         }
 808                 }
 809         }
 810         close CONTROL;
 811
 812         return @list;
 813 }
 814
 815 # Returns the arch a package will build for.
 816 sub package_arch {
 817         my $package=shift;
 818
 819         if (! exists $package_arches{$package}) {
 820                 warning "package $package is not in control info";
 821                 return buildarch();
 822         }
 823         return $package_arches{$package} eq 'all' ? "all" : buildarch();
 824 }
 825
 826 # Return true if a given package is really a udeb.
 827 sub is_udeb {
 828         my $package=shift;
 829
 830         if (! exists $package_types{$package}) {
 831                 warning "package $package is not in control info";
 832                 return 0;
 833         }
 834         return $package_types{$package} eq 'udeb';
 835 }
 836
 837 # Generates the filename that is used for a udeb package.
 838 sub udeb_filename {
 839         my $package=shift;
 840
 841         my $filearch=package_arch($package);
 842         isnative($package); # side effect
 843         my $version=$dh{VERSION};
 844         $version=~s/^[0-9]+://; # strip any epoch
 845         return "${package}_${version}_$filearch.udeb";
 846 }
 847
 848 # Handles #DEBHELPER# substitution in a script; also can generate a new
 849 # script from scratch if none exists but there is a .debhelper file for it.
 850 sub debhelper_script_subst {
 851         my $package=shift;
 852         my $script=shift;
 853
 854         my $tmp=tmpdir($package);
 855         my $ext=pkgext($package);
 856         my $file=pkgfile($package,$script);
 857
 858         if ($file ne '') {
 859                 if (-f "debian/$ext$script.debhelper") {
 860                         # Add this into the script, where it has #DEBHELPER#
 861                         complex_doit("perl -pe 's~#DEBHELPER#~qx{cat debian/$ext$script.debhelper}~eg' < $file > $tmp/DEBIAN/$script");
 862                 }
 863                 else {
 864                         # Just get rid of any #DEBHELPER# in the script.
 865                         complex_doit("sed s/#DEBHELPER#// < $file > $tmp/DEBIAN/$script");
 866                 }
 867                 doit("chown","0:0","$tmp/DEBIAN/$script");
 868                 doit("chmod",755,"$tmp/DEBIAN/$script");
 869         }
 870         elsif ( -f "debian/$ext$script.debhelper" ) {
 871                 complex_doit("printf '#!/bin/sh\nset -e\n' > $tmp/DEBIAN/$script");
 872                 complex_doit("cat debian/$ext$script.debhelper >> $tmp/DEBIAN/$script");
 873                 doit("chown","0:0","$tmp/DEBIAN/$script");
 874                 doit("chmod",755,"$tmp/DEBIAN/$script");
 875         }
 876 }
 877
 878 # Checks if make's jobserver is enabled via MAKEFLAGS, but
 879 # the FD used to communicate with it is actually not available.
 880 sub is_make_jobserver_unavailable {
 881         if (exists $ENV{MAKEFLAGS} &&
 882             $ENV{MAKEFLAGS} =~ /(?:^|\s)--jobserver-fds=(\d+)/) {
 883                 if (!open(my $in, "<&$1")) {
 884                         return 1; # unavailable
 885                 }
 886                 else {
 887                         close $in;
 888                         return 0; # available
 889                 }
 890         }
 891
 892         return; # no jobserver specified
 893 }
 894
 895 # Cleans out jobserver options from MAKEFLAGS.
 896 sub clean_jobserver_makeflags {
 897         if (exists $ENV{MAKEFLAGS}) {
 898                 if ($ENV{MAKEFLAGS} =~ /(?:^|\s)--jobserver-fds=(\d+)/) {
 899                         $ENV{MAKEFLAGS} =~ s/(?:^|\s)--jobserver-fds=\S+//g;
 900                         $ENV{MAKEFLAGS} =~ s/(?:^|\s)-j\b//g;
 901                 }
 902                 delete $ENV{MAKEFLAGS} if $ENV{MAKEFLAGS} =~ /^\s*$/;
 903         }
 904 }
 905
 906 # If cross-compiling, returns appropriate cross version of command.
 907 sub cross_command {
 908         my $command=shift;
 909         if (dpkg_architecture_value("DEB_BUILD_GNU_TYPE")
 910             ne dpkg_architecture_value("DEB_HOST_GNU_TYPE")) {
 911                 return dpkg_architecture_value("DEB_HOST_GNU_TYPE")."-$command";
 912         }
 913         else {
 914                 return $command;
 915         }
 916 }
 917
 918 # Sets environment variables from dpkg-buildflags. Avoids changing
 919 # any existing environment variables.
 920 sub set_buildflags {
 921         return if $ENV{DH_INTERNAL_BUILDFLAGS} || compat(8);
 922         $ENV{DH_INTERNAL_BUILDFLAGS}=1;
 923
 924         eval "use Dpkg::BuildFlags";
 925         if ($@) {
 926                 warning "unable to load build flags: $@";
 927                 return;
 928         }
 929
 930         my $buildflags = Dpkg::BuildFlags->new();
 931         $buildflags->load_config();
 932         foreach my $flag ($buildflags->list()) {
 933                 next unless $flag =~ /^[A-Z]/; # Skip flags starting with lowercase
 934                 if (! exists $ENV{$flag}) {
 935                         $ENV{$flag} = $buildflags->get($flag);
 936                 }
 937         }
 938 }
 939
 940 # Gets a DEB_BUILD_OPTIONS option, if set.
 941 sub get_buildoption {
 942         my $wanted=shift;
 943
 944         return undef unless exists $ENV{DEB_BUILD_OPTIONS};
 945
 946         foreach my $opt (split(/\s+/, $ENV{DEB_BUILD_OPTIONS})) {
 947                 # currently parallel= is the only one with a parameter
 948                 if ($opt =~ /^parallel=(-?\d+)$/ && $wanted eq 'parallel') {
 949                         return $1;
 950                 }
 951                 elsif ($opt eq $wanted) {
 952                         return 1;
 953                 }
 954         }
 955 }
 956
 957 1