Debian/Debhelper/Buildsystem/python_distutils.pm

   1 # A debhelper build system class for building Python Distutils based
   2 # projects. It prefers out of source tree building.
   3 #
   4 # Copyright: © 2008 Joey Hess
   5 #            © 2008-2009 Modestas Vainius
   6 # License: GPL-2+
   7
   8 package Debian::Debhelper::Buildsystem::python_distutils;
   9
  10 use strict;
  11 use Cwd ();
  12 use Debian::Debhelper::Dh_Lib qw(error);
  13 use base 'Debian::Debhelper::Buildsystem';
  14
  15 sub DESCRIPTION {
  16         "Python Distutils (setup.py)"
  17 }
  18
  19 sub DEFAULT_BUILD_DIRECTORY {
  20         my $this=shift;
  21         return $this->canonpath($this->get_sourcepath("build"));
  22 }
  23
  24 sub new {
  25         my $class=shift;
  26         my $this=$class->SUPER::new(@_);
  27         # Out of source tree building is prefered.
  28         $this->prefer_out_of_source_building(@_);
  29         return $this;
  30 }
  31
  32 sub check_auto_buildable {
  33         my $this=shift;
  34         return -e $this->get_sourcepath("setup.py");
  35 }
  36
  37 sub not_our_cfg {
  38         my $this=shift;
  39         my $ret;
  40         if (open(my $cfg, $this->get_buildpath(".pydistutils.cfg"))) {
  41                 $ret = not "# Created by dh_auto\n" eq <$cfg>;
  42                 close $cfg;
  43         }
  44         return $ret;
  45 }
  46
  47 sub create_cfg {
  48         my $this=shift;
  49         if (open(my $cfg, ">", $this->get_buildpath(".pydistutils.cfg"))) {
  50                 print $cfg "# Created by dh_auto", "\n";
  51                 print $cfg "[build]\nbuild-base=", $this->get_build_rel2sourcedir(), "\n";
  52                 close $cfg;
  53                 return 1;
  54         }
  55         return 0;
  56 }
  57
  58 sub pre_building_step {
  59         my $this=shift;
  60         my $step=shift;
  61
  62         return unless grep /$step/, qw(build install clean);
  63
  64         if ($this->get_buildpath() ne $this->DEFAULT_BUILD_DIRECTORY()) {
  65                 # --build-base can only be passed to the build command. However,
  66                 # it is always read from the config file (really weird design).
  67                 # Therefore create such a cfg config file.
  68                 # See http://bugs.python.org/issue818201
  69                 #     http://bugs.python.org/issue1011113
  70                 not $this->not_our_cfg() or
  71                     error("cannot set custom build directory: .pydistutils.cfg is in use");
  72                 $this->mkdir_builddir();
  73                 $this->create_cfg() or
  74                     error("cannot set custom build directory: unwritable .pydistutils.cfg");
  75                 # Distutils reads $HOME/.pydistutils.cfg
  76                 $ENV{HOME} = Cwd::abs_path($this->get_buildpath());
  77         }
  78
  79         $this->SUPER::pre_building_step($step);
  80 }
  81
  82 sub dbg_build_needed {
  83         my $this=shift;
  84         my $act=shift;
  85
  86         # Return a list of python-dbg package which are listed
  87         # in the build-dependencies. This is kinda ugly, but building
  88         # dbg extensions without checking if they're supposed to be
  89         # built may result in various FTBFS if the package is not
  90         # built in a clean chroot.
  91
  92         my @dbg;
  93         open (CONTROL,  $this->get_sourcepath('debian/control')) ||
  94                 error("cannot read debian/control: $!\n");
  95         foreach my $builddeps (join('', <CONTROL>) =~
  96                         /^Build-Depends[^:]*:.*\n(?:^[^\w\n].*\n)*/gmi) {
  97                 foreach ($builddeps =~ /(python[^, ]*-dbg)/g) {
  98                         push @dbg, $1;
  99                 }
 100         }
 101
 102         close CONTROL;
 103         return @dbg;
 104
 105 }
 106
 107 sub setup_py {
 108         my $this=shift;
 109         my $act=shift;
 110
 111         # We need to to run setup.py with the default python first
 112         # as distutils/setuptools modifies the shebang lines of scripts.
 113         # This ensures that #!/usr/bin/python is used and not pythonX.Y
 114         # Take into account that the default Python must not be in
 115         # the requested Python versions.
 116         # Then, run setup.py with each available python, to build
 117         # extensions for each.
 118
 119         my $python_default = `pyversions -d`;
 120         $python_default =~ s/^\s+//;
 121         $python_default =~ s/\s+$//;
 122         my @python_requested = split ' ', `pyversions -r 2>/dev/null`;
 123         if (grep /^$python_default/, @python_requested) {
 124                 @python_requested = ("python", grep(!/^$python_default/,
 125                                         @python_requested));
 126         }
 127         my @dbg_build_needed = $this->dbg_build_needed();
 128
 129         foreach my $python (@python_requested) {
 130                 if (-x "/usr/bin/".$python) {
 131                         $this->doit_in_sourcedir($python, "setup.py", $act, @_);
 132                 }
 133                 $python = $python . "-dbg";
 134                 if ((grep /^(python-all-dbg|$python)/, @dbg_build_needed)
 135                         or (($python eq "python-dbg")
 136                                 and (grep /^$python_default/, @dbg_build_needed))){
 137                         $this->doit_in_sourcedir($python, "setup.py", $act, @_);
 138                 }
 139         }
 140 }
 141
 142 sub build {
 143         my $this=shift;
 144         $this->setup_py("build", @_);
 145 }
 146
 147 sub install {
 148         my $this=shift;
 149         my $destdir=shift;
 150         $this->setup_py("install",
 151                 "--root=$destdir",
 152                 "--no-compile",
 153                 "-O0",
 154                 "--install-layout=deb",
 155                 @_);
 156 }
 157
 158 sub clean {
 159         my $this=shift;
 160         $this->setup_py("clean", "-a", @_);
 161
 162         # Config file will remain if it was created by us
 163         if (!$this->not_our_cfg()) {
 164                 unlink($this->get_buildpath(".pydistutils.cfg"));
 165                 $this->rmdir_builddir(1); # only if empty
 166         }
 167         # The setup.py might import files, leading to python creating pyc
 168         # files.
 169         $this->doit_in_sourcedir('find', '.', '-name', '*.pyc', '-exec', 'rm', '{}', ';');
 170 }
 171
 172 1