scm/define-music-display-methods.scm

   1 ;;; define-music-display-methods.scm -- data for displaying music
   2 ;;; expressions using LilyPond notation.
   3 ;;;
   4 ;;; Copyright (C) 2005--2012 Nicolas Sceaux  <nicolas.sceaux@free.fr>
   5 ;;;
   6
   7 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
   8 ;;;
   9 ;;; Display method implementation
  10 ;;;
  11
  12 (define-module (scm display-lily))
  13
  14 ;;;
  15 ;;; Scheme forms
  16 ;;;
  17 (define (scheme-expr->lily-string scm-arg)
  18   (cond ((or (number? scm-arg)
  19              (string? scm-arg)
  20              (boolean? scm-arg))
  21          (format #f "~s" scm-arg))
  22         ((or (symbol? scm-arg)
  23              (list? scm-arg))
  24          (format #f "'~s" scm-arg))
  25         ((procedure? scm-arg)
  26          (format #f "~a"
  27                  (or (procedure-name scm-arg)
  28                      (with-output-to-string
  29                        (lambda ()
  30                          (pretty-print (procedure-source scm-arg)))))))
  31         (else
  32          (format #f "~a"
  33                  (with-output-to-string
  34                    (lambda ()
  35                      (display-scheme-music scm-arg)))))))
  36 ;;;
  37 ;;; Markups
  38 ;;;
  39
  40 (define-public (markup->lily-string markup-expr)
  41   "Return a string describing, in LilyPond syntax, the given markup
  42 expression."
  43   (define (proc->command proc)
  44     (let ((cmd-markup (symbol->string (procedure-name proc))))
  45       (substring cmd-markup 0 (- (string-length cmd-markup)
  46                                  (string-length "-markup")))))
  47   (define (arg->string arg)
  48     (cond ((string? arg)
  49            (format #f "~s" arg))
  50           ((markup? arg) ;; a markup
  51            (markup->lily-string-aux arg))
  52           ((and (pair? arg) (every markup? arg)) ;; a markup list
  53            (format #f "{~{ ~a~}}" (map-in-order markup->lily-string-aux arg)))
  54           (else          ;; a scheme argument
  55            (format #f "#~a" (scheme-expr->lily-string arg)))))
  56   (define (markup->lily-string-aux expr)
  57     (if (string? expr)
  58         (format #f "~s" expr)
  59         (let ((cmd (car expr))
  60               (args (cdr expr)))
  61           (if (eqv? cmd simple-markup) ;; a simple markup
  62               (format #f "~s" (car args))
  63               (format #f "\\~a~{ ~a~}"
  64                       (proc->command cmd)
  65                       (map-in-order arg->string args))))))
  66   (cond ((string? markup-expr)
  67          (format #f "~s" markup-expr))
  68         ((eqv? (car markup-expr) simple-markup)
  69          (format #f "~s" (second markup-expr)))
  70         (else
  71          (format #f "\\markup ~a"
  72                  (markup->lily-string-aux markup-expr)))))
  73
  74 ;;;
  75 ;;; pitch names
  76 ;;;
  77
  78 ;; It is a pity that there is no rassoc in Scheme.
  79 (define* (rassoc item alist #:optional (test equal?))
  80   (do ((alist alist (cdr alist))
  81        (result #f result))
  82       ((or result (null? alist)) result)
  83     (if (and (car alist) (test item (cdar alist)))
  84         (set! result (car alist)))))
  85
  86 (define-public (note-name->lily-string ly-pitch parser)
  87   ;; here we define a custom pitch= function, since we do not want to
  88   ;; test whether octaves are also equal. (otherwise, we would be using equal?)
  89   (define (pitch= pitch1 pitch2)
  90     (and (= (ly:pitch-notename pitch1) (ly:pitch-notename pitch2))
  91          (= (ly:pitch-alteration pitch1) (ly:pitch-alteration pitch2))))
  92   (let ((result (rassoc ly-pitch (ly:parser-lookup parser 'pitchnames) pitch=)))
  93     (if result
  94         (car result)
  95         #f)))
  96
  97 (define-public (octave->lily-string pitch)
  98   (let ((octave (ly:pitch-octave pitch)))
  99     (cond ((>= octave 0)
 100            (make-string (1+ octave) #\'))
 101           ((< octave -1)
 102            (make-string (1- (* -1 octave)) #\,))
 103           (else ""))))
 104
 105 ;;;
 106 ;;; durations
 107 ;;;
 108 (define*-public (duration->lily-string ly-duration #:key (prev-duration (*previous-duration*))
 109                                        (force-duration (*force-duration*))
 110                                        (time-scale (*time-scale*))
 111                                        remember)
 112   (if remember (*previous-duration* ly-duration))
 113   (let ((log2    (ly:duration-log ly-duration))
 114         (dots    (ly:duration-dot-count ly-duration))
 115         (scale (ly:duration-scale ly-duration)))
 116     (if (or force-duration (not prev-duration) (not (equal? ly-duration prev-duration)))
 117         (string-append (case log2
 118                          ((-1) "\\breve")
 119                          ((-2) "\\longa")
 120                          ((-3) "\\maxima")
 121                          (else (number->string (expt 2 log2))))
 122                        (make-string dots #\.)
 123                        (let ((end-scale (/ scale time-scale)))
 124                          (if (= end-scale 1) ""
 125                              (format #f "*~a" end-scale))))
 126         "")))
 127
 128 ;;;
 129 ;;; post events
 130 ;;;
 131
 132 (define (post-event? m)
 133   (music-is-of-type? m 'post-event))
 134
 135 (define* (event-direction->lily-string event #:optional (required #t))
 136   (let ((direction (ly:music-property event 'direction)))
 137     (cond ((or (not direction) (null? direction) (= CENTER direction))
 138            (if required "-" ""))
 139           ((= UP direction) "^")
 140           ((= DOWN direction) "_")
 141           (else ""))))
 142
 143 (define-macro (define-post-event-display-method type vars direction-required str)
 144   `(define-display-method ,type ,vars
 145      (format #f "~a~a"
 146              (event-direction->lily-string ,(car vars) ,direction-required)
 147              ,str)))
 148
 149 (define-macro (define-span-event-display-method type vars direction-required str-start str-stop)
 150   `(define-display-method ,type ,vars
 151      (format #f "~a~a"
 152              (event-direction->lily-string ,(car vars) ,direction-required)
 153              (if (= START (ly:music-property ,(car vars) 'span-direction))
 154                  ,str-start
 155                  ,str-stop))))
 156
 157 (define-display-method HyphenEvent (event parser)
 158   " --")
 159 (define-display-method ExtenderEvent (event parser)
 160   " __")
 161 (define-display-method TieEvent (event parser)
 162   " ~")
 163 (define-display-method BeamForbidEvent (event parser)
 164   "\\noBeam")
 165 (define-display-method StringNumberEvent (event parser)
 166   (format #f "\\~a" (ly:music-property event 'string-number)))
 167
 168
 169 (define-display-method TremoloEvent (event parser)
 170   (let ((tremolo-type (ly:music-property event 'tremolo-type)))
 171     (format #f ":~a" (if (= 0 tremolo-type)
 172                          ""
 173                          tremolo-type))))
 174
 175 (define-display-method ArticulationEvent (event parser) #t
 176   (let* ((articulation  (ly:music-property event 'articulation-type))
 177          (shorthand
 178           (case (string->symbol articulation)
 179             ((marcato) "^")
 180             ((stopped) "+")
 181             ((tenuto)    "-")
 182             ((staccatissimo) "!")
 183             ((accent) ">")
 184             ((staccato) ".")
 185             ((portato) "_")
 186             (else #f))))
 187     (format #f "~a~:[\\~;~]~a"
 188             (event-direction->lily-string event shorthand)
 189             shorthand
 190             (or shorthand articulation))))
 191
 192 (define-post-event-display-method FingeringEvent (event parser) #t
 193   (ly:music-property event 'digit))
 194
 195 (define-post-event-display-method TextScriptEvent (event parser) #t
 196   (markup->lily-string (ly:music-property event 'text)))
 197
 198 (define-post-event-display-method MultiMeasureTextEvent (event parser) #t
 199   (markup->lily-string (ly:music-property event 'text)))
 200
 201 (define-post-event-display-method BendAfterEvent (event parser) #f
 202   (format #f "\\bendAfter #~a " (ly:music-property event 'delta-step)))
 203
 204 (define-post-event-display-method HarmonicEvent (event parser) #f "\\harmonic")
 205 (define-post-event-display-method GlissandoEvent (event parser) #f "\\glissando")
 206 (define-post-event-display-method ArpeggioEvent (event parser) #f "\\arpeggio")
 207 (define-post-event-display-method AbsoluteDynamicEvent (event parser) #f
 208   (format #f "\\~a" (ly:music-property event 'text)))
 209
 210 (define-post-event-display-method StrokeFingerEvent (event parser) #f
 211   (format #f "\\rightHandFinger #~a " (ly:music-property event 'digit)))
 212
 213 (define-span-event-display-method BeamEvent (event parser) #f "[" "]")
 214 (define-span-event-display-method SlurEvent (event parser) #f "(" ")")
 215 (define-span-event-display-method CrescendoEvent (event parser) #f "\\<" "\\!")
 216 (define-span-event-display-method DecrescendoEvent (event parser) #f "\\>" "\\!")
 217 (define-span-event-display-method EpisemaEvent (event parser) #f "\\episemInitium" "\\episemFinis")
 218 (define-span-event-display-method PhrasingSlurEvent (event parser) #f "\\(" "\\)")
 219 (define-span-event-display-method SustainEvent (event parser) #f "\\sustainOn" "\\sustainOff")
 220 (define-span-event-display-method SostenutoEvent (event parser) #f "\\sostenutoOn" "\\sostenutoOff")
 221 (define-span-event-display-method TextSpanEvent (event parser) #f "\\startTextSpan" "\\stopTextSpan")
 222 (define-span-event-display-method TrillSpanEvent (event parser) #f "\\startTrillSpan" "\\stopTrillSpan")
 223 (define-span-event-display-method StaffSpanEvent (event parser) #f "\\startStaff" "\\stopStaff")
 224 (define-span-event-display-method NoteGroupingEvent (event parser) #f "\\startGroup" "\\stopGroup")
 225 (define-span-event-display-method UnaCordaEvent (event parser) #f "\\unaCorda" "\\treCorde")
 226
 227 ;;;
 228 ;;; Graces
 229 ;;;
 230
 231 (define-display-method GraceMusic (expr parser)
 232   (format #f "\\grace ~a"
 233           (music->lily-string (ly:music-property expr 'element) parser)))
 234
 235 ;; \acciaccatura \appoggiatura \grace
 236 ;; TODO: it would be better to compare ?start and ?stop
 237 ;; with startAppoggiaturaMusic and stopAppoggiaturaMusic,
 238 ;; using a custom music equality predicate.
 239 (define-extra-display-method GraceMusic (expr parser)
 240   "Display method for appoggiatura."
 241   (with-music-match (expr (music
 242                            'GraceMusic
 243                            element (music
 244                                     'SequentialMusic
 245                                     elements (?start
 246                                               ?music
 247                                               ?stop))))
 248                     ;; we check whether ?start and ?stop look like
 249                     ;; startAppoggiaturaMusic stopAppoggiaturaMusic
 250                     (and (with-music-match (?start (music
 251                                                     'SequentialMusic
 252                                                     elements ((music
 253                                                                'EventChord
 254                                                                elements
 255                                                                ((music
 256                                                                  'SlurEvent
 257                                                                  span-direction START))))))
 258                                            #t)
 259                          (with-music-match (?stop (music
 260                                                    'SequentialMusic
 261                                                    elements ((music
 262                                                               'EventChord
 263                                                               elements
 264                                                               ((music
 265                                                                 'SlurEvent
 266                                                                 span-direction STOP))))))
 267                                            (format #f "\\appoggiatura ~a" (music->lily-string ?music parser))))))
 268
 269
 270 (define-extra-display-method GraceMusic (expr parser)
 271   "Display method for acciaccatura."
 272   (with-music-match (expr (music
 273                            'GraceMusic
 274                            element (music
 275                                     'SequentialMusic
 276                                     elements (?start
 277                                               ?music
 278                                               ?stop))))
 279                     ;; we check whether ?start and ?stop look like
 280                     ;; startAcciaccaturaMusic stopAcciaccaturaMusic
 281                     (and (with-music-match (?start (music
 282                                                     'SequentialMusic
 283                                                     elements ((music
 284                                                                'EventChord
 285                                                                elements
 286                                                                ((music
 287                                                                  'SlurEvent
 288                                                                  span-direction START)))
 289                                                               (music
 290                                                                'ContextSpeccedMusic
 291                                                                element (music
 292                                                                         'OverrideProperty
 293                                                                         grob-property-path '(stroke-style)
 294                                                                         grob-value "grace"
 295                                                                         symbol 'Flag)))))
 296                                            #t)
 297                          (with-music-match (?stop (music
 298                                                    'SequentialMusic
 299                                                    elements ((music
 300                                                               'ContextSpeccedMusic
 301                                                               element (music
 302                                                                        'RevertProperty
 303                                                                        grob-property-path '(stroke-style)
 304                                                                        symbol 'Flag))
 305
 306                                                              (music
 307                                                               'EventChord
 308                                                               elements
 309                                                               ((music
 310                                                                 'SlurEvent
 311                                                                 span-direction STOP))))))
 312                                            (format #f "\\acciaccatura ~a" (music->lily-string ?music parser))))))
 313
 314 (define-extra-display-method GraceMusic (expr parser)
 315   "Display method for grace."
 316   (with-music-match (expr (music
 317                            'GraceMusic
 318                            element (music
 319                                     'SequentialMusic
 320                                     elements (?start
 321                                               ?music
 322                                               ?stop))))
 323                     ;; we check whether ?start and ?stop look like
 324                     ;; startGraceMusic stopGraceMusic
 325                     (and (null? (ly:music-property ?start 'elements))
 326                          (null? (ly:music-property ?stop 'elements))
 327                          (format #f "\\grace ~a" (music->lily-string ?music parser)))))
 328
 329 ;;;
 330 ;;; Music sequences
 331 ;;;
 332
 333 (define-display-method SequentialMusic (seq parser)
 334   (let ((force-line-break (and (*force-line-break*)
 335                                ;; hm
 336                                (> (length (ly:music-property seq 'elements))
 337                                   (*max-element-number-before-break*))))
 338         (elements (ly:music-property seq 'elements))
 339         (chord? (make-music-type-predicate 'EventChord))
 340         (note-or-chord? (make-music-type-predicate 'EventChord 'NoteEvent
 341                                                    'LyricEvent 'RestEvent
 342                                                    'ClusterNoteEvent))
 343         (cluster? (make-music-type-predicate 'ClusterNoteEvent))
 344         (note? (make-music-type-predicate 'NoteEvent)))
 345     (format #f "~a~a{~v%~v_~{~a~^ ~}~v%~v_}"
 346             (if (any (lambda (e)
 347                        (or (cluster? e)
 348                            (and (chord? e)
 349                                 (any cluster? (ly:music-property e 'elements)))))
 350                      elements)
 351                 "\\makeClusters "
 352                 "")
 353             (if (*explicit-mode*)
 354                 ;; if the sequence contains EventChord which contains figures ==> figuremode
 355                 ;; if the sequence contains EventChord which contains lyrics ==> lyricmode
 356                 ;; if the sequence contains EventChord which contains drum notes ==> drummode
 357                 (cond ((any (lambda (chord)
 358                               (any (make-music-type-predicate 'BassFigureEvent)
 359                                    (ly:music-property chord 'elements)))
 360                             (filter chord? elements))
 361                        "\\figuremode ")
 362                       ((any (lambda (chord)
 363                               (any (make-music-type-predicate 'LyricEvent)
 364                                    (cons chord
 365                                          (ly:music-property chord 'elements))))
 366                             (filter note-or-chord? elements))
 367                        "\\lyricmode ")
 368                       ((any (lambda (chord)
 369                               (any (lambda (event)
 370                                      (and (note? event)
 371                                           (not (null? (ly:music-property event 'drum-type)))))
 372                                    (cons chord
 373                                          (ly:music-property chord 'elements))))
 374                             (filter note-or-chord? elements))
 375                        "\\drummode ")
 376                       (else ;; TODO: other modes?
 377                        ""))
 378                 "")
 379             (if force-line-break 1 0)
 380             (if force-line-break (+ 2 (*indent*)) 1)
 381             (parameterize ((*indent* (+ 2 (*indent*))))
 382                           (map-in-order (lambda (music)
 383                                           (music->lily-string music parser))
 384                                         elements))
 385             (if force-line-break 1 0)
 386             (if force-line-break (*indent*) 1))))
 387
 388 (define-display-method SimultaneousMusic (sim parser)
 389   (parameterize ((*indent* (+ 3 (*indent*))))
 390                 (format #f "<< ~{~a ~}>>"
 391                         (map-in-order (lambda (music)
 392                                         (music->lily-string music parser))
 393                                       (ly:music-property sim 'elements)))))
 394
 395 (define-extra-display-method SimultaneousMusic (expr parser)
 396   "If `sim' is an \afterGrace expression, return \"\\afterGrace ...\".
 397 Otherwise, return #f."
 398   ;; TODO: do something with afterGraceFraction?
 399   (with-music-match (expr (music 'SimultaneousMusic
 400                                  elements (?before-grace
 401                                            (music 'SequentialMusic
 402                                                   elements ((music 'SkipMusic)
 403                                                             (music 'GraceMusic
 404                                                                    element ?grace))))))
 405                     (format #f "\\afterGrace ~a ~a"
 406                             (music->lily-string ?before-grace parser)
 407                             (music->lily-string ?grace parser))))
 408
 409 ;;;
 410 ;;; Chords
 411 ;;;
 412
 413 (define-display-method EventChord (chord parser)
 414   ;; event_chord : command_element
 415   ;;               | note_chord_element
 416
 417   ;; TODO : tagged post_events
 418   ;; post_events : ( post_event | tagged_post_event )*
 419   ;; tagged_post_event: '-' \tag embedded_scm post_event
 420
 421   (let* ((elements (append (ly:music-property chord 'elements)
 422                            (ly:music-property chord 'articulations)))
 423          (chord-repeat (ly:music-property chord 'duration)))
 424     (call-with-values
 425         (lambda ()
 426           (partition (lambda (m) (music-is-of-type? m 'rhythmic-event))
 427                      elements))
 428       (lambda (chord-elements other-elements)
 429         (cond ((pair? chord-elements)
 430                ;; note_chord_element :
 431                ;; '<' (notepitch | drumpitch)* '>" duration post_events
 432                (let ((duration (duration->lily-string (ly:music-property
 433                                                        (car chord-elements)
 434                                                        'duration)
 435                                                       #:remember #t)))
 436                  ;; Format duration first so that it does not appear on
 437                  ;; chord elements
 438                  (format #f "< ~{~a ~}>~a~:{~:[-~;~]~a~^ ~}"
 439                          (map-in-order (lambda (music)
 440                                          (music->lily-string music parser))
 441                                        chord-elements)
 442                          duration
 443                          (map-in-order (lambda (music)
 444                                          (list
 445                                           (post-event? music)
 446                                           (music->lily-string music parser)))
 447                                        other-elements))))
 448               ((ly:duration? chord-repeat)
 449                (let ((duration (duration->lily-string chord-repeat
 450                                                       #:remember #t)))
 451                  (format #f "q~a~:{~:[-~;~]~a~^ ~}"
 452                          duration
 453                          (map-in-order (lambda (music)
 454                                          (list
 455                                           (post-event? music)
 456                                           (music->lily-string music parser)))
 457                                        other-elements))))
 458
 459               ((and (= 1 (length other-elements))
 460                     (not (post-event? (car other-elements))))
 461                (format #f (music->lily-string (car other-elements) parser)))
 462               (else
 463                (format #f "< >~:{~:[-~;~]~a~^ ~}"
 464                        (map-in-order (lambda (music)
 465                                        (list
 466                                         (post-event? music)
 467                                         (music->lily-string music parser)))
 468                                      other-elements))))))))
 469
 470 (define-display-method MultiMeasureRestMusic (mmrest parser)
 471   (format #f "R~a~{~a~^ ~}"
 472           (duration->lily-string (ly:music-property mmrest 'duration)
 473                                  #:remember #t)
 474           (map-in-order (lambda (music)
 475                           (music->lily-string music parser))
 476                         (ly:music-property mmrest 'articulations))))
 477
 478 (define-display-method SkipMusic (skip parser)
 479   (format #f "\\skip ~a" (duration->lily-string (ly:music-property skip 'duration) #:force-duration #t)))
 480
 481 (define-display-method OttavaMusic (ottava parser)
 482   (format #f "\\ottava #~a" (ly:music-property ottava 'ottava-number)))
 483
 484 ;;;
 485 ;;; Notes, rests, skips...
 486 ;;;
 487
 488 (define (simple-note->lily-string event parser)
 489   (format #f "~a~a~a~a~a~a~:{~:[-~;~]~a~}" ; pitchname octave !? octave-check duration optional_rest articulations
 490           (note-name->lily-string (ly:music-property event 'pitch) parser)
 491           (octave->lily-string (ly:music-property event 'pitch))
 492           (let ((forced (ly:music-property event 'force-accidental))
 493                 (cautionary (ly:music-property event 'cautionary)))
 494             (cond ((and (not (null? forced))
 495                         forced
 496                         (not (null? cautionary))
 497                         cautionary)
 498                    "?")
 499                   ((and (not (null? forced)) forced) "!")
 500                   (else "")))
 501           (let ((octave-check (ly:music-property event 'absolute-octave)))
 502             (if (not (null? octave-check))
 503                 (format #f "=~a" (cond ((>= octave-check 0)
 504                                         (make-string (1+ octave-check) #\'))
 505                                        ((< octave-check -1)
 506                                         (make-string (1- (* -1 octave-check)) #\,))
 507                                        (else "")))
 508                 ""))
 509           (duration->lily-string (ly:music-property event 'duration)
 510                                  #:remember #t)
 511           (if ((make-music-type-predicate 'RestEvent) event)
 512               "\\rest" "")
 513           (map-in-order (lambda (event)
 514                           (list
 515                            (post-event? event)
 516                            (music->lily-string event parser)))
 517                         (ly:music-property event 'articulations))))
 518
 519 (define-display-method NoteEvent (note parser)
 520   (cond ((not (null? (ly:music-property note 'pitch))) ;; note
 521          (simple-note->lily-string note parser))
 522         ((not (null? (ly:music-property note 'drum-type))) ;; drum
 523          (format #f "~a~a~{~a~}" (ly:music-property note 'drum-type)
 524                  (duration->lily-string (ly:music-property note 'duration)
 525                                         #:remember #t)
 526                  (map-in-order (lambda (event)
 527                                  (music->lily-string event parser))
 528                                (ly:music-property note 'articulations))))
 529         (else ;; unknown?
 530          "")))
 531
 532 (define-display-method ClusterNoteEvent (note parser)
 533   (simple-note->lily-string note parser))
 534
 535 (define-display-method RestEvent (rest parser)
 536   (if (not (null? (ly:music-property rest 'pitch)))
 537       (simple-note->lily-string rest parser)
 538       (format #f "r~a~{~a~}"
 539               (duration->lily-string (ly:music-property rest 'duration)
 540                                      #:remember #t)
 541               (map-in-order (lambda (event)
 542                               (music->lily-string event parser))
 543                             (ly:music-property rest 'articulations)))))
 544
 545 (define-display-method MultiMeasureRestEvent (rest parser)
 546   (string-append "R" (duration->lily-string (ly:music-property rest 'duration)
 547                                             #:remember #t)))
 548
 549 (define-display-method SkipEvent (rest parser)
 550   (format #f "s~a~{~a~}"
 551           (duration->lily-string (ly:music-property rest 'duration)
 552                                  #:remember #t)
 553           (map-in-order (lambda (event)
 554                           (music->lily-string event parser))
 555                         (ly:music-property rest 'articulations))))
 556
 557 (define-display-method RepeatedChord (chord parser)
 558   (music->lily-string (ly:music-property chord 'element) parser))
 559
 560 (define-display-method MarkEvent (mark parser)
 561   (let ((label (ly:music-property mark 'label)))
 562     (if (null? label)
 563         "\\mark \\default"
 564         (format #f "\\mark ~a" (markup->lily-string label)))))
 565
 566 (define-display-method KeyChangeEvent (key parser)
 567   (let ((pitch-alist (ly:music-property key 'pitch-alist))
 568         (tonic (ly:music-property key 'tonic)))
 569     (if (or (null? pitch-alist)
 570             (null? tonic))
 571         "\\key \\default"
 572         (let ((c-pitch-alist (ly:transpose-key-alist pitch-alist
 573                                                      (ly:pitch-diff (ly:make-pitch 0 0 0) tonic))))
 574           (format #f "\\key ~a \\~a~a"
 575                   (note-name->lily-string (ly:music-property key 'tonic) parser)
 576                   (any (lambda (mode)
 577                          (if (and parser
 578                                   (equal? (ly:parser-lookup parser mode) c-pitch-alist))
 579                              (symbol->string mode)
 580                              #f))
 581                        '(major minor ionian locrian aeolian mixolydian lydian phrygian dorian))
 582                   (new-line->lily-string))))))
 583
 584 (define-display-method RelativeOctaveCheck (octave parser)
 585   (let ((pitch (ly:music-property octave 'pitch)))
 586     (format #f "\\octaveCheck ~a~a"
 587             (note-name->lily-string pitch parser)
 588             (octave->lily-string pitch))))
 589
 590 (define-display-method VoiceSeparator (sep parser)
 591   "\\\\")
 592
 593 (define-display-method LigatureEvent (ligature parser)
 594   (if (= START (ly:music-property ligature 'span-direction))
 595       "\\["
 596       "\\]"))
 597
 598 (define-display-method BarCheck (check parser)
 599   (format #f "|~a" (new-line->lily-string)))
 600
 601 (define-display-method PesOrFlexaEvent (expr parser)
 602   "\\~")
 603
 604 (define-display-method BassFigureEvent (figure parser)
 605   (let ((alteration (ly:music-property figure 'alteration))
 606         (fig (ly:music-property figure 'figure))
 607         (bracket-start (ly:music-property figure 'bracket-start))
 608         (bracket-stop (ly:music-property figure 'bracket-stop)))
 609
 610     (format #f "~a~a~a~a"
 611             (if (null? bracket-start) "" "[")
 612             (cond ((null? fig) "_")
 613                   ((markup? fig) (second fig)) ;; fig: (<number-markup> "number")
 614                   (else fig))
 615             (if (null? alteration)
 616                 ""
 617                 (cond
 618                  ((= alteration DOUBLE-FLAT) "--")
 619                  ((= alteration FLAT) "-")
 620                  ((= alteration NATURAL) "!")
 621                  ((= alteration SHARP) "+")
 622                  ((= alteration DOUBLE-SHARP) "++")
 623                  (else "")))
 624             (if (null? bracket-stop) "" "]"))))
 625
 626 (define-display-method LyricEvent (lyric parser)
 627   (format "~a~{~a~^ ~}"
 628           (let ((text (ly:music-property lyric 'text)))
 629             (if (or (string? text)
 630                     (eqv? (first text) simple-markup))
 631                 ;; a string or a simple markup
 632                 (let ((string (if (string? text)
 633                                   text
 634                                   (second text))))
 635                   (if (string-match "(\"| |[0-9])" string)
 636                       ;; TODO check exactly in which cases double quotes should be used
 637                       (format #f "~s" string)
 638                       string))
 639                 (markup->lily-string text)))
 640           (map-in-order (lambda (m) (music->lily-string m parser))
 641                         (ly:music-property lyric 'articulations))))
 642
 643 (define-display-method BreathingEvent (event parser)
 644   "\\breathe")
 645
 646 ;;;
 647 ;;; Staff switches
 648 ;;;
 649
 650 (define-display-method AutoChangeMusic (m parser)
 651   (format #f "\\autochange ~a"
 652           (music->lily-string (ly:music-property m 'element) parser)))
 653
 654 (define-display-method ContextChange (m parser)
 655   (format #f "\\change ~a = \"~a\""
 656           (ly:music-property m 'change-to-type)
 657           (ly:music-property m 'change-to-id)))
 658
 659 ;;;
 660
 661 (define-display-method TimeScaledMusic (times parser)
 662   (let* ((num (ly:music-property times 'numerator))
 663          (den (ly:music-property times 'denominator))
 664          (span (ly:music-property times 'duration #f))
 665          ;; need to format before changing time scale
 666          (formatted-span
 667           (and span (duration->lily-string span #:force-duration #t)))
 668          (scale (/ num den))
 669          (time-scale (*time-scale*)))
 670     (*previous-duration* #f)
 671     (let ((result
 672            (parameterize ((*force-line-break* #f)
 673                           (*time-scale* (* time-scale scale)))
 674                          (format #f "\\tuplet ~a/~a ~@[~a ~]~a"
 675                                  den
 676                                  num
 677                                  formatted-span
 678                                  (music->lily-string (ly:music-property times 'element) parser)))))
 679       (*previous-duration* #f)
 680       result)))
 681
 682 (define-display-method RelativeOctaveMusic (m parser)
 683   (music->lily-string (ly:music-property m 'element) parser))
 684
 685 (define-display-method TransposedMusic (m parser)
 686   (music->lily-string (ly:music-property m 'element) parser))
 687
 688 ;;;
 689 ;;; Repeats
 690 ;;;
 691
 692 (define-display-method AlternativeEvent (alternative parser) "")
 693
 694 (define (repeat->lily-string expr repeat-type parser)
 695   (let* ((main (music->lily-string (ly:music-property expr 'element) parser)))
 696     (format #f "\\repeat ~a ~a ~a ~a"
 697             repeat-type
 698             (ly:music-property expr 'repeat-count)
 699             main
 700             (let ((alternatives (ly:music-property expr 'elements)))
 701               (if (null? alternatives)
 702                   ""
 703                   (format #f "\\alternative { ~{~a ~}}"
 704                           (map-in-order (lambda (music)
 705                                           (music->lily-string music parser))
 706                                         alternatives)))))))
 707
 708 (define-display-method VoltaRepeatedMusic (expr parser)
 709   (repeat->lily-string expr "volta" parser))
 710
 711 (define-display-method UnfoldedRepeatedMusic (expr parser)
 712   (repeat->lily-string expr "unfold" parser))
 713
 714 (define-display-method PercentRepeatedMusic (expr parser)
 715   (repeat->lily-string expr "percent" parser))
 716
 717 (define-display-method TremoloRepeatedMusic (expr parser)
 718   (let* ((main (ly:music-property expr 'element))
 719          (children (if (music-is-of-type? main 'sequential-music)
 720                        ;; \repeat tremolo n { ... }
 721                        (length (extract-named-music main '(EventChord
 722                                                            NoteEvent)))
 723                        ;; \repeat tremolo n c4
 724                        1))
 725          (times (ly:music-property expr 'repeat-count))
 726
 727          ;; # of dots is equal to the 1 in bitwise representation (minus 1)!
 728          (dots (1- (logcount (* times children))))
 729          ;; The remaining missing multiplicator to scale the notes by
 730          ;; times * children
 731          (mult (/ (* times children (ash 1 dots)) (1- (ash 2 dots))))
 732          (shift (- (ly:intlog2 (floor mult)))))
 733     (set! main (ly:music-deep-copy main))
 734     ;; Adjust the time of the notes
 735     (ly:music-compress main (ly:make-moment children 1))
 736     ;; Adjust the displayed note durations
 737     (shift-duration-log main (- shift) (- dots))
 738     (format #f "\\repeat tremolo ~a ~a"
 739             times
 740             (music->lily-string main parser))))
 741
 742 ;;;
 743 ;;; Contexts
 744 ;;;
 745
 746 (define-display-method ContextSpeccedMusic (expr parser)
 747   (let ((id    (ly:music-property expr 'context-id))
 748         (create-new (ly:music-property expr 'create-new))
 749         (music (ly:music-property expr 'element))
 750         (operations (ly:music-property expr 'property-operations))
 751         (ctype (ly:music-property expr 'context-type)))
 752     (format #f "~a ~a~a~a ~a"
 753             (if (and (not (null? create-new)) create-new)
 754                 "\\new"
 755                 "\\context")
 756             ctype
 757             (if (null? id)
 758                 ""
 759                 (format #f " = ~s" id))
 760             (if (null? operations)
 761                 ""
 762                 (format #f " \\with {~{~a~}~%~v_}"
 763                         (parameterize ((*indent* (+ (*indent*) 2)))
 764                                       (map (lambda (op)
 765                                              (format #f "~%~v_\\~a ~s"
 766                                                      (*indent*)
 767                                                      (first op)
 768                                                      (second op)))
 769                                            operations))
 770                         (*indent*)))
 771             (parameterize ((*current-context* ctype))
 772                           (music->lily-string music parser)))))
 773
 774 ;; special cases: \figures \lyrics \drums
 775 (define-extra-display-method ContextSpeccedMusic (expr parser)
 776   (with-music-match (expr (music 'ContextSpeccedMusic
 777                                  create-new #t
 778                                  property-operations ?op
 779                                  context-type ?context-type
 780                                  element ?sequence))
 781                     (if (null? ?op)
 782                         (parameterize ((*explicit-mode* #f))
 783                                       (case ?context-type
 784                                         ((FiguredBass)
 785                                          (format #f "\\figures ~a" (music->lily-string ?sequence parser)))
 786                                         ((Lyrics)
 787                                          (format #f "\\lyrics ~a" (music->lily-string ?sequence parser)))
 788                                         ((DrumStaff)
 789                                          (format #f "\\drums ~a" (music->lily-string ?sequence parser)))
 790                                         (else
 791                                          #f)))
 792                         #f)))
 793
 794 ;;; Context properties
 795
 796 (define-extra-display-method ContextSpeccedMusic (expr parser)
 797   (let ((element (ly:music-property expr 'element))
 798         (property-tuning? (make-music-type-predicate 'PropertySet
 799                                                      'PropertyUnset
 800                                                      'OverrideProperty
 801                                                      'RevertProperty))
 802         (sequence? (make-music-type-predicate 'SequentialMusic)))
 803     (if (and (ly:music? element)
 804              (or (property-tuning? element)
 805                  (and (sequence? element)
 806                       (every property-tuning? (ly:music-property element 'elements)))))
 807         (parameterize ((*current-context* (ly:music-property expr 'context-type)))
 808                       (music->lily-string element parser))
 809         #f)))
 810
 811 (define-public (value->lily-string arg parser)
 812   (cond ((ly:music? arg)
 813          (music->lily-string arg parser))
 814         ((string? arg)
 815          (format #f "#~s" arg))
 816         ((markup? arg)
 817          (markup->lily-string arg))
 818         ((ly:duration? arg)
 819          (format #f "##{ ~a #}" (duration->lily-string arg #:force-duration #t)))
 820         ((ly:pitch? arg)
 821          (format #f "~a~a"
 822                  (note-name->lily-string arg parser)
 823                  (octave->lily-string arg)))
 824         (else
 825          (format #f "#~a" (scheme-expr->lily-string arg)))))
 826
 827 (define-display-method PropertySet (expr parser)
 828   (let ((property (ly:music-property expr 'symbol))
 829         (value (ly:music-property expr 'value))
 830         (once (ly:music-property expr 'once)))
 831     (format #f "~a\\set ~a~a = ~a~a"
 832             (if (and (not (null? once)))
 833                 "\\once "
 834                 "")
 835             (if (eqv? (*current-context*) 'Bottom)
 836                 ""
 837                 (format #f "~a . " (*current-context*)))
 838             property
 839             (value->lily-string value parser)
 840             (new-line->lily-string))))
 841
 842 (define-display-method PropertyUnset (expr parser)
 843   (format #f "\\unset ~a~a~a"
 844           (if (eqv? (*current-context*) 'Bottom)
 845               ""
 846               (format #f "~a . " (*current-context*)))
 847           (ly:music-property expr 'symbol)
 848           (new-line->lily-string)))
 849
 850 ;;; Layout properties
 851
 852 (define-display-method OverrideProperty (expr parser)
 853   (let* ((symbol          (ly:music-property expr 'symbol))
 854          (properties   (ly:music-property expr 'grob-property-path
 855                                           (list (ly:music-property expr 'grob-property))))
 856          (value   (ly:music-property expr 'grob-value))
 857          (once    (ly:music-property expr 'once)))
 858
 859     (format #f "~a\\override ~{~a~^.~} = ~a~a"
 860             (if (or (null? once)
 861                     (not once))
 862                 ""
 863                 "\\once ")
 864             (if (eqv? (*current-context*) 'Bottom)
 865                 (cons symbol properties)
 866                 (cons* (*current-context*) symbol properties))
 867             (value->lily-string value parser)
 868             (new-line->lily-string))))
 869
 870 (define-display-method RevertProperty (expr parser)
 871   (let* ((symbol (ly:music-property expr 'symbol))
 872          (properties (ly:music-property expr 'grob-property-path
 873                                         (list (ly:music-property expr 'grob-property)))))
 874     (format #f "\\revert ~{~a~^.~}~a"
 875             (if (eqv? (*current-context*) 'Bottom)
 876                 (cons symbol properties)
 877                 (cons* (*current-context*) symbol properties))
 878             (new-line->lily-string))))
 879
 880 (define-display-method TimeSignatureMusic (expr parser)
 881   (let* ((num (ly:music-property expr 'numerator))
 882          (den (ly:music-property expr 'denominator))
 883          (structure (ly:music-property expr 'beat-structure)))
 884     (if (null? structure)
 885         (format #f
 886                 "\\time ~a/~a~a"
 887                 num den
 888                 (new-line->lily-string))
 889         (format #f
 890                 "\\time #'~a ~a/~a~a"
 891                 structure num den
 892                 (new-line->lily-string)))))
 893
 894 ;;; \melisma and \melismaEnd
 895 (define-extra-display-method ContextSpeccedMusic (expr parser)
 896   "If expr is a melisma, return \"\\melisma\", otherwise, return #f."
 897   (with-music-match (expr (music 'ContextSpeccedMusic
 898                                  element (music 'PropertySet
 899                                                 value #t
 900                                                 symbol 'melismaBusy)))
 901                     "\\melisma"))
 902
 903 (define-extra-display-method ContextSpeccedMusic (expr parser)
 904   "If expr is a melisma end, return \"\\melismaEnd\", otherwise, return #f."
 905   (with-music-match (expr (music 'ContextSpeccedMusic
 906                                  element (music 'PropertyUnset
 907                                                 symbol 'melismaBusy)))
 908                     "\\melismaEnd"))
 909
 910 ;;; \tempo
 911 (define-extra-display-method SequentialMusic (expr parser)
 912   (with-music-match (expr (music 'SequentialMusic
 913                                  elements ((music 'TempoChangeEvent
 914                                                   text ?text
 915                                                   tempo-unit ?unit
 916                                                   metronome-count ?count)
 917                                            (music 'ContextSpeccedMusic
 918                                                   element (music 'PropertySet
 919                                                                  symbol 'tempoWholesPerMinute)))))
 920                     (format #f "\\tempo ~{~a~a~}~a = ~a~a"
 921                             (if (markup? ?text)
 922                                 (list (markup->lily-string ?text) " ")
 923                                 '())
 924                             (duration->lily-string ?unit #:force-duration #t)
 925                             (if (pair? ?count)
 926                                 (format #f "~a - ~a" (car ?count) (cdr ?count))
 927                                 ?count)
 928                             (new-line->lily-string))))
 929
 930 (define-display-method TempoChangeEvent (expr parser)
 931   (let ((text (ly:music-property expr 'text)))
 932     (format #f "\\tempo ~a~a"
 933             (markup->lily-string text)
 934             (new-line->lily-string))))
 935
 936 ;;; \clef
 937 (define clef-name-alist #f)
 938 (define-public (memoize-clef-names clefs)
 939   "Initialize @code{clef-name-alist}, if not already set."
 940   (if (not clef-name-alist)
 941       (set! clef-name-alist
 942             (map (lambda (name+vals)
 943                    (cons (cdr name+vals)
 944                          (car name+vals)))
 945                  clefs))))
 946
 947 (define-extra-display-method ContextSpeccedMusic (expr parser)
 948   "If @var{expr} is a clef change, return \"\\clef ...\".
 949 Otherwise, return @code{#f}."
 950   (with-music-match (expr (music 'ContextSpeccedMusic
 951                                  context-type 'Staff
 952                                  element (music 'SequentialMusic
 953                                                 elements ((music 'PropertySet
 954                                                                  value ?clef-glyph
 955                                                                  symbol 'clefGlyph)
 956                                                           (music 'PropertySet
 957                                                                  symbol 'middleCClefPosition)
 958                                                           (music 'PropertySet
 959                                                                  value ?clef-position
 960                                                                  symbol 'clefPosition)
 961                                                           (music 'PropertySet
 962                                                                  value ?clef-transposition
 963                                                                  symbol 'clefTransposition)
 964                                                           (music 'ApplyContext
 965                                                                  procedure ly:set-middle-C!)))))
 966                     (let ((clef-name (assoc-get (list ?clef-glyph ?clef-position 0)
 967                                                 clef-name-alist)))
 968                       (if clef-name
 969                           (format #f "\\clef \"~a~{~a~a~}\"~a"
 970                                   clef-name
 971                                   (cond ((= 0 ?clef-transposition)
 972                                          (list "" ""))
 973                                         ((> ?clef-transposition 0)
 974                                          (list "^" (1+ ?clef-transposition)))
 975                                         (else
 976                                          (list "_" (- 1 ?clef-transposition))))
 977                                   (new-line->lily-string))
 978                           #f))))
 979
 980 ;;; \bar
 981 (define-extra-display-method ContextSpeccedMusic (expr parser)
 982   "If `expr' is a bar, return \"\\bar ...\".
 983 Otherwise, return #f."
 984   (with-music-match (expr (music 'ContextSpeccedMusic
 985                                  context-type 'Timing
 986                                  element (music 'PropertySet
 987                                                 value ?bar-type
 988                                                 symbol 'whichBar)))
 989                     (format #f "\\bar \"~a\"~a" ?bar-type (new-line->lily-string))))
 990
 991 ;;; \partial
 992 (define-extra-display-method ContextSpeccedMusic (expr parser)
 993   "If `expr' is a partial measure, return \"\\partial ...\".
 994 Otherwise, return #f."
 995   (with-music-match (expr (music
 996                            'ContextSpeccedMusic
 997                            element (music
 998                                     'ContextSpeccedMusic
 999                                     context-type 'Timing
1000                                     element (music
1001                                              'PartialSet
1002                                              duration ?duration))))
1003
1004                     (and ?duration
1005                          (format #f "\\partial ~a"
1006                                  (duration->lily-string ?duration #:force-duration #t)))))
1007
1008 ;;;
1009 ;;;
1010
1011 (define-display-method ApplyOutputEvent (applyoutput parser)
1012   (let ((proc (ly:music-property applyoutput 'procedure))
1013         (ctx  (ly:music-property applyoutput 'context-type)))
1014     (format #f "\\applyOutput #'~a #~a"
1015             ctx
1016             (or (procedure-name proc)
1017                 (with-output-to-string
1018                   (lambda ()
1019                     (pretty-print (procedure-source proc))))))))
1020
1021 (define-display-method ApplyContext (applycontext parser)
1022   (let ((proc (ly:music-property applycontext 'procedure)))
1023     (format #f "\\applyContext #~a"
1024             (or (procedure-name proc)
1025                 (with-output-to-string
1026                   (lambda ()
1027                     (pretty-print (procedure-source proc))))))))
1028
1029 ;;; \partcombine
1030 (define-display-method PartCombineMusic (expr parser)
1031   (format #f "\\partcombine ~{~a ~}"
1032           (map-in-order (lambda (music)
1033                           (music->lily-string music parser))
1034                         (ly:music-property expr 'elements))))
1035
1036 (define-extra-display-method PartCombineMusic (expr parser)
1037   (with-music-match (expr (music 'PartCombineMusic
1038                                  elements ((music 'UnrelativableMusic
1039                                                   element (music 'ContextSpeccedMusic
1040                                                                  context-id "one"
1041                                                                  context-type 'Voice
1042                                                                  element ?sequence1))
1043                                            (music 'UnrelativableMusic
1044                                                   element (music 'ContextSpeccedMusic
1045                                                                  context-id "two"
1046                                                                  context-type 'Voice
1047                                                                  element ?sequence2)))))
1048                     (format #f "\\partcombine ~a~a~a"
1049                             (music->lily-string ?sequence1 parser)
1050                             (new-line->lily-string)
1051                             (music->lily-string ?sequence2 parser))))
1052
1053 (define-display-method UnrelativableMusic (expr parser)
1054   (music->lily-string (ly:music-property expr 'element) parser))
1055
1056 ;;; Cue notes
1057 (define-display-method QuoteMusic (expr parser)
1058   (or (with-music-match (expr (music
1059                                'QuoteMusic
1060                                quoted-voice-direction ?quoted-voice-direction
1061                                quoted-music-name ?quoted-music-name
1062                                quoted-context-id "cue"
1063                                quoted-context-type 'CueVoice
1064                                element ?music))
1065                         (format #f "\\cueDuring #~s #~a ~a"
1066                                 ?quoted-music-name
1067                                 ?quoted-voice-direction
1068                                 (music->lily-string ?music parser)))
1069       (format #f "\\quoteDuring #~s ~a"
1070               (ly:music-property expr 'quoted-music-name)
1071               (music->lily-string (ly:music-property expr 'element) parser))))
1072
1073 ;;;
1074 ;;; Breaks
1075 ;;;
1076 (define-display-method LineBreakEvent (expr parser)
1077   (if (null? (ly:music-property expr 'break-permission))
1078       "\\noBreak"
1079       "\\break"))
1080
1081 (define-display-method PageBreakEvent (expr parser)
1082   (if (null? (ly:music-property expr 'break-permission))
1083       "\\noPageBreak"
1084       "\\pageBreak"))
1085
1086 (define-display-method PageTurnEvent (expr parser)
1087   (if (null? (ly:music-property expr 'break-permission))
1088       "\\noPageTurn"
1089       "\\pageTurn"))
1090
1091 (define-extra-display-method EventChord (expr parser)
1092   (with-music-match (expr (music 'EventChord
1093                                  elements ((music 'LineBreakEvent
1094                                                   break-permission 'force)
1095                                            (music 'PageBreakEvent
1096                                                   break-permission 'force))))
1097                     "\\pageBreak"))
1098
1099 (define-extra-display-method EventChord (expr parser)
1100   (with-music-match (expr (music 'EventChord
1101                                  elements ((music 'LineBreakEvent
1102                                                   break-permission 'force)
1103                                            (music 'PageBreakEvent
1104                                                   break-permission 'force)
1105                                            (music 'PageTurnEvent
1106                                                   break-permission 'force))))
1107                     "\\pageTurn"))
1108
1109 ;;;
1110 ;;; Lyrics
1111 ;;;
1112
1113 ;;; \lyricsto
1114 (define-display-method LyricCombineMusic (expr parser)
1115   (format #f "\\lyricsto ~s ~a"
1116           (ly:music-property expr 'associated-context)
1117           (parameterize ((*explicit-mode* #f))
1118                         (music->lily-string (ly:music-property expr 'element) parser))))
1119
1120 ;; \addlyrics
1121 (define-extra-display-method SimultaneousMusic (expr parser)
1122   (with-music-match (expr (music 'SimultaneousMusic
1123                                  elements ((music 'ContextSpeccedMusic
1124                                                   context-id ?id
1125                                                   context-type 'Voice
1126                                                   element ?note-sequence)
1127                                            (music 'ContextSpeccedMusic
1128                                                   context-type 'Lyrics
1129                                                   create-new #t
1130                                                   element (music 'LyricCombineMusic
1131                                                                  associated-context ?associated-id
1132                                                                  element ?lyric-sequence)))))
1133                     (if (string=? ?id ?associated-id)
1134                         (format #f "~a~a \\addlyrics ~a"
1135                                 (music->lily-string ?note-sequence parser)
1136                                 (new-line->lily-string)
1137                                 (parameterize ((*explicit-mode* #f))
1138                                               (music->lily-string ?lyric-sequence parser)))
1139                         #f)))
1140
1141 ;; Silence internal event sent at end of each lyrics block
1142 (define-display-method CompletizeExtenderEvent (expr parser)
1143   "")