#!/usr/bin/env perl

# Copyright (C) 2006-2009 Martin A. Hansen.

# This program is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License
# as published by the Free Software Foundation; either version 2
# of the License, or (at your option) any later version.

# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.

# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.

# http://www.gnu.org/copyleft/gpl.html

# >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

use strict;
use warnings;

use lib $ENV{ 'BP_PERL' };

use CGI;
use Data::Dumper;
use Digest::MD5;
use Maasha::Common;
use Maasha::Filesys;
use Maasha::Calc;
use Maasha::XHTML;
use Maasha::KISS;
use Maasha::BGB::Session;
use Maasha::BGB::Track;
use Maasha::BGB::Draw;

my ( $cgi, $cookie, @html );

$cgi    = new CGI;
$cookie = cookie_default( $cgi );;

push @html, Maasha::XHTML::html_header(
    cgi_header  => 1,
    title       => "Biopieces Genome Browser",
    css_file    => "bgb.css",
    author      => "Martin A. Hansen, mail\@maasha.dk",
    description => "Biopieces Genome Browser",
    keywords    => [ qw( Biopieces biopiece genome browser viewer bacterium bacteria prokaryote prokaryotes ) ],
    no_cache    => 1,
);

push @html, Maasha::XHTML::h1( txt => "Biopieces Genome Browser", class => 'center' );
push @html, Maasha::XHTML::form_beg( action => $cookie->{ 'SCRIPT' }, method => "post", enctype => "multipart/form-data" );

push @html, page( $cookie );

push @html, Maasha::XHTML::form_end;
push @html, Maasha::XHTML::body_end;
push @html, Maasha::XHTML::html_end;

# push @html, Maasha::XHTML::hdump( [ $cgi->Vars ] );  # DEBUG
# push @html, Maasha::XHTML::hdump( \%ENV );           # DEBUG
# push @html, Maasha::XHTML::hdump( $cookie );         # DEBUG

print "$_\n" foreach @html;


# >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> SUBROUTINES <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<


# >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> COOKIE <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<


