aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl StepMake subroutines for configure.in
   3
   4
   5 ### mostly interal macros
   6
   7 # Get full path of executable ($1)
   8 AC_DEFUN(STEPMAKE_GET_EXECUTABLE, [
   9     ## which doesn't work in ash, if /usr/bin/which isn't installed
  10     ## type -p doesn't work in ash
  11     ## command -v doesn't work in zsh
  12     ## command -v "$1" 2>&1
  13     ## this test should work in ash, bash, pdksh (ksh), zsh
  14     type -p $1 2>/dev/null | tail -n 1 | awk '{print $NF}'
  15 ])
  16
  17
  18 # Get version string from executable ($1)
  19 AC_DEFUN(STEPMAKE_GET_VERSION, [
  20     ## "$1" --version 2>&1 | grep -v '^$' | head -n 1 | awk '{print $NF}'
  21     ##
  22     ## ARG.
  23     ## Workaround for broken Debian gcc version string:
  24     ##     gcc (GCC) 3.1.1 20020606 (Debian prerelease)
  25     ##
  26     ## -V: Workaround for python
  27
  28     changequote(<<, >>)#dnl
  29
  30     ## Assume and hunt for dotted version multiplet.
  31     ## use eval trickery, because we cannot use multi-level $() instead of ``
  32     ## for compatibility reasons.
  33
  34     ## grab the first version number in  --version output.
  35     eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 | grep '\(^\| \)[0-9][0-9]*\.[0-9]' \
  36         | head -n 1 \
  37         | tr ' ' '\n' | sed 's/\([0-9][0-9]*\.[0-9][0-9.]*\).*/\1/g' | grep '\(^\| \)[0-9][0-9]*\.[0-9]' | head -n 1\`\"
  38
  39     if test -z "$_ver"; then
  40         ## If empty, try date [fontforge]
  41         eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 | grep '[0-9]\{6,8\}' \
  42             | head -n 1 \
  43             | sed -e 's/^[^.0-9]*//' -e 's/[^.0-9]*$//'\`\"
  44     fi
  45     echo "$_ver"
  46     changequote([, ])#dnl
  47 ])
  48
  49 # Calculate simplistic numeric version from version string ($1)
  50 # As yet, we have no need for something more elaborate.
  51 AC_DEFUN(STEPMAKE_NUMERIC_VERSION, [
  52     echo "$1" | awk -F. '
  53     {
  54       if ([$]3) {three = [$]3}
  55       else {three = 0}
  56     }
  57     {printf "%.0f\n", [$]1*1000000 + [$]2*1000 + three}'
  58 ])
  59
  60
  61 # Add item ($2) to list ($1, one of 'OPTIONAL', 'REQUIRED')
  62 AC_DEFUN(STEPMAKE_ADD_ENTRY, [
  63     eval "$1"=\"`eval echo \"'$'$1\" \"$2\"`\"
  64 ])
  65
  66 # Check if tested program ($2) was found ($1).
  67 # If not, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED').
  68 # We could abort here if a 'REQUIRED' program is not found
  69 AC_DEFUN(STEPMAKE_OPTIONAL_REQUIRED, [
  70     STEPMAKE_CHECK_SEARCH_RESULT($1)
  71     if test $? -ne 0; then
  72         STEPMAKE_ADD_ENTRY($3, $2)
  73         if test "$3" = "REQUIRED"; then
  74             command="echo ERROR: $2 not found"
  75             # abort configure process here?
  76         else
  77             command="- echo $2 not found"
  78         fi
  79         eval "$1"='$command'
  80         false
  81     else
  82         true
  83     fi
  84 ])
  85
  86
  87 # Return if tested proram ($1) was found (true) or not (false).
  88 AC_DEFUN(STEPMAKE_CHECK_SEARCH_RESULT, [
  89     r="`eval echo '$'"$1"`"
  90     if test -n "$r" -a "$r" != "error" -a "$r" != "no" && expr '`eval echo '$'"$1"`' : '.*\(echo\)' > /dev/null; then
  91         true
  92     else
  93         ##STEPMAKE_WARN(cannot find $2. $3)
  94         false
  95     fi
  96 ])
  97
  98
  99 # Check version of program ($1)
 100 # If version ($4: optional argument, supply if version cannot be
 101 # parsed using --version or -V ) is smaller than requested ($3), add
 102 # entry to missing-list ($2, one of 'OPTIONAL', 'REQUIRED').
 103 AC_DEFUN(STEPMAKE_CHECK_VERSION, [
 104     r="`eval echo '$'"$1"`"
 105     AC_MSG_CHECKING([$r version])
 106     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 107     if test -n "$4"; then
 108         ver="$4"
 109     else
 110         ver=`STEPMAKE_GET_VERSION($exe)`
 111     fi
 112     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 113     req=`STEPMAKE_NUMERIC_VERSION($3)`
 114     AC_MSG_RESULT([$ver])
 115     if test "$num" -lt "$req"; then
 116         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
 117     fi
 118     vervar="`echo $1 | tr '[a-z]' '[A-Z]'`_VERSION"
 119     eval `echo $vervar=$num`
 120 ##    AC_SUBST(`eval echo $vervar`)
 121 ])
 122
 123 # Check version of program ($1)
 124 # If version is greater than or equals unsupported ($3),
 125 # add entry to unsupported list ($2, 'UNSUPPORTED')
 126 AC_DEFUN(STEPMAKE_CHECK_VERSION_UNSUPPORTED, [
 127     r="`eval echo '$'"$1"`"
 128     AC_MSG_CHECKING([$r version])
 129     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 130     ver=`STEPMAKE_GET_VERSION($exe)`
 131     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 132     sup=`STEPMAKE_NUMERIC_VERSION($3)`
 133     AC_MSG_RESULT([$ver])
 134     if test "$num" -ge "$sup"; then
 135         STEPMAKE_ADD_ENTRY($2, ["$r < $3 (installed: $ver)"])
 136     fi
 137 ])
 138
 139 ### Macros to build configure.in
 140
 141
 142 AC_DEFUN(STEPMAKE_BIBTEX2HTML, [
 143     STEPMAKE_PROGS(BIBTEX2HTML, bibtex2html bib2html, $1)
 144     if test "$BIBTEX2HTML" = "bib2html"; then
 145         BIBTEX2HTML_FLAGS='$< $(@)'
 146     else
 147         BIBTEX2HTML_FLAGS='-o $(@D)/$(*F) $<'
 148     fi
 149     AC_SUBST(BIBTEX2HTML)
 150     AC_SUBST(BIBTEX2HTML_FLAGS)
 151 ])
 152
 153
 154 AC_DEFUN(STEPMAKE_BISON, [
 155     # ugh, automake: we want (and check for) bison
 156     AC_PROG_YACC
 157
 158     STEPMAKE_PROGS(BISON, bison, $1)
 159
 160     # urg.  should test functionality rather than version.
 161     if test "$BISON" = "bison" -a -n "$2"; then
 162         STEPMAKE_CHECK_VERSION(BISON, $1, $2)
 163     fi
 164 ])
 165
 166 AC_DEFUN(STEPMAKE_COMPILE_BEFORE, [
 167     # -O is necessary to get inlining
 168     CFLAGS=${CFLAGS-""}
 169     CXXFLAGS=${CXXFLAGS-$CFLAGS}
 170     LDFLAGS=${LDFLAGS-""}
 171     optimise_b=yes
 172     profile_b=no
 173     debug_b=yes
 174     pipe_b=yes
 175
 176     AC_ARG_ENABLE(debugging,
 177     [  --enable-debugging      compile with debugging info.  Default: on],
 178     [debug_b=$enableval])
 179
 180     AC_ARG_ENABLE(optimising,
 181     [  --enable-optimising     compile with optimising.  Default: on],
 182     [optimise_b=$enableval])
 183
 184     AC_ARG_ENABLE(profiling,
 185     [  --enable-profiling      compile with gprof support.  Default: off],
 186     [profile_b=$enableval])
 187
 188     AC_ARG_ENABLE(pipe,
 189     [  --enable-pipe           compile with -pipe.  Default: on],
 190     [pipe_b=$enableval])
 191
 192     if test "$optimise_b" = yes; then
 193         AC_DEFINE(NDEBUG)
 194         DEFINES="$DEFINES -DNDEBUG"
 195         OPTIMIZE=" -O2 -finline-functions"
 196     fi
 197
 198     if test $profile_b = yes; then
 199         EXTRA_LIBS="-pg"
 200         OPTIMIZE="$OPTIMIZE -pg"
 201     fi
 202
 203     if test $debug_b = yes; then
 204         OPTIMIZE="$OPTIMIZE -g"
 205     fi
 206 ])
 207
 208 AC_DEFUN(STEPMAKE_COMPILE, [
 209
 210     AC_REQUIRE([STEPMAKE_COMPILE_BEFORE])
 211     AC_REQUIRE([AC_PROG_CC])
 212
 213     STEPMAKE_OPTIONAL_REQUIRED(CC, cc, $1)
 214     LD='$(CC)'
 215     AC_SUBST(LD)
 216
 217     # If -pipe requested, test if it works and add to CFLAGS.
 218     if test "$pipe_b" = yes; then
 219         save_cflags="$CFLAGS"
 220         CFLAGS=" -pipe $CFLAGS";
 221         AC_CACHE_CHECK([whether compiler understands -pipe],
 222             [stepmake_cv_cflags_pipe],
 223             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[/* -pipe test */]])],
 224                 [stepmake_cv_cflags_pipe=yes],
 225                 [stepmake_cv_cflags_pipe=no]))
 226         CFLAGS=$save_cflags
 227         if test $stepmake_cv_cflags_pipe = yes; then
 228             OPTIMIZE="$OPTIMIZE -pipe"
 229         fi
 230     fi
 231
 232     CFLAGS="$CFLAGS $OPTIMIZE"
 233     CPPFLAGS=${CPPFLAGS-""}
 234
 235     AC_MSG_CHECKING([for IEEE-conformance compiler flags])
 236     save_cflags="$CFLAGS"
 237     case "$host" in
 238         alpha*-*-*)
 239             dnl should do compile test?
 240             AC_MSG_RESULT(-mieee)
 241             CFLAGS=" -mieee $CFLAGS"
 242             ;;
 243         *)
 244             AC_MSG_RESULT([none])
 245             ;;
 246     esac
 247
 248     AC_SUBST(cross_compiling)
 249     AC_SUBST(CFLAGS)
 250     AC_SUBST(CPPFLAGS)
 251     AC_SUBST(LDFLAGS)
 252     AC_SUBST(DEFINES)
 253     AC_SUBST(EXTRA_LIBS)
 254 ])
 255
 256 AC_DEFUN(STEPMAKE_CXX, [
 257     AC_LANG([C++])
 258     AC_PROG_CXX
 259     STEPMAKE_OPTIONAL_REQUIRED(CXX, c++, $1)
 260
 261     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
 262     LD='$(CXX)'
 263
 264     AC_SUBST(CXX)
 265     AC_SUBST(CXXFLAGS)
 266     AC_SUBST(LD)
 267 ])
 268
 269
 270 AC_DEFUN(STEPMAKE_CXXTEMPLATE, [
 271     AC_CACHE_CHECK([whether explicit instantiation is needed],
 272         stepmake_cv_need_explicit_instantiation,
 273         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 274     template <class T> struct foo { static int baz; };
 275     template <class T> int foo<T>::baz = 1;
 276     ]], [[ return foo<int>::baz; ]])],[stepmake_cv_need_explicit_instantiation=no],[stepmake_cv_need_explicit_instantiation=yes]))
 277     if test x"$stepmake_cv_need_explicit_instantiation"x = x"yes"x; then
 278         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 279     fi
 280 ])
 281
 282
 283 AC_DEFUN(STEPMAKE_DATADIR, [
 284     if test "$datadir" = "\${prefix}/share"; then
 285             datadir='${prefix}/share'
 286     fi
 287     presome=${prefix}
 288     if test "$prefix" = "NONE"; then
 289         presome=${ac_default_prefix}
 290     fi
 291
 292     build_package_datadir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/share/$package
 293
 294     DATADIR=`echo ${datadir} | sed "s!\\\${datarootdir}!${prefix}/share!"`
 295     DATADIR=`echo ${DATADIR} | sed "s!\\\${prefix}!$presome!"`
 296     BUILD_PACKAGE_DATADIR=`echo ${build_package_datadir} | sed "s!\\\${prefix}!$presome!"`
 297
 298     AC_SUBST(datadir)
 299     AC_SUBST(datarootdir)
 300     AC_SUBST(build_package_datadir)
 301     AC_DEFINE_UNQUOTED(DATADIR, ["${DATADIR}"])
 302     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_DATADIR, ["${BUILD_PACKAGE_DATADIR}"])
 303 ])
 304
 305 ## ugh: cut & paste programming from datadir.
 306 AC_DEFUN(STEPMAKE_LIBDIR, [
 307
 308     if test "$libdir" = "\${exec_prefix}/lib"; then
 309         libdir='${exec_prefix}/lib'
 310     fi
 311     presome=$exec_prefix
 312     build_package_libdir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/lib/$package
 313
 314     LIBDIR=`echo ${libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 315     BUILD_PACKAGE_LIBDIR=`echo ${build_package_libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 316
 317     AC_SUBST(libdir)
 318     AC_SUBST(build_package_libdir)
 319     AC_DEFINE_UNQUOTED(LIBDIR, ["${LIBDIR}"])
 320     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_LIBDIR, ["${BUILD_PACKAGE_LIBDIR}"])
 321 ])
 322
 323
 324 AC_DEFUN(STEPMAKE_PREFIX_EXPAND_FIXUP, [
 325     # undo expanding of explicit --infodir=/usr/share
 326     # to ease install-time override with prefix=...
 327     strip=`echo $includedir | eval sed s@^$prefix@@`
 328     if test "$includedir" = "`eval echo $prefix$strip`"; then
 329             includedir='${prefix}'$strip''
 330     fi
 331     strip=`echo $libdir | eval sed s@^$exec_prefix@@`
 332     if test "$libdir" = "`eval echo $exec_prefix$strip`"; then
 333             libdir='${exec_prefix}'$strip''
 334     fi
 335     strip=`echo $infodir | eval sed s@^$datarootdir@@`
 336     if test "$infodir" = "`eval echo $datarootdir$strip`"; then
 337             infodir='${datarootdir}'$strip''
 338     fi
 339     strip=`echo $mandir | eval sed s@^$datarootdir@@`
 340     if test "$mandir" = "`eval echo $datarootdir$strip`"; then
 341             mandir='${datarootdir}'$strip''
 342     fi
 343 ])
 344
 345
 346 AC_DEFUN(STEPMAKE_END, [
 347     STEPMAKE_PREFIX_EXPAND_FIXUP
 348
 349     AC_SUBST(OPTIONAL)
 350     AC_SUBST(REQUIRED)
 351
 352     AC_CONFIG_FILES([$CONFIGFILE.make:config.make.in])
 353     AC_OUTPUT
 354
 355     if test -n "$OPTIONAL"; then
 356         echo
 357         echo "WARNING: Please consider installing optional programs: $OPTIONAL"
 358     fi
 359
 360     if test -n "$REQUIRED"; then
 361         echo
 362         echo "ERROR: Please install required programs: $REQUIRED"
 363     fi
 364
 365     if test -n "$UNSUPPORTED"; then
 366         echo
 367         echo "ERROR: Please use older version of programs: $UNSUPPORTED"
 368     fi
 369
 370     if test -n "$OPTIONAL$REQUIRED$UNSUPPORTED"; then
 371         echo
 372         echo "See INSTALL.txt for more information on how to build $PACKAGE_NAME"
 373         if test -f config.cache ; then
 374             echo "Remove config.cache before rerunning ./configure"
 375         fi
 376     fi
 377
 378     if test -n "$REQUIRED$UNSUPPORTED"; then
 379         rm -f $srcdir/GNUmakefile
 380         exit 1
 381     fi
 382
 383     # regular in-place build
 384     # test for srcdir_build = yes ?
 385     if test "$srcdir_build" = "yes"; then
 386         rm -f $srcdir/GNUmakefile
 387         cp $srcdir/GNUmakefile.in $srcdir/GNUmakefile
 388         chmod 444 $srcdir/GNUmakefile
 389     else
 390         if test -f $srcdir/GNUmakefile; then
 391             cat <<EOF
 392 Source directory already configured.  Please clean the source directory
 393
 394      make -C $srcdir distclean
 395
 396 and rerun configure.
 397 EOF
 398             exit 2
 399         fi
 400
 401         for d in 2 3 4 ; do
 402             for mf in `cd $srcdir ; find -maxdepth $d -mindepth $d -name GNUmakefile`; do
 403                 mkdir -p $(dirname $mf)
 404                 cat <<EOF | $PYTHON -  > $mf
 405 print 'depth=' + ('../' * ( $d-1 ) )
 406 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 407 print 'include \$(configure-srcdir)/$mf'
 408 print 'MODULE_INCLUDES += \$(src-dir)/\$(outbase)'
 409 EOF
 410             done
 411             for mf in `cd $srcdir ; find -maxdepth $d -mindepth $d -name '*.make' | grep -v config.make `; do
 412                 mkdir -p $(dirname $mf)
 413                 cat <<EOF | $PYTHON -  > $mf
 414 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 415 print 'include \$(configure-srcdir)/$mf'
 416 EOF
 417             done
 418         done
 419
 420
 421         cat <<EOF > GNUmakefile
 422 depth = ./
 423 include config\$(if \$(conf),-\$(conf),).make
 424 include \$(configure-srcdir)/GNUmakefile.in
 425 EOF
 426         AC_SUBST(VPATH)
 427     fi
 428 ])
 429
 430
 431 AC_DEFUN(STEPMAKE_FLEX, [
 432     # ugh, automake: we want (and check for) flex
 433     # AC_PROG_LEX
 434     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 435
 436     # AC_PROG_LEX()
 437     # ugh, ugh
 438     ac_cv_prog_lex_root=lex.yy
 439     STEPMAKE_PROGS(FLEX, flex, $1)
 440 ])
 441
 442
 443 AC_DEFUN(STEPMAKE_FLEXLEXER, [
 444     AC_CHECK_HEADERS([FlexLexer.h],[true],[false])
 445     if test $? -ne 0; then
 446         warn='FlexLexer.h (flex package)'
 447         STEPMAKE_ADD_ENTRY($1, $warn)
 448     fi
 449     # check for yyFlexLexer.yy_current_buffer,
 450     # in 2.5.4 <= flex < 2.5.29
 451     AC_LANG_PUSH(C++)
 452     AC_CACHE_CHECK([for yyFlexLexer.yy_current_buffer],
 453         [stepmake_cv_flexlexer_yy_current_buffer],
 454         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 455 using namespace std;
 456 #include <FlexLexer.h>
 457 class yy_flex_lexer: public yyFlexLexer
 458 {
 459   public:
 460     yy_flex_lexer ()
 461     {
 462       yy_current_buffer = 0;
 463     }
 464 };
 465 ]])],
 466             [stepmake_cv_flexlexer_yy_current_buffer=yes],
 467             [stepmake_cv_flexlexer_yy_current_buffer=no]))
 468     if test $stepmake_cv_flexlexer_yy_current_buffer = yes; then
 469         AC_DEFINE(HAVE_FLEXLEXER_YY_CURRENT_BUFFER, 1, [Define to 1 if yyFlexLexer has yy_current_buffer.])
 470     fi
 471     AC_LANG_POP(C++)
 472 ])
 473
 474
 475
 476 AC_DEFUN(STEPMAKE_FLEXLEXER_LOCATION, [
 477         AC_MSG_CHECKING([FlexLexer.h location])
 478
 479         # ugh.
 480         cat <<EOF > conftest.cc
 481 using namespace std;
 482 #include <FlexLexer.h>
 483 EOF
 484         FLEXLEXER_FILE=`eval $ac_cpp conftest.cc | \
 485           sed 's!# 1 "\(.*FlexLexer.h\)"!@FLEXLEXER@\1@@!g' | grep '@@' | \
 486           sed 's!.*@FLEXLEXER@\(.*\)@@.*$!\1!g' ` 1> /dev/null 2> /dev/null
 487         rm conftest.cc
 488         AC_SUBST(FLEXLEXER_FILE)
 489         AC_MSG_RESULT($FLEXLEXER_FILE)
 490 ])
 491
 492 AC_DEFUN(STEPMAKE_GCC, [
 493     if test "$GCC" = "yes"; then
 494         STEPMAKE_CHECK_VERSION(CC, $1, $2)
 495     else
 496         warn="$CC (Please install *GNU* cc)"
 497         STEPMAKE_ADD_ENTRY($1, $warn)
 498     fi
 499 ])
 500
 501 AC_DEFUN(STEPMAKE_GETTEXT, [
 502     presome=${prefix}
 503     if test "$prefix" = "NONE"; then
 504             presome=${ac_default_prefix}
 505     fi
 506     LOCALEDIR=`echo ${localedir} | sed "s!\\\${prefix}!$presome!"`
 507
 508     AC_SUBST(localedir)
 509     AC_DEFINE_UNQUOTED(LOCALEDIR, ["${LOCALEDIR}"])
 510     # ouch.  autoconf <= 2.57's gettext check fails for
 511     # g++ >= 3.3 (with -std=gnu++98, the default).
 512     # While the check is OK for g++ -std=c++98,
 513     # LilyPond needs GNU g++, so who is to blame here?
 514     # Use a workaround until this is resolved:
 515     # for g++ >= 3.3, select C language.
 516     GCC_UNSUPPORTED=
 517     STEPMAKE_CHECK_VERSION_UNSUPPORTED(CXX, GCC_UNSUPPORTED, 3.3)
 518     if test -n "$GCC_UNSUPPORTED"; then
 519         AC_MSG_WARN([autoconf <= 2.59 with g++ >= 3.3 gettext test broken.])
 520         AC_MSG_WARN([Trying gcc, cross fingers.])
 521         AC_LANG_PUSH(C)
 522     fi
 523     AC_CHECK_LIB(intl, gettext)
 524     AC_CHECK_FUNCS(gettext)
 525     if test -n "$GCC_UNSUPPORTED"; then
 526         AC_LANG_POP(C)
 527     fi
 528 ])
 529
 530
 531 AC_DEFUN(STEPMAKE_GUILE, [
 532     STEPMAKE_PATH_PROG(GUILE, guile, $1)
 533 ])
 534
 535
 536 #   STEPMAKE_GUILE_FLAGS --- set flags for compiling and linking with Guile
 537 #
 538 #   This macro runs the guile-config script, installed with Guile,
 539 #   to find out where Guile's header files and libraries are
 540 #   installed.  It sets two variables, marked for substitution, as
 541 #   by AC_SUBST.
 542 #
 543 #     GUILE_CFLAGS --- flags to pass to a C or C++ compiler to build
 544 #             code that uses Guile header files.  This is almost
 545 #             always just a -I flag.
 546 #
 547 #     GUILE_LDFLAGS --- flags to pass to the linker to link a
 548 #             program against Guile.  This includes -lguile for
 549 #             the Guile library itself, any libraries that Guile
 550 #             itself requires (like -lqthreads), and so on.  It may
 551 #             also include a -L flag to tell the compiler where to
 552 #             find the libraries.
 553
 554 AC_DEFUN([STEPMAKE_GUILE_FLAGS], [
 555     exe=`STEPMAKE_GET_EXECUTABLE($guile_config)`
 556     if test -x $exe; then
 557         AC_MSG_CHECKING([guile compile flags])
 558         GUILE_CFLAGS="`$guile_config compile`"
 559         AC_MSG_RESULT($GUILE_CFLAGS)
 560         AC_MSG_CHECKING([guile link flags])
 561         GUILE_LDFLAGS="`$guile_config link`"
 562         AC_MSG_RESULT($GUILE_LDFLAGS)
 563     fi
 564     AC_SUBST(GUILE_CFLAGS)
 565     AC_SUBST(GUILE_LDFLAGS)
 566 ])
 567
 568
 569 AC_DEFUN(STEPMAKE_GUILE_DEVEL, [
 570     ## First, let's just see if we can find Guile at all.
 571     test -n "$target_alias" && target_guile_config=$target_alias-guile-config
 572     test -n "$host_alias" && host_guile_config=$host_alias-guile-config
 573     AC_MSG_CHECKING([for guile-config])
 574     for guile_config in $GUILE_CONFIG $target_guile_config $host_guile_config $build_guile_config guile-config; do
 575         AC_MSG_RESULT([$guile_config])
 576         if ! $guile_config --version > /dev/null 2>&1 ; then
 577             AC_MSG_WARN([cannot execute $guile_config])
 578             AC_MSG_CHECKING([if we are cross compiling])
 579             GUILE_CONFIG='echo no guile-config'
 580         else
 581             GUILE_CONFIG=$guile_config
 582             break
 583         fi
 584     done
 585     STEPMAKE_OPTIONAL_REQUIRED(GUILE_CONFIG, $guile_config, $1)
 586     if test $? -ne 0; then
 587         STEPMAKE_ADD_ENTRY($1, 'guile-config (guile-devel, guile-dev or libguile-dev package)')
 588     fi
 589
 590     STEPMAKE_CHECK_SEARCH_RESULT(GUILE_CONFIG)
 591     # urg.  should test functionality rather than version.
 592     if test $? -eq 0 -a -n "$2"; then
 593         STEPMAKE_CHECK_VERSION(GUILE_CONFIG, $1, $2)
 594     fi
 595
 596     AC_SUBST(GUILE_CONFIG)
 597
 598     guile_version="$ver"
 599     changequote(<<, >>)#dnl
 600     GUILE_MAJOR_VERSION=`expr $guile_version : '\([0-9]*\)'`
 601     GUILE_MINOR_VERSION=`expr $guile_version : '[0-9]*\.\([0-9]*\)'`
 602     GUILE_PATCH_LEVEL=`expr $guile_version : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
 603     changequote([, ])#dnl
 604     STEPMAKE_GUILE_FLAGS
 605     save_CPPFLAGS="$CPPFLAGS"
 606     save_LIBS="$LIBS"
 607     CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
 608     LIBS="$GUILE_LDFLAGS $LIBS"
 609     AC_CHECK_HEADERS([libguile.h])
 610     AC_CHECK_LIB(guile, scm_boot_guile)
 611     AC_CHECK_FUNCS(scm_boot_guile,,libguile_b=no)
 612     if test "$libguile_b" = "no"; then
 613             warn='libguile (libguile-dev, guile-devel or guile-dev
 614    package).'
 615             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 616     fi
 617     CPPFLAGS="$save_CPPFLAGS"
 618     LIBS="$save_LIBS"
 619     AC_DEFINE_UNQUOTED(GUILE_MAJOR_VERSION, $GUILE_MAJOR_VERSION)
 620     AC_DEFINE_UNQUOTED(GUILE_MINOR_VERSION, $GUILE_MINOR_VERSION)
 621     AC_DEFINE_UNQUOTED(GUILE_PATCH_LEVEL, $GUILE_PATCH_LEVEL)
 622 ])
 623
 624
 625 AC_DEFUN(STEPMAKE_DLOPEN, [
 626     AC_CHECK_LIB(dl, dlopen)
 627     AC_CHECK_FUNCS(dlopen)
 628 ])
 629
 630 AC_DEFUN(STEPMAKE_GXX, [
 631     if test "$GXX" = "yes"; then
 632         STEPMAKE_CHECK_VERSION(CXX, $1, $2)
 633     else
 634         warn="$CXX (Please install *GNU* c++)"
 635         STEPMAKE_ADD_ENTRY($1, $warn)
 636     fi
 637 ])
 638
 639
 640 AC_DEFUN(STEPMAKE_INIT, [
 641
 642     AC_PREREQ(2.50)
 643     . $srcdir/VERSION
 644     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 645     MICRO_VERSION=$PATCH_LEVEL
 646     TOPLEVEL_VERSION=$FULL_VERSION
 647     if test x$MY_PATCH_LEVEL != x; then
 648         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 649     fi
 650     VERSION=$FULL_VERSION
 651     export MAJOR_VERSION MINOR_VERSION PATCH_LEVEL
 652     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 653     changequote(<<, >>)#dnl
 654     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 655     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 656     changequote([, ])#dnl
 657
 658     # No versioning on directory names of sub-packages
 659     # urg, urg
 660     stepmake=${datadir}/stepmake
 661     presome=${prefix}
 662     if test "$prefix" = "NONE"; then
 663             presome=${ac_default_prefix}
 664     fi
 665     stepmake=`echo ${stepmake} | sed "s!\\\${prefix}!$presome!"`
 666
 667     # urg, how is this supposed to work?
 668     if test "$program_prefix" = "NONE"; then
 669           program_prefix=
 670     fi
 671     if test "$program_suffix" = "NONE"; then
 672           program_suffix=
 673     fi
 674
 675     AC_MSG_CHECKING(Package)
 676     if test "$PACKAGE" = "STEPMAKE"; then
 677         AC_MSG_RESULT(Stepmake package!)
 678
 679         AC_MSG_CHECKING(builddir)
 680
 681         ugh_ugh_autoconf250_builddir="`pwd`"
 682
 683         if test "$srcdir" = "."; then
 684             srcdir_build=yes
 685         else
 686             srcdir_build=no
 687             package_builddir="`dirname $ugh_ugh_autoconf250_builddir`"
 688             package_srcdir="`dirname  $srcdir`"
 689         fi
 690         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 691
 692         (cd stepmake 2>/dev/null || mkdir stepmake)
 693         (cd stepmake; rm -f bin; ln -s ../$srcdir/bin .)
 694         stepmake=stepmake
 695     else
 696         AC_MSG_RESULT($PACKAGE)
 697
 698         AC_MSG_CHECKING(builddir)
 699         ugh_ugh_autoconf250_builddir="`pwd`"
 700
 701         here_dir=$(cd . && pwd)
 702         full_src_dir=$(cd $srcdir && pwd)
 703
 704         if test "$full_src_dir" = "$here_dir"; then
 705             srcdir_build=yes
 706         else
 707             srcdir_build=no
 708         fi
 709         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 710
 711         AC_MSG_CHECKING(for stepmake)
 712         # Check for installed stepmake
 713         if test -d $stepmake; then
 714             AC_MSG_RESULT($stepmake)
 715         else
 716             stepmake="`cd $srcdir/stepmake; pwd`"
 717             AC_MSG_RESULT([$srcdir/stepmake  ($datadir/stepmake not found)])
 718         fi
 719     fi
 720
 721     AC_SUBST(ugh_ugh_autoconf250_builddir)
 722
 723     # Use absolute directory for non-srcdir builds, so that build
 724     # dir can be moved.
 725     if test "$srcdir_build" = "no" ;  then
 726         srcdir="`cd $srcdir; pwd`"
 727     fi
 728
 729     AC_SUBST(srcdir)
 730     AC_SUBST(stepmake)
 731     AC_SUBST(package)
 732     AC_SUBST(PACKAGE)
 733     AC_SUBST(PACKAGE_NAME)
 734     AC_SUBST(VERSION)
 735     AC_SUBST(MAJOR_VERSION)
 736     AC_SUBST(MINOR_VERSION)
 737     AC_SUBST(MICRO_VERSION)
 738
 739     # stepmake nonstandard names
 740     AC_SUBST(PATCH_LEVEL)
 741     AC_SUBST(TOPLEVEL_VERSION)
 742
 743     # We don't need the upper case variant,
 744     # so stick to macros are uppercase convention.
 745     # AC_DEFINE_UNQUOTED(package, ["${package}"])
 746     # AC_DEFINE_UNQUOTED(PACKAGE, ["${PACKAGE}"])
 747     AC_DEFINE_UNQUOTED(PACKAGE, ["${package}"])
 748     AC_DEFINE_UNQUOTED(PACKAGE_NAME, ["${PACKAGE_NAME}"])
 749     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, ["${FULL_VERSION}"])
 750
 751     if test -z "$package_depth"; then
 752         package_depth="."
 753     else
 754         package_depth="../$package_depth"
 755     fi
 756     export package_depth
 757     AC_SUBST(package_depth)
 758
 759     AUTOGENERATE="This file was automatically generated by configure"
 760     AC_SUBST(AUTOGENERATE)
 761
 762     CONFIGSUFFIX=
 763     AC_ARG_ENABLE(config,
 764     [  --enable-config=CONF    put settings in config-CONF.make and config-CONF.h;
 765                             do `make conf=CONF' to get output in ./out-CONF],
 766     [CONFIGURATION=$enableval])
 767
 768     ##'`#
 769
 770     test -n "$CONFIGURATION" && CONFIGSUFFIX="-$CONFIGURATION"
 771     CONFIGFILE=config$CONFIGSUFFIX
 772     AC_SUBST(CONFIGSUFFIX)
 773
 774     AC_CANONICAL_HOST
 775     STEPMAKE_PROGS(MAKE, gmake make, REQUIRED)
 776     STEPMAKE_PROGS(FIND, find, REQUIRED)
 777
 778     STEPMAKE_PROGS(TAR, tar, REQUIRED)
 779
 780     if test "$(echo 2)" != "2" ||
 781         test "x`uname`" = "xHP-UX"; then
 782         AC_PATH_PROG(KSH, ksh, /bin/ksh)
 783         AC_PATH_PROG(BASH, bash, $KSH)
 784         STEPMAKE_WARN(avoiding buggy /bin/sh)
 785         AC_PATH_PROG(SHELL, bash, $KSH)
 786     else
 787         SHELL=/bin/sh
 788         AC_PATH_PROG(BASH, bash, $SHELL)
 789     fi
 790     AC_SUBST(SHELL)
 791
 792     STEPMAKE_PYTHON(REQUIRED, 1.5)
 793
 794     if expr "$MAKE" : '.*\(echo\)' >/dev/null; then
 795         $MAKE -v 2> /dev/null | grep GNU > /dev/null
 796         if test "$?" = 1; then
 797             warn='make (Please install *GNU* make)'
 798             # STEPMAKE_WARN($warn)
 799             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 800         fi
 801     fi
 802
 803     ROOTSEP=':'
 804     DIRSEP='/'
 805     PATHSEP=':'
 806     LN=ln
 807     LN_S='ln -s'
 808     ZIP="zip -r -9"
 809
 810     AC_SUBST(program_prefix)
 811     AC_SUBST(program_suffix)
 812     AC_SUBST(ZIP)
 813     AC_SUBST(LN)
 814     AC_SUBST(LN_S)
 815     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
 816     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
 817     AC_SUBST(DIRSEP)
 818     AC_SUBST(PATHSEP)
 819     AC_SUBST(ROOTSEP)
 820
 821     STEPMAKE_DATADIR
 822     STEPMAKE_LIBDIR
 823 ])
 824
 825
 826 AC_DEFUN(STEPMAKE_LIB, [
 827     STEPMAKE_PROGS(AR, ar, $1)
 828     AC_PROG_RANLIB
 829     STEPMAKE_OPTIONAL_REQUIRED(RANLIB, ranlib, $1)
 830 ])
 831
 832
 833 AC_DEFUN(STEPMAKE_LIBTOOL, [
 834     # libtool.info ...
 835     # **Never** try to set library version numbers so that they correspond
 836     # to the release number of your package.  This is an abuse that only
 837     # fosters misunderstanding of the purpose of library versions.
 838
 839     REVISION=$PATCH_LEVEL
 840     # CURRENT=$MINOR_VERSION
 841     CURRENT=`expr $MINOR_VERSION + 1`
 842     # AGE=`expr $MAJOR_VERSION + 1`
 843     AGE=$MAJOR_VERSION
 844     AC_SUBST(CURRENT)
 845     AC_SUBST(REVISION)
 846     AC_SUBST(AGE)
 847 ])
 848
 849
 850 AC_DEFUN(STEPMAKE_LOCALE, [
 851     lang=English
 852     ALL_LINGUAS="en nl"
 853
 854     # with/enable ??
 855     AC_ARG_WITH(localedir,
 856     [  --with-localedir=DIR    location of locales.  Default: PREFIX/share/locale ],
 857     localedir=$with_localedir,
 858     localedir='${prefix}/share/locale')
 859
 860     AC_ARG_WITH(lang,
 861     [  --with-lang=LANG        use LANG as language to emit messages],
 862     language=$with_lang,
 863     language=English)
 864
 865     AC_MSG_CHECKING(language)
 866     case "$language" in
 867       En* | en* | Am* | am* | US* | us*)
 868             lang=English;;
 869       NL | nl | Du* | du* | Ned* | ned*)
 870             lang=Dutch;;
 871       "")
 872             lang=English;;
 873       *)
 874             lang=unknown;;
 875     esac
 876     AC_MSG_RESULT($lang)
 877
 878     if test "$lang" = "unknown" ; then
 879         STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 880     fi
 881
 882 ])
 883
 884
 885 AC_DEFUN(STEPMAKE_MAKEINFO, [
 886     STEPMAKE_PROGS(MAKEINFO, makeinfo, $1)
 887 ])
 888
 889
 890 AC_DEFUN(STEPMAKE_MAN, [
 891     STEPMAKE_PROGS(GROFF, groff ditroff, $1)
 892     AC_SUBST(GROFF)
 893     STEPMAKE_PROGS(TROFF, troff, $1)
 894     AC_SUBST(TROFF)
 895     STEPMAKE_PROGS(TBL, tbl, $1)
 896     AC_SUBST(TBL)
 897 ])
 898
 899
 900 AC_DEFUN(STEPMAKE_MSGFMT, [
 901     STEPMAKE_PROGS(MSGFMT, msgfmt, $1)
 902 ])
 903
 904
 905 # Check for program ($2), set full path result to ($1).
 906 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 907 AC_DEFUN(STEPMAKE_PATH_PROG, [
 908     AC_CHECK_PROGS($1, $2, no)
 909     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 910     if test $? -eq 0; then
 911         AC_PATH_PROG($1, $2)
 912         if test -n "$4"; then
 913             STEPMAKE_CHECK_VERSION($1, $3, $4)
 914         fi
 915     fi
 916 ])
 917
 918
 919 # Check for program in set of names ($2), set result to ($1) .
 920 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 921 # If exists, and a minimal version ($4) is required
 922 AC_DEFUN(STEPMAKE_PROGS, [
 923     AC_CHECK_PROGS($1, $2, no)
 924     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 925     if test $? -eq 0 -a -n "$4"; then
 926         STEPMAKE_CHECK_VERSION($1, $3, $4)
 927     fi
 928 ])
 929
 930
 931 AC_DEFUN(STEPMAKE_PERL, [
 932     STEPMAKE_PATH_PROG(PERL, perl, $1)
 933 ])
 934
 935
 936 AC_DEFUN(STEPMAKE_PYTHON, [
 937     unset pv
 938     AC_MSG_CHECKING([for python])
 939     for python in $PYTHON python python2 python2.4 python2.3 python2.2 python2.1 python2.0; do
 940         AC_MSG_RESULT([$python])
 941         if ! $python -V > /dev/null 2>&1 ; then
 942             #AC_MSG_WARN([cannot execute $python])
 943             PYTHON='echo no python'
 944         else
 945             unset pv
 946             STEPMAKE_CHECK_VERSION(python, pv, $2)
 947             if test -z "$pv"; then
 948                 PYTHON=$python
 949                 break
 950             fi
 951         fi
 952     done
 953     if test -n "$pv"; then
 954         STEPMAKE_ADD_ENTRY($1, $pv)
 955     fi
 956     # clear cached value since arg 2 might point us to a new binary
 957     unset ac_cv_path_PYTHON
 958
 959     AC_PATH_PROG(PYTHON, $PYTHON)
 960     AC_SUBST(PYTHON)
 961 ])
 962
 963 AC_DEFUN(STEPMAKE_PYTHON_DEVEL, [
 964     AC_ARG_WITH(python-include,
 965         [  --with-python-include=DIR
 966                           location of the python include dir],[
 967             if test "$withval" = "yes" -o "$withval" = "no"; then
 968                 AC_MSG_WARN(Usage: --with-python-include=includedir)
 969             else
 970                 PYTHON_CFLAGS="-I${withval}"
 971             fi
 972             ])
 973
 974     AC_ARG_WITH(python-lib,
 975         [  --with-python-lib=NAME  name of the python lib],[
 976             if test "$withval" = "yes" -o "$withval" = "no"; then
 977                 AC_MSG_WARN(Usage: --with-python-lib=name)
 978             else
 979                 LDFLAGS="$LDFLAGS -l${withval}"
 980             fi
 981             ])
 982
 983     AC_CHECK_PROGS(PYTHON_CONFIG, python-config, no)
 984
 985     if test -z "$PYTHON_CFLAGS" -a "$PYTHON_CONFIG" != "no"; then
 986         # Clean out junk: http://bugs.python.org/issue3290
 987         # Python headers may need some -f* flags, leave them in.
 988         PYTHON_CFLAGS=`$PYTHON_CONFIG --cflags | sed -e 's/ -\(W\|D\|O\|m\)\(\w\|-\|=\|,\)\+//g'`
 989         PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
 990     fi
 991
 992     if test -z "$PYTHON_CFLAGS" -a "$cross_compiling" = "no"; then
 993         changequote(<<, >>)#dnl
 994         # alternatively, for python >= 2.0
 995         # 'import sys, distutils.sysconfig; sys.stdout.write (distutils.sysconfig.get_python_inc ())'
 996         PYTHON_INCLUDE=`$PYTHON -c 'import sys; sys.stdout.write ("%s/include/python%s" % (sys.prefix, sys.version[:3]))'`
 997         PYTHON_CFLAGS="-I$PYTHON_INCLUDE"
 998         changequote([, ])#dnl
 999     fi
1000
1001     if test -z "$PYTHON_HEADER"; then
1002         CPPFLAGS="$PYTHON_CFLAGS $CPPFLAGS"
1003         AC_CHECK_HEADERS([Python.h],[PYTHON_HEADER=yes])
1004     fi
1005
1006     if test -z "$PYTHON_HEADER"; then
1007         warn="Python.h (python-devel, python-dev or libpython-dev package)"
1008         STEPMAKE_ADD_ENTRY($1, $warn)
1009     fi
1010 ])
1011
1012
1013
1014 AC_DEFUN(STEPMAKE_STL_DATA_METHOD, [
1015     AC_LANG_PUSH(C++)
1016     AC_CACHE_CHECK([for stl.data () method],
1017         [stepmake_cv_stl_data_method],
1018         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1019 #include <vector>
1020 using namespace std;
1021 vector <int> v;
1022 void *p = v.data ();
1023 ]])],
1024             [stepmake_cv_stl_data_method=yes],
1025             [stepmake_cv_stl_data_method=no]))
1026     if test $stepmake_cv_stl_data_method = yes; then
1027         AC_DEFINE(HAVE_STL_DATA_METHOD, 1, [define if stl classes have data () method])
1028     fi
1029     AC_LANG_POP(C++)
1030 ])
1031
1032
1033 AC_DEFUN(STEPMAKE_TEXMF_DIRS, [
1034     # ugh
1035     STEPMAKE_PROGS(KPSEWHICH, kpsewhich, OPTIONAL)
1036 ])
1037
1038 AC_DEFUN(STEPMAKE_TEXMF, [
1039     STEPMAKE_PROGS(METAFONT, mf-nowin mf mfw mfont, $1)
1040     STEPMAKE_PROGS(METAPOST, mpost, $1)
1041     # STEPMAKE_PROGS(INIMETAFONT, inimf inimfont "$METAFONT -ini", $1)
1042
1043     AC_MSG_CHECKING(for working metafont mode)
1044     modelist='ljfour lj4 lj3 lj2 ljet laserjet'
1045     for MFMODE in $modelist; do
1046         $METAFONT -progname=mf "\mode:=$MFMODE; mode_setup; end." > /dev/null 2>&1
1047         if test -f mfput.tfm; then
1048             break;
1049         fi
1050     done
1051     AC_MSG_RESULT($MFMODE)
1052
1053     rm -f mfput.*
1054
1055     AC_SUBST(MFMODE)
1056 ])
1057
1058
1059 AC_DEFUN(STEPMAKE_WARN, [
1060     AC_MSG_WARN($1)
1061     warn_b=yes
1062 ])
1063
1064
1065 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1066 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1067 dnl also defines GSTUFF_PKG_ERRORS on error
1068 AC_DEFUN(PKG_CHECK_MODULES, [
1069   succeeded=no
1070
1071   if test -z "$PKG_CONFIG"; then
1072     AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1073   fi
1074
1075   if test "$PKG_CONFIG" = "no" ; then
1076      echo "*** The pkg-config script could not be found. Make sure it is"
1077      echo "*** in your path, or set the PKG_CONFIG environment variable"
1078      echo "*** to the full path to pkg-config."
1079      echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
1080   else
1081      PKG_CONFIG_MIN_VERSION=0.9.0
1082      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1083         AC_MSG_CHECKING(for $2)
1084
1085         if $PKG_CONFIG --exists "$2" ; then
1086             AC_MSG_RESULT(yes)
1087             succeeded=yes
1088
1089             AC_MSG_CHECKING($1_CFLAGS)
1090             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
1091             AC_MSG_RESULT($$1_CFLAGS)
1092
1093             AC_MSG_CHECKING($1_LIBS)
1094             $1_LIBS=`$PKG_CONFIG --libs "$2"`
1095             AC_MSG_RESULT($$1_LIBS)
1096         else
1097             $1_CFLAGS=""
1098             $1_LIBS=""
1099             ## If we have a custom action on failure, don't print errors, but
1100             ## do set a variable so people can do so.
1101             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1102             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1103         fi
1104
1105         AC_SUBST($1_CFLAGS)
1106         AC_SUBST($1_LIBS)
1107      fi
1108   fi
1109
1110   if test $succeeded = yes; then
1111      ifelse([$3], , :, [$3])
1112   else
1113      ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
1114   fi
1115 ])
1116
1117 AC_DEFUN(STEPMAKE_FREETYPE2, [
1118     PKG_CHECK_MODULES(FREETYPE2, $1 >= $3, have_freetype2=yes, true)
1119     if test "$have_freetype2" = yes; then
1120         AC_DEFINE(HAVE_FREETYPE2)
1121         save_CPPFLAGS="$CPPFLAGS"
1122         save_LIBS="$LIBS"
1123         CPPFLAGS="$FREETYPE2_CFLAGS $CPPFLAGS"
1124         LIBS="$FREETYPE2_LIBS $LIBS"
1125         AC_SUBST(FREETYPE2_CFLAGS)
1126         AC_SUBST(FREETYPE2_LIBS)
1127         CPPFLAGS="$save_CPPFLAGS"
1128         LIBS="$save_LIBS"
1129     else
1130         # UGR
1131         #r="lib$1-dev or $1-devel"
1132         r="libfreetype6-dev or freetype?-devel"
1133         ver="`pkg-config --modversion $1`"
1134         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1135     fi
1136 ])
1137
1138 AC_DEFUN(STEPMAKE_GTK2, [
1139     PKG_CHECK_MODULES(GTK2, $1 >= $3, have_gtk2=yes, true)
1140     if test "$have_gtk2" = yes ; then
1141         AC_DEFINE(HAVE_GTK2)
1142         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1143         save_CPPFLAGS="$CPPFLAGS"
1144         save_LIBS="$LIBS"
1145         CPPFLAGS="$GTK2_CFLAGS $CPPFLAGS"
1146         LIBS="$GTK2_LIBS $LIBS"
1147         AC_SUBST(GTK2_CFLAGS)
1148         AC_SUBST(GTK2_LIBS)
1149         CPPFLAGS="$save_CPPFLAGS"
1150         LIBS="$save_LIBS"
1151     else
1152         # UGR
1153         # r="lib$1-dev or $1-devel"
1154         r="libgtk2.0-dev or gtk2-devel"
1155         ver="`pkg-config --modversion $1`"
1156         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1157     fi
1158 ])
1159
1160 AC_DEFUN(STEPMAKE_PANGO, [
1161     PKG_CHECK_MODULES(PANGO, $1 >= $3, have_pango16=yes, true)
1162     if test "$have_pango16" = yes ; then
1163         AC_DEFINE(HAVE_PANGO16)
1164         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1165         save_CPPFLAGS="$CPPFLAGS"
1166         save_LIBS="$LIBS"
1167         CPPFLAGS="$PANGO_CFLAGS $CPPFLAGS"
1168         LIBS="$PANGO_LIBS $LIBS"
1169         AC_CHECK_HEADERS([pango/pangofc-fontmap.h])
1170         AC_CHECK_FUNCS([pango_fc_font_map_add_decoder_find_func])
1171         AC_SUBST(PANGO_CFLAGS)
1172         AC_SUBST(PANGO_LIBS)
1173         CPPFLAGS="$save_CPPFLAGS"
1174         LIBS="$save_LIBS"
1175     else
1176         # UGR
1177         #r="lib$1-dev or $1-devel"
1178         r="libpango1.0-dev or pango1.0-devel"
1179         ver="`pkg-config --modversion $1`"
1180         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1181     fi
1182 ])
1183
1184 AC_DEFUN(STEPMAKE_PANGO_FT2, [
1185     PKG_CHECK_MODULES(PANGO_FT2, $1 >= $3, have_pangoft2=yes, true)
1186     if test "$have_pangoft2" = yes ; then
1187         AC_DEFINE(HAVE_PANGO16)
1188         AC_DEFINE(HAVE_PANGO_FT2)
1189         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1190         save_CPPFLAGS="$CPPFLAGS"
1191         save_LIBS="$LIBS"
1192         CPPFLAGS="$CPPFLAGS $PANGO_FT2_CFLAGS"
1193         LIBS="$PANGO_FT2_LIBS $LIBS"
1194         AC_CHECK_HEADERS([pango/pangoft2.h])
1195         AC_CHECK_FUNCS([pango_ft2_font_map_create_context])
1196         AC_SUBST(PANGO_FT2_CFLAGS)
1197         AC_SUBST(PANGO_FT2_LIBS)
1198         CPPFLAGS="$save_CPPFLAGS"
1199         LIBS="$save_LIBS"
1200     else
1201         # UGR
1202         #r="lib$1-dev or $1-devel"e
1203         r="libpango1.0-dev or pango?-devel"
1204         ver="`pkg-config --modversion $1`"
1205         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1206     fi
1207 ])
1208
1209 AC_DEFUN(STEPMAKE_FONTCONFIG, [
1210     PKG_CHECK_MODULES(FONTCONFIG, $1 >= $3, have_fontconfig=yes, true)
1211     if test "$have_fontconfig" = yes ; then
1212         AC_DEFINE(HAVE_FONTCONFIG)
1213         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1214         save_CPPFLAGS="$CPPFLAGS"
1215         save_LIBS="$LIBS"
1216         CPPFLAGS="$FONTCONFIG_CFLAGS $CPPFLAGS"
1217         LIBS="$FONTCONFIG_LIBS $LIBS"
1218         AC_SUBST(FONTCONFIG_CFLAGS)
1219         AC_SUBST(FONTCONFIG_LIBS)
1220         CPPFLAGS="$save_CPPFLAGS"
1221         LIBS="$save_LIBS"
1222     else
1223         r="lib$1-dev or $1-devel"
1224         ver="`pkg-config --modversion $1`"
1225         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1226     fi
1227 ])
1228
1229 AC_DEFUN(STEPMAKE_WINDOWS, [
1230     AC_CYGWIN
1231     AC_MINGW32
1232
1233     if test "$CYGWIN" = "yes"; then
1234         LN_S='cp -r' # Cygwin symbolic links do not work for native apps.
1235         program_suffix=.exe
1236         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1237     elif test "$MINGW32" = "yes"; then
1238         LN='cp -r'
1239         LN_S='cp -r'
1240         program_suffix=.exe
1241         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1242         PATHSEP=';'
1243     fi
1244
1245     AC_SUBST(LN)
1246     AC_SUBST(LN_S)
1247     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
1248     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
1249     AC_SUBST(DIRSEP)
1250     AC_SUBST(PATHSEP)
1251     AC_SUBST(program_suffix)
1252
1253     AC_MSG_CHECKING([for some flavor of Windows])
1254     if test "$CYGWIN$MINGW32" = "nono"; then
1255         PLATFORM_WINDOWS=no
1256     else
1257         PLATFORM_WINDOWS=yes
1258     fi
1259     AC_MSG_RESULT([$PLATFORM_WINDOWS])
1260     AC_SUBST(PLATFORM_WINDOWS)
1261     STEPMAKE_PROGS(WINDRES, $target-windres windres, x)
1262     AC_SUBST(WINDRES)
1263 ])