t/lib/DebbugsTest.pm

   1
   2 package DebbugsTest;
   3
   4 =head1 NAME
   5
   6 DebbugsTest
   7
   8 =head1 SYNOPSIS
   9
  10 use DebbugsTest
  11
  12
  13 =head1 DESCRIPTION
  14
  15 This module contains various testing routines used to test debbugs in
  16 a "pseudo install"
  17
  18 =head1 FUNCTIONS
  19
  20 =cut
  21
  22 use warnings;
  23 use strict;
  24 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT);
  25 use base qw(Exporter);
  26
  27 use IO::File;
  28 use File::Temp qw(tempdir);
  29 use Cwd qw(getcwd);
  30 use Debbugs::MIME qw(create_mime_message);
  31 use File::Basename qw(dirname basename);
  32 use IPC::Open3;
  33 use IO::Handle;
  34 use Test::More;
  35
  36 use Params::Validate qw(validate_with :types);
  37
  38 BEGIN{
  39      $VERSION = 1.00;
  40      $DEBUG = 0 unless defined $DEBUG;
  41
  42      @EXPORT = ();
  43      %EXPORT_TAGS = (configuration => [qw(dirsize create_debbugs_configuration send_message)],
  44                      mail          => [qw(num_messages_sent)],
  45                     );
  46      @EXPORT_OK = ();
  47      Exporter::export_ok_tags(qw(configuration mail));
  48      $EXPORT_TAGS{all} = [@EXPORT_OK];
  49 }
  50
  51 # First, we're going to send mesages to receive.
  52 # To do so, we'll first send a message to submit,
  53 # then send messages to the newly created bugnumber.
  54
  55
  56
  57 sub create_debbugs_configuration {
  58      my %param = validate_with(params => \@_,
  59                                spec   => {debug => {type => BOOLEAN,
  60                                                     default => 0,
  61                                                    },
  62                                           cleanup => {type => BOOLEAN,
  63                                                       optional => 1,
  64                                                      },
  65                                          },
  66                               );
  67      $param{cleanup} = $param{debug}?0:1 if not exists $param{cleanup};
  68      my $sendmail_dir = tempdir(CLEANUP => $param{cleanup});
  69      my $spool_dir = tempdir(CLEANUP => $param{cleanup});
  70      my $config_dir = tempdir(CLEANUP => $param{cleanup});
  71
  72
  73      $ENV{DEBBUGS_CONFIG_FILE}  ="$config_dir/debbugs_config";
  74      $ENV{PERL5LIB} = getcwd();
  75      $ENV{SENDMAIL_TESTDIR} = $sendmail_dir;
  76      my $sendmail_tester = getcwd().'/t/sendmail_tester';
  77      unless (-x $sendmail_tester) {
  78           die q(t/sendmail_tester doesn't exist or isn't executable. You may be in the wrong directory.);
  79      }
  80      my %files_to_create = ("$config_dir/debbugs_config" => <<END,
  81 \$gSendmail='$sendmail_tester';
  82 \$gSpoolDir='$spool_dir';
  83 \$gLibPath='@{[getcwd()]}/scripts';
  84 \$gTemplateDir='@{[getcwd()]}/templates';
  85 \$gWebHost='localhost';
  86 1;
  87 END
  88                             "$spool_dir/nextnumber" => qq(1\n),
  89                             "$config_dir/Maintainers" => qq(foo Blah Bleargh <foo\@baz.com>\nbar Bar Bleargh <bar\@baz.com>\n),
  90                             "$config_dir/Maintainers.override" => qq(),
  91                             "$config_dir/indices/sources" => <<END,
  92 foo main foo
  93 END
  94                             "$config_dir/pseudo-packages.description" => '',
  95                            );
  96      while (my ($file,$contents) = each %files_to_create) {
  97           system('mkdir','-p',dirname($file));
  98           my $fh = IO::File->new($file,'w') or
  99                die "Unable to create $file: $!";
 100           print {$fh} $contents or die "Unable to write $contents to $file: $!";
 101           close $fh or die "Unable to close $file: $!";
 102      }
 103
 104      system('touch',"$spool_dir/index.db.realtime");
 105      system('ln','-s','index.db.realtime',
 106             "$spool_dir/index.db");
 107      system('touch',"$spool_dir/index.archive.realtime");
 108      system('ln','-s','index.archive.realtime',
 109             "$spool_dir/index.archive");
 110
 111      # create the spool files and sub directories
 112      map {system('mkdir','-p',"$spool_dir/$_"); }
 113           map {('db-h/'.$_,'archive/'.$_)}
 114                map { sprintf "%02d",$_ % 100} 0..99;
 115      system('mkdir','-p',"$spool_dir/incoming");
 116      system('mkdir','-p',"$spool_dir/lock");
 117
 118      return (spool_dir => $spool_dir,
 119              sendmail_dir => $sendmail_dir,
 120              config_dir => $config_dir,
 121             );
 122 }
 123
 124 sub dirsize{
 125      my ($dir) = @_;
 126      opendir(DIR,$dir);
 127      my @content = grep {!/^\.\.?$/} readdir(DIR);
 128      closedir(DIR);
 129      return scalar @content;
 130 }
 131
 132
 133 # We're going to use create mime message to create these messages, and
 134 # then just send them to receive.
 135 # First, check that submit@ works
 136
 137 sub send_message{
 138      my %param = validate_with(params => \@_,
 139                                spec   => {to => {type => SCALAR,
 140                                                  default => 'submit@bugs.something',
 141                                                 },
 142                                           headers => {type => ARRAYREF,
 143                                                      },
 144                                           body    => {type => SCALAR,
 145                                                      },
 146                                           run_processall =>{type => BOOLEAN,
 147                                                             default => 1,
 148                                                            },
 149                                          }
 150                               );
 151      $ENV{LOCAL_PART} = $param{to};
 152      my ($rfd,$wfd);
 153      my $output='';
 154      local $SIG{PIPE} = 'IGNORE';
 155      local $SIG{CHLD} = sub {};
 156      my $pid = open3($wfd,$rfd,$rfd,'scripts/receive')
 157           or die "Unable to start receive: $!";
 158      print {$wfd} create_mime_message($param{headers},
 159                                          $param{body}) or die "Unable to to print to receive";
 160      close($wfd) or die "Unable to close receive";
 161      my $err = $? >> 8;
 162      my $childpid = waitpid($pid,0);
 163      if ($childpid != -1) {
 164           $err = $? >> 8;
 165           print STDERR "receive pid: $pid doesn't match childpid: $childpid\n" if $childpid != $pid;
 166      }
 167      if ($err != 0 ) {
 168           my $rfh =  IO::Handle->new_from_fd($rfd,'r') or die "Unable to create filehandle: $!";
 169           $rfh->blocking(0);
 170           my $rv;
 171           while ($rv = $rfh->sysread($output,1000,length($output))) {}
 172           if (not defined $rv) {
 173                print STDERR "Reading from STDOUT/STDERR would have blocked.";
 174           }
 175           print STDERR $output,qq(\n);
 176           die "receive failed with exit status $err";
 177      }
 178      # now we should run processall to see if the message gets processed
 179      if ($param{run_processall}) {
 180           system('scripts/processall') == 0 or die "processall failed";
 181      }
 182 }
 183
 184 {
 185      package DebbugsTest::HTTPServer;
 186      use base qw(HTTP::Server::Simple::CGI);
 187
 188      our $child_pid = undef;
 189      our $webserver = undef;
 190      our $server_handler = undef;
 191
 192      END {
 193           if (defined $child_pid) {
 194                # stop the child
 195                my $temp_exit = $?;
 196                kill(15,$child_pid);
 197                waitpid(-1,0);
 198                $? = $temp_exit;
 199           }
 200      }
 201
 202      sub fork_and_create_webserver {
 203           my ($handler,$port) = @_;
 204           $port ||= 8080;
 205           if (defined $child_pid) {
 206                die "We appear to have already forked once";
 207           }
 208           $server_handler = $handler;
 209           my $pid = fork;
 210           return 0 if not defined $pid;
 211           if ($pid) {
 212                $child_pid = $pid;
 213                # Wait here for a second to let the child start up
 214                sleep 1;
 215                return $pid;
 216           }
 217           else {
 218                $webserver = DebbugsTest::HTTPServer->new($port);
 219                $webserver->run;
 220           }
 221
 222      }
 223
 224      sub handle_request {
 225           if (defined $server_handler) {
 226                $server_handler->(@_);
 227           }
 228           else {
 229                warn "No handler defined\n";
 230                print "No handler defined\n";
 231           }
 232      }
 233 }
 234
 235 =head2 num_messages_sent
 236
 237      $SD_SIZE = num_messages_sent($SD_SIZE,2,$sendmail_dir,'2 messages have been sent properly');
 238
 239 Tests to make sure that at least a certain number of messages have
 240 been sent since the last time this command was run. Usefull to test to
 241 make sure that mail has been sent.
 242
 243 =cut
 244
 245 sub num_messages_sent {
 246     my ($prev_size,$num_messages,$sendmail_dir,$test_name) = @_;
 247     my $cur_size = dirsize($sendmail_dir);
 248     ## print STDERR "sendmail: $sendmail_dir, want: $num_messages,
 249     ## size: $cur_size, prev_size: $prev_size\n";
 250     ok($cur_size-$prev_size >= $num_messages, $test_name);
 251     return $cur_size;
 252 }
 253
 254
 255 1;
 256
 257 __END__
 258
 259
 260