sub cookie_default
{
    # Martin A. Hansen, November 2009.

    # Set a cookie with values from the CGI object or defaults.

    my ( $cgi,   # CGI object
       ) = @_;

    # Returns a hash.

    my ( $cookie, $path );

    $cookie = {};

    if ( $cgi->param( 'nav_search' ) )
    {
        if ( $cgi->param( 'nav_search' ) =~ /([0-9,]+)[ -]([0-9,]+)/ )
        {
            $cookie->{ 'NAV_START' } = $1;
            $cookie->{ 'NAV_END' }   = $2;
        }
        else
        {
            $cookie->{ 'SEARCH' } = $cgi->param( 'nav_search' );

            $cgi->param( 'page', 'search' );
        }
    }

    $cookie->{ 'SCRIPT' }          = Maasha::Common::get_scriptname();
    $cookie->{ 'DATA_DIR' }        = "Data";
    $cookie->{ 'SESSION_DIR' }     = "Sessions";
    $cookie->{ 'LIST_PAGES' }      = [ qw( clade genome assembly contig browse ) ];

    $cookie->{ 'USER' }            = $cgi->param( 'user' ) || '';
    $cookie->{ 'PASSWORD' }        = $cgi->param( 'password' );
    $cookie->{ 'SESSION_ID' }      = $cgi->param( 'session_id' );

    cookie_session( $cookie );
    cookie_login( $cookie );

    $cookie->{ 'PAGE' }          ||= $cgi->param( 'page' )     || 'login';
    $cookie->{ 'CLADE' }           = $cgi->param( 'clade' )    || '';
    $cookie->{ 'GENOME' }          = $cgi->param( 'genome' )   || '';
    $cookie->{ 'ASSEMBLY' }        = $cgi->param( 'assembly' ) || '';
    $cookie->{ 'CONTIG' }          = $cgi->param( 'contig' )   || '';
    $cookie->{ 'Q_ID' }            = $cgi->param( 'q_id' );
    $cookie->{ 'NAV_START' }     ||= $cgi->param( 'nav_start' );
    $cookie->{ 'NAV_END' }       ||= $cgi->param( 'nav_end' );
    $cookie->{ 'S_BEG' }           = $cgi->param( 's_beg' );
    $cookie->{ 'S_END' }           = $cgi->param( 's_end' );
    $cookie->{ 'STRAND' }          = $cgi->param( 'strand' );
    $cookie->{ 'ZOOM_IN1' }        = $cgi->param( 'zoom_in1' );
    $cookie->{ 'ZOOM_IN2' }        = $cgi->param( 'zoom_in2' );
    $cookie->{ 'ZOOM_IN3' }        = $cgi->param( 'zoom_in3' );
    $cookie->{ 'ZOOM_OUT1' }       = $cgi->param( 'zoom_out1' );
    $cookie->{ 'ZOOM_OUT2' }       = $cgi->param( 'zoom_out2' );
    $cookie->{ 'ZOOM_OUT3' }       = $cgi->param( 'zoom_out3' );
    $cookie->{ 'MOVE_LEFT1' }      = $cgi->param( 'move_left1' );
    $cookie->{ 'MOVE_LEFT2' }      = $cgi->param( 'move_left2' );
    $cookie->{ 'MOVE_LEFT3' }      = $cgi->param( 'move_left3' );
    $cookie->{ 'MOVE_RIGHT1' }     = $cgi->param( 'move_right1' );
    $cookie->{ 'MOVE_RIGHT2' }     = $cgi->param( 'move_right2' );
    $cookie->{ 'MOVE_RIGHT3' }     = $cgi->param( 'move_right3' );

    $cookie->{ 'IMG_WIDTH' }       = 1200;
    $cookie->{ 'IMG_HEIGHT' }      = 800;
    $cookie->{ 'TRACK_OFFSET' }    = 20;
    $cookie->{ 'TRACK_SPACE' }     = 20;
    $cookie->{ 'RULER_FONT_SIZE' } = 10;
    $cookie->{ 'RULER_COLOR' }     = [ 0, 0, 0 ];
    $cookie->{ 'SEQ_FONT_SIZE' }   = 10;
    $cookie->{ 'SEQ_COLOR' }       = [ 0, 0, 0, ];
    $cookie->{ 'FEAT_WIDTH' }      = 5;
    $cookie->{ 'FEAT_COLOR' }      = [ 0, 0, 0 ];
    $cookie->{ 'FEAT_MAX' }        = 5000;

    $path = "$cookie->{ 'DATA_DIR' }/Users";

    $cookie->{ 'LIST_USER' }       = Maasha::Filesys::ls_dirs_base( $path ) if -d $path;

    $path .= "/$cookie->{ 'USER' }";

    $cookie->{ 'LIST_CLADE' }      = Maasha::Filesys::ls_dirs_base( $path ) if -d $path;

    $path .= "/$cookie->{ 'CLADE' }";

    $cookie->{ 'LIST_GENOME' }     = Maasha::Filesys::ls_dirs_base( $path ) if -d $path;

    $path .= "/$cookie->{ 'GENOME' }";

    $cookie->{ 'LIST_ASSEMBLY' }   = Maasha::Filesys::ls_dirs_base( $path ) if -d $path;

    $path .= "/$cookie->{ 'ASSEMBLY' }";

    $cookie->{ 'LIST_CONTIG' }     = Maasha::Filesys::ls_dirs_base( $path ) if -d $path;

    if ( $cookie->{ 'CONTIG' } )
    {
        cookie_start( $cookie );
        cookie_end( $cookie );
        cookie_zoom( $cookie );
        cookie_move( $cookie );
    }

    $cookie->{ 'STRAND' } = '+' if defined $cookie->{ 'STRAND' } and $cookie->{ 'STRAND' } eq ' ';   # FIXME ugly HTML fix

    return wantarray ? %{ $cookie } : $cookie;
}


sub cookie_session
{
    # Martin A. Hansen, December 2009.

    # Check cookie information against session information.

    my ( $cookie,   # cookie hash
       ) = @_;

    # Returns nothing.

    my ( $session );

    $session = Maasha::BGB::Session::session_restore( "$cookie->{ 'SESSION_DIR' }/sessions.txt" );

    # if ( $cookie->{ 'SESSION_ID' } )
    # {
    #     if ( $cookie->{ 'SESSION_ID' } ne $ENV{ 'SSL_SESSION_ID' } ) {
    #         $cookie->{ 'PAGE' } = 'login';
    #         print STDERR "HER1"; # DEBUG
    #     }
    # }
    # else
    # {
    #     $cookie->{ 'PAGE' } = 'login';
    # 
    #     print STDERR "HER2"; # DEBUG
    # }

    if ( exists $session->{ $cookie->{ 'USER' } } and $cookie->{ 'SESSION_ID' } )
    {
        if ( $session->{ $cookie->{ 'USER' } }->{ 'SESSION_ID' } ne $cookie->{ 'SESSION_ID' } ) {
            $cookie->{ 'PAGE' } = 'login';
            print STDERR "HER3"; # DEBUG
        }
    }
    else
    {
        $cookie->{ 'PAGE' } = 'login';
        print STDERR "HER4"; # DEBUG
        print STDERR "NO COOKIE SESSION ID\n" if not $cookie->{ 'SESSION_ID' }; # DEBUG
        print STDERR "NO COOKIE SESSION ID\n" if not $cookie->{ 'USER' }; # DEBUG
        print STDERR "NO SESSION USER\n"      if not exists $session->{ $cookie->{ 'USER' } }; # DEBUG
    }
}


