cgi/bugreport.cgi

   1 #!/usr/bin/perl -wT
   2
   3 package debbugs;
   4
   5 use strict;
   6 use POSIX qw(strftime tzset);
   7 use MIME::Parser;
   8 use MIME::Decoder;
   9 use IO::Scalar;
  10 use IO::Lines;
  11
  12 #require '/usr/lib/debbugs/errorlib';
  13 require './common.pl';
  14
  15 require '/etc/debbugs/config';
  16 require '/etc/debbugs/text';
  17
  18 use vars(qw($gEmailDomain $gHTMLTail $gSpoolDir $gWebDomain));
  19
  20 my %param = readparse();
  21
  22 my $tail_html;
  23
  24 my $ref = $param{'bug'} || quitcgi("No bug number");
  25 $ref =~ /(\d+)/ or quitcgi("Invalid bug number");
  26 $ref = $1;
  27 my $short = "#$ref";
  28 my $msg = $param{'msg'} || "";
  29 my $att = $param{'att'};
  30 my $boring = ($param{'boring'} || 'no') eq 'yes';
  31 my $terse = ($param{'terse'} || 'no') eq 'yes';
  32 my $reverse = ($param{'reverse'} || 'no') eq 'yes';
  33 my $mbox = ($param{'mbox'} || 'no') eq 'yes';
  34 my $mime = ($param{'mime'} || 'yes') eq 'yes';
  35
  36 # Not used by this script directly, but fetch these so that pkgurl() and
  37 # friends can propagate them correctly.
  38 my $archive = ($param{'archive'} || 'no') eq 'yes';
  39 my $repeatmerged = ($param{'repeatmerged'} || 'yes') eq 'yes';
  40 set_option('archive', $archive);
  41 set_option('repeatmerged', $repeatmerged);
  42
  43 my $buglog = buglog($ref);
  44
  45 if ($ENV{REQUEST_METHOD} eq 'HEAD' and not defined($att) and not $mbox) {
  46     print "Content-Type: text/html\n";
  47     my @stat = stat $buglog;
  48     if (@stat) {
  49         my $mtime = strftime '%a, %d %b %Y %T GMT', gmtime($stat[9]);
  50         print "Last-Modified: $mtime\n";
  51     }
  52     print "\n";
  53     exit 0;
  54 }
  55
  56 sub display_entity ($$$$\$\@);
  57 sub display_entity ($$$$\$\@) {
  58     my $entity = shift;
  59     my $ref = shift;
  60     my $top = shift;
  61     my $xmessage = shift;
  62     my $this = shift;
  63     my $attachments = shift;
  64
  65     my $head = $entity->head;
  66     my $disposition = $head->mime_attr('content-disposition');
  67     $disposition = 'inline' if not defined $disposition or $disposition eq '';
  68     my $type = $entity->effective_type;
  69     my $filename = $entity->head->recommended_filename;
  70     $filename = '' unless defined $filename;
  71
  72     if ($top) {
  73         $$this .= htmlsanit($entity->stringify_header) unless ($terse);
  74         $$this .= "\n";
  75     }
  76
  77     unless (($top and $type =~ m[^text(?:/plain)?(?:;|$)]) or
  78             ($type =~ m[^multipart/])) {
  79         push @$attachments, $entity;
  80         my @dlargs = ($ref, "msg=$xmessage", "att=$#$attachments");
  81         push @dlargs, "filename=$filename" if $filename ne '';
  82         my $printname = $filename;
  83         $printname = 'Message part ' . ($#$attachments + 1) if $filename eq '';
  84         $$this .= '[<a href="' . dlurl(@dlargs) . qq{">$printname</a> } .
  85                   "($type, $disposition)]\n\n";
  86
  87         if ($msg and defined($att) and $att eq $#$attachments) {
  88             my $head = $entity->head;
  89             chomp(my $type = $entity->effective_type);
  90             my $body = $entity->stringify_body;
  91             print "Content-Type: $type";
  92             print "; name=$filename" if $filename ne '';
  93             print "\n\n";
  94             my $decoder = new MIME::Decoder($head->mime_encoding);
  95             $decoder->decode(new IO::Scalar(\$body), \*STDOUT);
  96             exit(0);
  97         }
  98     }
  99
 100     return if not $top and $disposition eq 'attachment' and not defined($att);
 101     return unless ($type =~ m[^text/?] and $type !~ m[^text/html(?:;|$)]) or
 102                   $type =~ m[^application/pgp(?:;|$)] or
 103                   $entity->parts;
 104
 105     if ($entity->is_multipart) {
 106         my @parts = $entity->parts;
 107         foreach my $part (@parts) {
 108             display_entity($part, $ref, 0, $xmessage,
 109                            $$this, @$attachments);
 110             $$this .= "\n";
 111         }
 112     } elsif ($entity->parts) {
 113         # We must be dealing with a nested message.
 114         $$this .= "<blockquote>\n";
 115         my @parts = $entity->parts;
 116         foreach my $part (@parts) {
 117             display_entity($part, $ref, 1, $xmessage,
 118                            $$this, @$attachments);
 119             $$this .= "\n";
 120         }
 121         $$this .= "</blockquote>\n";
 122     } else {
 123         $$this .= htmlsanit($entity->bodyhandle->as_string) unless ($terse);
 124     }
 125 }
 126
 127 my %maintainer = %{getmaintainers()};
 128 my %pkgsrc = %{getpkgsrc()};
 129
 130 my $indexentry;
 131 my $descriptivehead;
 132 my $showseverity;
 133
 134 my $tpack;
 135 my $tmain;
 136
 137 $ENV{"TZ"} = 'UTC';
 138 tzset();
 139
 140 my $dtime = strftime "%a, %e %b %Y %T UTC", localtime;
 141 $tail_html = $debbugs::gHTMLTail;
 142 $tail_html =~ s/SUBSTITUTE_DTIME/$dtime/;
 143
 144 my %status = %{getbugstatus($ref)};
 145 unless (%status) {
 146     print <<EOF;
 147 Content-Type: text/html
 148
 149 <!DOCTYPE html PUBLIC "-//W3C//DTD HTML 4.01 Transitional//EN">
 150 <html>
 151 <head><title>$debbugs::gProject $debbugs::gBug report logs - $short</title></head>
 152 <body>
 153 <h1>$debbugs::gProject $debbugs::gBug report logs - $short</h1>
 154 <p>There is no record of $debbugs::gBug $short.
 155 Try the <a href="http://$gWebDomain/">search page</a> instead.</p>
 156 $tail_html</body></html>
 157 EOF
 158     exit 0;
 159 }
 160
 161 $|=1;
 162
 163 $tpack = lc $status{'package'};
 164 my @tpacks = splitpackages($tpack);
 165
 166 if  ($status{severity} eq 'normal') {
 167         $showseverity = '';
 168 #} elsif (grep($status{severity} eq $_, @strongseverities)) {
 169 #       $showseverity = "<strong>Severity: $status{severity}</strong>;\n";
 170 } else {
 171         $showseverity = "Severity: <em>$status{severity}</em>;\n";
 172 }
 173
 174 $indexentry .= "<p>$showseverity";
 175 $indexentry .= htmlpackagelinks($status{package}, 0);
 176
 177 $indexentry .= "Reported by: <a href=\"" . submitterurl($status{originator})
 178               . "\">" . htmlsanit($status{originator}) . "</a>;\n";
 179
 180 my $dummy = strftime "%a, %e %b %Y %T UTC", localtime($status{date});
 181 $indexentry .= "Date: ".$dummy.";\n<br>";
 182
 183 my @descstates;
 184
 185 push @descstates, "Tags: <strong>"
 186                 . htmlsanit(join(", ", sort(split(/\s+/, $status{tags}))))
 187                 . "</strong>"
 188                         if length($status{tags});
 189
 190 my @merged= split(/ /,$status{mergedwith});
 191 if (@merged) {
 192         my $descmerged = 'merged with ';
 193         my $mseparator = '';
 194         for my $m (@merged) {
 195                 $descmerged .= $mseparator."<a href=\"" . bugurl($m) . "\">#$m</a>";
 196                 $mseparator= ",\n";
 197         }
 198         push @descstates, $descmerged;
 199 }
 200
 201 if (length($status{done})) {
 202         push @descstates, "<strong>Done:</strong> ".htmlsanit($status{done});
 203 } elsif (length($status{forwarded})) {
 204         push @descstates, "<strong>Forwarded</strong> to ".maybelink($status{forwarded});
 205 }
 206
 207 $indexentry .= join(";\n", @descstates) . ";\n<br>" if @descstates;
 208
 209 $descriptivehead = $indexentry;
 210 foreach my $pkg (@tpacks) {
 211     my $tmaint = defined($maintainer{$pkg}) ? $maintainer{$pkg} : '(unknown)';
 212     my $tsrc = defined($pkgsrc{$pkg}) ? $pkgsrc{$pkg} : '(unknown)';
 213
 214     $descriptivehead .=
 215             htmlmaintlinks(sub { $_[0] == 1 ? "Maintainer for $pkg is\n"
 216                                             : "Maintainers for $pkg are\n" },
 217                            $tmaint);
 218     $descriptivehead .= ";\nSource for $pkg is\n".
 219             '<a href="'.srcurl($tsrc)."\">$tsrc</a>" if ($tsrc ne "(unknown)");
 220     $descriptivehead .= ".\n<br>";
 221 }
 222
 223 open L, "<$buglog" or &quitcgi("open log for $ref: $!");
 224 if ($buglog !~ m#^\Q$gSpoolDir/db#) {
 225     $descriptivehead .= "\n<p>Bug is <strong>archived</strong>. No further changes may be made.</p>";
 226 }
 227
 228 my $log='';
 229
 230 my $xmessage = 1;
 231 my $suppressnext = 0;
 232 my $found_msgid = 0;
 233 my %seen_msgid = ();
 234
 235 my $thisheader = '';
 236 my $this = '';
 237
 238 my $cmsg = 1;
 239
 240 my $normstate= 'kill-init';
 241 my $linenum = 0;
 242 my @mail = ();
 243 my @mails = ();
 244 while(my $line = <L>) {
 245         $linenum++;
 246         if ($line =~ m/^.$/ and 1 <= ord($line) && ord($line) <= 7) {
 247                 # state transitions
 248                 my $newstate;
 249                 my $statenum = ord($line);
 250
 251                 $newstate = 'autocheck'     if ($statenum == 1);
 252                 $newstate = 'recips'        if ($statenum == 2);
 253                 $newstate = 'kill-end'      if ($statenum == 3);
 254                 $newstate = 'go'            if ($statenum == 5);
 255                 $newstate = 'html'          if ($statenum == 6);
 256                 $newstate = 'incoming-recv' if ($statenum == 7);
 257
 258                 # disallowed transitions:
 259                 $_ = "$normstate $newstate";
 260                 unless (m/^(go|go-nox|html) kill-end$/
 261                     || m/^(kill-init|kill-end) (incoming-recv|autocheck|recips|html)$/
 262                     || m/^kill-body go$/)
 263                 {
 264                         &quitcgi("$ref: Transition from $normstate to $newstate at $linenum disallowed");
 265                 }
 266
 267 #$this .= "\n<br>states: $normstate $newstate<br>\n";
 268
 269 #               if ($newstate eq 'go') {
 270 #                       $this .= "<pre>\n";
 271 #               }
 272                 if ($newstate eq 'html') {
 273                         $this = '';
 274                 }
 275
 276                 if ($newstate eq 'kill-end') {
 277
 278                         my $show = 1;
 279                         $show = $boring
 280                                 if ($suppressnext && $normstate ne 'html');
 281
 282                         $show = ($xmessage == $msg) if ($msg);
 283
 284                         push @mails, join( '', @mail ) if ( $mbox && @mail );
 285                         if ($show) {
 286                                 if (not $mime and @mail) {
 287                                         $this .= htmlsanit(join '', @mail);
 288                                 } elsif (@mail) {
 289                                         my $parser = new MIME::Parser;
 290                                         $parser->tmp_to_core(1);
 291                                         $parser->output_to_core(1);
 292 #                                       $parser->output_under("/tmp");
 293                                         my $entity = $parser->parse( new IO::Lines \@mail );
 294                                         # TODO: make local subdir, clean it ourselves
 295                                         # the following does NOT delete the msg dirs in /tmp
 296                                         END { if ( $entity ) { $entity->purge; } if ( $parser ) { $parser->filer->purge; } }
 297                                         my @attachments = ();
 298                                         display_entity($entity, $ref, 1, $xmessage, $this, @attachments);
 299                                 }
 300 #                               if ($normstate eq 'go' || $normstate eq 'go-nox') {
 301                                 if ($normstate ne 'html') {
 302                                         $this = "<pre>\n$this</pre>\n";
 303                                 }
 304                                 if ($normstate eq 'html') {
 305                                         $this .= "  <em><a href=\"" . bugurl($ref, "msg=$xmessage") . "\">Full text</a> available.</em>";
 306                                 }
 307                                 $this = "$thisheader$this" if $thisheader && !( $normstate eq 'html' );;
 308                                 $thisheader = '';
 309                                 my $delim = $terse ? "<p>" : "<hr>";
 310                                 if ($reverse) {
 311                                         $log = "$this\n$delim$log";
 312                                 } else {
 313                                         $log .= "$this\n$delim\n";
 314                                 }
 315                         }
 316
 317                         $xmessage++ if ($normstate ne 'html');
 318
 319                         $suppressnext = $normstate eq 'html';
 320                         $found_msgid = 0;
 321                 }
 322
 323                 $normstate = $newstate;
 324                 @mail = ();
 325                 next;
 326         }
 327
 328         $_ = $line;
 329         if ($normstate eq 'incoming-recv') {
 330                 my $pl= $_;
 331                 $pl =~ s/\n+$//;
 332                 m/^Received: \(at (\S+)\) by (\S+)\;/
 333                         || &quitcgi("bad line \`$pl' in state incoming-recv");
 334                 $thisheader = "<h2>Message received at ".htmlsanit("$1\@$2")
 335                         . ":</h2>\n";
 336                 $this = '';
 337                 $normstate= 'go';
 338                 push @mail, $_;
 339         } elsif ($normstate eq 'html') {
 340                 $this .= $_;
 341         } elsif ($normstate eq 'go') {
 342                 s/^\030//;
 343                 if (!$suppressnext && !$found_msgid &&
 344                     /^Message-ID: <(.*)>/i) {
 345                         my $msgid = $1;
 346                         $found_msgid = 1;
 347                         if ($seen_msgid{$msgid}) {
 348                                 $suppressnext = 1;
 349                         } else {
 350                                 $seen_msgid{$msgid} = 1;
 351                         }
 352                 }
 353                 if (@mail) {
 354                         push @mail, $_;
 355                 } else {
 356                         $this .= htmlsanit($_);
 357                 }
 358         } elsif ($normstate eq 'go-nox') {
 359                 next if !s/^X//;
 360                 if (!$suppressnext && !$found_msgid &&
 361                     /^Message-ID: <(.*)>/i) {
 362                         my $msgid = $1;
 363                         $found_msgid = 1;
 364                         if ($seen_msgid{$msgid}) {
 365                                 $suppressnext = 1;
 366                         } else {
 367                                 $seen_msgid{$msgid} = 1;
 368                         }
 369                 }
 370                 if (@mail) {
 371                         push @mail, $_;
 372                 } else {
 373                         $this .= htmlsanit($_);
 374                 }
 375         } elsif ($normstate eq 'recips') {
 376                 if (m/^-t$/) {
 377                         $thisheader = "<h2>Message sent:</h2>\n";
 378                 } else {
 379                         s/\04/, /g; s/\n$//;
 380                         $thisheader = "<h2>Message sent to ".htmlsanit($_).":</h2>\n";
 381                 }
 382                 $this = "";
 383                 $normstate= 'kill-body';
 384         } elsif ($normstate eq 'autocheck') {
 385                 next if !m/^X-Debian-Bugs(-\w+)?: This is an autoforward from (\S+)/;
 386                 $normstate= 'autowait';
 387                 $thisheader = "<h2>Message received at $2:</h2>\n";
 388                 $this = '';
 389                 push @mail, $_;
 390         } elsif ($normstate eq 'autowait') {
 391                 next if !m/^$/;
 392                 $normstate= 'go-nox';
 393         } else {
 394                 &quitcgi("$ref state $normstate line \`$_'");
 395         }
 396 }
 397 &quitcgi("$ref state $normstate at end") unless $normstate eq 'kill-end';
 398 close(L);
 399
 400 if ( $mbox ) {
 401         print "Content-Type: text/plain\n\n";
 402         foreach ( @mails ) {
 403                 my @lines = split( "\n", $_, -1 );
 404                 if ( $lines[ 1 ] =~ m/^From / ) {
 405                         my $tmp = $lines[ 0 ];
 406                         $lines[ 0 ] = $lines[ 1 ];
 407                         $lines[ 1 ] = $tmp;
 408                 }
 409                 if ( !( $lines[ 0 ] =~ m/^From / ) ) {
 410                         my $date = strftime "%a %b %d %T %Y", localtime;
 411                         unshift @lines, "From unknown $date";
 412                 }
 413                 map { s/^(>*From )/>$1/ } @lines[ 1 .. $#lines ];
 414                 $_ = join( "\n", @lines ) . "\n";
 415         }
 416         print join("", @mails );
 417         exit 0;
 418 }
 419 print "Content-Type: text/html\n\n";
 420
 421 my $title = htmlsanit($status{subject});
 422
 423 print "<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 4.01 Transitional//EN\">\n";
 424 print "<HTML><HEAD>\n" .
 425     "<TITLE>$debbugs::gProject $debbugs::gBug report logs - $short - $title</TITLE>\n" .
 426     "</HEAD>\n" .
 427     '<BODY TEXT="#000000" BGCOLOR="#FFFFFF" LINK="#0000FF" VLINK="#800080">' .
 428     "\n";
 429 print "<H1>" . "$debbugs::gProject $debbugs::gBug report logs - <A HREF=\"mailto:$ref\@$gEmailDomain\">$short</A>" .
 430       "<BR>" . $title . "</H1>\n";
 431
 432 print "$descriptivehead\n";
 433 printf "<p>View this report as an <a href=\"%s\">mbox folder</a>.</p>\n", mboxurl($ref);
 434 print "<HR>";
 435 print "$log";
 436 print $tail_html;
 437
 438 print "</BODY></HTML>\n";
 439
 440 exit 0;