t/lib/DebbugsTest.pm

   1
   2 package DebbugsTest;
   3
   4 =head1 NAME
   5
   6 DebbugsTest
   7
   8 =head1 SYNOPSIS
   9
  10 use DebbugsTest
  11
  12
  13 =head1 DESCRIPTION
  14
  15 This module contains various testing routines used to test debbugs in
  16 a "pseudo install"
  17
  18 =head1 FUNCTIONS
  19
  20 =cut
  21
  22 use warnings;
  23 use strict;
  24 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT);
  25 use base qw(Exporter);
  26
  27 use IO::File;
  28 use File::Temp qw(tempdir);
  29 use Cwd qw(getcwd);
  30 use Debbugs::MIME qw(create_mime_message);
  31 use File::Basename qw(dirname basename);
  32 use IPC::Open3;
  33 use IO::Handle;
  34 use Test::More;
  35
  36 use Params::Validate qw(validate_with :types);
  37
  38 BEGIN{
  39      $VERSION = 1.00;
  40      $DEBUG = 0 unless defined $DEBUG;
  41
  42      @EXPORT = ();
  43      %EXPORT_TAGS = (configuration => [qw(dirsize create_debbugs_configuration send_message)],
  44                      mail          => [qw(num_messages_sent)],
  45                     );
  46      @EXPORT_OK = ();
  47      Exporter::export_ok_tags(qw(configuration mail));
  48      $EXPORT_TAGS{all} = [@EXPORT_OK];
  49 }
  50
  51 # First, we're going to send mesages to receive.
  52 # To do so, we'll first send a message to submit,
  53 # then send messages to the newly created bugnumber.
  54
  55
  56
  57 sub create_debbugs_configuration {
  58      my %param = validate_with(params => \@_,
  59                                spec   => {debug => {type => BOOLEAN,
  60                                                     default => 0,
  61                                                    },
  62                                           cleanup => {type => BOOLEAN,
  63                                                       optional => 1,
  64                                                      },
  65                                          },
  66                               );
  67      $param{cleanup} = $param{debug}?0:1 if not exists $param{cleanup};
  68      my $sendmail_dir = tempdir(CLEANUP => $param{cleanup});
  69      my $spool_dir = tempdir(CLEANUP => $param{cleanup});
  70      my $config_dir = tempdir(CLEANUP => $param{cleanup});
  71
  72
  73      $ENV{DEBBUGS_CONFIG_FILE}  ="$config_dir/debbugs_config";
  74      $ENV{PERL5LIB} = getcwd();
  75      $ENV{SENDMAIL_TESTDIR} = $sendmail_dir;
  76      my $sendmail_tester = getcwd().'/t/sendmail_tester';
  77      unless (-x $sendmail_tester) {
  78           die q(t/sendmail_tester doesn't exist or isn't executable. You may be in the wrong directory.);
  79      }
  80      my %files_to_create = ("$config_dir/debbugs_config" => <<END,
  81 \$gSendmail='$sendmail_tester';
  82 \$gSpoolDir='$spool_dir';
  83 \$gLibPath='@{[getcwd()]}/scripts';
  84 \$gTemplateDir='@{[getcwd()]}/templates';
  85 \$gWebHost='localhost';
  86 1;
  87 END
  88                             "$spool_dir/nextnumber" => qq(1\n),
  89                             "$config_dir/Maintainers" => qq(foo Blah Bleargh <foo\@baz.com>\nbar Bar Bleargh <bar\@baz.com>\n),
  90                             "$config_dir/Maintainers.override" => qq(),
  91                             "$config_dir/Source_maintainers" => qq(foo Blah Bleargh <foo\@baz.com>\nbar Bar Bleargh <bar\@baz.com>\n),
  92                             "$config_dir/indices/sources" => <<END,
  93 foo main foo
  94 END
  95                             "$config_dir/pseudo-packages.description" => '',
  96                             "$config_dir/pseudo-packages.maint" => '',
  97                            );
  98      while (my ($file,$contents) = each %files_to_create) {
  99           system('mkdir','-p',dirname($file));
 100           my $fh = IO::File->new($file,'w') or
 101                die "Unable to create $file: $!";
 102           print {$fh} $contents or die "Unable to write $contents to $file: $!";
 103           close $fh or die "Unable to close $file: $!";
 104      }
 105
 106      system('touch',"$spool_dir/index.db.realtime");
 107      system('ln','-s','index.db.realtime',
 108             "$spool_dir/index.db");
 109      system('touch',"$spool_dir/index.archive.realtime");
 110      system('ln','-s','index.archive.realtime',
 111             "$spool_dir/index.archive");
 112
 113      # create the spool files and sub directories
 114      map {system('mkdir','-p',"$spool_dir/$_"); }
 115           map {('db-h/'.$_,'archive/'.$_)}
 116                map { sprintf "%02d",$_ % 100} 0..99;
 117      system('mkdir','-p',"$spool_dir/incoming");
 118      system('mkdir','-p',"$spool_dir/lock");
 119
 120      return (spool_dir => $spool_dir,
 121              sendmail_dir => $sendmail_dir,
 122              config_dir => $config_dir,
 123             );
 124 }
 125
 126 sub dirsize{
 127      my ($dir) = @_;
 128      opendir(DIR,$dir);
 129      my @content = grep {!/^\.\.?$/} readdir(DIR);
 130      closedir(DIR);
 131      return scalar @content;
 132 }
 133
 134
 135 # We're going to use create mime message to create these messages, and
 136 # then just send them to receive.
 137 # First, check that submit@ works
 138
 139 sub send_message{
 140      my %param = validate_with(params => \@_,
 141                                spec   => {to => {type => SCALAR,
 142                                                  default => 'submit@bugs.something',
 143                                                 },
 144                                           headers => {type => ARRAYREF,
 145                                                      },
 146                                           body    => {type => SCALAR,
 147                                                      },
 148                                           run_processall =>{type => BOOLEAN,
 149                                                             default => 1,
 150                                                            },
 151                                          }
 152                               );
 153      $ENV{LOCAL_PART} = $param{to};
 154      my ($rfd,$wfd);
 155      my $output='';
 156      local $SIG{PIPE} = 'IGNORE';
 157      local $SIG{CHLD} = sub {};
 158      my $pid = open3($wfd,$rfd,$rfd,'scripts/receive')
 159           or die "Unable to start receive: $!";
 160      print {$wfd} create_mime_message($param{headers},
 161                                          $param{body}) or die "Unable to to print to receive";
 162      close($wfd) or die "Unable to close receive";
 163      my $err = $? >> 8;
 164      my $childpid = waitpid($pid,0);
 165      if ($childpid != -1) {
 166           $err = $? >> 8;
 167           print STDERR "receive pid: $pid doesn't match childpid: $childpid\n" if $childpid != $pid;
 168      }
 169      if ($err != 0 ) {
 170           my $rfh =  IO::Handle->new_from_fd($rfd,'r') or die "Unable to create filehandle: $!";
 171           $rfh->blocking(0);
 172           my $rv;
 173           while ($rv = $rfh->sysread($output,1000,length($output))) {}
 174           if (not defined $rv) {
 175                print STDERR "Reading from STDOUT/STDERR would have blocked.";
 176           }
 177           print STDERR $output,qq(\n);
 178           die "receive failed with exit status $err";
 179      }
 180      # now we should run processall to see if the message gets processed
 181      if ($param{run_processall}) {
 182           system('scripts/processall') == 0 or die "processall failed";
 183      }
 184 }
 185
 186 {
 187      package DebbugsTest::HTTPServer;
 188      use base qw(HTTP::Server::Simple::CGI);
 189
 190      our $child_pid = undef;
 191      our $webserver = undef;
 192      our $server_handler = undef;
 193
 194      END {
 195           if (defined $child_pid) {
 196                # stop the child
 197                my $temp_exit = $?;
 198                kill(15,$child_pid);
 199                waitpid(-1,0);
 200                $? = $temp_exit;
 201           }
 202      }
 203
 204      sub fork_and_create_webserver {
 205           my ($handler,$port) = @_;
 206           $port ||= 8080;
 207           if (defined $child_pid) {
 208                die "We appear to have already forked once";
 209           }
 210           $server_handler = $handler;
 211           my $pid = fork;
 212           return 0 if not defined $pid;
 213           if ($pid) {
 214                $child_pid = $pid;
 215                # Wait here for a second to let the child start up
 216                sleep 1;
 217                return $pid;
 218           }
 219           else {
 220                $webserver = DebbugsTest::HTTPServer->new($port);
 221                $webserver->run;
 222           }
 223
 224      }
 225
 226      sub handle_request {
 227           if (defined $server_handler) {
 228                $server_handler->(@_);
 229           }
 230           else {
 231                warn "No handler defined\n";
 232                print "No handler defined\n";
 233           }
 234      }
 235 }
 236
 237 =head2 num_messages_sent
 238
 239      $SD_SIZE = num_messages_sent($SD_SIZE,2,$sendmail_dir,'2 messages have been sent properly');
 240
 241 Tests to make sure that at least a certain number of messages have
 242 been sent since the last time this command was run. Usefull to test to
 243 make sure that mail has been sent.
 244
 245 =cut
 246
 247 sub num_messages_sent {
 248     my ($prev_size,$num_messages,$sendmail_dir,$test_name) = @_;
 249     my $cur_size = dirsize($sendmail_dir);
 250     ## print STDERR "sendmail: $sendmail_dir, want: $num_messages,
 251     ## size: $cur_size, prev_size: $prev_size\n";
 252     ok($cur_size-$prev_size >= $num_messages, $test_name);
 253     return $cur_size;
 254 }
 255
 256
 257 1;
 258
 259 __END__
 260
 261
 262