sub cookie_login
{
    # Martin A. Hansen, December 2009.

    # Check a user and password from CGI against the password file and
    # set the session ID, if found, in the cookie.

    my ( $cookie,   # cookie hash
       ) = @_;

    # Returns nothing.

    my ( $session );

    if ( $cookie->{ 'USER' } and $cookie->{ 'PASSWORD' } )
    {
        $session = Maasha::BGB::Session::session_restore( "$cookie->{ 'SESSION_DIR' }/sessions.txt" );
    
        if ( exists $session->{ $cookie->{ 'USER' } } and
             $session->{ $cookie->{ 'USER' } }->{ 'PASSWORD' } eq Digest::MD5::md5_hex( $cookie->{ 'PASSWORD' } ) )
        {
            $session->{ $cookie->{ 'USER' } }->{ 'SESSION_ID' } ||= Maasha::BGB::Session::session_new();
            # $session->{ $cookie->{ 'USER' } }->{ 'SESSION_ID' }   = $ENV{ 'SSL_SESSION_ID' };
            $session->{ $cookie->{ 'USER' } }->{ 'TIME' }         = Maasha::Common::time_stamp();

            $cookie->{ 'SESSION_ID' } = $session->{ $cookie->{ 'USER' } }->{ 'SESSION_ID' };
            $cookie->{ 'LOGIN' }      = "OK";
            $cookie->{ 'PAGE' }       = 'clade'; 

            Maasha::BGB::Session::session_store( "$cookie->{ 'SESSION_DIR' }/sessions.txt", $session );
        }
        else
        {
            $cookie->{ 'LOGIN' } = "ERROR";
        }
    }
}


sub cookie_start
{
    # Martin A. Hansen, November 2009.

    # Decommify the cookie value for NAV_START and adjust it to
    # to prevent negative values.

    my ( $cookie,   # cookie hash
       ) = @_;

    # Returns nothing.

    if ( defined $cookie->{ 'NAV_START' } )
    {
        $cookie->{ 'NAV_START' } =~ tr/,//d;
        $cookie->{ 'NAV_START' } = 0 if $cookie->{ 'NAV_START' } < 0;
    }
    else
    {
        $cookie->{ 'NAV_START' } = 0;
    }
}


sub cookie_end
{
    # Martin A. Hansen, November 2009.

    # Decommify the cookie value for NAV_END and adjust it to prevent
    # overshooting the max value for the contig size as determined
    # from the cookie.

    my ( $cookie,   # cookie hash
       ) = @_;

    # Returns nothing.

    my ( $max );
    
    $max = Maasha::Filesys::file_size( Maasha::BGB::Track::path_seq( $cookie ) );

    if ( defined $cookie->{ 'NAV_END' } )
    {
        $cookie->{ 'NAV_END' } =~ tr/,//d;
        $cookie->{ 'NAV_END' } = $max if $cookie->{ 'NAV_END' } > $max;
    }
    else
    {
        $cookie->{ 'NAV_END' } = $max;
    }
}


sub cookie_zoom
{
    # Martin A. Hansen, November 2009.

    # Adjust the cookie values for NAV_START and NAV_END based
    # on cookie ZOOM values.

    my ( $cookie,   # cookie hash
       ) = @_;

    # Returns nothing.

    my ( $max, $dist, $new_dist, $dist_diff );

    $max = Maasha::Filesys::file_size( Maasha::BGB::Track::path_seq( $cookie ) );

    $dist = $cookie->{ 'NAV_END' } - $cookie->{ 'NAV_START' };

    if ( defined $cookie->{ 'ZOOM_IN1' } ) {
        $new_dist = $dist / 1.5;
    } elsif ( defined $cookie->{ 'ZOOM_IN2' } ) {
        $new_dist = $dist / 3;
    } elsif ( defined $cookie->{ 'ZOOM_IN3' } ) {
        $new_dist = $dist / 10;
    } elsif ( defined $cookie->{ 'ZOOM_OUT1' } ) {
        $new_dist = $dist * 1.5;
    } elsif ( defined $cookie->{ 'ZOOM_OUT2' } ) {
        $new_dist = $dist * 3;
    } elsif ( defined $cookie->{ 'ZOOM_OUT3' } ) {
        $new_dist = $dist * 10;
    }

    if ( $new_dist )
    {
        $dist_diff = $dist - $new_dist;

        $cookie->{ 'NAV_START' } = int( $cookie->{ 'NAV_START' } + ( $dist_diff / 2 ) );
        $cookie->{ 'NAV_END' }   = int( $cookie->{ 'NAV_END' }   - ( $dist_diff / 2 ) );

        $cookie->{ 'NAV_START' } = 0    if $cookie->{ 'NAV_START' } < 0;
        $cookie->{ 'NAV_END' }   = $max if $cookie->{ 'NAV_END' } > $max;
    }
}


