www/index.cgi

   1 #!/usr/bin/env perl
   2
   3 # Copyright (C) 2006-2009 Martin A. Hansen.
   4
   5 # This program is free software; you can redistribute it and/or
   6 # modify it under the terms of the GNU General Public License
   7 # as published by the Free Software Foundation; either version 2
   8 # of the License, or (at your option) any later version.
   9
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
  18
  19 # http://www.gnu.org/copyleft/gpl.html
  20
  21 # >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
  22
  23 use strict;
  24 use warnings;
  25
  26 use lib $ENV{ 'BP_PERL' };
  27
  28 use CGI;
  29 use Data::Dumper;
  30 use Digest::MD5;
  31 use Maasha::Common;
  32 use Maasha::Filesys;
  33 use Maasha::Calc;
  34 use Maasha::XHTML;
  35 use Maasha::KISS;
  36 use Maasha::BGB::Session;
  37 use Maasha::BGB::Track;
  38 use Maasha::BGB::Draw;
  39
  40 my ( $cgi, $cookie, @html );
  41
  42 $cgi    = new CGI;
  43 $cookie = cookie_default( $cgi );;
  44
  45 push @html, Maasha::XHTML::html_header(
  46     cgi_header  => 1,
  47     title       => "Biopieces Genome Browser",
  48     css_file    => "bgb.css",
  49     author      => "Martin A. Hansen, mail\@maasha.dk",
  50     description => "Biopieces Genome Browser",
  51     keywords    => [ qw( Biopieces biopiece genome browser viewer bacterium bacteria prokaryote prokaryotes ) ],
  52     no_cache    => 1,
  53 );
  54
  55 push @html, Maasha::XHTML::h1( txt => "Biopieces Genome Browser", class => 'center' );
  56 push @html, Maasha::XHTML::form_beg( action => $cookie->{ 'SCRIPT' }, method => "post", enctype => "multipart/form-data" );
  57
  58 push @html, page( $cookie );
  59
  60 push @html, Maasha::XHTML::form_end;
  61 push @html, Maasha::XHTML::body_end;
  62 push @html, Maasha::XHTML::html_end;
  63
  64 # push @html, Maasha::XHTML::hdump( [ $cgi->Vars ] );  # DEBUG
  65 # push @html, Maasha::XHTML::hdump( \%ENV );           # DEBUG
  66 # push @html, Maasha::XHTML::hdump( $cookie );         # DEBUG
  67
  68 print "$_\n" foreach @html;
  69
  70
  71 # >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> SUBROUTINES <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
  72
  73
  74 # >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> COOKIE <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
  75
  76
  77 sub cookie_default
  78 {
  79     # Martin A. Hansen, November 2009.
  80
  81     # Set a cookie with values from the CGI object or defaults.
  82
  83     my ( $cgi,   # CGI object
  84        ) = @_;
  85
  86     # Returns a hash.
  87
  88     my ( $cookie, $path );
  89
  90     $cookie = {};
  91
  92     if ( $cgi->param( 'nav_search' ) )
  93     {
  94         if ( $cgi->param( 'nav_search' ) =~ /([0-9,]+)[ -]([0-9,]+)/ )
  95         {
  96             $cookie->{ 'NAV_START' } = $1;
  97             $cookie->{ 'NAV_END' }   = $2;
  98         }
  99         else
 100         {
 101             $cookie->{ 'SEARCH' } = $cgi->param( 'nav_search' );
 102
 103             $cgi->param( 'page', 'search' );
 104         }
 105     }
 106
 107     $cookie->{ 'SCRIPT' }          = Maasha::Common::get_scriptname();
 108     $cookie->{ 'DATA_DIR' }        = "Data";
 109     $cookie->{ 'SESSION_DIR' }     = "Sessions";
 110     $cookie->{ 'LIST_PAGES' }      = [ qw( clade genome assembly contig browse ) ];
 111
 112     $cookie->{ 'USER' }            = $cgi->param( 'user' ) || '';
 113     $cookie->{ 'PASSWORD' }        = $cgi->param( 'password' );
 114     $cookie->{ 'SESSION_ID' }      = $cgi->param( 'session_id' );
 115
 116     cookie_session( $cookie );
 117     cookie_login( $cookie );
 118
 119     $cookie->{ 'PAGE' }          ||= $cgi->param( 'page' )     || 'login';
 120     $cookie->{ 'CLADE' }           = $cgi->param( 'clade' )    || '';
 121     $cookie->{ 'GENOME' }          = $cgi->param( 'genome' )   || '';
 122     $cookie->{ 'ASSEMBLY' }        = $cgi->param( 'assembly' ) || '';
 123     $cookie->{ 'CONTIG' }          = $cgi->param( 'contig' )   || '';
 124     $cookie->{ 'Q_ID' }            = $cgi->param( 'q_id' );
 125     $cookie->{ 'NAV_START' }     ||= $cgi->param( 'nav_start' );
 126     $cookie->{ 'NAV_END' }       ||= $cgi->param( 'nav_end' );
 127     $cookie->{ 'S_BEG' }           = $cgi->param( 's_beg' );
 128     $cookie->{ 'S_END' }           = $cgi->param( 's_end' );
 129     $cookie->{ 'STRAND' }          = $cgi->param( 'strand' );
 130     $cookie->{ 'ZOOM_IN1' }        = $cgi->param( 'zoom_in1' );
 131     $cookie->{ 'ZOOM_IN2' }        = $cgi->param( 'zoom_in2' );
 132     $cookie->{ 'ZOOM_IN3' }        = $cgi->param( 'zoom_in3' );
 133     $cookie->{ 'ZOOM_OUT1' }       = $cgi->param( 'zoom_out1' );
 134     $cookie->{ 'ZOOM_OUT2' }       = $cgi->param( 'zoom_out2' );
 135     $cookie->{ 'ZOOM_OUT3' }       = $cgi->param( 'zoom_out3' );
 136     $cookie->{ 'MOVE_LEFT1' }      = $cgi->param( 'move_left1' );
 137     $cookie->{ 'MOVE_LEFT2' }      = $cgi->param( 'move_left2' );
 138     $cookie->{ 'MOVE_LEFT3' }      = $cgi->param( 'move_left3' );
 139     $cookie->{ 'MOVE_RIGHT1' }     = $cgi->param( 'move_right1' );
 140     $cookie->{ 'MOVE_RIGHT2' }     = $cgi->param( 'move_right2' );
 141     $cookie->{ 'MOVE_RIGHT3' }     = $cgi->param( 'move_right3' );
 142
 143     $cookie->{ 'IMG_WIDTH' }       = 1200;
 144     $cookie->{ 'IMG_HEIGHT' }      = 800;
 145     $cookie->{ 'TRACK_OFFSET' }    = 20;
 146     $cookie->{ 'TRACK_SPACE' }     = 20;
 147     $cookie->{ 'RULER_FONT_SIZE' } = 10;
 148     $cookie->{ 'RULER_COLOR' }     = [ 0, 0, 0 ];
 149     $cookie->{ 'SEQ_FONT_SIZE' }   = 10;
 150     $cookie->{ 'SEQ_COLOR' }       = [ 0, 0, 0, ];
 151     $cookie->{ 'FEAT_WIDTH' }      = 5;
 152     $cookie->{ 'FEAT_COLOR' }      = [ 0, 0, 0 ];
 153     $cookie->{ 'FEAT_MAX' }        = 5000;
 154
 155     $path = "$cookie->{ 'DATA_DIR' }/Users";
 156
 157     $cookie->{ 'LIST_USER' }       = Maasha::Filesys::ls_dirs_base( $path ) if -d $path;
 158
 159     $path .= "/$cookie->{ 'USER' }";
 160
 161     $cookie->{ 'LIST_CLADE' }      = Maasha::Filesys::ls_dirs_base( $path ) if -d $path;
 162
 163     $path .= "/$cookie->{ 'CLADE' }";
 164
 165     $cookie->{ 'LIST_GENOME' }     = Maasha::Filesys::ls_dirs_base( $path ) if -d $path;
 166
 167     $path .= "/$cookie->{ 'GENOME' }";
 168
 169     $cookie->{ 'LIST_ASSEMBLY' }   = Maasha::Filesys::ls_dirs_base( $path ) if -d $path;
 170
 171     $path .= "/$cookie->{ 'ASSEMBLY' }";
 172
 173     $cookie->{ 'LIST_CONTIG' }     = Maasha::Filesys::ls_dirs_base( $path ) if -d $path;
 174
 175     if ( $cookie->{ 'CONTIG' } )
 176     {
 177         cookie_start( $cookie );
 178         cookie_end( $cookie );
 179         cookie_zoom( $cookie );
 180         cookie_move( $cookie );
 181     }
 182
 183     $cookie->{ 'STRAND' } = '+' if defined $cookie->{ 'STRAND' } and $cookie->{ 'STRAND' } eq ' ';   # FIXME ugly HTML fix
 184
 185     return wantarray ? %{ $cookie } : $cookie;
 186 }
 187
 188
 189 sub cookie_session
 190 {
 191     # Martin A. Hansen, December 2009.
 192
 193     # Check cookie information against session information.
 194
 195     my ( $cookie,   # cookie hash
 196        ) = @_;
 197
 198     # Returns nothing.
 199
 200     my ( $session );
 201
 202     $session = Maasha::BGB::Session::session_restore( "$cookie->{ 'SESSION_DIR' }/sessions.txt" );
 203
 204     # if ( $cookie->{ 'SESSION_ID' } )
 205     # {
 206     #     if ( $cookie->{ 'SESSION_ID' } ne $ENV{ 'SSL_SESSION_ID' } ) {
 207     #         $cookie->{ 'PAGE' } = 'login';
 208     #         print STDERR "HER1"; # DEBUG
 209     #     }
 210     # }
 211     # else
 212     # {
 213     #     $cookie->{ 'PAGE' } = 'login';
 214     #
 215     #     print STDERR "HER2"; # DEBUG
 216     # }
 217
 218     if ( exists $session->{ $cookie->{ 'USER' } } and $cookie->{ 'SESSION_ID' } )
 219     {
 220         if ( $session->{ $cookie->{ 'USER' } }->{ 'SESSION_ID' } ne $cookie->{ 'SESSION_ID' } ) {
 221             $cookie->{ 'PAGE' } = 'login';
 222             print STDERR "HER3"; # DEBUG
 223         }
 224     }
 225     else
 226     {
 227         $cookie->{ 'PAGE' } = 'login';
 228         print STDERR "HER4"; # DEBUG
 229         print STDERR "NO COOKIE SESSION ID\n" if not $cookie->{ 'SESSION_ID' }; # DEBUG
 230         print STDERR "NO COOKIE SESSION ID\n" if not $cookie->{ 'USER' }; # DEBUG
 231         print STDERR "NO SESSION USER\n"      if not exists $session->{ $cookie->{ 'USER' } }; # DEBUG
 232     }
 233 }
 234
 235
 236 sub cookie_login
 237 {
 238     # Martin A. Hansen, December 2009.
 239
 240     # Check a user and password from CGI against the password file and
 241     # set the session ID, if found, in the cookie.
 242
 243     my ( $cookie,   # cookie hash
 244        ) = @_;
 245
 246     # Returns nothing.
 247
 248     my ( $session );
 249
 250     if ( $cookie->{ 'USER' } and $cookie->{ 'PASSWORD' } )
 251     {
 252         $session = Maasha::BGB::Session::session_restore( "$cookie->{ 'SESSION_DIR' }/sessions.txt" );
 253
 254         if ( exists $session->{ $cookie->{ 'USER' } } and
 255              $session->{ $cookie->{ 'USER' } }->{ 'PASSWORD' } eq Digest::MD5::md5_hex( $cookie->{ 'PASSWORD' } ) )
 256         {
 257             $session->{ $cookie->{ 'USER' } }->{ 'SESSION_ID' } ||= Maasha::BGB::Session::session_new();
 258             # $session->{ $cookie->{ 'USER' } }->{ 'SESSION_ID' }   = $ENV{ 'SSL_SESSION_ID' };
 259             $session->{ $cookie->{ 'USER' } }->{ 'TIME' }         = Maasha::Common::time_stamp();
 260
 261             $cookie->{ 'SESSION_ID' } = $session->{ $cookie->{ 'USER' } }->{ 'SESSION_ID' };
 262             $cookie->{ 'LOGIN' }      = "OK";
 263             $cookie->{ 'PAGE' }       = 'clade';
 264
 265             Maasha::BGB::Session::session_store( "$cookie->{ 'SESSION_DIR' }/sessions.txt", $session );
 266         }
 267         else
 268         {
 269             $cookie->{ 'LOGIN' } = "ERROR";
 270         }
 271     }
 272 }
 273
 274
 275 sub cookie_start
 276 {
 277     # Martin A. Hansen, November 2009.
 278
 279     # Decommify the cookie value for NAV_START and adjust it to
 280     # to prevent negative values.
 281
 282     my ( $cookie,   # cookie hash
 283        ) = @_;
 284
 285     # Returns nothing.
 286
 287     if ( defined $cookie->{ 'NAV_START' } )
 288     {
 289         $cookie->{ 'NAV_START' } =~ tr/,//d;
 290         $cookie->{ 'NAV_START' } = 0 if $cookie->{ 'NAV_START' } < 0;
 291     }
 292     else
 293     {
 294         $cookie->{ 'NAV_START' } = 0;
 295     }
 296 }
 297
 298
 299 sub cookie_end
 300 {
 301     # Martin A. Hansen, November 2009.
 302
 303     # Decommify the cookie value for NAV_END and adjust it to prevent
 304     # overshooting the max value for the contig size as determined
 305     # from the cookie.
 306
 307     my ( $cookie,   # cookie hash
 308        ) = @_;
 309
 310     # Returns nothing.
 311
 312     my ( $max );
 313
 314     $max = Maasha::Filesys::file_size( Maasha::BGB::Track::path_seq( $cookie ) );
 315
 316     if ( defined $cookie->{ 'NAV_END' } )
 317     {
 318         $cookie->{ 'NAV_END' } =~ tr/,//d;
 319         $cookie->{ 'NAV_END' } = $max if $cookie->{ 'NAV_END' } > $max;
 320     }
 321     else
 322     {
 323         $cookie->{ 'NAV_END' } = $max;
 324     }
 325 }
 326
 327
 328 sub cookie_zoom
 329 {
 330     # Martin A. Hansen, November 2009.
 331
 332     # Adjust the cookie values for NAV_START and NAV_END based
 333     # on cookie ZOOM values.
 334
 335     my ( $cookie,   # cookie hash
 336        ) = @_;
 337
 338     # Returns nothing.
 339
 340     my ( $max, $dist, $new_dist, $dist_diff );
 341
 342     $max = Maasha::Filesys::file_size( Maasha::BGB::Track::path_seq( $cookie ) );
 343
 344     $dist = $cookie->{ 'NAV_END' } - $cookie->{ 'NAV_START' };
 345
 346     if ( defined $cookie->{ 'ZOOM_IN1' } ) {
 347         $new_dist = $dist / 1.5;
 348     } elsif ( defined $cookie->{ 'ZOOM_IN2' } ) {
 349         $new_dist = $dist / 3;
 350     } elsif ( defined $cookie->{ 'ZOOM_IN3' } ) {
 351         $new_dist = $dist / 10;
 352     } elsif ( defined $cookie->{ 'ZOOM_OUT1' } ) {
 353         $new_dist = $dist * 1.5;
 354     } elsif ( defined $cookie->{ 'ZOOM_OUT2' } ) {
 355         $new_dist = $dist * 3;
 356     } elsif ( defined $cookie->{ 'ZOOM_OUT3' } ) {
 357         $new_dist = $dist * 10;
 358     }
 359
 360     if ( $new_dist )
 361     {
 362         $dist_diff = $dist - $new_dist;
 363
 364         $cookie->{ 'NAV_START' } = int( $cookie->{ 'NAV_START' } + ( $dist_diff / 2 ) );
 365         $cookie->{ 'NAV_END' }   = int( $cookie->{ 'NAV_END' }   - ( $dist_diff / 2 ) );
 366
 367         $cookie->{ 'NAV_START' } = 0    if $cookie->{ 'NAV_START' } < 0;
 368         $cookie->{ 'NAV_END' }   = $max if $cookie->{ 'NAV_END' } > $max;
 369     }
 370 }
 371
 372
 373 sub cookie_move
 374 {
 375     # Martin A. Hansen, November 2009.
 376
 377     # Adjust the cookie values for NAV_START and NAV_END based
 378     # on cookie MOVE values.
 379
 380     my ( $cookie,   # cookie hash
 381        ) = @_;
 382
 383     my ( $max, $dist, $shift, $new_start, $new_end );
 384
 385     $max = Maasha::Filesys::file_size( Maasha::BGB::Track::path_seq( $cookie ) );
 386
 387     $dist = $cookie->{ 'NAV_END' } - $cookie->{ 'NAV_START' };
 388
 389     if ( defined $cookie->{ 'MOVE_LEFT1' } ) {
 390         $shift = -1 * $dist * 0.10;
 391     } elsif ( defined $cookie->{ 'MOVE_LEFT2' } ) {
 392         $shift = -1 * $dist * 0.475;
 393     } elsif ( defined $cookie->{ 'MOVE_LEFT3' } ) {
 394         $shift = -1 * $dist * 0.95;
 395     } elsif ( defined $cookie->{ 'MOVE_RIGHT1' } ) {
 396         $shift = $dist * 0.10;
 397     } elsif ( defined $cookie->{ 'MOVE_RIGHT2' } ) {
 398         $shift = $dist * 0.475;
 399     } elsif ( defined $cookie->{ 'MOVE_RIGHT3' } ) {
 400         $shift = $dist * 0.95;
 401     }
 402
 403     if ( $shift )
 404     {
 405         $new_start = int( $cookie->{ 'NAV_START' } + $shift );
 406         $new_end   = int( $cookie->{ 'NAV_END' }   + $shift );
 407
 408         if ( $new_start > 0 and $new_end < $max )
 409         {
 410             $cookie->{ 'NAV_START' } = $new_start;
 411             $cookie->{ 'NAV_END' }   = $new_end;
 412         }
 413     }
 414 }
 415
 416
 417 sub cookie_href
 418 {
 419     # Martin A. Hansen, November 2009.
 420
 421     # Returns the href for a taxonomy path terminated at a given
 422     # page using information stored in a cookie.
 423
 424     my ( $cookie,   # cookie hash
 425          $page,     # page
 426        ) = @_;
 427
 428     # Returns a string.
 429
 430     my ( @href_list, %href_hash, $href );
 431
 432     $href_hash{ "user" } = $cookie->{ 'USER' } if $cookie->{ 'USER' };
 433
 434     while ( 1 )
 435     {
 436         $href_hash{ "clade" } = $cookie->{ 'CLADE' }        if $cookie->{ 'CLADE' };
 437         last if $page eq 'clade';
 438         $href_hash{ "genome" } = $cookie->{ 'GENOME' }      if $cookie->{ 'GENOME' };
 439         last if $page eq 'genome';
 440         $href_hash{ "assembly" } = $cookie->{ 'ASSEMBLY' }  if $cookie->{ 'ASSEMBLY' };
 441         last if $page eq 'assembly';
 442         $href_hash{ "contig" } = $cookie->{ 'CONTIG' }      if $cookie->{ 'CONTIG' };
 443         last if $page eq 'contig';
 444         last;
 445     }
 446
 447     if ( defined $cookie->{ 'NAV_START' } and defined $cookie->{ 'NAV_END' } and $page !~ /clade|genome|assembly|contig|browse/ ) {
 448         $href_hash{ "nav_search" } = "$cookie->{ 'NAV_START' }-$cookie->{ 'NAV_END' }";
 449     }
 450
 451     $href_hash{ "s_beg" }      = $cookie->{ 'S_BEG' }      if defined $cookie->{ 'S_BEG' };
 452     $href_hash{ "s_end" }      = $cookie->{ 'S_END' }      if defined $cookie->{ 'S_END' };
 453     $href_hash{ "q_id" }       = $cookie->{ 'Q_ID' }       if defined $cookie->{ 'Q_ID' };
 454     $href_hash{ "strand" }     = $cookie->{ 'STRAND' }     if defined $cookie->{ 'STRAND' };
 455     $href_hash{ "session_id" } = $cookie->{ 'SESSION_ID' } if defined $cookie->{ 'SESSION_ID' };
 456
 457     push @href_list, "$cookie->{ 'SCRIPT' }?page=$page";
 458
 459     foreach $href ( keys %href_hash ) {
 460         push @href_list, "$href=$href_hash{ $href }";
 461     }
 462
 463     return join "&", @href_list;
 464 }
 465
 466
 467 sub cookie_page_next
 468 {
 469     # Martin A. Hansen, November 2009.
 470
 471     # Returns the next page in the taxonomy path.
 472
 473     my ( $cookie,   # cookie hash
 474        ) = @_;
 475
 476     # Returns a string.
 477
 478     my ( $i );
 479
 480     for ( $i = 0; $i < @{ $cookie->{ 'LIST_PAGES' } }; $i++ ) {
 481         last if $cookie->{ 'PAGE' } eq $cookie->{ 'LIST_PAGES' }->[ $i ];
 482     }
 483
 484     return $cookie->{ 'LIST_PAGES' }->[ $i + 1 ];
 485 }
 486
 487
 488 # >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> PAGES <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
 489
 490
 491 sub page
 492 {
 493     # Martin A. Hansen, November 2009.
 494
 495     # Determines what page to render based on
 496     # the cookie's PAGE setting.
 497
 498     my ( $cookie,   # cookie hash
 499        ) = @_;
 500
 501     # Returns a list.
 502
 503     my ( @html );
 504
 505     if ( $cookie->{ 'PAGE' } eq 'login' ) {
 506         push @html, page_login( $cookie );
 507     } elsif ( $cookie->{ 'PAGE' } eq 'search' ) {
 508         push @html, page_search( $cookie );
 509     } elsif ( $cookie->{ 'PAGE' } eq 'browse' ) {
 510         push @html, page_browse( $cookie );
 511     } elsif ( $cookie->{ 'PAGE' } eq 'dna' ) {
 512         push @html, page_dna( $cookie );
 513     } elsif ( $cookie->{ 'PAGE' } eq 'export' ) {
 514         push @html, page_export( $cookie );
 515     } else {
 516         push @html, page_taxonomy( $cookie );
 517     }
 518
 519     if ( $cookie->{ 'SESSION_ID' } ) {
 520         push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "session_id", value => "$cookie->{ 'SESSION_ID' }" ) );
 521     }
 522
 523     return wantarray ? @html : \@html;
 524 }
 525
 526
 527 sub page_login
 528 {
 529     # Martin A. Hansen, December 2009.
 530
 531     # Renders the login page.
 532
 533     my ( $cookie,
 534        ) = @_;
 535
 536     # Returns a list.
 537
 538     my ( @html );
 539
 540     push @html, section_login( $cookie );
 541
 542     return wantarray ? @html : \@html;
 543 }
 544
 545
 546 sub page_search
 547 {
 548     # Martin A. Hansen, December 2009.
 549
 550     # Renders the search page.
 551
 552     my ( $cookie,
 553        ) = @_;
 554
 555     # Returns a list.
 556
 557     my ( @html );
 558
 559     push @html, section_taxonomy_table( $cookie );
 560     push @html, section_search( $cookie );
 561
 562     return wantarray ? @html : \@html;
 563 }
 564
 565
 566 sub page_browse
 567 {
 568     # Martin A. Hansen, November 2009.
 569
 570     # Renders the browse page.
 571
 572     my ( $cookie,
 573        ) = @_;
 574
 575     # Returns a list.
 576
 577     my ( @html );
 578
 579     push @html, section_taxonomy_table( $cookie );
 580     push @html, section_navigate( $cookie );
 581     push @html, section_browse( $cookie );
 582     push @html, section_permalink( $cookie );
 583
 584     return wantarray ? @html : \@html;
 585 }
 586
 587
 588 sub page_dna
 589 {
 590     # Martin A. Hansen, November 2009.
 591
 592     # Renders the DNA page.
 593
 594     my ( $cookie,
 595        ) = @_;
 596
 597     # Returns a list.
 598
 599     my ( @html );
 600
 601     push @html, section_taxonomy_table( $cookie );
 602     push @html, section_dna( $cookie );
 603
 604     return wantarray ? @html : \@html;
 605 }
 606
 607
 608 sub page_export
 609 {
 610     # Martin A. Hansen, November 2009.
 611
 612     # Renders the export page.
 613
 614     my ( $cookie,
 615        ) = @_;
 616
 617     # Returns a list.
 618
 619     my ( @html );
 620
 621     push @html, section_taxonomy_table( $cookie );
 622     push @html, section_export( $cookie );
 623
 624     return wantarray ? @html : \@html;
 625 }
 626
 627
 628 sub page_taxonomy
 629 {
 630     # Martin A. Hansen, November 2009.
 631
 632     # Renders the browse page.
 633
 634     my ( $cookie,   # cookie hash
 635        ) = @_;
 636
 637     # Returns a list.
 638
 639     my ( @html );
 640
 641     push @html, section_taxonomy_table( $cookie );
 642     push @html, section_taxonomy_select( $cookie );
 643
 644     return wantarray ? @html : \@html;
 645 }
 646
 647
 648 # >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> SECTIONS <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
 649
 650
 651 sub section_login
 652 {
 653     # Martin A. Hansen, December 2009.
 654
 655     # Returns a HTML section with a login menu.
 656
 657     my ( $cookie,   # cookie hash
 658        ) = @_;
 659
 660     # Returns a list.
 661
 662     my ( $user, $password, $login, @html );
 663
 664     $user     = Maasha::XHTML::text( name => "user", value => "", size => 20 );
 665     $password = Maasha::XHTML::password( name => "password", value => "", size => 20 );
 666     $login    = Maasha::XHTML::submit( name => "login_submit", value => "Login" );
 667
 668     push @html, Maasha::XHTML::h2( txt => "Login", class => 'center' );
 669
 670     push @html, Maasha::XHTML::table_beg( summary => "Login table", align => 'center' );
 671     push @html, Maasha::XHTML::table_row_simple( tr => [ "User:", $user ] );
 672     push @html, Maasha::XHTML::table_row_simple( tr => [ "Password:", $password ] );
 673     push @html, Maasha::XHTML::table_row_simple( tr => [ "", $login ] );
 674     push @html, Maasha::XHTML::table_end;
 675
 676     if ( $cookie->{ 'LOGIN' } and $cookie->{ 'LOGIN' } eq 'ERROR' ) {
 677         push @html, Maasha::XHTML::h3( txt => "Bad user or password - please retry", class => 'error' );
 678     }
 679
 680     return wantarray ? @html : \@html;
 681 }
 682
 683
 684 sub section_taxonomy_table
 685 {
 686     # Martin A. Hansen, November 2009.
 687
 688     # Returns a HTML section with a taxonomy table
 689     # showing the location in the taxonomy and with
 690     # links to browse the taxonomy.
 691
 692     my ( $cookie,   # cookie hash
 693        ) = @_;
 694
 695     # Returns a list.
 696
 697     my ( $page, @row, @html, $href, $txt );
 698
 699     foreach $page ( @{ $cookie->{ 'LIST_PAGES' } } )
 700     {
 701         last if $page eq $cookie->{ 'PAGE' } or $page eq 'browse';
 702
 703         $href = cookie_href( $cookie, $page );
 704
 705         $txt = ": $cookie->{ uc $page }";
 706
 707         push @row, Maasha::XHTML::ln( txt => $page, href => $href, class => 'inline' );
 708         push @row, Maasha::XHTML::p(  txt => $txt, class => 'inline' );
 709     }
 710
 711     push @html, Maasha::XHTML::table_beg( summary => "Taxonomy table", align => 'center', cellpadding => '5px' );
 712     push @html, Maasha::XHTML::table_row_simple( tr => [ join( "\n", @row ) ], align => 'center' );
 713     push @html, Maasha::XHTML::table_end;
 714
 715     return wantarray ? @html : \@html;
 716 }
 717
 718
 719 sub section_taxonomy_select
 720 {
 721     # Martin A. Hansen, November 2009.
 722
 723     # Returns a HTML section with selection choices
 724     # for navigating the taxonomy tree.
 725
 726     my ( $cookie,   # cookie hash
 727        ) = @_;
 728
 729     # Returns a list.
 730
 731     my ( $list, @html, $item, $href );
 732
 733     $list = "LIST_" . uc $cookie->{ 'PAGE' };
 734
 735     push @html, Maasha::XHTML::h2( txt => "Select $cookie->{ 'PAGE' }", class => 'center' );
 736
 737     push @html, Maasha::XHTML::table_beg( summary => "Taxonomy select table", align => 'center', cellpadding => '5px' );
 738
 739     foreach $item ( @{ $cookie->{ $list } } )
 740     {
 741         $cookie->{ uc $cookie->{ 'PAGE' } } = $item;
 742
 743         $href = cookie_href( $cookie, cookie_page_next( $cookie ) );
 744
 745         push @html, Maasha::XHTML::table_row_simple( tr => [ Maasha::XHTML::ln( txt => $item, href => $href ) ] );
 746     }
 747
 748     push @html, Maasha::XHTML::table_end;
 749
 750     return wantarray ? @html : \@html;
 751 }
 752
 753
 754 sub section_navigate
 755 {
 756     # Martin A. Hansen, November 2009.
 757
 758     # Returns a HTML section for navigating in the browser window.
 759
 760     my ( $cookie,   # cookie hash
 761        ) = @_;
 762
 763     # Returns a list.
 764
 765     my ( @html, $nav_val );
 766
 767     $nav_val = Maasha::Calc::commify( $cookie->{ 'NAV_START' } ) . "-" . Maasha::Calc::commify( $cookie->{ 'NAV_END' } );
 768
 769     push @html, Maasha::XHTML::table_beg( summary => "Navigation table", align => 'center' );
 770     push @html, Maasha::XHTML::table_row_simple( tr => [
 771         "Position or search term:",
 772         Maasha::XHTML::text( name => "nav_search", value => $nav_val, size => 30 ),
 773         Maasha::XHTML::submit( name => "nav_submit", value => "Submit" ),
 774     ] );
 775     push @html, Maasha::XHTML::table_end;
 776
 777     push @html, Maasha::XHTML::table_beg( summary => "Zoom table", align => 'center' );
 778     push @html, Maasha::XHTML::table_row_simple( tr => [
 779         Maasha::XHTML::p( txt => 'Move:' ),
 780         Maasha::XHTML::submit( name => "move_left3",  value => "<<<", title => "move 95% to the left" ),
 781         Maasha::XHTML::submit( name => "move_left2",  value => "<<",  title => "move 47.5% to the left" ),
 782         Maasha::XHTML::submit( name => "move_left1",  value => "<",   title => "move 10% to the left" ),
 783         Maasha::XHTML::submit( name => "move_right1", value => ">",   title => "move 10% to the rigth" ),
 784         Maasha::XHTML::submit( name => "move_right2", value => ">>",  title => "move 47.5% to the rigth" ),
 785         Maasha::XHTML::submit( name => "move_right3", value => ">>>", title => "move 95% to the right" ),
 786         Maasha::XHTML::p( txt => 'Zoom in:' ),
 787         Maasha::XHTML::submit( name => "zoom_in1", value => "1.5x" ),
 788         Maasha::XHTML::submit( name => "zoom_in2", value => "3x" ),
 789         Maasha::XHTML::submit( name => "zoom_in3", value => "10x" ),
 790         Maasha::XHTML::p( txt => 'Zoom out:' ),
 791         Maasha::XHTML::submit( name => "zoom_out1", value => "1.5x" ),
 792         Maasha::XHTML::submit( name => "zoom_out2", value => "3x" ),
 793         Maasha::XHTML::submit( name => "zoom_out3", value => "10x" ),
 794     ] );
 795     push @html, Maasha::XHTML::table_end;
 796
 797     push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "page",     value => "browse" ) );
 798     push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "user",     value => "$cookie->{ 'USER' }" ) );
 799     push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "clade",    value => "$cookie->{ 'CLADE' }" ) );
 800     push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "genome",   value => "$cookie->{ 'GENOME' }" ) );
 801     push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "assembly", value => "$cookie->{ 'ASSEMBLY' }" ) );
 802     push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "contig",   value => "$cookie->{ 'CONTIG' }" ) );
 803
 804     return wantarray ? @html : \@html;
 805 }
 806
 807
 808 sub section_browse
 809 {
 810     my ( $cookie,
 811        ) = @_;
 812
 813     # Returns a list.
 814
 815     my ( @tracks, $i, @features, $feat, $elem, $surface, $cr, $png_data, @html, @img );
 816
 817     push @features, [ Maasha::BGB::Track::track_ruler( $cookie ) ];
 818     push @features, [ Maasha::BGB::Track::track_seq( $cookie ) ];
 819
 820     @tracks = Maasha::BGB::Track::path_tracks( $cookie );
 821
 822     for ( $i = 0; $i < @tracks; $i++ )
 823     {
 824         $cookie->{ 'FEAT_COLOR' } = Maasha::BGB::Draw::palette( $i );
 825
 826         push @features, [ Maasha::BGB::Track::track_feature( $tracks[ $i ], $cookie ) ];
 827     }
 828
 829     $surface = Cairo::ImageSurface->create( 'argb32', $cookie->{ 'IMG_WIDTH' }, $cookie->{ 'TRACK_OFFSET' } );
 830     $cr      = Cairo::Context->create( $surface );
 831
 832     $cr->rectangle ( 0, 0, $cookie->{ 'IMG_WIDTH' },  $cookie->{ 'TRACK_OFFSET' } );
 833     $cr->set_source_rgb ( 1, 1, 1 );
 834     $cr->fill;
 835
 836     foreach $feat ( @features ) {
 837         Maasha::BGB::Draw::draw_feature( $cr, $feat ) if $feat;
 838     }
 839
 840     $png_data = Maasha::BGB::Draw::base64_png( $surface );
 841
 842     push @img, Maasha::XHTML::img(
 843         src    => "data:image/png;base64,$png_data",
 844         alt    => "Browser Tracks",
 845         height => $cookie->{ 'TRACK_OFFSET' },
 846         width  => $cookie->{ 'IMG_WIDTH' },
 847         id     => "browser_map",
 848         usemap => "#browser_map"
 849     );
 850
 851     push @img, Maasha::XHTML::map_beg( name => "browser_map", id => "browser_map" );
 852
 853     foreach $feat ( @features )
 854     {
 855         foreach $elem ( @{ $feat } )
 856         {
 857             next if $elem->{ 'type' } eq 'text';
 858
 859             #$elem->{ 'strand' } = '&#43' if $elem->{ 'strand' } eq '+';
 860
 861             $cookie->{ 'Q_ID' }   = $elem->{ 'q_id' };
 862             $cookie->{ 'S_BEG' }  = $elem->{ 's_beg' };
 863             $cookie->{ 'S_END' }  = $elem->{ 's_end' };
 864             $cookie->{ 'STRAND' } = $elem->{ 'strand' };
 865
 866             push @img, Maasha::XHTML::area(
 867                 href   => cookie_href( $cookie, "export" ),
 868                 # href   => cookie_href( $cookie, "export" ) . "&q_id=$elem->{ 'q_id' }&s_beg=$elem->{ 's_beg' }&s_end=$elem->{ 's_end' }&strand=$elem->{ 'strand' }",
 869                 shape  => "rect",
 870                 coords => "$elem->{ x1 }, $elem->{ y1 }, $elem->{ x2 }, $elem->{ y2 }", title => "$elem->{ 'title' }",
 871             );
 872         }
 873     }
 874
 875     push @img, Maasha::XHTML::map_end();
 876
 877     push @html, Maasha::XHTML::p( txt => join( "\n", @img ) );
 878
 879     @html = Maasha::XHTML::div( txt => join( "\n", @html ), class => 'browse' );
 880
 881     return wantarray ? @html : \@html;
 882 }
 883
 884
 885 sub section_permalink
 886 {
 887     # Martin A. Hansen, December 2009.
 888
 889     # Return HTML with a permanent link to current browser view.
 890
 891     my ( $cookie,   # cookie hash
 892        ) = @_;
 893
 894     # Returns a list.
 895
 896     my ( $href, @html );
 897
 898     $href = join( "&",
 899         "$cookie->{ 'SCRIPT' }?page=browse",
 900         "user=$cookie->{ 'USER' }",
 901         "clade=$cookie->{ 'CLADE' }",
 902         "genome=$cookie->{ 'GENOME' }",
 903         "assembly=$cookie->{ 'ASSEMBLY' }",
 904         "contig=$cookie->{ 'CONTIG' }",
 905         "nav_start=$cookie->{ 'NAV_START' }",
 906         "nav_end=$cookie->{ 'NAV_END' }",
 907         "session_id=$cookie->{ 'SESSION_ID' }",
 908     );
 909
 910     push @html, Maasha::XHTML::p( txt => Maasha::XHTML::ln( txt => "Permalink", href => $href ), class => 'center' );
 911
 912     return wantarray ? @html : \@html;
 913 }
 914
 915
 916 sub section_export
 917 {
 918     # Martin A. Hansen, November 2009.
 919
 920     # Returns a HTML section with export table.
 921
 922     my ( $cookie,   # cookie hash
 923        ) = @_;
 924
 925     # Returns a list.
 926
 927     my ( @row_dna_contig, @html );
 928
 929     push @row_dna_contig, Maasha::XHTML::p( txt => qq(Export Feature: "$cookie->{ 'Q_ID' }" DNA from Contig: ), class => 'inline' );
 930     push @row_dna_contig, Maasha::XHTML::p( txt  => "$cookie->{ 'CONTIG' } Start: ", class => 'inline' );
 931     push @row_dna_contig, Maasha::XHTML::text( name => "s_beg", value => Maasha::Calc::commify( $cookie->{ 'S_BEG' } ), size => 15 );
 932     push @row_dna_contig, Maasha::XHTML::p( txt => "End: ", class => 'inline' );
 933     push @row_dna_contig, Maasha::XHTML::text( name => "s_end", value => Maasha::Calc::commify( $cookie->{ 'S_END' } ), size => 15 );
 934     push @row_dna_contig, Maasha::XHTML::p( txt => "Strand: ", class => 'inline' );
 935     push @row_dna_contig, Maasha::XHTML::menu( name => "strand", options => [ qw( + - ) ], selected => $cookie->{ 'STRAND' } );
 936     push @row_dna_contig, Maasha::XHTML::submit( name => "export", value => "Export", title => "Fetch DNA from this region" );
 937
 938     push @html, Maasha::XHTML::h2( txt => "Export", class => 'center' );
 939     push @html, Maasha::XHTML::table_beg( summary => "Taxonomy select table", align => 'center' );
 940     push @html, Maasha::XHTML::table_row_simple( tr => \@row_dna_contig );
 941     push @html, Maasha::XHTML::table_end;
 942
 943     push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "page", value => "dna" ) );
 944     push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "user",     value => "$cookie->{ 'USER' }" ) );
 945     push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "clade",    value => "$cookie->{ 'CLADE' }" ) );
 946     push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "genome",   value => "$cookie->{ 'GENOME' }" ) );
 947     push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "assembly", value => "$cookie->{ 'ASSEMBLY' }" ) );
 948     push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "contig",   value => "$cookie->{ 'CONTIG' }" ) );
 949
 950     return wantarray ? @html : \@html;
 951 }
 952
 953
 954 sub section_search
 955 {
 956     # Martin A. Hansen, November 2009.
 957
 958     # Returns a HTML section with export table.
 959
 960     my ( $cookie,   # cookie hash
 961        ) = @_;
 962
 963     # Returns a list.
 964
 965     my ( $results, $result, $count, @html, $export, $browse );
 966
 967     $results = Maasha::BGB::Track::search_tracks( $cookie );
 968
 969     $count = scalar @{ $results };
 970
 971     push @html, Maasha::XHTML::h2( txt => "Search", class => 'center' );
 972     push @html, Maasha::XHTML::p( txt => qq(Results for "$cookie->{ 'SEARCH' }": $count), class => 'center' );
 973
 974     if ( $count > 0 )
 975     {
 976         push @html, Maasha::XHTML::table_beg( summary => "Search table", align => 'center', cellpadding => '5px' );
 977         push @html, Maasha::XHTML::table_row_simple( tr => [ qw( S_ID S_BEG S_END Q_ID SCORE STRAND HITS ALIGN BLOCK_COUNT BLOCK_BEGS BLOCK_LENS BLOCK_TYPE) ] );
 978
 979         foreach $result ( @{ $results } )
 980         {
 981             $cookie->{ 'CONTIG' }    = $result->{ 'S_ID' };
 982             $cookie->{ 'NAV_START' } = $result->{ 'S_BEG' };
 983             $cookie->{ 'NAV_END' }   = $result->{ 'S_END' };
 984             $cookie->{ 'S_BEG' }     = $result->{ 'S_BEG' };
 985             $cookie->{ 'S_END' }     = $result->{ 'S_END' };
 986             $cookie->{ 'STRAND' }    = $result->{ 'STRAND' };
 987             $cookie->{ 'Q_ID' }      = $result->{ 'Q_ID' };
 988
 989             $browse = Maasha::XHTML::ln( txt => "browse", href => cookie_href( $cookie, "browse" ) );
 990             $export = Maasha::XHTML::ln( txt => "export", href => cookie_href( $cookie, "export" ) );
 991
 992             push @html, Maasha::XHTML::table_row_advanced(
 993                 tr => [ { td => $result->{ 'S_ID' } },
 994                         { td => $result->{ 'S_BEG' }, align => 'right' },
 995                         { td => $result->{ 'S_END' }, align => 'right' },
 996                         { td => $result->{ 'Q_ID' } },
 997                         { td => $result->{ 'SCORE' }, align => 'right' },
 998                         { td => $result->{ 'STRAND' } },
 999                         { td => $result->{ 'HITS' }, align => 'right' },
1000                         { td => $result->{ 'ALIGN' } },
1001                         { td => $result->{ 'BLOCK_COUNT' }, align => 'right' },
1002                         { td => $result->{ 'BLOCK_BEGS' } },
1003                         { td => $result->{ 'BLOCK_LENS' } },
1004                         { td => $result->{ 'BLOCK_TYPE' } },
1005                         { td => $browse },
1006                         { td => $export },
1007                 ], class => "monospace"
1008             );
1009         }
1010
1011         push @html, Maasha::XHTML::table_end;
1012     }
1013
1014     return wantarray ? @html : \@html;
1015 }
1016
1017
1018 sub section_dna
1019 {
1020     # Martin A. Hansen, November 2009.
1021
1022     # Returns a HTML section with extracted DNA.
1023
1024     my ( $cookie,   # cookie hash
1025        ) = @_;
1026
1027     # Returns a list.
1028
1029     my ( @html, $beg, $end, $seq );
1030
1031     $beg = $cookie->{ 'S_BEG' };
1032     $end = $cookie->{ 'S_END' };
1033     $beg =~ tr/,//d;
1034     $end =~ tr/,//d;
1035
1036     $seq = join ";", ">$cookie->{ 'GENOME' }", $cookie->{ 'ASSEMBLY' }, $cookie->{ 'CONTIG' }, $beg, $end, "$cookie->{ 'STRAND' }\n";
1037     $seq .= Maasha::BGB::Track::dna_get( $cookie );
1038
1039     push @html, Maasha::XHTML::h2( txt => "DNA", class => 'center' );
1040     push @html, Maasha::XHTML::pre( txt => $seq );
1041
1042     return wantarray ? @html : \@html;
1043 }
1044
1045
1046 # >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
1047
1048
1049 __END__