examples/debian/versions/build-versions-db

   1 #!/usr/bin/perl
   2 # build-versions-db builds the versions mldmb database
   3 # and is released under the terms of the GNU GPL version 3, or any
   4 # later version, at your option. See the file README and COPYING for
   5 # more information.
   6 # Copyright 2016 by Don Armstrong <don@donarmstrong.com>.
   7
   8
   9 use warnings;
  10 use strict;
  11
  12 use Getopt::Long;
  13 use Pod::Usage;
  14
  15 =head1 NAME
  16
  17 build-versions-db -- builds source and source maintainers file
  18
  19 =head1 SYNOPSIS
  20
  21     build-versions-db [options] versions.idx.new versions.idx.new \
  22            /srv/bugs.debian.org/versions/indices/ftp
  23
  24  Options:
  25    --debug, -d debugging level (Default 0)
  26    --help, -h display this help
  27    --man, -m display manual
  28
  29 =head1 OPTIONS
  30
  31 =over
  32
  33 =item B<--update>
  34
  35 Update an existing database; the default. B<--no-update> will regenerate an
  36 existing database from scratch.
  37
  38 =item B<--debug, -d>
  39
  40 Debug verbosity. (Default 0)
  41
  42 =item B<--help, -h>
  43
  44 Display brief usage information.
  45
  46 =item B<--man, -m>
  47
  48 Display this manual.
  49
  50 =back
  51
  52 =head1 EXAMPLES
  53
  54      build-versions-db versions.idx.new versions.idx.new \
  55            /srv/bugs.debian.org/versions/indices/ftp \
  56            stable
  57
  58 =cut
  59
  60
  61 use vars qw($DEBUG);
  62 use Debbugs::Versions::Dpkg;
  63 use Debbugs::Config qw(:config);
  64 use File::Copy;
  65 use MLDBM qw(DB_File Storable);
  66 use Fcntl;
  67
  68 my %options = (debug           => 0,
  69                help            => 0,
  70                man             => 0,
  71                update          => 1,
  72               );
  73
  74 GetOptions(\%options,
  75            'update!',
  76            'debug|d+','help|h|?','man|m');
  77
  78 pod2usage() if $options{help};
  79 pod2usage({verbose=>2}) if $options{man};
  80
  81 $DEBUG = $options{debug};
  82
  83 my @USAGE_ERRORS;
  84
  85 if (not @ARGV >= 4) {
  86     push @USAGE_ERRORS,
  87         "You must provide at least four arguments, two databases, ".
  88         "a top level directory and at least one suite";
  89 }
  90
  91
  92 pod2usage(join("\n",@USAGE_ERRORS)) if @USAGE_ERRORS;
  93
  94
  95 my $versions = shift @ARGV;
  96 my $versions_time = shift @ARGV;
  97 my $versions_new = $versions."_".$$."_".time;
  98 my $versions_time_new = $versions_time."_".$$."_".time;
  99 my $toplevel = shift @ARGV;
 100 my @suites = @ARGV;
 101
 102 $MLDBM::DumpMeth=q(portable);
 103
 104 my $time = time;
 105
 106 my %db;
 107 my %db2;
 108 if ($options{update}) {
 109     copy($versions,$versions_new);
 110     copy($versions_time,$versions_time_new);
 111 }
 112 tie %db, "MLDBM", $versions_new, O_CREAT|O_RDWR, 0664
 113     or die "tie $versions: $!";
 114 tie %db2, "MLDBM", $versions_time_new,O_CREAT|O_RDWR, 0664
 115      or die "tie $versions_time failed: $!";
 116
 117 update_versions_suites(\%db,\%db2,\@suites);
 118 versions_time_cleanup(\%db2) if $options{update};
 119
 120 move($versions_new,$versions);
 121 move($versions_time_new,$versions_time);
 122
 123 sub open_compressed_file {
 124     my ($file) = @_;
 125     my $fh;
 126     my $mode = '<:encoding(UTF-8)';
 127     my @opts;
 128     if ($file =~ /\.gz$/) {
 129         $mode = '-|:encoding(UTF-8)';
 130         push @opts,'gzip','-dc';
 131     }
 132     if ($file =~ /^\.xz$/) {
 133         $mode = '-|:encoding(UTF-8)';
 134         push @opts,'xz','-dc';
 135     }
 136     open($fh,$mode,@opts,$file);
 137     return $fh;
 138 }
 139
 140 # Read Package, Version, and Source fields from a Packages.gz file.
 141 sub read_packages {
 142     my ($db,$db2,$packages, $component,$arch,$dist) = @_;
 143     my $PACKAGES = open_compressed_file($packages) or
 144         die "Unable to open $packages for reading: $!";
 145     local $_;
 146     local $/ = '';      # paragraph mode
 147
 148     print STDERR "reading packages $packages\n" if $DEBUG;
 149     for (<$PACKAGES>) {
 150         /^Package: (.+)/im or next;
 151         my $pkg = $1;
 152         /^Version: (.+)/im or next;
 153         my $ver = $1;
 154         my $extra_source_only = 0;
 155         if (/^Extra-Source-Only: yes/im) {
 156             $extra_source_only = 1;
 157         }
 158         update_package_version($db,$db2,$dist,$arch,$pkg,$ver,$time) unless
 159             $extra_source_only;
 160     }
 161 }
 162
 163
 164 sub update_package_version {
 165     my ($db,$db2,$d,$a,$p,$v,$t) = @_;
 166     # see MLDBM(3pm)/BUGS
 167     my $tmp = $db->{$p};
 168     # we allow multiple versions in an architecture now; this
 169     # should really only happen in the case of source, however.
 170     push @{$tmp->{$d}{$a}}, $v;
 171     $db->{$p} = $tmp;
 172     $tmp = $db2->{$p};
 173     $tmp->{$d}{$a}{$v} = $time if not exists
 174         $tmp->{$d}{$a}{$v};
 175     $db2->{$p} = $tmp;
 176 }
 177
 178 sub update_versions_suites {
 179     my ($db,$db2,$suites) = @_;
 180 # Iterate through all Packages and Sources files.
 181 for my $suite (@{$suites}) {
 182     my $suitedir = "$toplevel/$suite";
 183
 184     for my $component ('main', 'main/debian-installer',
 185                        'contrib', 'non-free') {
 186         my $componentdir = "$suitedir/$component";
 187         next unless -d $componentdir;
 188         my $COMPONENT;
 189         opendir $COMPONENT, $componentdir or die "opendir $componentdir: $!";
 190
 191         # debian-installer is really a section rather than a component
 192         # (ugh).
 193         (my $viscomponent = $component) =~ s[/.*][];
 194
 195         my $sources = (grep { -f $_ } glob "$suitedir/$component/source/Sources.*")[0];
 196         next unless defined $sources;
 197         read_packages($db,$db2,$sources, $viscomponent,'source',$suite);
 198
 199         for my $arch (readdir $COMPONENT) {
 200             next unless $arch =~ s/^binary-//;
 201             my $archdir = "$componentdir/binary-$arch";
 202
 203             my $packages = (grep { -f $_ } glob("$archdir/Packages.*"))[0];
 204             next unless defined $packages;
 205             read_packages($db,$db2,$packages, $viscomponent,$arch,$suite);
 206         }
 207
 208         closedir $COMPONENT;
 209     }
 210 }
 211 }
 212
 213 sub versions_time_cleanup {
 214     my ($db) = @_;
 215     my $time = time;
 216     for my $package (keys %{$db}) {
 217         my $temp = $db->{$package};
 218         for my $dist (keys %{$temp}) {
 219             for my $arch (keys %{$temp->{$dist}}) {
 220                 my @versions =  (sort {$temp->{$dist}{$arch}{$a} <=>
 221                                            $temp->{$dist}{$arch}{$b}
 222                                        }
 223                                  keys %{$temp->{$dist}{$arch}});
 224                 next unless @versions > 1;
 225                 for my $i (0 .. ($#versions-1)) {
 226                     last if $temp->{$dist}{$arch}{$versions[$i+1]} >
 227                         ($time - $config{remove_age}*60*60*24);
 228                     last if keys %{$temp->{$dist}{$arch}} <= 1;
 229                     delete $temp->{$dist}{$arch}{$versions[$i]};
 230                 }
 231             }
 232         }
 233         $db->{$package} = $temp;
 234     }
 235 }