sub cookie_move
{
    # Martin A. Hansen, November 2009.

    # Adjust the cookie values for NAV_START and NAV_END based
    # on cookie MOVE values.

    my ( $cookie,   # cookie hash
       ) = @_;

    my ( $max, $dist, $shift, $new_start, $new_end );

    $max = Maasha::Filesys::file_size( Maasha::BGB::Track::path_seq( $cookie ) );

    $dist = $cookie->{ 'NAV_END' } - $cookie->{ 'NAV_START' };

    if ( defined $cookie->{ 'MOVE_LEFT1' } ) {
        $shift = -1 * $dist * 0.10;
    } elsif ( defined $cookie->{ 'MOVE_LEFT2' } ) {
        $shift = -1 * $dist * 0.475;
    } elsif ( defined $cookie->{ 'MOVE_LEFT3' } ) {
        $shift = -1 * $dist * 0.95;
    } elsif ( defined $cookie->{ 'MOVE_RIGHT1' } ) {
        $shift = $dist * 0.10;
    } elsif ( defined $cookie->{ 'MOVE_RIGHT2' } ) {
        $shift = $dist * 0.475;
    } elsif ( defined $cookie->{ 'MOVE_RIGHT3' } ) {
        $shift = $dist * 0.95;
    }

    if ( $shift )
    {
        $new_start = int( $cookie->{ 'NAV_START' } + $shift );
        $new_end   = int( $cookie->{ 'NAV_END' }   + $shift );

        if ( $new_start > 0 and $new_end < $max )
        {
            $cookie->{ 'NAV_START' } = $new_start;
            $cookie->{ 'NAV_END' }   = $new_end;
        }
    }
}


sub cookie_href
{
    # Martin A. Hansen, November 2009.

    # Returns the href for a taxonomy path terminated at a given
    # page using information stored in a cookie.

    my ( $cookie,   # cookie hash
         $page,     # page
       ) = @_;

    # Returns a string.

    my ( @href_list, %href_hash, $href );

    $href_hash{ "user" } = $cookie->{ 'USER' } if $cookie->{ 'USER' };

    while ( 1 )
    {
        $href_hash{ "clade" } = $cookie->{ 'CLADE' }        if $cookie->{ 'CLADE' };
        last if $page eq 'clade';
        $href_hash{ "genome" } = $cookie->{ 'GENOME' }      if $cookie->{ 'GENOME' };
        last if $page eq 'genome';
        $href_hash{ "assembly" } = $cookie->{ 'ASSEMBLY' }  if $cookie->{ 'ASSEMBLY' };
        last if $page eq 'assembly';
        $href_hash{ "contig" } = $cookie->{ 'CONTIG' }      if $cookie->{ 'CONTIG' };
        last if $page eq 'contig';
        last;
    }

    if ( defined $cookie->{ 'NAV_START' } and defined $cookie->{ 'NAV_END' } and $page !~ /clade|genome|assembly|contig|browse/ ) {
        $href_hash{ "nav_search" } = "$cookie->{ 'NAV_START' }-$cookie->{ 'NAV_END' }";
    }

    $href_hash{ "s_beg" }      = $cookie->{ 'S_BEG' }      if defined $cookie->{ 'S_BEG' };
    $href_hash{ "s_end" }      = $cookie->{ 'S_END' }      if defined $cookie->{ 'S_END' };
    $href_hash{ "q_id" }       = $cookie->{ 'Q_ID' }       if defined $cookie->{ 'Q_ID' };
    $href_hash{ "strand" }     = $cookie->{ 'STRAND' }     if defined $cookie->{ 'STRAND' };
    $href_hash{ "session_id" } = $cookie->{ 'SESSION_ID' } if defined $cookie->{ 'SESSION_ID' };

    push @href_list, "$cookie->{ 'SCRIPT' }?page=$page";

    foreach $href ( keys %href_hash ) {
        push @href_list, "$href=$href_hash{ $href }";
    }

    return join "&", @href_list;
}


sub cookie_page_next
{
    # Martin A. Hansen, November 2009.
    
    # Returns the next page in the taxonomy path.

    my ( $cookie,   # cookie hash
       ) = @_;

    # Returns a string.

    my ( $i );

    for ( $i = 0; $i < @{ $cookie->{ 'LIST_PAGES' } }; $i++ ) {
        last if $cookie->{ 'PAGE' } eq $cookie->{ 'LIST_PAGES' }->[ $i ];
    }

    return $cookie->{ 'LIST_PAGES' }->[ $i + 1 ];
}


# >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> PAGES <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<


