Debbugs/Bug.pm

   1 # This module is part of debbugs, and
   2 # is released under the terms of the GPL version 2, or any later
   3 # version (at your option). See the file README and COPYING for more
   4 # information.
   5 # Copyright 2018 by Don Armstrong <don@donarmstrong.com>.
   6
   7 package Debbugs::Bug;
   8
   9 =head1 NAME
  10
  11 Debbugs::Bug -- OO interface to bugs
  12
  13 =head1 SYNOPSIS
  14
  15    use Debbugs::Bug;
  16    Debbugs::Bug->new(schema => $s,binaries => [qw(foo)],sources => [qw(bar)]);
  17
  18 =head1 DESCRIPTION
  19
  20
  21
  22 =cut
  23
  24 use Mouse;
  25 use strictures 2;
  26 use namespace::clean;
  27 use v5.10; # for state
  28
  29 use DateTime;
  30 use List::AllUtils qw(max first min);
  31
  32 use Params::Validate qw(validate_with :types);
  33 use Debbugs::Config qw(:config);
  34 use Debbugs::Status qw(read_bug);
  35 use Debbugs::Bug::Tag;
  36 use Debbugs::Collection::Package;
  37 use Debbugs::Collection::Bug;
  38 use Debbugs::Collection::Correspondent;
  39
  40 use Debbugs::OOTypes;
  41
  42 use Carp;
  43
  44 extends 'Debbugs::OOBase';
  45
  46 state $strong_severities =
  47    {map {($_,1)} @{$config{strong_severities}}};
  48
  49 has bug => (is => 'ro', isa => 'Int',
  50             required => 1,
  51            );
  52
  53 sub id {
  54     return $_[0]->bug;
  55 }
  56
  57 has saved => (is => 'ro', isa => 'Bool',
  58               default => 0,
  59               writer => '_set_saved',
  60              );
  61
  62 has status => (is => 'ro', isa => 'HashRef',
  63                lazy => 1,
  64                builder => '_build_status',
  65               );
  66
  67 sub _build_status {
  68     my $self = shift;
  69     $self->reset;
  70     my $status = read_bug(bug=>$self->bug) or
  71         confess("Unable to read bug ".$self->bug);
  72     return $status;
  73 }
  74
  75 has 'package_collection' => (is => 'ro',
  76                              isa => 'Debbugs::Collection::Package',
  77                              builder => '_build_package_collection',
  78                              lazy => 1,
  79                             );
  80
  81 sub _build_package_collection {
  82     my $self = shift;
  83     if ($self->has_schema) {
  84         return Debbugs::Collection::Package->new(schema => $self->schema);
  85     }
  86     carp "No schema when building package collection";
  87     return Debbugs::Collection::Package->new();
  88 }
  89
  90 has bug_collection => (is => 'ro',
  91                        isa => 'Debbugs::Collection::Bug',
  92                        builder => '_build_bug_collection',
  93                       );
  94 sub _build_bug_collection {
  95     my $self = shift;
  96     if ($self->has_schema) {
  97         return Debbugs::Collection::Bug->new(schema => $self->schema);
  98     }
  99     return Debbugs::Collection::Bug->new();
 100 }
 101
 102 has correspondent_collection =>
 103     (is => 'ro',
 104      isa => 'Debbugs::Collection::Correspondent',
 105      builder => '_build_package_collection',
 106      lazy => 1,
 107     );
 108 sub _build_correspondent_collection   {
 109     my $self = shift;
 110     return Debbugs::Collection::Correspondent->new($self->schema_argument);
 111 }
 112
 113 sub reset {
 114     my $self = shift;
 115     $self->_clear_done();
 116     $self->_clear_severity();
 117     $self->_clear_packages();
 118     $self->_clear_sources();
 119     $self->_clear_affects();
 120     $self->_clear_blocks();
 121     $self->_clear_blockedby();
 122     $self->_clear_found();
 123     $self->_clear_fixed();
 124     $self->_clear_mergedwith();
 125     $self->_clear_pending();
 126     $self->_clear_location();
 127     $self->_clear_archived();
 128     $self->_clear_archiveable();
 129     $self->_clear_when_archiveable();
 130     $self->_clear_submitter();
 131     $self->_clear_created();
 132     $self->_clear_modified();
 133     $self->_set_saved(1);
 134 }
 135
 136 sub _clear_saved_if_changed {
 137     my ($self,$new,$old) = @_;
 138     if (@_ > 2) {
 139         if ($new ne $old) {
 140             $self->_set_saved(0);
 141         }
 142     }
 143 }
 144
 145 # package attributes
 146 for my $attr (qw(packages affects sources)) {
 147     has $attr =>
 148         (is => 'rw',
 149          isa => 'Debbugs::Collection::Package',
 150          clearer => '_clear_'.$attr,
 151          builder => '_build_'.$attr,
 152          trigger => \&_clear_saved_if_changed,
 153          lazy => 1,
 154         );
 155 }
 156
 157 # bugs
 158 for my $attr (qw(blocks blockedby mergedwith)) {
 159     has $attr =>
 160         (is => 'ro',
 161          isa => 'Debbugs::Collection::Bug',
 162          clearer => '_clear_'.$attr,
 163          builder => '_build_'.$attr,
 164          handles => {},
 165          lazy => 1,
 166         );
 167 }
 168
 169
 170 for my $attr (qw(owner submitter)) {
 171     has $attr.'_corr' =>
 172         (is => 'ro',
 173          isa => 'Debbugs::Correspondent',
 174          lazy => 1,
 175          builder => '_build_'.$attr.'_corr',
 176          clearer => '_clear_'.$attr.'_corr',
 177          handles => {$attr.'_url' => $attr.'_url',
 178                      $attr.'_email' => 'email',
 179                      $attr.'_phrase' => 'phrase',
 180                     },
 181         );
 182 }
 183
 184 sub _build_owner_corr {
 185     my $self = shift;
 186     return $self->correspondent_collection->get_or_create($self->owner);
 187 }
 188
 189 sub _build_submitter_corr {
 190     my $self = shift;
 191     return $self->correspondent_collection->get_or_create($self->submitter);
 192 }
 193
 194 for my $attr (qw(done severity),
 195               qw(forwarded),
 196               qw(pending location submitter),
 197               qw(owner subject),
 198              ) {
 199     has $attr =>
 200         (is => 'rw',
 201          isa => 'Str',
 202          clearer => '_clear_'.$attr,
 203          builder => '_build_'.$attr,
 204          trigger => \&_clear_saved_if_changed,
 205          lazy => 1,
 206         );
 207 }
 208
 209 sub is_done {
 210     return length $_[0]->done?1:0;
 211 }
 212 sub _build_done {
 213     return $_[0]->status->{done} // '';
 214 }
 215
 216 sub _build_severity {
 217     return $_[0]->status->{severity} // $config{default_severity};
 218 }
 219
 220 sub _build_subject {
 221     return $_[0]->status->{subject} // '(No subject)';
 222 }
 223
 224 sub strong_severity {
 225     my $self = shift;
 226     return exists $strong_severities->{$self->severity};
 227 }
 228
 229 sub short_severity {
 230     $_[0]->severity =~ m/^(.)/;
 231     return $1;
 232 }
 233
 234 sub package {
 235     my $self = shift;
 236     return join(', ',$self->packages->apply(sub{$_->name}));
 237 }
 238
 239 sub _build_packages {
 240     my $self = shift;
 241     my @packages;
 242     if (length($self->status->{package}//'')) {
 243         @packages = split /,/,$self->status->{package}//'';
 244     }
 245     return $self->package_collection->
 246             limit(@packages);
 247 }
 248
 249 sub is_affecting {
 250     my $self = shift;
 251     return $self->affects->count > 0;
 252 }
 253
 254 sub affect {
 255     local $_;
 256     return join(', ',map {$_->name} $_[0]->affects->members);
 257 }
 258
 259 sub _build_affects {
 260     my @packages;
 261     if (length($_[0]->status->{affects}//'')) {
 262         @packages = split /,/,$_[0]->status->{affects}//'';
 263     }
 264     return $_[0]->package_collection->
 265             limit(@packages);
 266 }
 267 sub source {
 268     local $_;
 269     return join(', ',map {$_->name} $_[0]->sources->members);
 270 }
 271 sub _build_sources {
 272     local $_;
 273     my @sources = map {$_->sources} $_[0]->packages->members;
 274     return @sources;
 275 }
 276
 277 sub is_owned {
 278     my $self = shift;
 279     return length($self->owner) > 0;
 280 }
 281 sub _build_owner {
 282     my $self = shift;
 283     return $self->status->{owner} // '';
 284 }
 285
 286
 287 sub _split_if_defined {
 288     my ($self,$field,$split) = @_;
 289     $split //= ' ';
 290     my $e = $self->status->{$field};
 291     my @f;
 292     if (defined $e and
 293         length $e) {
 294         return split /$split/,$e;
 295     }
 296     return ();
 297 }
 298
 299 sub is_blocking {
 300     my $self = shift;
 301     return $self->blocks->count > 0;
 302 }
 303
 304 sub _build_blocks {
 305     my $self = shift;
 306     return $self->bug_collection->
 307         limit(sort {$a <=> $b}
 308               $self->_split_if_defined('blocks'));
 309 }
 310
 311 sub is_blocked {
 312     my $self = shift;
 313     return $self->blockedby->count > 0;
 314 }
 315
 316 sub _build_blockedby {
 317     my $self = shift;
 318     return $self->bug_collection->
 319         limit(sort {$a <=> $b}
 320               $self->_split_if_defined('blockedby'));
 321 }
 322
 323 sub is_forwarded {
 324     length($_[0]->forwarded) > 0;
 325 }
 326
 327 sub _build_forwarded {
 328     my $self = shift;
 329     return $self->status->{forwarded} // '';
 330 }
 331
 332
 333
 334 for my $attr (qw(fixed found)) {
 335     has $attr =>
 336         (is => 'ro',
 337          isa => 'Debbugs::Collection::Version',
 338          clearer => '_clear_'.$attr,
 339          builder => '_build_'.$attr,
 340          handles => {},
 341          lazy => 1,
 342         );
 343 }
 344
 345 sub has_found {
 346     my $self = shift;
 347     return $self->found->count > 0;
 348 }
 349
 350 sub _build_found {
 351     my $self = shift;
 352     return $self->packages->
 353         get_source_versions(@{$self->status->{found_versions} // []});
 354 }
 355
 356 sub has_fixed {
 357     my $self = shift;
 358     return $self->fixed->count > 0;
 359 }
 360
 361 sub _build_fixed {
 362     my $self = shift;
 363     return $self->packages->
 364         get_source_versions(@{$self->status->{fixed_versions} // []});
 365 }
 366
 367 sub is_merged {
 368     my $self = shift;
 369     return $self->mergedwith->count > 0;
 370 }
 371
 372 sub _build_mergedwith {
 373     my $self = shift;
 374     return $self->bug_collection->
 375         limit(sort {$a <=> $b}
 376               $self->_split_if_defined('mergedwith'));
 377 }
 378 sub _build_pending {
 379     return $_[0]->status->{pending} // '';
 380 }
 381 sub _build_submitter {
 382     return $_[0]->status->{originator} // '';
 383 }
 384
 385 for my $attr (qw(created modified)) {
 386     has $attr => (is => 'rw', isa => 'Object',
 387                 clearer => '_clear_'.$attr,
 388                 builder => '_build_'.$attr,
 389                 lazy => 1);
 390 }
 391 sub _build_created {
 392     return DateTime->
 393         from_epoch(epoch => $_[0]->status->{date} // time);
 394 }
 395 sub _build_modified {
 396     return DateTime->
 397         from_epoch(epoch => max($_[0]->status->{log_modified},
 398                                 $_[0]->status->{last_modified}
 399                                ));
 400 }
 401 sub _build_location {
 402     return $_[0]->status->{location};
 403 }
 404 has archived => (is => 'ro', isa => 'Bool',
 405                  clearer => '_clear_archived',
 406                  builder => '_build_archived',
 407                  lazy => 1);
 408 sub _build_archived {
 409     return $_[0]->location eq 'archived'?1:0;
 410 }
 411
 412 has tags => (is => 'ro', isa => 'Object',
 413              clearer => '_clear_tags',
 414              builder => '_build_tags',
 415              lazy => 1,
 416             );
 417 sub _build_tags {
 418     return Debbugs::Bug::Tag->new($_[0]->status->{keywords});
 419 }
 420
 421 =item buggy
 422
 423      $bug->buggy('debbugs/2.6.0-1','debbugs/2.6.0-2');
 424      $bug->buggy(Debbugs::Version->new('debbugs/2.6.0-1'),
 425                  Debbugs::Version->new('debbugs/2.6.0-2'),
 426                 );
 427
 428 Returns the output of Debbugs::Versions::buggy for a particular
 429 package, version and found/fixed set. Automatically turns found, fixed
 430 and version into source/version strings.
 431
 432 =cut
 433
 434 sub buggy {
 435     my $self = shift;
 436     my $vertree =
 437         $self->package_collection->
 438         universe->versiontree;
 439     my $max_buggy = 'absent';
 440     for my $ver (@_) {
 441         if (not ref($ver)) {
 442             $ver = Debbugs::Version->
 443                 new(version => $ver,
 444                     package => $self,
 445                     package_collection => $self->package_collection,
 446                    );
 447         }
 448         $vertree->load($ver->source);
 449         my $buggy =
 450             $vertree->buggy($ver,
 451                             [$self->found],
 452                             [$self->fixed]);
 453         if ($buggy eq 'found') {
 454             return 'found'
 455         }
 456         if ($buggy eq 'fixed') {
 457             $max_buggy = 'fixed';
 458         }
 459     }
 460     return $max_buggy;
 461 }
 462
 463 has archiveable =>
 464     (is => 'ro', isa => 'Bool',
 465      writer => '_set_archiveable',
 466      builder => '_build_archiveable',
 467      clearer => '_clear_archiveable',
 468      lazy => 1,
 469     );
 470 has when_archiveable =>
 471     (is => 'ro', isa => 'Num',
 472      writer => '_set_when_archiveable',
 473      builder => '_build_when_archiveable',
 474      clearer => '_clear_when_archiveable',
 475      lazy => 1,
 476     );
 477
 478 sub _build_archiveable {
 479     my $self = shift;
 480     $self->_populate_archiveable(0);
 481     return $self->archiveable;
 482 }
 483 sub _build_when_archiveable {
 484     my $self = shift;
 485     $self->_populate_archiveable(1);
 486     return $self->when_archiveable;
 487 }
 488
 489 sub _populate_archiveable {
 490     my $self = shift;
 491     my ($need_time) = @_;
 492     $need_time //= 0;
 493     # Bugs can be archived if they are
 494     # 1. Closed
 495     if (not $self->done) {
 496         $self->_set_archiveable(0);
 497         $self->_set_when_archiveable(-1);
 498         return;
 499     }
 500     # 2. Have no unremovable tags set
 501     if (@{$config{removal_unremovable_tags}}) {
 502         state $unrem_tags =
 503            {map {($_=>1)} @{$config{removal_unremovable_tags}}};
 504         for my $tag ($self->tags) {
 505             if ($unrem_tags->{$tag}) {
 506                 $self->_set_archiveable(0);
 507                 $self->_set_when_archiveable(-1);
 508                 return;
 509             }
 510         }
 511     }
 512     my $time = time;
 513     state $remove_time = 24 * 60 * 60 * ($config{removal_age} // 30);
 514     # 4. Have been modified more than removal_age ago
 515     my $moded_ago =
 516         $time - $self->modified->epoch;
 517     # if we don't need to know when we can archive, we can stop here if it's
 518     # been modified too recently
 519     if ($moded_ago < $remove_time) {
 520         $self->_set_archiveable(0);
 521         return unless $need_time;
 522     }
 523     my @distributions =
 524         @{$config{removal_default_distribution_tags}};
 525     if ($self->strong_severity) {
 526         @distributions =
 527             @{$config{removal_strong_severity_default_distribution_tags}};
 528     }
 529     # 3. Have a maximum buggy of fixed
 530     my $buggy = $self->buggy($self->packages->
 531                              get_source_versions_distributions(@distributions));
 532     if ('found' eq $buggy) {
 533         $self->_set_archiveable(0);
 534         $self->_set_when_archiveable(-1);
 535         return;
 536     }
 537     my $fixed_ago = $moded_ago;
 538     # $fixed_ago = $time - $self->when_fixed(@distributions);
 539     # if ($fixed_ago < $remove_time) {
 540     #     $self->_set_archiveable(0);
 541     # }
 542     $self->_set_when_archiveable(($remove_time - min($fixed_ago,$moded_ago)) / (24 * 60 * 60));
 543     if ($fixed_ago > $remove_time and
 544         $moded_ago > $remove_time) {
 545         $self->_set_archiveable(1);
 546         $self->_set_when_archiveable(0);
 547     }
 548     return;
 549 }
 550
 551 sub filter {
 552     my $self = shift;
 553     my %param = validate_with(params => \@_,
 554                               spec   => {seen_merged => {type => HASHREF,
 555                                                          default => sub {return {}},
 556                                                         },
 557                                          repeat_merged => {type => BOOLEAN,
 558                                                            default => 1,
 559                                                           },
 560                                          include => {type => HASHREF,
 561                                                      optional => 1,
 562                                                     },
 563                                          exclude => {type => HASHREF,
 564                                                      optional => 1,
 565                                                     },
 566                                          min_days => {type => SCALAR,
 567                                                       optional => 1,
 568                                                      },
 569                                          max_days => {type => SCALAR,
 570                                                       optional => 1,
 571                                                      },
 572                                          },
 573                              );
 574     if (exists $param{include}) {
 575         return 1 if not $self->matches($param{include});
 576     }
 577     if (exists $param{exclude}) {
 578         return 1 if $self->matches($param{exclude});
 579     }
 580     if (exists $param{repeat_merged} and not $param{repeat_merged}) {
 581         my @merged = sort {$a<=>$b} $self->bug, map {$_->bug} $self->mergedwith->members;
 582         return 1 if first {sub {defined $_}}
 583             @{$param{seen_merged}}{@merged};
 584         @{$param{seen_merged}}{@merged} = (1) x @merged;
 585     }
 586     if (exists $param{min_days}) {
 587         return 1 unless $param{min_days} <=
 588             (DateTime->now() - $self->created)->days();
 589     }
 590     if (exists $param{max_days}) {
 591         return 1 unless $param{max_days} >=
 592             (DateTime->now() - $self->created)->days();
 593     }
 594     return 0;
 595
 596 }
 597
 598 sub __exact_match {
 599     my ($field, $values) = @_;
 600     my @ret = first {sub {$_ eq $field}} @{$values};
 601     return @ret != 0;
 602 }
 603
 604 sub __contains_match {
 605     my ($field, $values) = @_;
 606     foreach my $value (@{$values}) {
 607         return 1 if (index($field, $value) > -1);
 608     }
 609     return 0;
 610 }
 611
 612 state $field_match =
 613    {subject => sub {__contains_match($_[0]->subject,@_)},
 614     tags => sub {
 615         for my $value (@{$_[1]}) {
 616             if ($_[0]->tags->is_set($value)) {
 617                 return 1;
 618             }
 619         }
 620         return 0;
 621         },
 622     severity => sub {__exact_match($_[0]->severity,@_)},
 623     pending => sub {__exact_match($_[0]->pending,@_)},
 624     originator => sub {__exact_match($_[0]->submitter,@_)},
 625     submitter => sub {__exact_match($_[0]->submitter,@_)},
 626     forwarded => sub {__exact_match($_[0]->forwarded,@_)},
 627     owner => sub {__exact_match($_[0]->owner,@_)},
 628    };
 629
 630 sub matches {
 631     my ($self,$hash) = @_;
 632     for my $key (keys %{$hash}) {
 633         my $sub = $field_match->{$key};
 634         if (not defined $sub) {
 635             carp "No subroutine for key: $key";
 636             next;
 637         }
 638         return 1 if $sub->($self,$hash->{$key});
 639     }
 640     return 0;
 641 }
 642
 643 sub url {
 644     my $self = shift;
 645     return $config{web_domain}.'/'.$self->id;
 646 }
 647
 648 sub related_packages_and_versions {
 649     my $self = shift;
 650     my @packages;
 651     if (length($self->status->{package}//'')) {
 652         @packages = split /,/,$self->status->{package}//'';
 653     }
 654     my @versions =
 655         (@{$self->status->{found_versions}//[]},
 656          @{$self->status->{fixed_versions}//[]});
 657     my @unqualified_versions;
 658     my @return;
 659     for my $ver (@versions) {
 660         if ($ver =~ m{(<src>.+)/(<ver>.+)}) { # It's a src_pkg_ver
 661             push @return, ['src:'.$+{src}, $+{ver}];
 662         } else {
 663            push @unqualified_versions,$ver;
 664         }
 665     }
 666     for my $pkg (@packages) {
 667         push @return,
 668             [$pkg,@unqualified_versions];
 669     }
 670     return @return;
 671 }
 672
 673 sub CARP_TRACE {
 674     my $self = shift;
 675     return 'Debbugs::Bug={bug='.$self->bug.'}';
 676 }
 677
 678 __PACKAGE__->meta->make_immutable;
 679
 680 no Mouse;
 681 1;
 682
 683
 684 __END__
 685 # Local Variables:
 686 # indent-tabs-mode: nil
 687 # cperl-indent-level: 4
 688 # End: