scm/part-combiner.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 2004--2012 Han-Wen Nienhuys <hanwen@xs4all.nl>
   4 ;;;;
   5 ;;;; LilyPond is free software: you can redistribute it and/or modify
   6 ;;;; it under the terms of the GNU General Public License as published by
   7 ;;;; the Free Software Foundation, either version 3 of the License, or
   8 ;;;; (at your option) any later version.
   9 ;;;;
  10 ;;;; LilyPond is distributed in the hope that it will be useful,
  11 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 ;;;; GNU General Public License for more details.
  14 ;;;;
  15 ;;;; You should have received a copy of the GNU General Public License
  16 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 ;; todo: figure out how to make module,
  19 ;; without breaking nested ly scopes
  20
  21 (define-class <Voice-state> ()
  22   (event-list #:init-value '() #:accessor events #:init-keyword #:events)
  23   (when-moment #:accessor moment #:init-keyword #:moment)
  24   (tuning #:accessor tuning #:init-keyword #:tuning)
  25   (split-index #:accessor split-index)
  26   (vector-index)
  27   (state-vector)
  28   ;;;
  29   ;; spanner-state is an alist
  30   ;; of (SYMBOL . RESULT-INDEX), which indicates where
  31   ;; said spanner was started.
  32   (spanner-state #:init-value '() #:accessor span-state))
  33
  34 (define-method (write (x <Voice-state> ) file)
  35   (display (moment x) file)
  36   (display " evs = " file)
  37   (display (events x) file)
  38   (display " active = " file)
  39   (display (span-state x) file)
  40   (display "\n" file))
  41
  42 (define-method (note-events (vs <Voice-state>))
  43   (define (f? x)
  44     (ly:in-event-class? x 'note-event))
  45   (filter f? (events vs)))
  46
  47 (define-method (previous-voice-state (vs <Voice-state>))
  48   (let ((i (slot-ref vs 'vector-index))
  49         (v (slot-ref vs 'state-vector)))
  50     (if (< 0 i)
  51         (vector-ref v (1- i))
  52         #f)))
  53
  54 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  55
  56 (define-class <Split-state> ()
  57   ;; The automatically determined split configuration
  58   (configuration #:init-value '() #:accessor configuration)
  59   ;; Allow overriding split configuration, takes precedence over configuration
  60   (forced-configuration #:init-value #f #:accessor forced-configuration)
  61   (when-moment #:accessor moment #:init-keyword #:moment)
  62   ;; voice-states are states starting with the Split-state or later
  63   ;;
  64   (is #:init-keyword #:voice-states #:accessor voice-states)
  65   (synced  #:init-keyword #:synced #:init-value  #f #:getter synced?))
  66
  67
  68 (define-method (write (x <Split-state> ) f)
  69   (display (moment x) f)
  70   (display " = " f)
  71   (display (configuration x) f)
  72   (if (synced? x)
  73       (display " synced "))
  74   (display "\n" f))
  75
  76 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  77
  78
  79 (define (previous-span-state vs)
  80   (let ((p (previous-voice-state vs)))
  81     (if p (span-state p) '())))
  82
  83 (define (make-voice-states evl)
  84   (let ((vec (list->vector (map (lambda (v)
  85                                   (make <Voice-state>
  86                                     #:moment (caar v)
  87                                     #:tuning (cdar v)
  88                                     #:events (map car (cdr v))))
  89                                 evl))))
  90     (do ((i 0 (1+ i)))
  91         ((= i (vector-length vec)) vec)
  92       (slot-set! (vector-ref vec i) 'vector-index i)
  93       (slot-set! (vector-ref vec i) 'state-vector vec))))
  94
  95 (define (make-split-state vs1 vs2)
  96   "Merge lists VS1 and VS2, containing Voice-state objects into vector
  97 of Split-state objects, crosslinking the Split-state vector and
  98 Voice-state objects
  99 "
 100   (define (helper ss-idx ss-list idx1 idx2)
 101     (let* ((state1 (if (< idx1 (vector-length vs1)) (vector-ref vs1 idx1) #f))
 102            (state2 (if (< idx2 (vector-length vs2)) (vector-ref vs2 idx2) #f))
 103            (min (cond ((and state1 state2) (moment-min (moment state1) (moment state2)))
 104                       (state1 (moment state1))
 105                       (state2 (moment state2))
 106                       (else #f)))
 107            (inc1 (if (and state1 (equal? min (moment state1))) 1 0))
 108            (inc2 (if (and state2 (equal? min (moment state2))) 1 0))
 109            (ss-object (if min
 110                           (make <Split-state>
 111                             #:moment min
 112                             #:voice-states (cons state1 state2)
 113                             #:synced (= inc1 inc2))
 114                           #f)))
 115       (if state1
 116           (set! (split-index state1) ss-idx))
 117       (if state2
 118           (set! (split-index state2) ss-idx))
 119       (if min
 120           (helper (1+ ss-idx)
 121                   (cons ss-object ss-list)
 122                   (+ idx1 inc1)
 123                   (+ idx2 inc2))
 124           ss-list)))
 125   (list->vector (reverse! (helper 0 '() 0  0) '())))
 126
 127 (define (analyse-spanner-states voice-state-vec)
 128
 129   (define (helper index active)
 130     "Analyse EVS at INDEX, given state ACTIVE."
 131
 132     (define (analyse-tie-start active ev)
 133       (if (ly:in-event-class? ev 'tie-event)
 134           (acons 'tie (split-index (vector-ref voice-state-vec index))
 135                  active)
 136           active))
 137
 138     (define (analyse-tie-end active ev)
 139       (if (ly:in-event-class? ev 'note-event)
 140           (assoc-remove! active 'tie)
 141           active))
 142
 143     (define (analyse-absdyn-end active ev)
 144       (if (or (ly:in-event-class? ev 'absolute-dynamic-event)
 145               (and (ly:in-event-class? ev 'span-dynamic-event)
 146                    (equal? STOP (ly:event-property ev 'span-direction))))
 147           (assoc-remove! (assoc-remove! active 'cresc) 'decr)
 148           active))
 149
 150     (define (active<? a b)
 151       (cond ((symbol<? (car a) (car b)) #t)
 152             ((symbol<? (car b) (car a)) #f)
 153             (else (< (cdr a) (cdr b)))))
 154
 155     (define (analyse-span-event active ev)
 156       (let* ((name (car (ly:event-property ev 'class)))
 157              (key (cond ((equal? name 'slur-event) 'slur)
 158                         ((equal? name 'phrasing-slur-event) 'tie)
 159                         ((equal? name 'beam-event) 'beam)
 160                         ((equal? name 'crescendo-event) 'cresc)
 161                         ((equal? name 'decrescendo-event) 'decr)
 162                         (else #f)))
 163              (sp (ly:event-property ev 'span-direction)))
 164         (if (and (symbol? key) (ly:dir? sp))
 165             (if (= sp STOP)
 166                 (assoc-remove! active key)
 167                 (acons key
 168                        (split-index (vector-ref voice-state-vec index))
 169                        active))
 170             active)))
 171
 172     (define (analyse-events active evs)
 173       "Run all analyzers on ACTIVE and EVS"
 174       (define (run-analyzer analyzer active evs)
 175         (if (pair? evs)
 176             (run-analyzer analyzer (analyzer active (car evs)) (cdr evs))
 177             active))
 178       (define (run-analyzers analyzers active evs)
 179         (if (pair? analyzers)
 180             (run-analyzers (cdr analyzers)
 181                            (run-analyzer (car analyzers) active evs)
 182                            evs)
 183             active))
 184       (sort ;; todo: use fold or somesuch.
 185        (run-analyzers (list analyse-absdyn-end analyse-span-event
 186                             ;; note: tie-start/span comes after tie-end/absdyn.
 187                             analyse-tie-end analyse-tie-start)
 188                       active evs)
 189        active<?))
 190
 191     ;; must copy, since we use assoc-remove!
 192     (if (< index (vector-length voice-state-vec))
 193         (begin
 194           (set! active (analyse-events active (events (vector-ref voice-state-vec index))))
 195           (set! (span-state (vector-ref voice-state-vec index))
 196                 (list-copy active))
 197           (helper (1+ index) active))))
 198
 199   (helper 0 '()))
 200
 201 (define recording-group-functions
 202   ;;Selected parts from @var{toplevel-music-functions} not requiring @code{parser}.
 203   (list
 204    (lambda (music) (expand-repeat-chords! '(rhythmic-event) music))))
 205
 206
 207 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 208 (define-public (recording-group-emulate music odef)
 209   "Interpret @var{music} according to @var{odef}, but store all events
 210 in a chronological list, similar to the @code{Recording_group_engraver} in
 211 LilyPond version 2.8 and earlier."
 212   (let*
 213       ((context-list '())
 214        (now-mom (ly:make-moment 0 0))
 215        (global (ly:make-global-context odef))
 216        (mom-listener (ly:make-listener
 217                       (lambda (tev) (set! now-mom (ly:event-property tev 'moment)))))
 218        (new-context-listener
 219         (ly:make-listener
 220          (lambda (sev)
 221            (let*
 222                ((child (ly:event-property sev 'context))
 223                 (this-moment-list (cons (ly:context-id child) '()))
 224                 (dummy (set! context-list (cons this-moment-list context-list)))
 225                 (acc '())
 226                 (accumulate-event-listener
 227                  (ly:make-listener (lambda (ev)
 228                                      (set! acc (cons (cons ev #t) acc)))))
 229                 (save-acc-listener
 230                  (ly:make-listener (lambda (tev)
 231                                      (if (pair? acc)
 232                                          (let ((this-moment
 233                                                 (cons (cons now-mom
 234                                                             (ly:context-property child 'instrumentTransposition))
 235                                                       ;; The accumulate-event-listener above creates
 236                                                       ;; the list of events in reverse order, so we
 237                                                       ;; have to revert it to the original order again
 238                                                       (reverse acc))))
 239                                            (set-cdr! this-moment-list
 240                                                      (cons this-moment (cdr this-moment-list)))
 241                                            (set! acc '())))))))
 242              (ly:add-listener accumulate-event-listener
 243                               (ly:context-event-source child) 'StreamEvent)
 244              (ly:add-listener save-acc-listener
 245                               (ly:context-event-source global) 'OneTimeStep))))))
 246     (ly:add-listener new-context-listener
 247                      (ly:context-events-below global) 'AnnounceNewContext)
 248     (ly:add-listener mom-listener (ly:context-event-source global) 'Prepare)
 249     (ly:interpret-music-expression
 250      (make-non-relative-music
 251       (fold (lambda (x m) (x m)) music recording-group-functions))
 252      global)
 253     context-list))
 254
 255 (define-public (make-part-combine-music parser music-list direction)
 256   (let* ((m (make-music 'PartCombineMusic))
 257          (m1 (make-non-relative-music (context-spec-music (first music-list) 'Voice "one")))
 258          (m2  (make-non-relative-music  (context-spec-music (second music-list) 'Voice "two")))
 259          (listener (ly:parser-lookup parser 'partCombineListener))
 260          (evs2 (recording-group-emulate m2 listener))
 261          (evs1 (recording-group-emulate m1 listener)))
 262
 263     (set! (ly:music-property m 'elements) (list m1 m2))
 264     (set! (ly:music-property m 'direction) direction)
 265     (set! (ly:music-property m 'split-list)
 266           (if (and (assoc "one" evs1) (assoc "two" evs2))
 267               (determine-split-list (reverse! (assoc-get "one" evs1) '())
 268                                     (reverse! (assoc-get "two" evs2) '()))
 269               '()))
 270     m))
 271
 272 (define-public (determine-split-list evl1 evl2)
 273   "@var{evl1} and @var{evl2} should be ascending."
 274   (let* ((pc-debug #f)
 275          (chord-threshold 8)
 276          (voice-state-vec1 (make-voice-states evl1))
 277          (voice-state-vec2 (make-voice-states evl2))
 278          (result (make-split-state voice-state-vec1 voice-state-vec2)))
 279
 280     ;; Go through all moments recursively and check if the events of that
 281     ;; moment contain a part-combine-force-event override. If so, store its
 282     ;; value in the forced-configuration field, which will override. The
 283     ;; previous configuration is used to determine non-terminated settings.
 284     (define (analyse-forced-combine result-idx prev-res)
 285
 286       (define (get-forced-event x)
 287         (and (ly:in-event-class? x 'part-combine-force-event)
 288              (cons (ly:event-property x 'forced-type)
 289                    (ly:event-property x 'once))))
 290       (define (part-combine-events vs)
 291         (if (not vs)
 292             '()
 293             (filter-map get-forced-event (events vs))))
 294       ;; end part-combine-events
 295
 296       ;; forced-result: Take the previous config and analyse whether
 297       ;; any change happened.... Return new once and permanent config
 298       (define (forced-result evt state)
 299         ;; sanity check, evt should always be (new-state . once)
 300         (if (not (and (pair? evt) (pair? state)))
 301             state
 302             (if (cdr evt)
 303                 ;; Once-event, leave permanent state unchanged
 304                 (cons (car evt) (cdr state))
 305                 ;; permanent change, leave once state unchanged
 306                 (cons (car state) (car evt)))))
 307       ;; end forced-combine-result
 308
 309       ;; body of analyse-forced-combine:
 310       (if (< result-idx (vector-length result))
 311           (let* ((now-state (vector-ref result result-idx)) ; current result
 312                  ;; Extract all part-combine force events
 313                  (ev1 (part-combine-events (car (voice-states now-state))))
 314                  (ev2 (part-combine-events (cdr (voice-states now-state))))
 315                  (evts (append ev1 ev2))
 316                  ;; result is (once-state permament-state):
 317                  (state (fold forced-result (cons 'automatic prev-res) evts))
 318                  ;; Now let once override permanent changes:
 319                  (force-state (if (equal? (car state) 'automatic)
 320                                   (cdr state)
 321                                   (car state))))
 322             (set! (forced-configuration (vector-ref result result-idx))
 323                   force-state)
 324             ;; For the next moment, ignore the once override (car stat)
 325             ;; and pass on the permanent override, stored as (cdr state)
 326             (analyse-forced-combine (1+ result-idx) (cdr state)))))
 327     ;; end analyse-forced-combine
 328
 329
 330     (define (analyse-time-step result-idx)
 331       (define (put x . index)
 332         "Put the result to X, starting from INDEX backwards.
 333
 334 Only set if not set previously.
 335 "
 336         (let ((i (if (pair? index) (car index) result-idx)))
 337           (if (and (<= 0 i)
 338                    (not (symbol? (configuration (vector-ref result i)))))
 339               (begin
 340                 (set! (configuration (vector-ref result i)) x)
 341                 (put x (1- i))))))
 342
 343       (define (copy-state-from state-vec vs)
 344         (define (copy-one-state key-idx)
 345           (let* ((idx (cdr key-idx))
 346                  (prev-ss (vector-ref result idx))
 347                  (prev (configuration prev-ss)))
 348             (if (symbol? prev)
 349                 (put prev))))
 350         (for-each copy-one-state (span-state vs)))
 351
 352       (define (analyse-notes now-state)
 353         (let* ((vs1 (car (voice-states now-state)))
 354                (vs2 (cdr (voice-states now-state)))
 355                (notes1 (note-events vs1))
 356                (durs1 (sort (map (lambda (x) (ly:event-property x 'duration))
 357                                  notes1)
 358                             ly:duration<?))
 359                (pitches1 (sort (map (lambda (x) (ly:event-property x 'pitch))
 360                                     notes1)
 361                                ly:pitch<?))
 362                (notes2 (note-events vs2))
 363                (durs2 (sort (map (lambda (x) (ly:event-property x 'duration))
 364                                  notes2)
 365                             ly:duration<?))
 366                (pitches2 (sort (map (lambda (x) (ly:event-property x 'pitch))
 367                                     notes2)
 368                                ly:pitch<?)))
 369           (cond ((> (length notes1) 1) (put 'apart))
 370                 ((> (length notes2) 1) (put 'apart))
 371                 ((= 1 (+ (length notes2) (length notes1))) (put 'apart))
 372                 ((and (= (length durs1) 1)
 373                       (= (length durs2) 1)
 374                       (not (equal? (car durs1) (car durs2))))
 375                  (put 'apart))
 376                 (else
 377                  (if (and (= (length pitches1) (length pitches2)))
 378                      (if (and (pair? pitches1)
 379                               (pair? pitches2)
 380                               (or
 381                                (< chord-threshold (ly:pitch-steps
 382                                                    (ly:pitch-diff (car pitches1)
 383                                                                   (car pitches2))))
 384
 385                                ;; voice crossings:
 386                                (> 0 (ly:pitch-steps (ly:pitch-diff (car pitches1)
 387                                                                    (car pitches2))))
 388                                ))
 389                          (put 'apart)
 390                          ;; copy previous split state from spanner state
 391                          (begin
 392                            (if (previous-voice-state vs1)
 393                                (copy-state-from voice-state-vec1
 394                                                 (previous-voice-state vs1)))
 395                            (if (previous-voice-state vs2)
 396                                (copy-state-from voice-state-vec2
 397                                                 (previous-voice-state vs2)))
 398                            (if (and (null? (span-state vs1)) (null? (span-state vs2)))
 399                                (put 'chords)))))))))
 400
 401       (if (< result-idx (vector-length result))
 402           (let* ((now-state (vector-ref result result-idx))
 403                  (vs1 (car (voice-states now-state)))
 404                  (vs2 (cdr (voice-states now-state))))
 405
 406             (cond ((not vs1) (put 'apart))
 407                   ((not vs2) (put 'apart))
 408                   (else
 409                    (let ((active1 (previous-span-state vs1))
 410                          (active2 (previous-span-state vs2))
 411                          (new-active1 (span-state vs1))
 412                          (new-active2 (span-state vs2)))
 413                      (if #f ; debug
 414                          (display (list (moment now-state) result-idx
 415                                         active1 "->" new-active1
 416                                         active2 "->" new-active2
 417                                         "\n")))
 418                      (if (and (synced? now-state)
 419                               (equal? active1 active2)
 420                               (equal? new-active1 new-active2))
 421                          (analyse-notes now-state)
 422
 423                          ;; active states different:
 424                          (put 'apart)))
 425
 426                    ;; go to the next one, if it exists.
 427                    (analyse-time-step (1+ result-idx)))))))
 428
 429     (define (analyse-a2 result-idx)
 430       (if (< result-idx (vector-length result))
 431           (let* ((now-state (vector-ref result result-idx))
 432                  (vs1 (car (voice-states now-state)))
 433                  (vs2 (cdr (voice-states now-state))))
 434             (if (and (equal? (configuration now-state) 'chords)
 435                      vs1 vs2)
 436                 (let ((notes1 (note-events vs1))
 437                       (notes2 (note-events vs2)))
 438                   (cond ((and (= 1 (length notes1))
 439                               (= 1 (length notes2))
 440                               (equal? (ly:event-property (car notes1) 'pitch)
 441                                       (ly:event-property (car notes2) 'pitch)))
 442                          (set! (configuration now-state) 'unisono))
 443                         ((and (= 0 (length notes1))
 444                               (= 0 (length notes2)))
 445                          (set! (configuration now-state) 'unisilence)))))
 446             (analyse-a2 (1+ result-idx)))))
 447
 448     (define (analyse-solo12 result-idx)
 449
 450       (define (previous-config vs)
 451         (let* ((pvs (previous-voice-state vs))
 452                (spi (if pvs (split-index pvs) #f))
 453                (prev-split (if spi (vector-ref result spi) #f)))
 454           (if prev-split
 455               (configuration prev-split)
 456               'apart)))
 457
 458       (define (put-range x a b)
 459         ;; (display (list "put range "  x a b "\n"))
 460         (do ((i a (1+ i)))
 461             ((> i b) b)
 462           (set! (configuration (vector-ref result i)) x)))
 463
 464       (define (put x)
 465         ;; (display (list "putting "  x "\n"))
 466         (set! (configuration (vector-ref result result-idx)) x))
 467
 468       (define (current-voice-state now-state voice-num)
 469         (define vs ((if (= 1 voice-num) car cdr)
 470                     (voice-states now-state)))
 471         (if (or (not vs) (equal? (moment now-state) (moment vs)))
 472             vs
 473             (previous-voice-state vs)))
 474
 475       (define (try-solo type start-idx current-idx)
 476         "Find a maximum stretch that can be marked as solo.  Only set
 477 the mark when there are no spanners active.
 478
 479       return next idx to analyse.
 480 "
 481         (if (< current-idx (vector-length result))
 482             (let* ((now-state (vector-ref result current-idx))
 483                    (solo-state (current-voice-state now-state (if (equal? type 'solo1) 1 2)))
 484                    (silent-state (current-voice-state now-state (if (equal? type 'solo1) 2 1)))
 485                    (silent-notes (if silent-state (note-events silent-state) '()))
 486                    (solo-notes (if solo-state (note-events solo-state) '())))
 487               ;; (display (list "trying " type " at "  (moment now-state) solo-state silent-state        "\n"))
 488               (cond ((not (equal? (configuration now-state) 'apart))
 489                      current-idx)
 490                     ((> (length silent-notes) 0) start-idx)
 491                     ((not solo-state)
 492                      (put-range type start-idx current-idx)
 493                      current-idx)
 494                     ((and
 495                       (null? (span-state solo-state)))
 496
 497                      ;;
 498                      ;; This includes rests. This isn't a problem: long rests
 499                      ;; will be shared with the silent voice, and be marked
 500                      ;; as unisilence. Therefore, long rests won't
 501                      ;;  accidentally be part of a solo.
 502                      ;;
 503                      (put-range type start-idx current-idx)
 504                      (try-solo type (1+ current-idx) (1+  current-idx)))
 505                     (else
 506                      (try-solo type start-idx (1+ current-idx)))))
 507             ;; try-solo
 508             start-idx))
 509
 510       (define (analyse-moment result-idx)
 511         "Analyse 'apart starting at RESULT-IDX.  Return next index."
 512         (let* ((now-state (vector-ref result result-idx))
 513                (vs1 (current-voice-state now-state 1))
 514                (vs2 (current-voice-state now-state 2))
 515                ;; (vs1 (car (voice-states now-state)))
 516                ;; (vs2 (cdr (voice-states now-state)))
 517                (notes1 (if vs1 (note-events vs1) '()))
 518                (notes2 (if vs2 (note-events vs2) '()))
 519                (n1 (length notes1))
 520                (n2 (length notes2)))
 521           ;; (display (list "analyzing step " result-idx "  moment " (moment now-state) vs1 vs2  "\n"))
 522           (max
 523            ;; we should always increase.
 524            (cond ((and (= n1 0) (= n2 0))
 525                   (put 'apart-silence)
 526                   (1+ result-idx))
 527                  ((and (= n2 0)
 528                        (equal? (moment vs1) (moment now-state))
 529                        (null? (previous-span-state vs1)))
 530                   (try-solo 'solo1 result-idx result-idx))
 531                  ((and (= n1 0)
 532                        (equal? (moment vs2) (moment now-state))
 533                        (null? (previous-span-state vs2)))
 534                   (try-solo 'solo2 result-idx result-idx))
 535
 536                  (else (1+ result-idx)))
 537            ;; analyse-moment
 538            (1+ result-idx))))
 539
 540       (if (< result-idx (vector-length result))
 541           (if (equal? (configuration (vector-ref result result-idx)) 'apart)
 542               (analyse-solo12 (analyse-moment result-idx))
 543               (analyse-solo12 (1+ result-idx))))) ; analyse-solo12
 544
 545     (analyse-spanner-states voice-state-vec1)
 546     (analyse-spanner-states voice-state-vec2)
 547     (if #f
 548         (begin
 549           (display voice-state-vec1)
 550           (display "***\n")
 551           (display voice-state-vec2)
 552           (display "***\n")
 553           (display result)
 554           (display "***\n")))
 555
 556     ;; Extract all forced combine strategies, i.e. events inserted by
 557     ;; \partcombine(Apart|Automatic|SoloI|SoloII|Chords)[Once]
 558     ;; They will in the end override the automaically determined ones.
 559     ;; Initial state for both voices is no override
 560     (analyse-forced-combine 0 #f)
 561     ;; Now go through all time steps in a loop and find a combination strategy
 562     ;; based only on the events of that one moment (i.e. neglecting longer
 563     ;; periods of solo/apart, etc.)
 564     (analyse-time-step 0)
 565     ;; (display result)
 566     ;; Check for unisono or unisilence moments
 567     (analyse-a2 0)
 568     ;;(display result)
 569     (analyse-solo12 0)
 570     ;; (display result)
 571     (set! result (map
 572                   ;; forced-configuration overrides, if it is set
 573                   (lambda (x) (cons (moment x) (or (forced-configuration x) (configuration x))))
 574                   (vector->list result)))
 575     (if #f ;; pc-debug
 576         (display result))
 577     result))
 578
 579
 580 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 581
 582 (define-public (add-quotable parser name mus)
 583   (let* ((tab (eval 'musicQuotes (current-module)))
 584          (voicename (get-next-unique-voice-name))
 585          ;; recording-group-emulate returns an assoc list (reversed!), so
 586          ;; hand it a proper unique context name and extract that key:
 587          (ctx-spec (context-spec-music mus 'Voice voicename))
 588          (listener (ly:parser-lookup parser 'partCombineListener))
 589          (context-list (reverse (recording-group-emulate ctx-spec listener)))
 590          (raw-voice (assoc voicename context-list))
 591          (quote-contents (if (pair? raw-voice) (cdr raw-voice) '())))
 592
 593     ;; If the context-specced quoted music does not contain anything, try to
 594     ;; use the first child, i.e. the next in context-list after voicename
 595     ;; That's the case e.g. for \addQuote "x" \relative c \new Voice {...}
 596     (if (null? quote-contents)
 597         (let find-non-empty ((current-tail (member raw-voice context-list)))
 598           ;; if voice has contents, use them, otherwise check next ctx
 599           (cond ((null? current-tail) #f)
 600                 ((and (pair? (car current-tail))
 601                       (pair? (cdar current-tail)))
 602                  (set! quote-contents (cdar current-tail)))
 603                 (else (find-non-empty (cdr current-tail))))))
 604
 605     (if (not (null? quote-contents))
 606         (hash-set! tab name (list->vector (reverse! quote-contents '())))
 607         (ly:music-warning mus (ly:format (_ "quoted music `~a' is empty") name)))))