sub page
{
    # Martin A. Hansen, November 2009.

    # Determines what page to render based on
    # the cookie's PAGE setting.

    my ( $cookie,   # cookie hash
       ) = @_;

    # Returns a list.

    my ( @html );

    if ( $cookie->{ 'PAGE' } eq 'login' ) {
        push @html, page_login( $cookie );
    } elsif ( $cookie->{ 'PAGE' } eq 'search' ) {
        push @html, page_search( $cookie );
    } elsif ( $cookie->{ 'PAGE' } eq 'browse' ) {
        push @html, page_browse( $cookie );
    } elsif ( $cookie->{ 'PAGE' } eq 'dna' ) {
        push @html, page_dna( $cookie );
    } elsif ( $cookie->{ 'PAGE' } eq 'export' ) {
        push @html, page_export( $cookie );
    } else {
        push @html, page_taxonomy( $cookie );
    }

    if ( $cookie->{ 'SESSION_ID' } ) {
        push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "session_id", value => "$cookie->{ 'SESSION_ID' }" ) );
    }

    return wantarray ? @html : \@html;
}


sub page_login
{
    # Martin A. Hansen, December 2009.

    # Renders the login page.

    my ( $cookie,
       ) = @_;

    # Returns a list.

    my ( @html );

    push @html, section_login( $cookie );

    return wantarray ? @html : \@html;
}


sub page_search
{
    # Martin A. Hansen, December 2009.

    # Renders the search page.

    my ( $cookie,
       ) = @_;

    # Returns a list.

    my ( @html );

    push @html, section_taxonomy_table( $cookie );
    push @html, section_search( $cookie );

    return wantarray ? @html : \@html;
}


sub page_browse
{
    # Martin A. Hansen, November 2009.
    
    # Renders the browse page.

    my ( $cookie,
       ) = @_;

    # Returns a list.

    my ( @html );

    push @html, section_taxonomy_table( $cookie );
    push @html, section_navigate( $cookie );
    push @html, section_browse( $cookie );
    push @html, section_permalink( $cookie );

    return wantarray ? @html : \@html;
}


sub page_dna
{
    # Martin A. Hansen, November 2009.
    
    # Renders the DNA page.

    my ( $cookie,
       ) = @_;

    # Returns a list.

    my ( @html );

    push @html, section_taxonomy_table( $cookie );
    push @html, section_dna( $cookie );

    return wantarray ? @html : \@html;
}


sub page_export
{
    # Martin A. Hansen, November 2009.

    # Renders the export page.

    my ( $cookie,
       ) = @_;

    # Returns a list.

    my ( @html );

    push @html, section_taxonomy_table( $cookie );
    push @html, section_export( $cookie );

    return wantarray ? @html : \@html;
}


sub page_taxonomy
{
    # Martin A. Hansen, November 2009.
    
    # Renders the browse page.

    my ( $cookie,   # cookie hash
       ) = @_;

    # Returns a list.

    my ( @html );

    push @html, section_taxonomy_table( $cookie );
    push @html, section_taxonomy_select( $cookie );

    return wantarray ? @html : \@html;
}


# >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> SECTIONS <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<


sub section_login
{
    # Martin A. Hansen, December 2009.
   
    # Returns a HTML section with a login menu.

    my ( $cookie,   # cookie hash
       ) = @_;

    # Returns a list.

    my ( $user, $password, $login, @html );

    $user     = Maasha::XHTML::text( name => "user", value => "", size => 20 );
    $password = Maasha::XHTML::password( name => "password", value => "", size => 20 );
    $login    = Maasha::XHTML::submit( name => "login_submit", value => "Login" );

    push @html, Maasha::XHTML::h2( txt => "Login", class => 'center' );

    push @html, Maasha::XHTML::table_beg( summary => "Login table", align => 'center' );
    push @html, Maasha::XHTML::table_row_simple( tr => [ "User:", $user ] );
    push @html, Maasha::XHTML::table_row_simple( tr => [ "Password:", $password ] );
    push @html, Maasha::XHTML::table_row_simple( tr => [ "", $login ] );
    push @html, Maasha::XHTML::table_end;

    if ( $cookie->{ 'LOGIN' } and $cookie->{ 'LOGIN' } eq 'ERROR' ) {
        push @html, Maasha::XHTML::h3( txt => "Bad user or password - please retry", class => 'error' );
    }

    return wantarray ? @html : \@html;
}


sub section_taxonomy_table
{
    # Martin A. Hansen, November 2009.

    # Returns a HTML section with a taxonomy table
    # showing the location in the taxonomy and with
    # links to browse the taxonomy.

    my ( $cookie,   # cookie hash
       ) = @_;

    # Returns a list.

    my ( $page, @row, @html, $href, $txt );
    
    foreach $page ( @{ $cookie->{ 'LIST_PAGES' } } )
    {
        last if $page eq $cookie->{ 'PAGE' } or $page eq 'browse';

        $href = cookie_href( $cookie, $page );

        $txt = ": $cookie->{ uc $page }";

        push @row, Maasha::XHTML::ln( txt => $page, href => $href, class => 'inline' );
        push @row, Maasha::XHTML::p(  txt => $txt, class => 'inline' );
    }

    push @html, Maasha::XHTML::table_beg( summary => "Taxonomy table", align => 'center', cellpadding => '5px' );
    push @html, Maasha::XHTML::table_row_simple( tr => [ join( "\n", @row ) ], align => 'center' );
    push @html, Maasha::XHTML::table_end;

    return wantarray ? @html : \@html;
}


