blootbot/src/Modules/nickometer.pl

   1 #
   2 # Lame-o-Nickometer backend
   3 #
   4 # (c) 1998 Adam Spiers <adam.spiers@new.ox.ac.uk>
   5 #
   6 # You may do whatever you want with this code, but give me credit.
   7 #
   8 # $Id$
   9 #
  10
  11 package nickometer;
  12
  13 use strict;
  14
  15 my $pi          = 3.14159265;
  16 my $score       = 0;
  17 my $verbose     = 0;
  18
  19 sub query {
  20   my ($message) = @_;
  21
  22   my $term = (lc $message eq 'me') ? $::who : $message;
  23
  24   if ($term =~ /^$::mask{chan}$/) {
  25     &::status("Doing nickometer for chan $term.");
  26
  27     if (!&::validChan($term)) {
  28         &::msg($::who, "error: channel is invalid.");
  29         return;
  30     }
  31
  32     # step 1.
  33     my %nickometer;
  34     foreach (keys %{ $::channels{lc $term}{''} }) {
  35       my $str   = $_;
  36       if (!defined $str) {
  37         &WARN("nickometer: nick in chan $term undefined?");
  38         next;
  39       }
  40
  41       my $value = &nickometer($str);
  42       $nickometer{$value}{$str} = 1;
  43     }
  44
  45     # step 2.
  46     ### TODO: compact with map?
  47     my @list;
  48     foreach (sort {$b <=> $a} keys %nickometer) {
  49       my $str = join(", ", sort keys %{ $nickometer{$_} });
  50       push(@list, "$str ($_%)");
  51     }
  52
  53     &::performStrictReply( &::formListReply(0, "Nickometer list for $term ", @list) );
  54     &::DEBUG("test.");
  55
  56     return;
  57   }
  58
  59   my $percentage = &nickometer($term);
  60
  61   if ($percentage =~ /NaN/) {
  62     $percentage = "off the scale";
  63   } else {
  64     $percentage = sprintf("%0.4f", $percentage);
  65     $percentage =~ s/(\.\d+)0+$/$1/;
  66     $percentage .= '%';
  67   }
  68
  69   if ($::msgType eq 'public') {
  70     &::say("'$term' is $percentage lame, $::who");
  71   } else {
  72     &::msg($::who, "the 'lame nick-o-meter' reading for $term is $percentage, $::who");
  73   }
  74
  75   return;
  76 }
  77
  78 sub nickometer ($) {
  79   my ($text) = @_;
  80   $score = 0;
  81
  82 #  return unless &loadPerlModule("Getopt::Std");
  83   return unless &::loadPerlModule("Math::Trig");
  84
  85   if (!defined $text) {
  86     &::DEBUG("nickometer: arg == NULL. $text");
  87     return;
  88   }
  89
  90   # Deal with special cases (precede with \ to prevent de-k3wlt0k)
  91   my %special_cost = (
  92     '69'                => 500,
  93     'dea?th'            => 500,
  94     'dark'              => 400,
  95     'n[i1]ght'          => 300,
  96     'n[i1]te'           => 500,
  97     'fuck'              => 500,
  98     'sh[i1]t'           => 500,
  99     'coo[l1]'           => 500,
 100     'kew[l1]'           => 500,
 101     'lame'              => 500,
 102     'dood'              => 500,
 103     'dude'              => 500,
 104     '[l1](oo?|u)[sz]er' => 500,
 105     '[l1]eet'           => 500,
 106     'e[l1]ite'          => 500,
 107     '[l1]ord'           => 500,
 108     'pron'              => 1000,
 109     'warez'             => 1000,
 110     'xx'                => 100,
 111     '\[rkx]0'           => 1000,
 112     '\0[rkx]'           => 1000,
 113   );
 114
 115   foreach my $special (keys %special_cost) {
 116     my $special_pattern = $special;
 117     my $raw = ($special_pattern =~ s/^\\//);
 118     my $nick = $text;
 119     unless (defined $raw) {
 120       $nick =~ tr/023457+8/ozeasttb/;
 121     }
 122     &punish($special_cost{$special}, "matched special case /$special_pattern/")
 123       if (defined $nick and $nick =~ /$special_pattern/i);
 124   }
 125
 126   # Allow Perl referencing
 127   $text =~ s/^\\([A-Za-z])/$1/;
 128
 129   # C-- ain't so bad either
 130   $text =~ s/^C--$/C/;
 131
 132   # Punish consecutive non-alphas
 133   $text =~ s/([^A-Za-z0-9]{2,})
 134    /my $consecutive = length($1);
 135     &punish(&slow_pow(10, $consecutive),
 136             "$consecutive total consecutive non-alphas")
 137       if $consecutive;
 138     $1
 139    /egx;
 140
 141   # Remove balanced brackets (and punish a little bit) and punish for unmatched
 142   while ($text =~ s/^([^()]*)   (\() (.*) (\)) ([^()]*)   $/$1$3$5/x ||
 143          $text =~ s/^([^{}]*)   (\{) (.*) (\}) ([^{}]*)   $/$1$3$5/x ||
 144          $text =~ s/^([^\[\]]*) (\[) (.*) (\]) ([^\[\]]*) $/$1$3$5/x)
 145   {
 146     print "Removed $2$4 outside parentheses; nick now $_\n" if $verbose;
 147     &punish(15, "brackets");
 148   }
 149   my $parentheses = $text =~ tr/(){}[]/(){}[]/;
 150   &punish(&slow_pow(10, $parentheses),
 151           "$parentheses unmatched " .
 152             ($parentheses == 1 ? 'parenthesis' : 'parentheses'))
 153     if $parentheses;
 154
 155   # Punish k3wlt0k
 156   my @k3wlt0k_weights = (5, 5, 2, 5, 2, 3, 1, 2, 2, 2);
 157   for my $digit (0 .. 9) {
 158     my $occurrences = $text =~ s/$digit/$digit/g || 0;
 159     &punish($k3wlt0k_weights[$digit] * $occurrences * 30,
 160             $occurrences . ' ' .
 161               (($occurrences == 1) ? 'occurrence' : 'occurrences') .
 162               " of $digit")
 163       if $occurrences;
 164   }
 165
 166   # An alpha caps is not lame in middle or at end, provided the first
 167   # alpha is caps.
 168   my $orig_case = $text;
 169   $text =~ s/^([^A-Za-z]*[A-Z].*[a-z].*?)[_-]?([A-Z])/$1\l$2/;
 170
 171   # A caps first alpha is sometimes not lame
 172   $text =~ s/^([^A-Za-z]*)([A-Z])([a-z])/$1\l$2$3/;
 173
 174   # Punish uppercase to lowercase shifts and vice-versa, modulo
 175   # exceptions above
 176   my $case_shifts = &case_shifts($orig_case);
 177   &punish(&slow_pow(9, $case_shifts),
 178           $case_shifts . ' case ' .
 179             (($case_shifts == 1) ? 'shift' : 'shifts'))
 180     if ($case_shifts > 1 && /[A-Z]/);
 181
 182   # Punish lame endings (TorgoX, WraithX et al. might kill me for this :-)
 183   &punish(50, 'last alpha lame') if $orig_case =~ /[XZ][^a-zA-Z]*$/;
 184
 185   # Punish letter to numeric shifts and vice-versa
 186   my $number_shifts = &number_shifts($_);
 187   &punish(&slow_pow(9, $number_shifts),
 188           $number_shifts . ' letter/number ' .
 189             (($number_shifts == 1) ? 'shift' : 'shifts'))
 190     if $number_shifts > 1;
 191
 192   # Punish extraneous caps
 193   my $caps = $text =~ tr/A-Z/A-Z/;
 194   &punish(&slow_pow(7, $caps), "$caps extraneous caps") if $caps;
 195
 196   # One and only one trailing underscore is OK.
 197   $text =~ s/\_$//;
 198
 199   # Now punish anything that's left
 200   my $remains = $text;
 201   $remains =~ tr/a-zA-Z0-9//d;
 202   my $remains_length = length($remains);
 203
 204   &punish(50 * $remains_length + &slow_pow(9, $remains_length),
 205           $remains_length . ' extraneous ' .
 206             (($remains_length == 1) ? 'symbol' : 'symbols'))
 207     if $remains;
 208
 209   print "\nRaw lameness score is $score\n" if $verbose;
 210
 211   # Use an appropriate function to map [0, +inf) to [0, 100)
 212   my $percentage = 100 *
 213                 (1 + &Math::Trig::tanh(($score-400)/400)) *
 214                 (1 - 1/(1+$score/5)) / 2;
 215
 216   my $digits = 2 * (2 - &round_up(log(100 - $percentage) / log(10)));
 217
 218   return sprintf "%.${digits}f", $percentage;
 219 }
 220
 221 sub case_shifts ($) {
 222   # This is a neat trick suggested by freeside.  Thanks freeside!
 223
 224   my $shifts = shift;
 225
 226   $shifts =~ tr/A-Za-z//cd;
 227   $shifts =~ tr/A-Z/U/s;
 228   $shifts =~ tr/a-z/l/s;
 229
 230   return length($shifts) - 1;
 231 }
 232
 233 sub number_shifts ($) {
 234   my $shifts = shift;
 235
 236   $shifts =~ tr/A-Za-z0-9//cd;
 237   $shifts =~ tr/A-Za-z/l/s;
 238   $shifts =~ tr/0-9/n/s;
 239
 240   return length($shifts) - 1;
 241 }
 242
 243 sub slow_pow ($$) {
 244   my ($x, $y) = @_;
 245
 246   return $x ** &slow_exponent($y);
 247 }
 248
 249 sub slow_exponent ($) {
 250   my $x = shift;
 251
 252   return 1.3 * $x * (1 - &Math::Trig::atan($x/6) *2/$pi);
 253 }
 254
 255 sub round_up ($) {
 256   my $float = shift;
 257
 258   return int($float) + ((int($float) == $float) ? 0 : 1);
 259 }
 260
 261 sub punish ($$) {
 262   my ($damage, $reason) = @_;
 263
 264   return unless $damage;
 265
 266   $score += $damage;
 267   print "$damage lameness points awarded: $reason\n" if $verbose;
 268 }
 269
 270 1;