bin/debbugs-installsql

   1 #!/usr/bin/perl
   2 # debbugs-installsql installs the SQL database using DBIx::Class::DeploymentHandler
   3 # and is released under the terms of the GNU GPL version 3, or any
   4 # later version, at your option. See the file README and COPYING for
   5 # more information.
   6 # Copyright 2013-2014 by Don Armstrong <don@donarmstrong.com>.
   7
   8
   9 use warnings;
  10 use strict;
  11
  12 use Getopt::Long;
  13 use Pod::Usage;
  14
  15 =head1 NAME
  16
  17 debbugs-installsql - installs the SQL database using DBIx::Class::DeploymentHandler
  18
  19 =head1 SYNOPSIS
  20
  21 debbugs-installsql [ --upgrade | --install ]
  22
  23  Options:
  24   --service postgresql service to connect to
  25   --sysconfdir postgresql system configuration directory
  26   --deployment-dir SQL deployment directory
  27   --debug, -d debugging level (Default 0)
  28   --help, -h display this help
  29   --man, -m display manual
  30
  31 =head1 OPTIONS
  32
  33 =over
  34
  35 =item B<--service>
  36
  37 Postgresl service to connect to (defaults to debbugs)
  38
  39 =item B<--sysconfdir>
  40
  41 Postgresql sysconf dir. May also be set using the PGSYSCONFDIR
  42 environmental variable (which this option overrides).
  43
  44 =item B<--deployment-dir>
  45
  46 Deployment directory (defaults to /usr/share/debbugs/sqldeployment)
  47
  48 =item B<--debug, -d>
  49
  50 Debug verbosity. (Default 0)
  51
  52 =item B<--help, -h>
  53
  54 Display brief usage information.
  55
  56 =item B<--man, -m>
  57
  58 Display this manual.
  59
  60 =back
  61
  62 =head1 EXAMPLES
  63
  64 debbugs-installsql
  65
  66 =cut
  67
  68
  69 use vars qw($DEBUG);
  70
  71 # if we're running out of git, we want to use the git base directory as the
  72 # first INC directory. If you're not running out of git, or someone has given a
  73 # non-absolute INC, don't do that.
  74 use FindBin;
  75 use if (-d $FindBin::Bin.'/../.git/' && $INC[0] =~ m#^/#),
  76     lib => $FindBin::Bin.'/../';
  77
  78 use Debbugs::DB;
  79 use Debbugs::DB::Util qw(prepare_execute);
  80 use aliased 'DBIx::Class::DeploymentHandler' => 'DH';
  81
  82 my %options = (debug           => 0,
  83                help            => 0,
  84                man             => 0,
  85                overwrite_deployment => 0,
  86                service         => 'debbugs',
  87                deployment_dir  => '/usr/share/debbugs/sqldeployment',
  88               );
  89
  90 GetOptions(\%options,
  91            'service|s=s',
  92            'dsn=s',
  93            'sysconfdir|c=s',
  94            'install',
  95            'install_version_storage|install-version-storage',
  96            'upgrade',
  97            'current_version|current-version',
  98            'overwrite_deployment|overwrite-deployment|force_overwrite|force-overwrite',
  99            'deployment_dir|deployment-dir=s',
 100            'debug|d+','help|h|?','man|m');
 101
 102 pod2usage() if $options{help};
 103 pod2usage({verbose=>2}) if $options{man};
 104
 105 $DEBUG = $options{debug};
 106
 107 my @USAGE_ERRORS;
 108
 109 my @exclusive_options = qw(install upgrade current_version install_version_storage);
 110 if (1 < grep {exists $options{$_}} @exclusive_options) {
 111       push @USAGE_ERRORS,"You must only give one of the ".
 112           join(', ',map {s/_/-/g; "--".$_} @exclusive_options).
 113           " options";
 114 }
 115 if (not grep {exists $options{$_}} @exclusive_options) {
 116     $options{current_version} = 1;
 117 }
 118
 119 pod2usage(join("\n",@USAGE_ERRORS)) if @USAGE_ERRORS;
 120
 121 if (exists $options{sysconfdir}) {
 122     if (not defined $options{sysconfdir} or not length $options{sysconfdir}) {
 123         delete $ENV{PGSYSCONFDIR};
 124     } else {
 125         $ENV{PGSYSCONFDIR} = $options{sysconfdir};
 126     }
 127 }
 128
 129 if (not exists $options{dsn} or
 130     not defined $options{dsn} or
 131     not length $options{dsn}) {
 132     $options{dsn} = 'dbi:Pg:service='.$options{service};
 133 }
 134
 135
 136 my $schema = Debbugs::DB->connect($options{dsn}) or
 137     die "Unable to connect to database";
 138
 139
 140 my $dh = DH->new({schema => $schema,
 141                   force_overwrite => $options{overwrite_deployment},
 142                   script_directory => $options{deployment_dir},
 143                   databases => 'PostgreSQL',
 144                   sql_translator_args => {producer_args=> {postgres_version => 8.1}},
 145                  });
 146
 147 if ($options{current_version}) {
 148     print "The current database version is: ".$dh->database_version."\n";
 149     exit 0;
 150 } elsif ($options{install}) {
 151     $dh->prepare_install;
 152     $dh->install;
 153     ## this is lame, but because the current release of DeploymentHandler does
 154     ## not support WHERE or quoted indexes properly (fixed in git), we create
 155     ## these indexes manually here.
 156     $schema->storage->
 157         dbh_do(sub{my ($s,$dbh) = @_;
 158                    prepare_execute($dbh,<<SQL);
 159 CREATE UNIQUE INDEX bug_status_cache_bug_col_suite_col_arch_idx ON
 160  bug_status_cache(bug,COALESCE(suite,0),COALESCE(arch,0));
 161 CREATE UNIQUE INDEX bug_status_cache_bug_suite_idx ON
 162  bug_status_cache(bug,suite) WHERE arch is NULL;
 163 CREATE UNIQUE INDEX bug_status_cache_bug_idx ON
 164  bug_status_cache(bug) WHERE arch is NULL AND suite IS NULL;
 165 SQL
 166                    });
 167 } elsif ($options{upgrade}) {
 168     $dh->prepare_deploy;
 169     $dh->prepare_upgrade;
 170     $dh->upgrade;
 171 } elsif ($options{install_version_storage}) {
 172     $dh->prepare_version_storage_install;
 173     $dh->install_version_storage;
 174 }
 175
 176
 177 __END__