sub section_taxonomy_select
{
    # Martin A. Hansen, November 2009.
    
    # Returns a HTML section with selection choices
    # for navigating the taxonomy tree.

    my ( $cookie,   # cookie hash
       ) = @_;

    # Returns a list.

    my ( $list, @html, $item, $href );

    $list = "LIST_" . uc $cookie->{ 'PAGE' };

    push @html, Maasha::XHTML::h2( txt => "Select $cookie->{ 'PAGE' }", class => 'center' );

    push @html, Maasha::XHTML::table_beg( summary => "Taxonomy select table", align => 'center', cellpadding => '5px' );

    foreach $item ( @{ $cookie->{ $list } } )
    {
        $cookie->{ uc $cookie->{ 'PAGE' } } = $item;

        $href = cookie_href( $cookie, cookie_page_next( $cookie ) );

        push @html, Maasha::XHTML::table_row_simple( tr => [ Maasha::XHTML::ln( txt => $item, href => $href ) ] );
    }

    push @html, Maasha::XHTML::table_end;

    return wantarray ? @html : \@html;
}


sub section_navigate
{
    # Martin A. Hansen, November 2009.

    # Returns a HTML section for navigating in the browser window.

    my ( $cookie,   # cookie hash
       ) = @_;

    # Returns a list.

    my ( @html, $nav_val );

    $nav_val = Maasha::Calc::commify( $cookie->{ 'NAV_START' } ) . "-" . Maasha::Calc::commify( $cookie->{ 'NAV_END' } );

    push @html, Maasha::XHTML::table_beg( summary => "Navigation table", align => 'center' );
    push @html, Maasha::XHTML::table_row_simple( tr => [
        "Position or search term:",
        Maasha::XHTML::text( name => "nav_search", value => $nav_val, size => 30 ),
        Maasha::XHTML::submit( name => "nav_submit", value => "Submit" ),
    ] );
    push @html, Maasha::XHTML::table_end;

    push @html, Maasha::XHTML::table_beg( summary => "Zoom table", align => 'center' );
    push @html, Maasha::XHTML::table_row_simple( tr => [
        Maasha::XHTML::p( txt => 'Move:' ),
        Maasha::XHTML::submit( name => "move_left3",  value => "<<<", title => "move 95% to the left" ),
        Maasha::XHTML::submit( name => "move_left2",  value => "<<",  title => "move 47.5% to the left" ),
        Maasha::XHTML::submit( name => "move_left1",  value => "<",   title => "move 10% to the left" ),
        Maasha::XHTML::submit( name => "move_right1", value => ">",   title => "move 10% to the rigth" ),
        Maasha::XHTML::submit( name => "move_right2", value => ">>",  title => "move 47.5% to the rigth" ),
        Maasha::XHTML::submit( name => "move_right3", value => ">>>", title => "move 95% to the right" ),
        Maasha::XHTML::p( txt => 'Zoom in:' ),
        Maasha::XHTML::submit( name => "zoom_in1", value => "1.5x" ),
        Maasha::XHTML::submit( name => "zoom_in2", value => "3x" ),
        Maasha::XHTML::submit( name => "zoom_in3", value => "10x" ),
        Maasha::XHTML::p( txt => 'Zoom out:' ),
        Maasha::XHTML::submit( name => "zoom_out1", value => "1.5x" ),
        Maasha::XHTML::submit( name => "zoom_out2", value => "3x" ),
        Maasha::XHTML::submit( name => "zoom_out3", value => "10x" ),
    ] );
    push @html, Maasha::XHTML::table_end;

    push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "page",     value => "browse" ) );
    push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "user",     value => "$cookie->{ 'USER' }" ) );
    push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "clade",    value => "$cookie->{ 'CLADE' }" ) );
    push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "genome",   value => "$cookie->{ 'GENOME' }" ) );
    push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "assembly", value => "$cookie->{ 'ASSEMBLY' }" ) );
    push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "contig",   value => "$cookie->{ 'CONTIG' }" ) );

    return wantarray ? @html : \@html;
}


