inc/Module/Install/Makefile.pm

   1 #line 1
   2 package Module::Install::Makefile;
   3
   4 use strict 'vars';
   5 use ExtUtils::MakeMaker   ();
   6 use Module::Install::Base ();
   7 use Fcntl qw/:flock :seek/;
   8
   9 use vars qw{$VERSION @ISA $ISCORE};
  10 BEGIN {
  11         $VERSION = '1.04';
  12         @ISA     = 'Module::Install::Base';
  13         $ISCORE  = 1;
  14 }
  15
  16 sub Makefile { $_[0] }
  17
  18 my %seen = ();
  19
  20 sub prompt {
  21         shift;
  22
  23         # Infinite loop protection
  24         my @c = caller();
  25         if ( ++$seen{"$c[1]|$c[2]|$_[0]"} > 3 ) {
  26                 die "Caught an potential prompt infinite loop ($c[1]|$c[2]|$_[0])";
  27         }
  28
  29         # In automated testing or non-interactive session, always use defaults
  30         if ( ($ENV{AUTOMATED_TESTING} or -! -t STDIN) and ! $ENV{PERL_MM_USE_DEFAULT} ) {
  31                 local $ENV{PERL_MM_USE_DEFAULT} = 1;
  32                 goto &ExtUtils::MakeMaker::prompt;
  33         } else {
  34                 goto &ExtUtils::MakeMaker::prompt;
  35         }
  36 }
  37
  38 # Store a cleaned up version of the MakeMaker version,
  39 # since we need to behave differently in a variety of
  40 # ways based on the MM version.
  41 my $makemaker = eval $ExtUtils::MakeMaker::VERSION;
  42
  43 # If we are passed a param, do a "newer than" comparison.
  44 # Otherwise, just return the MakeMaker version.
  45 sub makemaker {
  46         ( @_ < 2 or $makemaker >= eval($_[1]) ) ? $makemaker : 0
  47 }
  48
  49 # Ripped from ExtUtils::MakeMaker 6.56, and slightly modified
  50 # as we only need to know here whether the attribute is an array
  51 # or a hash or something else (which may or may not be appendable).
  52 my %makemaker_argtype = (
  53  C                  => 'ARRAY',
  54  CONFIG             => 'ARRAY',
  55 # CONFIGURE          => 'CODE', # ignore
  56  DIR                => 'ARRAY',
  57  DL_FUNCS           => 'HASH',
  58  DL_VARS            => 'ARRAY',
  59  EXCLUDE_EXT        => 'ARRAY',
  60  EXE_FILES          => 'ARRAY',
  61  FUNCLIST           => 'ARRAY',
  62  H                  => 'ARRAY',
  63  IMPORTS            => 'HASH',
  64  INCLUDE_EXT        => 'ARRAY',
  65  LIBS               => 'ARRAY', # ignore ''
  66  MAN1PODS           => 'HASH',
  67  MAN3PODS           => 'HASH',
  68  META_ADD           => 'HASH',
  69  META_MERGE         => 'HASH',
  70  PL_FILES           => 'HASH',
  71  PM                 => 'HASH',
  72  PMLIBDIRS          => 'ARRAY',
  73  PMLIBPARENTDIRS    => 'ARRAY',
  74  PREREQ_PM          => 'HASH',
  75  CONFIGURE_REQUIRES => 'HASH',
  76  SKIP               => 'ARRAY',
  77  TYPEMAPS           => 'ARRAY',
  78  XS                 => 'HASH',
  79 # VERSION            => ['version',''],  # ignore
  80 # _KEEP_AFTER_FLUSH  => '',
  81
  82  clean      => 'HASH',
  83  depend     => 'HASH',
  84  dist       => 'HASH',
  85  dynamic_lib=> 'HASH',
  86  linkext    => 'HASH',
  87  macro      => 'HASH',
  88  postamble  => 'HASH',
  89  realclean  => 'HASH',
  90  test       => 'HASH',
  91  tool_autosplit => 'HASH',
  92
  93  # special cases where you can use makemaker_append
  94  CCFLAGS   => 'APPENDABLE',
  95  DEFINE    => 'APPENDABLE',
  96  INC       => 'APPENDABLE',
  97  LDDLFLAGS => 'APPENDABLE',
  98  LDFROM    => 'APPENDABLE',
  99 );
 100
 101 sub makemaker_args {
 102         my ($self, %new_args) = @_;
 103         my $args = ( $self->{makemaker_args} ||= {} );
 104         foreach my $key (keys %new_args) {
 105                 if ($makemaker_argtype{$key}) {
 106                         if ($makemaker_argtype{$key} eq 'ARRAY') {
 107                                 $args->{$key} = [] unless defined $args->{$key};
 108                                 unless (ref $args->{$key} eq 'ARRAY') {
 109                                         $args->{$key} = [$args->{$key}]
 110                                 }
 111                                 push @{$args->{$key}},
 112                                         ref $new_args{$key} eq 'ARRAY'
 113                                                 ? @{$new_args{$key}}
 114                                                 : $new_args{$key};
 115                         }
 116                         elsif ($makemaker_argtype{$key} eq 'HASH') {
 117                                 $args->{$key} = {} unless defined $args->{$key};
 118                                 foreach my $skey (keys %{ $new_args{$key} }) {
 119                                         $args->{$key}{$skey} = $new_args{$key}{$skey};
 120                                 }
 121                         }
 122                         elsif ($makemaker_argtype{$key} eq 'APPENDABLE') {
 123                                 $self->makemaker_append($key => $new_args{$key});
 124                         }
 125                 }
 126                 else {
 127                         if (defined $args->{$key}) {
 128                                 warn qq{MakeMaker attribute "$key" is overriden; use "makemaker_append" to append values\n};
 129                         }
 130                         $args->{$key} = $new_args{$key};
 131                 }
 132         }
 133         return $args;
 134 }
 135
 136 # For mm args that take multiple space-seperated args,
 137 # append an argument to the current list.
 138 sub makemaker_append {
 139         my $self = shift;
 140         my $name = shift;
 141         my $args = $self->makemaker_args;
 142         $args->{$name} = defined $args->{$name}
 143                 ? join( ' ', $args->{$name}, @_ )
 144                 : join( ' ', @_ );
 145 }
 146
 147 sub build_subdirs {
 148         my $self    = shift;
 149         my $subdirs = $self->makemaker_args->{DIR} ||= [];
 150         for my $subdir (@_) {
 151                 push @$subdirs, $subdir;
 152         }
 153 }
 154
 155 sub clean_files {
 156         my $self  = shift;
 157         my $clean = $self->makemaker_args->{clean} ||= {};
 158           %$clean = (
 159                 %$clean,
 160                 FILES => join ' ', grep { length $_ } ($clean->{FILES} || (), @_),
 161         );
 162 }
 163
 164 sub realclean_files {
 165         my $self      = shift;
 166         my $realclean = $self->makemaker_args->{realclean} ||= {};
 167           %$realclean = (
 168                 %$realclean,
 169                 FILES => join ' ', grep { length $_ } ($realclean->{FILES} || (), @_),
 170         );
 171 }
 172
 173 sub libs {
 174         my $self = shift;
 175         my $libs = ref $_[0] ? shift : [ shift ];
 176         $self->makemaker_args( LIBS => $libs );
 177 }
 178
 179 sub inc {
 180         my $self = shift;
 181         $self->makemaker_args( INC => shift );
 182 }
 183
 184 sub _wanted_t {
 185 }
 186
 187 sub tests_recursive {
 188         my $self = shift;
 189         my $dir = shift || 't';
 190         unless ( -d $dir ) {
 191                 die "tests_recursive dir '$dir' does not exist";
 192         }
 193         my %tests = map { $_ => 1 } split / /, ($self->tests || '');
 194         require File::Find;
 195         File::Find::find(
 196         sub { /\.t$/ and -f $_ and $tests{"$File::Find::dir/*.t"} = 1 },
 197         $dir
 198     );
 199         $self->tests( join ' ', sort keys %tests );
 200 }
 201
 202 sub write {
 203         my $self = shift;
 204         die "&Makefile->write() takes no arguments\n" if @_;
 205
 206         # Check the current Perl version
 207         my $perl_version = $self->perl_version;
 208         if ( $perl_version ) {
 209                 eval "use $perl_version; 1"
 210                         or die "ERROR: perl: Version $] is installed, "
 211                         . "but we need version >= $perl_version";
 212         }
 213
 214         # Make sure we have a new enough MakeMaker
 215         require ExtUtils::MakeMaker;
 216
 217         if ( $perl_version and $self->_cmp($perl_version, '5.006') >= 0 ) {
 218                 # MakeMaker can complain about module versions that include
 219                 # an underscore, even though its own version may contain one!
 220                 # Hence the funny regexp to get rid of it.  See RT #35800
 221                 # for details.
 222                 my ($v) = $ExtUtils::MakeMaker::VERSION =~ /^(\d+\.\d+)/;
 223                 $self->build_requires(     'ExtUtils::MakeMaker' => $v );
 224                 $self->configure_requires( 'ExtUtils::MakeMaker' => $v );
 225         } else {
 226                 # Allow legacy-compatibility with 5.005 by depending on the
 227                 # most recent EU:MM that supported 5.005.
 228                 $self->build_requires(     'ExtUtils::MakeMaker' => 6.36 );
 229                 $self->configure_requires( 'ExtUtils::MakeMaker' => 6.36 );
 230         }
 231
 232         # Generate the MakeMaker params
 233         my $args = $self->makemaker_args;
 234         $args->{DISTNAME} = $self->name;
 235         $args->{NAME}     = $self->module_name || $self->name;
 236         $args->{NAME}     =~ s/-/::/g;
 237         $args->{VERSION}  = $self->version or die <<'EOT';
 238 ERROR: Can't determine distribution version. Please specify it
 239 explicitly via 'version' in Makefile.PL, or set a valid $VERSION
 240 in a module, and provide its file path via 'version_from' (or
 241 'all_from' if you prefer) in Makefile.PL.
 242 EOT
 243
 244         if ( $self->tests ) {
 245                 my @tests = split ' ', $self->tests;
 246                 my %seen;
 247                 $args->{test} = {
 248                         TESTS => (join ' ', grep {!$seen{$_}++} @tests),
 249                 };
 250     } elsif ( $Module::Install::ExtraTests::use_extratests ) {
 251         # Module::Install::ExtraTests doesn't set $self->tests and does its own tests via harness.
 252         # So, just ignore our xt tests here.
 253         } elsif ( -d 'xt' and ($Module::Install::AUTHOR or $ENV{RELEASE_TESTING}) ) {
 254                 $args->{test} = {
 255                         TESTS => join( ' ', map { "$_/*.t" } grep { -d $_ } qw{ t xt } ),
 256                 };
 257         }
 258         if ( $] >= 5.005 ) {
 259                 $args->{ABSTRACT} = $self->abstract;
 260                 $args->{AUTHOR}   = join ', ', @{$self->author || []};
 261         }
 262         if ( $self->makemaker(6.10) ) {
 263                 $args->{NO_META}   = 1;
 264                 #$args->{NO_MYMETA} = 1;
 265         }
 266         if ( $self->makemaker(6.17) and $self->sign ) {
 267                 $args->{SIGN} = 1;
 268         }
 269         unless ( $self->is_admin ) {
 270                 delete $args->{SIGN};
 271         }
 272         if ( $self->makemaker(6.31) and $self->license ) {
 273                 $args->{LICENSE} = $self->license;
 274         }
 275
 276         my $prereq = ($args->{PREREQ_PM} ||= {});
 277         %$prereq = ( %$prereq,
 278                 map { @$_ } # flatten [module => version]
 279                 map { @$_ }
 280                 grep $_,
 281                 ($self->requires)
 282         );
 283
 284         # Remove any reference to perl, PREREQ_PM doesn't support it
 285         delete $args->{PREREQ_PM}->{perl};
 286
 287         # Merge both kinds of requires into BUILD_REQUIRES
 288         my $build_prereq = ($args->{BUILD_REQUIRES} ||= {});
 289         %$build_prereq = ( %$build_prereq,
 290                 map { @$_ } # flatten [module => version]
 291                 map { @$_ }
 292                 grep $_,
 293                 ($self->configure_requires, $self->build_requires)
 294         );
 295
 296         # Remove any reference to perl, BUILD_REQUIRES doesn't support it
 297         delete $args->{BUILD_REQUIRES}->{perl};
 298
 299         # Delete bundled dists from prereq_pm, add it to Makefile DIR
 300         my $subdirs = ($args->{DIR} || []);
 301         if ($self->bundles) {
 302                 my %processed;
 303                 foreach my $bundle (@{ $self->bundles }) {
 304                         my ($mod_name, $dist_dir) = @$bundle;
 305                         delete $prereq->{$mod_name};
 306                         $dist_dir = File::Basename::basename($dist_dir); # dir for building this module
 307                         if (not exists $processed{$dist_dir}) {
 308                                 if (-d $dist_dir) {
 309                                         # List as sub-directory to be processed by make
 310                                         push @$subdirs, $dist_dir;
 311                                 }
 312                                 # Else do nothing: the module is already present on the system
 313                                 $processed{$dist_dir} = undef;
 314                         }
 315                 }
 316         }
 317
 318         unless ( $self->makemaker('6.55_03') ) {
 319                 %$prereq = (%$prereq,%$build_prereq);
 320                 delete $args->{BUILD_REQUIRES};
 321         }
 322
 323         if ( my $perl_version = $self->perl_version ) {
 324                 eval "use $perl_version; 1"
 325                         or die "ERROR: perl: Version $] is installed, "
 326                         . "but we need version >= $perl_version";
 327
 328                 if ( $self->makemaker(6.48) ) {
 329                         $args->{MIN_PERL_VERSION} = $perl_version;
 330                 }
 331         }
 332
 333         if ($self->installdirs) {
 334                 warn qq{old INSTALLDIRS (probably set by makemaker_args) is overriden by installdirs\n} if $args->{INSTALLDIRS};
 335                 $args->{INSTALLDIRS} = $self->installdirs;
 336         }
 337
 338         my %args = map {
 339                 ( $_ => $args->{$_} ) } grep {defined($args->{$_} )
 340         } keys %$args;
 341
 342         my $user_preop = delete $args{dist}->{PREOP};
 343         if ( my $preop = $self->admin->preop($user_preop) ) {
 344                 foreach my $key ( keys %$preop ) {
 345                         $args{dist}->{$key} = $preop->{$key};
 346                 }
 347         }
 348
 349         my $mm = ExtUtils::MakeMaker::WriteMakefile(%args);
 350         $self->fix_up_makefile($mm->{FIRST_MAKEFILE} || 'Makefile');
 351 }
 352
 353 sub fix_up_makefile {
 354         my $self          = shift;
 355         my $makefile_name = shift;
 356         my $top_class     = ref($self->_top) || '';
 357         my $top_version   = $self->_top->VERSION || '';
 358
 359         my $preamble = $self->preamble
 360                 ? "# Preamble by $top_class $top_version\n"
 361                         . $self->preamble
 362                 : '';
 363         my $postamble = "# Postamble by $top_class $top_version\n"
 364                 . ($self->postamble || '');
 365
 366         local *MAKEFILE;
 367         open MAKEFILE, "+< $makefile_name" or die "fix_up_makefile: Couldn't open $makefile_name: $!";
 368         eval { flock MAKEFILE, LOCK_EX };
 369         my $makefile = do { local $/; <MAKEFILE> };
 370
 371         $makefile =~ s/\b(test_harness\(\$\(TEST_VERBOSE\), )/$1'inc', /;
 372         $makefile =~ s/( -I\$\(INST_ARCHLIB\))/ -Iinc$1/g;
 373         $makefile =~ s/( "-I\$\(INST_LIB\)")/ "-Iinc"$1/g;
 374         $makefile =~ s/^(FULLPERL = .*)/$1 "-Iinc"/m;
 375         $makefile =~ s/^(PERL = .*)/$1 "-Iinc"/m;
 376
 377         # Module::Install will never be used to build the Core Perl
 378         # Sometimes PERL_LIB and PERL_ARCHLIB get written anyway, which breaks
 379         # PREFIX/PERL5LIB, and thus, install_share. Blank them if they exist
 380         $makefile =~ s/^PERL_LIB = .+/PERL_LIB =/m;
 381         #$makefile =~ s/^PERL_ARCHLIB = .+/PERL_ARCHLIB =/m;
 382
 383         # Perl 5.005 mentions PERL_LIB explicitly, so we have to remove that as well.
 384         $makefile =~ s/(\"?)-I\$\(PERL_LIB\)\1//g;
 385
 386         # XXX - This is currently unused; not sure if it breaks other MM-users
 387         # $makefile =~ s/^pm_to_blib\s+:\s+/pm_to_blib :: /mg;
 388
 389         seek MAKEFILE, 0, SEEK_SET;
 390         truncate MAKEFILE, 0;
 391         print MAKEFILE  "$preamble$makefile$postamble" or die $!;
 392         close MAKEFILE  or die $!;
 393
 394         1;
 395 }
 396
 397 sub preamble {
 398         my ($self, $text) = @_;
 399         $self->{preamble} = $text . $self->{preamble} if defined $text;
 400         $self->{preamble};
 401 }
 402
 403 sub postamble {
 404         my ($self, $text) = @_;
 405         $self->{postamble} ||= $self->admin->postamble;
 406         $self->{postamble} .= $text if defined $text;
 407         $self->{postamble}
 408 }
 409
 410 1;
 411
 412 __END__
 413
 414 #line 540