mf/ital-m.mf

   1 % ital-m.mf
   2 % from itall.mf
   3 %
   4 % Computer Modern Italic lower case:
   5 % This lowercase italic alphabet was prepared by D. E. Knuth in December, 1979,
   6 % inspired by the Monotype faces used in {\sl The Art of Computer Programming}.
   7 % The programs were revised for the new \MF\ conventions in 1985.
   8
   9 % Character codes \0141 through \0172 are generated.
  10 % not
  11
  12 % cmchar "Italic letter m";
  13 % beginchar("m",15u#,x_height#,0);
  14 \"Dynamic letter m";
  15 beginchar(1,15u#,x_height#,0);
  16 italcorr 1/3x_height#*slant+.5hair#+.5u#;
  17 adjust_fit(if monospace:-1.5u#,-2u# else: 0,0 fi); pickup fine.nib;
  18 numeric shaved_stem; shaved_stem=mfudged.stem;
  19 save stem; stem=shaved_stem;
  20 pos2(stem,0); x1=x2;
  21 if monospace: pos1(stem,0); lft x1l=hround(2.5u-.5stem); top y1=h;
  22 else: x0=0; lft x2l=hround(2.5u-.5stem);
  23  hook_in(0,a,1); fi  % opening hook
  24 y2-.5stem=-oo; filldraw circ_stroke z2e--z1e;  % left stem
  25 x4+.5stem=hround(.5w+.5stem); ital_arch(2,3,4);  % left arch
  26 pos5(stem,0); y5=y2; x5=x4;
  27 filldraw circ_stroke z5e--z4e;  % middle stem
  28 x7+.5stem=hround(w-2.5u+.5stem);
  29 x8=x7-.25u; ital_arch(5,6,7);  % right arch
  30 if monospace: pos9(vair,90); x9=good.x .5[x8,w]; bot y9l=0; y8=1/3h;
  31  pos8(stem,0); filldraw stroke z8e{-u,-x_height}...{right}z9e; % terminal
  32 else: x9=w; hook_out(8,b,9)(skewed); fi  % closing hook
  33 filldraw stroke z7e{down}..{-u,-x_height}z8e;  % right stem
  34 math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  35 penlabels(0,a,1,2,3,4,5,6,7,8,9); endchar;