sub section_browse
{
    my ( $cookie,
       ) = @_;

    # Returns a list.

    my ( @tracks, $i, @features, $feat, $elem, $surface, $cr, $png_data, @html, @img );

    push @features, [ Maasha::BGB::Track::track_ruler( $cookie ) ];
    push @features, [ Maasha::BGB::Track::track_seq( $cookie ) ];

    @tracks = Maasha::BGB::Track::path_tracks( $cookie );

    for ( $i = 0; $i < @tracks; $i++ )
    {
        $cookie->{ 'FEAT_COLOR' } = Maasha::BGB::Draw::palette( $i );

        push @features, [ Maasha::BGB::Track::track_feature( $tracks[ $i ], $cookie ) ];
    }

    $surface = Cairo::ImageSurface->create( 'argb32', $cookie->{ 'IMG_WIDTH' }, $cookie->{ 'TRACK_OFFSET' } );
    $cr      = Cairo::Context->create( $surface );

    $cr->rectangle ( 0, 0, $cookie->{ 'IMG_WIDTH' },  $cookie->{ 'TRACK_OFFSET' } );
    $cr->set_source_rgb ( 1, 1, 1 );
    $cr->fill;

    foreach $feat ( @features ) {
        Maasha::BGB::Draw::draw_feature( $cr, $feat ) if $feat;
    }

    $png_data = Maasha::BGB::Draw::base64_png( $surface );

    push @img, Maasha::XHTML::img(
        src    => "data:image/png;base64,$png_data",
        alt    => "Browser Tracks",
        height => $cookie->{ 'TRACK_OFFSET' },
        width  => $cookie->{ 'IMG_WIDTH' },
        id     => "browser_map",
        usemap => "#browser_map"
    );

    push @img, Maasha::XHTML::map_beg( name => "browser_map", id => "browser_map" );

    foreach $feat ( @features )
    {
        foreach $elem ( @{ $feat } )
        {
            next if $elem->{ 'type' } eq 'text';

            #$elem->{ 'strand' } = '&#43' if $elem->{ 'strand' } eq '+';

            $cookie->{ 'Q_ID' }   = $elem->{ 'q_id' };
            $cookie->{ 'S_BEG' }  = $elem->{ 's_beg' };
            $cookie->{ 'S_END' }  = $elem->{ 's_end' };
            $cookie->{ 'STRAND' } = $elem->{ 'strand' };

            push @img, Maasha::XHTML::area(
                href   => cookie_href( $cookie, "export" ),
                # href   => cookie_href( $cookie, "export" ) . "&q_id=$elem->{ 'q_id' }&s_beg=$elem->{ 's_beg' }&s_end=$elem->{ 's_end' }&strand=$elem->{ 'strand' }",
                shape  => "rect",
                coords => "$elem->{ x1 }, $elem->{ y1 }, $elem->{ x2 }, $elem->{ y2 }", title => "$elem->{ 'title' }",
            );
        }
    }

    push @img, Maasha::XHTML::map_end();

    push @html, Maasha::XHTML::p( txt => join( "\n", @img ) );

    @html = Maasha::XHTML::div( txt => join( "\n", @html ), class => 'browse' );

    return wantarray ? @html : \@html;
}


sub section_permalink
{
    # Martin A. Hansen, December 2009.

    # Return HTML with a permanent link to current browser view.

    my ( $cookie,   # cookie hash
       ) = @_;

    # Returns a list.

    my ( $href, @html );

    $href = join( "&",
        "$cookie->{ 'SCRIPT' }?page=browse",
        "user=$cookie->{ 'USER' }",
        "clade=$cookie->{ 'CLADE' }",
        "genome=$cookie->{ 'GENOME' }",
        "assembly=$cookie->{ 'ASSEMBLY' }",
        "contig=$cookie->{ 'CONTIG' }",
        "nav_start=$cookie->{ 'NAV_START' }",
        "nav_end=$cookie->{ 'NAV_END' }",
        "session_id=$cookie->{ 'SESSION_ID' }",
    );

    push @html, Maasha::XHTML::p( txt => Maasha::XHTML::ln( txt => "Permalink", href => $href ), class => 'center' );

    return wantarray ? @html : \@html;
}


sub section_export
{
    # Martin A. Hansen, November 2009.

    # Returns a HTML section with export table.

    my ( $cookie,   # cookie hash
       ) = @_;

    # Returns a list.

    my ( @row_dna_contig, @html );

    push @row_dna_contig, Maasha::XHTML::p( txt => qq(Export Feature: "$cookie->{ 'Q_ID' }" DNA from Contig: ), class => 'inline' );
    push @row_dna_contig, Maasha::XHTML::p( txt  => "$cookie->{ 'CONTIG' } Start: ", class => 'inline' );
    push @row_dna_contig, Maasha::XHTML::text( name => "s_beg", value => Maasha::Calc::commify( $cookie->{ 'S_BEG' } ), size => 15 );
    push @row_dna_contig, Maasha::XHTML::p( txt => "End: ", class => 'inline' );
    push @row_dna_contig, Maasha::XHTML::text( name => "s_end", value => Maasha::Calc::commify( $cookie->{ 'S_END' } ), size => 15 );
    push @row_dna_contig, Maasha::XHTML::p( txt => "Strand: ", class => 'inline' );
    push @row_dna_contig, Maasha::XHTML::menu( name => "strand", options => [ qw( + - ) ], selected => $cookie->{ 'STRAND' } );
    push @row_dna_contig, Maasha::XHTML::submit( name => "export", value => "Export", title => "Fetch DNA from this region" );

    push @html, Maasha::XHTML::h2( txt => "Export", class => 'center' );
    push @html, Maasha::XHTML::table_beg( summary => "Taxonomy select table", align => 'center' );
    push @html, Maasha::XHTML::table_row_simple( tr => \@row_dna_contig );
    push @html, Maasha::XHTML::table_end;

    push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "page", value => "dna" ) );
    push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "user",     value => "$cookie->{ 'USER' }" ) );
    push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "clade",    value => "$cookie->{ 'CLADE' }" ) );
    push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "genome",   value => "$cookie->{ 'GENOME' }" ) );
    push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "assembly", value => "$cookie->{ 'ASSEMBLY' }" ) );
    push @html, Maasha::XHTML::p( txt => Maasha::XHTML::hidden( name => "contig",   value => "$cookie->{ 'CONTIG' }" ) );

    return wantarray ? @html : \@html;
}


sub section_search
{
    # Martin A. Hansen, November 2009.

    # Returns a HTML section with export table.

    my ( $cookie,   # cookie hash
       ) = @_;

    # Returns a list.

    my ( $results, $result, $count, @html, $export, $browse );

    $results = Maasha::BGB::Track::search_tracks( $cookie );

    $count = scalar @{ $results };

    push @html, Maasha::XHTML::h2( txt => "Search", class => 'center' );
    push @html, Maasha::XHTML::p( txt => qq(Results for "$cookie->{ 'SEARCH' }": $count), class => 'center' );

    if ( $count > 0 )
    {
        push @html, Maasha::XHTML::table_beg( summary => "Search table", align => 'center', cellpadding => '5px' );
        push @html, Maasha::XHTML::table_row_simple( tr => [ qw( S_ID S_BEG S_END Q_ID SCORE STRAND HITS ALIGN BLOCK_COUNT BLOCK_BEGS BLOCK_LENS BLOCK_TYPE) ] );

        foreach $result ( @{ $results } )
        {
            $cookie->{ 'CONTIG' }    = $result->{ 'S_ID' };
            $cookie->{ 'NAV_START' } = $result->{ 'S_BEG' };
            $cookie->{ 'NAV_END' }   = $result->{ 'S_END' };
            $cookie->{ 'S_BEG' }     = $result->{ 'S_BEG' };
            $cookie->{ 'S_END' }     = $result->{ 'S_END' };
            $cookie->{ 'STRAND' }    = $result->{ 'STRAND' };
            $cookie->{ 'Q_ID' }      = $result->{ 'Q_ID' };

            $browse = Maasha::XHTML::ln( txt => "browse", href => cookie_href( $cookie, "browse" ) );
            $export = Maasha::XHTML::ln( txt => "export", href => cookie_href( $cookie, "export" ) );

            push @html, Maasha::XHTML::table_row_advanced(
                tr => [ { td => $result->{ 'S_ID' } },
                        { td => $result->{ 'S_BEG' }, align => 'right' },
                        { td => $result->{ 'S_END' }, align => 'right' },
                        { td => $result->{ 'Q_ID' } },
                        { td => $result->{ 'SCORE' }, align => 'right' },
                        { td => $result->{ 'STRAND' } },
                        { td => $result->{ 'HITS' }, align => 'right' },
                        { td => $result->{ 'ALIGN' } },
                        { td => $result->{ 'BLOCK_COUNT' }, align => 'right' },
                        { td => $result->{ 'BLOCK_BEGS' } },
                        { td => $result->{ 'BLOCK_LENS' } },
                        { td => $result->{ 'BLOCK_TYPE' } },
                        { td => $browse },
                        { td => $export },
                ], class => "monospace"
            );
        }

        push @html, Maasha::XHTML::table_end;
    }

    return wantarray ? @html : \@html;
}


sub section_dna
{
    # Martin A. Hansen, November 2009.

    # Returns a HTML section with extracted DNA.

    my ( $cookie,   # cookie hash
       ) = @_;

    # Returns a list.

    my ( @html, $beg, $end, $seq );
    
    $beg = $cookie->{ 'S_BEG' };
    $end = $cookie->{ 'S_END' };
    $beg =~ tr/,//d;
    $end =~ tr/,//d;

    $seq = join ";", ">$cookie->{ 'GENOME' }", $cookie->{ 'ASSEMBLY' }, $cookie->{ 'CONTIG' }, $beg, $end, "$cookie->{ 'STRAND' }\n";
    $seq .= Maasha::BGB::Track::dna_get( $cookie );

    push @html, Maasha::XHTML::h2( txt => "DNA", class => 'center' );
    push @html, Maasha::XHTML::pre( txt => $seq );

    return wantarray ? @html : \@html;
}


# >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<


__END__